development/autotests/ExportTests.cmake

   1 #
   2 #  Copyright (c) 2014 Kornel Benko <kornel@lyx.org>
   3 #  Copyright (c) 2014 Scott Kostyshak <skotysh@lyx.org>
   4 #
   5 #  Redistribution and use in source and binary forms, with or without
   6 #  modification, are permitted provided that the following conditions
   7 #  are met:
   8 #
   9 #  1. Redistributions of source code must retain the copyright
  10 #         notice, this list of conditions and the following disclaimer.
  11 #  2. Redistributions in binary form must reproduce the copyright
  12 #         notice, this list of conditions and the following disclaimer in the
  13 #         documentation and/or other materials provided with the distribution.
  14 #  3. The name of the author may not be used to endorse or promote products
  15 #         derived from this software without specific prior written permission.
  16 #
  17 #  THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  18 #  IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19 #  OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20 #  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  21 #  INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  22 #  NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  23 #  DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  24 #  THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  25 #  (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  26 #  THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27 #
  28
  29 find_package(Perl)
  30
  31 if(PERL_FOUND)
  32   set(DVI_FORMATS "dvi" "dvi3")
  33   set(PDF_FORMATS "pdf" "pdf2" "pdf3" "pdf4" "pdf5")
  34 else()
  35   set(DVI_FORMATS "dvi")
  36   set(PDF_FORMATS "pdf" "pdf2" "pdf3")
  37 endif()
  38
  39 macro(getoutputformats filepath varname)
  40   file(STRINGS "${filepath}" lines)
  41   # What should we test, if default_output_format is not defined?
  42   # For now we test everything ...
  43   set(out_formats "xhtml" ${DVI_FORMATS} ${PDF_FORMATS})
  44   foreach(_l ${lines})
  45     if(_l MATCHES "^\\\\default_output_format +\([^ ]+\)")
  46       set(_format ${CMAKE_MATCH_1})
  47       if(_format STREQUAL "default")
  48         set(out_formats "xhtml" ${DVI_FORMATS} ${PDF_FORMATS})
  49       elseif(_format MATCHES "pdf$")
  50         set(out_formats "xhtml" ${PDF_FORMATS})
  51       elseif(_format MATCHES "dvi$")
  52         set(out_formats "xhtml" ${DVI_FORMATS})
  53       elseif(_format MATCHES "xhtml")
  54         set(out_formats "xhtml")
  55       else()
  56         # Respect all other output formats
  57         # like "eps3"
  58         set(out_formats "xhtml" ${_format})
  59       endif()
  60       break()
  61     endif()
  62   endforeach()
  63   set(${varname} ${out_formats})
  64 endmacro()
  65
  66 macro(findexpr found testname listname rsublabel)
  67   set(_found 0)
  68   set(sublabel "")
  69   foreach(_itrx ${${listname}})
  70     if ("${_itrx}" MATCHES "^Sublabel:")
  71       set(sublabel "")
  72       string(REGEX REPLACE "^Sublabel:[ \t]*" "" _itrlabels ${_itrx})
  73       string(REGEX MATCHALL "([a-zA-Z]+)" _labels ${_itrlabels})
  74       foreach(subl ${_labels})
  75         if (subl STREQUAL "RESET")
  76           set(sublabel "")
  77         else()
  78           list(APPEND sublabel ${subl})
  79         endif()
  80       endforeach()
  81       # remove doubles in sublabel
  82       list(REMOVE_DUPLICATES sublabel)
  83     else()
  84       set(_itr "^${_itrx}$")
  85       if (${testname} MATCHES "${_itr}")
  86         set(_found 1)
  87         break()
  88       endif()
  89     endif()
  90   endforeach()
  91   if (${_found})
  92     if (NOT "${sublabel}" STREQUAL "")
  93       set(${rsublabel} ${sublabel})
  94     endif()
  95   endif()
  96   set(${found} ${_found})
  97 endmacro()
  98
  99 function(join rvalues glue routput)
 100   string(REGEX REPLACE "([^\\]|^);" "\\1${glue}" out "${${rvalues}}")
 101   set(${routput} ${out} PARENT_SCOPE)
 102 endfunction()
 103
 104 macro(maketestname testname reverted listreverted listignored listunreliable listlabels)
 105   set(sublabel "")
 106   string(REGEX MATCH "\\/[a-z][a-z](_[A-Z][A-Z])?\\/" _v ${${testname}})
 107   if(_v)
 108     string(REGEX REPLACE "\\/" "" _v ${_v})
 109     set(listrevertedx ${listreverted}_${_v})
 110     set(listignoredx ${listignored}_${_v})
 111     set(listunreliablex ${listunreliable}_${_v})
 112   else()
 113     set(listrevertedx ${listreverted})
 114     set(listignoredx ${listignored})
 115     set(listunreliablex ${listunreliable})
 116   endif()
 117   findexpr(mfound ${testname} ${listignoredx} sublabel)
 118   if (NOT mfound)
 119     # check if they are unreliable
 120     set(sublabel "")
 121     findexpr(nsfound ${testname} ${listunreliablex} sublabel)
 122     if (nsfound)
 123       if (NOT "${sublabel}" STREQUAL "")
 124         list(APPEND ${listlabels} ${sublabel})
 125         join(sublabel "." tmpprefixx)
 126         string(TOUPPER "${tmpprefixx}_" tmpprefix)
 127       else()
 128         set(tmpprefix "")
 129       endif()
 130       set(${testname} "UNRELIABLE.${tmpprefix}${${testname}}")
 131     else ()
 132       string(REGEX MATCH "_(systemF|texF|pdf3|pdf2|pdf|dvi|lyx16|xhtml)$" _v ${${testname}})
 133       set(sublabel "")
 134       # check if test _may_ be in listreverted
 135       if (_v)
 136         findexpr(mfound ${testname} ${listrevertedx} sublabel)
 137       else()
 138         set(mfound OFF)
 139       endif()
 140       if (NOT mfound)
 141         set(${reverted} 0)
 142       else()
 143         set(${reverted} 1)
 144         if (NOT sublabel STREQUAL "")
 145           string(TOUPPER "${sublabel}_" tmpprefix)
 146         else()
 147           set(tmpprefix "ctest_")
 148         endif()
 149         set(${testname} "INVERTED_SEE-README.${tmpprefix}${${testname}}")
 150         if (NOT sublabel STREQUAL "")
 151           list(APPEND ${listlabels} ${sublabel})
 152         endif()
 153       endif()
 154     endif()
 155   else()
 156     set(${testname} "")
 157   endif()
 158 endmacro()
 159
 160 # This labels should not be used in .*Tests files
 161 set(known_labels "export" "key" "layout" "load" "lyx2lyx"
 162   "examples" "manuals" "mathmacros" "reverted" "templates" "unreliable" "suspended"
 163   "module" "roundtrip" "url")
 164
 165 macro(loadTestList filename resList)
 166   # Create list of strings from a file without comments
 167   # ENCODING parameter is a new feature in cmake 3.1
 168   if (CMAKE_VERSION VERSION_GREATER "3.1")
 169     file(STRINGS ${filename} tempList ENCODING "UTF-8")
 170   else()
 171     file(STRINGS ${filename} tempList)
 172   endif()
 173   set(${resList})
 174   set(sublabel)
 175   set(mylabels "")
 176   foreach(_l ${tempList})
 177     set(_newl "${_l}")
 178     string(REGEX REPLACE "[ \t]*#.*$" "" _newl "${_l}")
 179     if(_newl)
 180       string(REGEX REPLACE "(\\/|\\||\\(|\\))" "  " _vxx ${_newl})
 181       string(REGEX MATCHALL " ([a-z][a-z](_[A-Z][A-Z])?) " _vx ${_vxx})
 182       if (_newl MATCHES "^Sublabel:")
 183         string(REGEX REPLACE "^Sublabel:[ \t]*" "" _newlabels ${_newl})
 184         string(REGEX MATCHALL "([a-zA-Z]+)" _labels ${_newlabels})
 185         foreach(labname ${_labels})
 186           if (NOT labname STREQUAL "RESET")
 187             list(REMOVE_ITEM mylabels ${labname})
 188             list(APPEND mylabels ${labname})
 189           endif()
 190         endforeach()
 191         set(sublabel ${_newl})
 192       endif()
 193       if(_vx)
 194         foreach(_v ${_vx})
 195           string(REGEX REPLACE " " "" _v ${_v})
 196           #message(STATUS " ==> ${resList}_${_v}")
 197           if (NOT ${sublabel} STREQUAL "${sublabel}_${_v}")
 198             list(APPEND ${resList}_${_v} "${sublabel}")
 199             set(${sublabel}_${_v} "${sublabel}")
 200           endif()
 201           list(APPEND ${resList}_${_v} "${_newl}")
 202         endforeach()
 203         if(_newl MATCHES "\\(\\|")
 204           #message(STATUS " ==> ${resList}")
 205           list(APPEND ${resList} "${_newl}")
 206         endif()
 207       else()
 208         #message(STATUS " ==> ${resList}")
 209         list(APPEND ${resList} "${_newl}")
 210       endif()
 211     endif()
 212   endforeach()
 213   foreach(_l ${mylabels})
 214     list(FIND known_labels ${_l} _ff)
 215     if (_ff GREATER -1)
 216       message(STATUS "Label \"${_l}\" already in use. Reused in ${filename}")
 217     else()
 218       list(APPEND known_labels ${_l})
 219     endif()
 220   endforeach()
 221 endmacro()
 222
 223 loadTestList(revertedTests revertedTests)
 224 loadTestList(ignoredTests ignoredTests)
 225 loadTestList(suspendedTests suspendedTests)
 226 loadTestList(unreliableTests unreliableTests)
 227
 228 macro(handlesuspended TestName reverted testlabel)
 229   set(mylabel ${${testlabel}})
 230   set(myreverted ${reverted})
 231   set(sublabel)
 232
 233   # check for unreliable
 234   if ("${TestName}" MATCHES "^UNRELIABLE")
 235     list(REMOVE_ITEM mylabel "export" "reverted" "templates" "mathmacros" "manuals")
 236     list(APPEND mylabel "unreliable")
 237     set(myreverted 0)
 238   elseif (${reverted})
 239     # check suspension only for reverted tests
 240     findexpr(tfound TestName suspendedTests sublabel)
 241     if (tfound)
 242       set(mylabel "suspended")
 243       if (sublabel)
 244         list(APPEND mylabel ${sublabel})
 245       endif()
 246       set(myreverted 0) # if test is to be suspended, remove the 'reverted' flag
 247     endif()
 248   endif()
 249   setmarkedtestlabel(${TestName} ${myreverted} ${mylabel})
 250 endmacro()
 251
 252 # preparing to add e.g. development/mathmacros to the foreach() loop
 253 foreach(libsubfolderx lib/doc lib/examples lib/templates development/mathmacros autotests/export)
 254   set(testlabel "export")
 255   if (libsubfolderx MATCHES "lib/doc")
 256     list(APPEND testlabel "manuals")
 257   elseif (libsubfolderx MATCHES "lib/examples")
 258     list(APPEND testlabel "examples")
 259   elseif (libsubfolderx MATCHES "lib/templates")
 260     list(APPEND testlabel "templates")
 261   elseif (libsubfolderx MATCHES "development/mathmacros")
 262     list(APPEND testlabel "mathmacros")
 263   elseif (libsubfolderx MATCHES "autotests/.+")
 264     list(APPEND testlabel "autotests")
 265   endif()
 266   set(LIBSUB_SRC_DIR "${TOP_SRC_DIR}/${libsubfolderx}")
 267   string(REGEX REPLACE "^(lib|development|autotests)/" "" libsubfolder "${libsubfolderx}")
 268   set(LIBSUB_SRC_DIR "${TOP_SRC_DIR}/${libsubfolderx}")
 269   message(STATUS "Handling export dir ${LIBSUB_SRC_DIR}")
 270   file(GLOB_RECURSE lyx_files RELATIVE "${LIBSUB_SRC_DIR}" "${LIBSUB_SRC_DIR}/*.lyx")
 271   list(SORT lyx_files)
 272   # Now create 2 lists. One for files in a language dir, one without
 273   set(lang_lyx_files)
 274   set(nolang_lyx_files)
 275   foreach(f ${lyx_files})
 276     string(REGEX MATCHALL "^[a-z][a-z](_[A-Z][A-Z])?\\/" _v ${f})
 277     if(_v)
 278       list(APPEND lang_lyx_files ${f})
 279     else()
 280       list(APPEND nolang_lyx_files ${f})
 281     endif()
 282   endforeach()
 283   foreach(f ${nolang_lyx_files} ${lang_lyx_files})
 284     # Strip extension
 285     string(REGEX REPLACE "\\.lyx$" "" f ${f})
 286     set(TestName "export/${libsubfolder}/${f}_lyx16")
 287     set(mytestlabel ${testlabel})
 288     maketestname(TestName reverted revertedTests ignoredTests unreliableTests mytestlabel)
 289     if(TestName)
 290       add_test(NAME ${TestName}
 291         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 292         COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 293         -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 294         -Dlyx=$<TARGET_FILE:${_lyx}>
 295         -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 296         -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
 297         -Dformat=lyx16x
 298         -Dextension=16.lyx
 299         -Dfile=${f}
 300         -Dreverted=${reverted}
 301         -DTOP_SRC_DIR=${TOP_SRC_DIR}
 302         -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
 303         -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 304       handlesuspended(${TestName} ${reverted} mytestlabel) # checking for suspended lyx16 exports
 305     endif()
 306     if(LYX_PYTHON_EXECUTABLE)
 307       set(lyx2lyxtestlabel "lyx2lyx")
 308       # For use of lyx2lyx we need the python executable
 309       set(mytestlabel ${lyx2lyxtestlabel})
 310       set(TestName "lyx2lyx/${libsubfolder}/${f}")
 311       maketestname(TestName reverted revertedTests ignoredTests unreliableTests mytestlabel)
 312       if(TestName)
 313         add_test(NAME ${TestName}
 314           WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 315           COMMAND ${CMAKE_COMMAND}
 316           "-DLYX_PYTHON_EXECUTABLE=${LYX_PYTHON_EXECUTABLE}"
 317           "-DLYX2LYX=${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx"
 318           "-DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}"
 319           "-DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx"
 320           -P "${TOP_SRC_DIR}/development/autotests/lyx2lyxtest.cmake")
 321         handlesuspended(${TestName} ${reverted} mytestlabel)
 322       endif()
 323     endif()
 324     set(loadtestlabel "load")
 325     set(mytestlabel ${loadtestlabel})
 326     set(TestName "check_load/${libsubfolder}/${f}")
 327     maketestname(TestName reverted revertedTests ignoredTests unreliableTests mytestlabel)
 328     if(TestName)
 329       add_test(NAME ${TestName}
 330         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 331         COMMAND ${CMAKE_COMMAND} -DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx
 332         -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 333         -Dlyx=$<TARGET_FILE:${_lyx}>
 334         -DPARAMS_DIR=${TOP_SRC_DIR}/development/autotests
 335         -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 336         -P "${TOP_SRC_DIR}/development/autotests/check_load.cmake")
 337       handlesuspended(${TestName} ${reverted} mytestlabel)
 338       set_tests_properties(${TestName} PROPERTIES RUN_SERIAL ON)
 339     endif()
 340     getoutputformats("${LIBSUB_SRC_DIR}/${f}.lyx" formatlist)
 341     foreach(format ${formatlist})
 342       if(format MATCHES "dvi3|pdf4|pdf5")
 343         set(fonttypes "texF" "systemF")
 344       else()
 345         set(fonttypes "defaultF")
 346       endif()
 347       foreach(fonttype ${fonttypes})
 348         if(fonttype MATCHES "defaultF")
 349           set(TestName "export/${libsubfolder}/${f}_${format}")
 350         else()
 351           set(TestName "export/${libsubfolder}/${f}_${format}_${fonttype}")
 352         endif()
 353         set(mytestlabel ${testlabel})
 354         maketestname(TestName reverted revertedTests ignoredTests unreliableTests mytestlabel)
 355         if(TestName)
 356           add_test(NAME ${TestName}
 357             WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 358             COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 359             -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 360             -Dlyx=$<TARGET_FILE:${_lyx}>
 361             -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 362             -Dformat=${format}
 363             -Dfonttype=${fonttype}
 364             -Dextension=${format}
 365             -Dfile=${f}
 366             -Dreverted=${reverted}
 367             -DTOP_SRC_DIR=${TOP_SRC_DIR}
 368             -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
 369             -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 370           handlesuspended(${TestName} ${reverted} mytestlabel) # check for suspended pdf/dvi exports
 371         endif()
 372       endforeach()
 373     endforeach()
 374   endforeach()
 375 endforeach()