development/autotests/ExportTests.cmake

   1 #
   2 #  Copyright (c) 2014 Kornel Benko <kornel@lyx.org>
   3 #  Copyright (c) 2014 Scott Kostyshak <skotysh@lyx.org>
   4 #
   5 #  Redistribution and use in source and binary forms, with or without
   6 #  modification, are permitted provided that the following conditions
   7 #  are met:
   8 #
   9 #  1. Redistributions of source code must retain the copyright
  10 #         notice, this list of conditions and the following disclaimer.
  11 #  2. Redistributions in binary form must reproduce the copyright
  12 #         notice, this list of conditions and the following disclaimer in the
  13 #         documentation and/or other materials provided with the distribution.
  14 #  3. The name of the author may not be used to endorse or promote products
  15 #         derived from this software without specific prior written permission.
  16 #
  17 #  THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  18 #  IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19 #  OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20 #  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  21 #  INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  22 #  NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  23 #  DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  24 #  THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  25 #  (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  26 #  THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27 #
  28
  29 find_package(Perl)
  30 find_program(XMLLINT_EXECUTABLE xmllint)
  31
  32 if(PERL_FOUND)
  33   set(DVI_FORMATS "dvi" "dvi3")
  34   set(PDF_FORMATS "pdf" "pdf2" "pdf3" "pdf4" "pdf5")
  35 else()
  36   set(DVI_FORMATS "dvi")
  37   set(PDF_FORMATS "pdf" "pdf2" "pdf3")
  38 endif()
  39
  40 set(potential_languages "ca" "cs" "da" "de" "el" "es" "eu" "fa" "fr" "gl" "he" "hu" "id" "it" "ja" "ko" "nb" "nl" "pl" "pt" "ro" "ru" "sk" "sl" "sr" "sv" "uk" "zh_CN")
  41
  42 # Used to select labels from .*Tests files
  43 set(label_chars "[a-zA-Z:_]+")
  44
  45 macro(initLangVars varname)
  46   foreach(_l ${potential_languages})
  47     set(${varname}_${_l})
  48   endforeach()
  49 endmacro()
  50
  51 macro(getoutputformats filepath varname)
  52   file(STRINGS "${filepath}" lines)
  53   # What should we test, if default_output_format is not defined?
  54   # For now we test everything ...
  55   set(out_formats "xhtml" ${DVI_FORMATS} ${PDF_FORMATS})
  56   foreach(_l ${lines})
  57     if(_l MATCHES "^\\\\default_output_format +\([^ ]+\)")
  58       set(_format ${CMAKE_MATCH_1})
  59       if(_format STREQUAL "default")
  60         set(out_formats "xhtml" ${DVI_FORMATS} ${PDF_FORMATS})
  61       elseif(_format STREQUAL "pdf2" AND "${filepath}" MATCHES "/doc/")
  62         set(out_formats "xhtml" ${DVI_FORMATS} ${PDF_FORMATS})
  63       elseif(_format MATCHES "pdf$")
  64         set(out_formats "xhtml" ${PDF_FORMATS})
  65       elseif(_format MATCHES "dvi$")
  66         set(out_formats "xhtml" ${DVI_FORMATS})
  67       elseif(_format MATCHES "xhtml")
  68         set(out_formats "xhtml")
  69       else()
  70         # Respect all other output formats
  71         # like "eps3"
  72         set(out_formats "xhtml" ${_format})
  73       endif()
  74       break()
  75     endif()
  76   endforeach()
  77   set(${varname} ${out_formats})
  78 endmacro()
  79
  80 macro(findexpr found testname listname rsublabel)
  81   set(_found 0)
  82   set(tmpsublabel "")
  83   foreach(_itrx ${${listname}})
  84     if ("${_itrx}" MATCHES "^Sublabel:")
  85       set(tmpsublabel "")
  86       string(REGEX REPLACE "^Sublabel:[ \t]*" "" _itrlabels ${_itrx})
  87       string(REGEX MATCHALL ${label_chars} _labels ${_itrlabels})
  88       foreach(subl ${_labels})
  89         if (subl STREQUAL "RESET")
  90           set(tmpsublabel "")
  91         else()
  92           list(APPEND tmpsublabel ${subl})
  93         endif()
  94       endforeach()
  95       # remove doubles in sublabel
  96       list(REMOVE_DUPLICATES tmpsublabel)
  97     else()
  98       set(_itr "^${_itrx}$")
  99       if (${testname} MATCHES "${_itr}")
 100         set(_found 1)
 101         break()
 102       endif()
 103     endif()
 104   endforeach()
 105   if (${_found})
 106     if (NOT "${tmpsublabel}" STREQUAL "")
 107       list(APPEND ${rsublabel} ${tmpsublabel})
 108     endif()
 109   endif()
 110   set(${found} ${_found})
 111 endmacro()
 112
 113 function(join rvalues glue routput)
 114   set(locallist ${${rvalues}})
 115   set(removelist "export" "lyx2lyx" "load")
 116   foreach(_l ${locallist})
 117     if (depth_${_l} LESS 0)
 118       list(APPEND removelist ${_l})
 119     endif()
 120   endforeach()
 121   list(REMOVE_ITEM locallist ${removelist})
 122   string(REGEX REPLACE "([^\\]|^);" "\\1${glue}" out "${locallist}")
 123   set(${routput} ${out} PARENT_SCOPE)
 124 endfunction()
 125
 126 macro(maketestname testname inverted listinverted listignored listunreliable listlabels)
 127   # initialize output variable
 128   set(${inverted} 0)
 129   string(REGEX MATCH "\\/[a-z][a-z](_[A-Z][A-Z])?\\/" _v ${${testname}})
 130   if(_v)
 131     string(REGEX REPLACE "\\/" "" _v ${_v})
 132     set(listinvertedx ${listinverted}_${_v})
 133     set(listignoredx ${listignored}_${_v})
 134     set(listunreliablex ${listunreliable}_${_v})
 135     set(listsuspendedx suspendedTests_${_v})
 136   else()
 137     set(listinvertedx ${listinverted})
 138     set(listignoredx ${listignored})
 139     set(listunreliablex ${listunreliable})
 140     set(listsuspendedx suspendedTests)
 141   endif()
 142   set(sublabel "${${listlabels}}")
 143   findexpr(mfound ${testname} ${listignoredx} sublabel)
 144   if (NOT mfound)
 145     set(sublabel2 "")
 146     findexpr(foundunreliable ${testname} ${listunreliablex} sublabel2)
 147     if (foundunreliable)
 148       set(sublabel "unreliable" ${sublabel} ${sublabel2})
 149       list(REMOVE_ITEM sublabel "export" "inverted" "templates" "mathmacros" "manuals" "autotests")
 150     endif()
 151     string(REGEX MATCH "(^check_load|_(systemF|texF|pdf3|pdf2|pdf|dvi|lyx[0-9][0-9]|xhtml)$)" _v ${${testname}})
 152     # check if test _may_ be in listinverted
 153     set(sublabel2 "")
 154     if (_v)
 155       findexpr(mfound ${testname} ${listinvertedx} sublabel2)
 156     else()
 157       set(mfound OFF)
 158     endif()
 159     if (mfound)
 160       set(sublabel3 "")
 161       findexpr(foundsuspended ${testname} ${listsuspendedx} sublabel3)
 162       set(${inverted} 1)
 163       if (foundsuspended)
 164         set(sublabel "suspended" ${sublabel} ${sublabel2} ${sublabel3})
 165         list(REMOVE_ITEM sublabel "export" "inverted" )
 166       else()
 167         set(sublabel "inverted" ${sublabel} ${sublabel2} ${sublabel3})
 168       endif()
 169     else()
 170       set(${inverted} 0)
 171     endif()
 172     list(REMOVE_DUPLICATES sublabel)
 173     if (NOT sublabel STREQUAL "")
 174       join(sublabel "." tmpprefixx)
 175       if (tmpprefixx)
 176         string(TOUPPER "${tmpprefixx}_" tmpprefix)
 177       else()
 178         set(tmpprefix "")
 179       endif()
 180       set(${testname} "${tmpprefix}${${testname}}")
 181       set(${listlabels} ${sublabel})
 182     endif()
 183   else()
 184     # No testname because ignored
 185     set(${testname} "")
 186   endif()
 187 endmacro()
 188
 189 macro(loadTestList filename resList depth)
 190   # Create list of strings from a file without comments
 191   # ENCODING parameter is a new feature in cmake 3.1
 192   initLangVars(${resList})
 193   initLangVars("sublabel")
 194   if (CMAKE_VERSION VERSION_GREATER "3.1")
 195     file(STRINGS ${filename} tempList ENCODING "UTF-8")
 196   else()
 197     file(STRINGS ${filename} tempList)
 198   endif()
 199   set(${resList})
 200   set(sublabel)
 201   set(mylabels "")
 202   set(languages "")
 203   message(STATUS "Reading list ${filename}")
 204   foreach(_l ${tempList})
 205     set(_newl "${_l}")
 206     string(REGEX REPLACE "[ \t]+$" "" _newl "${_l}")
 207     string(REGEX REPLACE "[ \t]*#.*$" "" _newl "${_l}")
 208     if(_newl)
 209       list(APPEND ${resList} "${_newl}")
 210       if (_newl MATCHES "^Sublabel:")
 211         string(REGEX REPLACE "^Sublabel:[ \t]*" "" _newlabels ${_newl})
 212         string(REGEX MATCHALL "([0-9]*${label_chars})" _labels ${_newlabels})
 213         foreach(labname ${_labels})
 214           if (NOT labname STREQUAL "RESET")
 215             list(APPEND mylabels ${labname})
 216           endif()
 217         endforeach()
 218         list(REMOVE_DUPLICATES mylabels)
 219         set(sublabel ${_newl})
 220       else()
 221         string(REGEX REPLACE "(\\/|\\||\\(|\\))" "  " _vxx ${_newl})
 222         string(REGEX MATCHALL " ([a-z][a-z](_[A-Z][A-Z])?) " _vx ${_vxx})
 223         if(_vx)
 224           foreach(_v ${_vx})
 225             string(REGEX REPLACE " " "" _v ${_v})
 226             #message(STATUS " ==> ${resList}_${_v}")
 227             #message(STATUS "sublabel = ${sublabel}, sublabel_${_v} = ${sublabel_${_v}}")
 228             if (NOT sublabel STREQUAL "${sublabel_${_v}}")
 229               list(APPEND ${resList}_${_v} "${sublabel}")
 230               set(sublabel_${_v} "${sublabel}")
 231               #message(STATUS "Setting variable sublabel_${_v} with \"${sublabel}\"")
 232             endif()
 233             list(APPEND ${resList}_${_v} "${_newl}")
 234             list(APPEND languages ${_v})
 235           endforeach()
 236           list(REMOVE_DUPLICATES languages)
 237           #message(STATUS "languages = ${languages}")
 238         endif()
 239       endif()
 240     endif()
 241   endforeach()
 242   foreach(_l1 ${mylabels})
 243     if (_l1 MATCHES "^([0-9]+)(${label_chars})$")
 244       set(_l ${CMAKE_MATCH_2})
 245       set(depth1 ${CMAKE_MATCH_1})
 246     else()
 247       set(_l ${_l1})
 248       set(depth1 "0")
 249     endif()
 250     list(FIND known_labels ${_l} _ff)
 251     if (_ff GREATER -1)
 252       message(STATUS "Label \"${_l}\" already in use. Reused in ${filename}")
 253     else()
 254       assignLabelDepth(${depth}${depth1} ${_l})
 255     endif()
 256   endforeach()
 257   foreach(_lg ${languages})
 258     # reset label for each used language string at end of file
 259     #message(STATUS "Resetting variable sublabel_${_lg}, previously set to ${sublabel_${_lg}}")
 260     set(sublabel_${_lg} "")
 261   endforeach()
 262 endmacro()
 263
 264 # This labels should not be used in .*Tests files
 265 set(known_labels "")
 266 # Create depth info to each label
 267 macro(assignLabelDepth depth)
 268   foreach(_lab ${ARGN})
 269     list(APPEND known_labels ${_lab})
 270     set(depth_${_lab} ${depth})
 271   endforeach()
 272 endmacro()
 273
 274 assignLabelDepth(0 "export" "key" "layout" "load" "lyx2lyx" "module" "roundtrip" "url")
 275 assignLabelDepth(1 "unreliable" "inverted")
 276 assignLabelDepth(2 "suspended")
 277 assignLabelDepth(-1 "examples" "manuals" "mathmacros" "templates" "autotests")
 278
 279 loadTestList(invertedTests invertedTests 7)
 280 loadTestList(ignoredTests ignoredTests 0)
 281 loadTestList(suspendedTests suspendedTests 6)
 282 loadTestList(unreliableTests unreliableTests 5)
 283
 284 foreach(libsubfolderx autotests/export lib/doc lib/examples lib/templates autotests/mathmacros)
 285   set(testlabel "export")
 286   if (libsubfolderx MATCHES "lib/doc")
 287     list(APPEND testlabel "manuals")
 288   elseif (libsubfolderx MATCHES "lib/examples")
 289     list(APPEND testlabel "examples")
 290   elseif (libsubfolderx MATCHES "lib/templates")
 291     list(APPEND testlabel "templates")
 292   elseif (libsubfolderx MATCHES "autotests/mathmacros")
 293     list(APPEND testlabel "mathmacros")
 294   elseif (libsubfolderx MATCHES "autotests/.+")
 295     list(APPEND testlabel "autotests")
 296   endif()
 297   set(LIBSUB_SRC_DIR "${TOP_SRC_DIR}/${libsubfolderx}")
 298   string(REGEX REPLACE "^(lib|development|autotests)/" "" libsubfolder "${libsubfolderx}")
 299   set(LIBSUB_SRC_DIR "${TOP_SRC_DIR}/${libsubfolderx}")
 300   message(STATUS "Handling export dir ${LIBSUB_SRC_DIR}")
 301   file(GLOB_RECURSE lyx_files RELATIVE "${LIBSUB_SRC_DIR}" "${LIBSUB_SRC_DIR}/*.lyx")
 302   list(SORT lyx_files)
 303   # Now create 2 lists. One for files in a language dir, one without
 304   set(lang_lyx_files)
 305   set(nolang_lyx_files)
 306   foreach(f ${lyx_files})
 307     string(REGEX MATCHALL "^[a-z][a-z](_[A-Z][A-Z])?\\/" _v ${f})
 308     if(_v)
 309       list(APPEND lang_lyx_files ${f})
 310     else()
 311       list(APPEND nolang_lyx_files ${f})
 312     endif()
 313   endforeach()
 314   foreach(f ${nolang_lyx_files} ${lang_lyx_files})
 315     # Strip extension
 316     string(REGEX REPLACE "\\.lyx$" "" f ${f})
 317     foreach(_lyx_format_num 16 21 22)
 318       set(TestName "export/${libsubfolder}/${f}_lyx${_lyx_format_num}")
 319       set(mytestlabel ${testlabel} "lyx2lyx" "load")
 320       maketestname(TestName inverted invertedTests ignoredTests unreliableTests mytestlabel)
 321       if(TestName)
 322         add_test(NAME ${TestName}
 323           WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 324           COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 325           -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 326           -Dlyx=$<TARGET_FILE:${_lyx}>
 327           -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 328           -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
 329           -Dformat=lyx${_lyx_format_num}x
 330           -Dextension=${_lyx_format_num}.lyx
 331           -DLYX_FORMAT_NUM=${_lyx_format_num}
 332           -Dfile=${f}
 333           -Dinverted=${inverted}
 334           -DTOP_SRC_DIR=${TOP_SRC_DIR}
 335           -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
 336           -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 337         setmarkedtestlabel(${TestName} ${mytestlabel})
 338       endif()
 339     endforeach()
 340     if(LYX_PYTHON_EXECUTABLE)
 341       set(lyx2lyxtestlabel "lyx2lyx")
 342       # For use of lyx2lyx we need the python executable
 343       set(mytestlabel ${lyx2lyxtestlabel})
 344       set(TestName "lyx2lyx/${libsubfolder}/${f}")
 345       maketestname(TestName inverted invertedTests ignoredTests unreliableTests mytestlabel)
 346       if(TestName)
 347         add_test(NAME ${TestName}
 348           WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 349           COMMAND ${CMAKE_COMMAND}
 350           "-DLYX_PYTHON_EXECUTABLE=${LYX_PYTHON_EXECUTABLE}"
 351           "-DLYX2LYX=${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx"
 352           "-DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}"
 353           "-DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx"
 354           -P "${TOP_SRC_DIR}/development/autotests/lyx2lyxtest.cmake")
 355         setmarkedtestlabel(${TestName} ${mytestlabel})
 356       endif()
 357     endif()
 358     set(loadtestlabel "load")
 359     set(mytestlabel ${loadtestlabel})
 360     set(TestName "check_load/${libsubfolder}/${f}")
 361     maketestname(TestName inverted invertedTests ignoredTests unreliableTests mytestlabel)
 362     if(TestName)
 363       add_test(NAME ${TestName}
 364         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 365         COMMAND ${CMAKE_COMMAND} -DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx
 366         -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 367         -Dlyx=$<TARGET_FILE:${_lyx}>
 368         -DPARAMS_DIR=${TOP_SRC_DIR}/development/autotests
 369         -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 370         -Dinverted=${inverted}
 371         -P "${TOP_SRC_DIR}/development/autotests/check_load.cmake")
 372       setmarkedtestlabel(${TestName} ${mytestlabel})
 373       #set_tests_properties(${TestName} PROPERTIES RUN_SERIAL ON)
 374     endif()
 375     getoutputformats("${LIBSUB_SRC_DIR}/${f}.lyx" formatlist)
 376     foreach(format ${formatlist})
 377       if(format MATCHES "dvi3|pdf4|pdf5")
 378         set(fonttypes "texF" "systemF")
 379       else()
 380         set(fonttypes "defaultF")
 381       endif()
 382       foreach(fonttype ${fonttypes})
 383         if (format MATCHES "pdf2" AND f MATCHES "latex/unicodesymbols")
 384           #message(STATUS "Test ${TestName} matches Unicode encodings")
 385           # test_encodings does not include "default", since it should be covered
 386           # by one of the supplied encodings
 387           set(test_encodings "ascii" "utf8x" "armscii8" "applemac"
 388             "cp437" "cp437de" "cp850" "cp852"
 389             "cp855" "cp862" "cp865"
 390             "cp866" "cp1250" "cp1251" "cp1252"
 391             "cp1255" "cp1256" "cp1257"
 392             "koi8-r" "koi8-u"
 393             "iso8859-1" "iso8859-2" "iso8859-3"
 394             "iso8859-4" "iso8859-5" "iso8859-6"
 395             "iso8859-7" "iso8859-8" "iso8859-9"
 396             "iso8859-13" "iso8859-15" "iso8859-16"
 397             "pt154" "big5" "shift-jis"
 398             "euc-cn" "gbk" "jis" "euc-kr"
 399             "utf8-cjk" "euc-tw" "euc-jp"
 400             "euc-jp-platex" "jis-platex"
 401             "shift-jis-platex" "utf8-platex"
 402             "tis620-0")
 403         else()
 404           set(test_encodings "default")
 405         endif()
 406         foreach (_enc2 ${test_encodings})
 407           if ("${_enc2}" STREQUAL "default")
 408             set(_enc "")
 409           else()
 410             set(_enc "_${_enc2}")
 411           endif()
 412           if(fonttype MATCHES "defaultF")
 413             set(TestName "export/${libsubfolder}/${f}${_enc}_${format}")
 414           else()
 415             set(TestName "export/${libsubfolder}/${f}${_enc}_${format}_${fonttype}")
 416           endif()
 417           set(mytestlabel ${testlabel})
 418           maketestname(TestName inverted invertedTests ignoredTests unreliableTests mytestlabel)
 419           if(TestName)
 420             add_test(NAME ${TestName}
 421               WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 422               COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 423               -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 424               -Dlyx=$<TARGET_FILE:${_lyx}>
 425               -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 426               -Dformat=${format}
 427               -Dfonttype=${fonttype}
 428               -Dextension=${format}
 429               -Dfile=${f}
 430               -Dinverted=${inverted}
 431               -DTOP_SRC_DIR=${TOP_SRC_DIR}
 432               -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
 433               -DXMLLINT_EXECUTABLE=${XMLLINT_EXECUTABLE}
 434               -DENCODING=${_enc2}
 435               -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 436             setmarkedtestlabel(${TestName} ${mytestlabel}) # check for suspended pdf/dvi exports
 437           endif()
 438         endforeach()
 439       endforeach()
 440     endforeach()
 441   endforeach()
 442 endforeach()