development/autotests/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6
   7 set(LYX_HOME "out-home")
   8 set(LOCALE_DIR "${CMAKE_CURRENT_BINARY_DIR}/locale")
   9 file(MAKE_DIRECTORY "${LOCALE_DIR}" "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}")
  10
  11 if(Q_WS_X11)
  12   set(Missing)
  13   set(XVFBDLIBS)
  14   # Make sure, the needed programs are in PATH
  15   find_program(PCREGREP_EXE "pcregrep")
  16   if (NOT PCREGREP_EXE)
  17     list(APPEND Missing "pcregrep")
  18   endif()
  19   find_program(WMCTRL_EXE "wmctrl")
  20   if(NOT WMCTRL_EXE)
  21     list(APPEND Missing "wmctrl")
  22   endif()
  23   # This is needed to build xvkbd
  24   # Programs pcregrep wmctrl and xvkbd are used in subsequent scripts
  25   # while testing
  26
  27   # Check for needed libraries for xvkbd
  28   # do not add autotests, if any of them is lacking
  29
  30   find_package(X11)
  31   if(NOT X11_FOUND)
  32     list(APPEND Missing "X11")
  33   endif()
  34   find_package(PkgConfig)
  35   if(PKG_CONFIG_FOUND)
  36     foreach(_lb "xaw7" "xmu" "xtst")
  37       pkg_check_modules(${_lb}LIB ${_lb})
  38       if(${_lb}LIB_LIBRARIES)
  39         list(APPEND XVFBDLIBS ${${_lb}LIB_LIBRARIES})
  40       else()
  41         list(APPEND Missing ${_lb})
  42       endif()
  43     endforeach()
  44   else()
  45     foreach(_lb "Xaw7" "Xmu")
  46       find_library(${_lb}LIB ${_lb})
  47       if(${_lb}LIB)
  48         list(APPEND XVFBDLIBS ${${_lb}LIB})
  49       else()
  50         list(APPEND Missing ${_lb})
  51       endif()
  52     endforeach()
  53     foreach(_lb Xt XTest X11)
  54       if(X11_${_lb}_LIB)
  55         list(APPEND XVFBDLIBS ${X11_${_lb}_LIB})
  56       else()
  57         list(APPEND Missing ${_lb})
  58       endif()
  59     endforeach()
  60   endif()
  61   if (XVFBDLIBS)
  62     list(REMOVE_DUPLICATES XVFBDLIBS)
  63   endif()
  64
  65   if(Missing)
  66     message(STATUS "Missing Libraries or programs to create xvkbd: ${Missing}")
  67     message(STATUS "cmake build is therefore omitting keytests")
  68   endif()
  69
  70   if(NOT Missing)
  71     project(keytest)
  72
  73     add_subdirectory(xvkbd)
  74
  75     set(KEYTEST "${CMAKE_CURRENT_SOURCE_DIR}/keytest.py")
  76     file(GLOB TESTST RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.txt")
  77     file(GLOB TESTSS RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.sh")
  78     list(REMOVE_ITEM TESTST hello-world-in.txt first-time-in.txt)
  79     list(SORT TESTST)
  80
  81     foreach(_tf first-time-in.txt hello-world-in.txt ${TESTST})
  82       string(REGEX REPLACE "-in\\.(txt|sh)" "" _t ${_tf})
  83       add_test(NAME keytest/${_t}
  84         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
  85         COMMAND ${CMAKE_COMMAND}
  86         -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
  87         -DAUTOTEST_ROOT=${TOP_SRC_DIR}/development/autotests
  88         -DPO_BUILD_DIR=${TOP_BINARY_DIR}/po
  89         -DKEYTEST_INFILE=${_tf}
  90         -DBINDIR=$<TARGET_FILE_DIR:${_lyx}>
  91         -DLYX=${_lyx}
  92         -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
  93         -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
  94         -DKEYTEST_OUTFILE=${_t}-out.txt
  95         -DPACKAGE=${PACKAGE}
  96         -DLOCALE_DIR=${LOCALE_DIR}
  97         -P ${TOP_SRC_DIR}/development/autotests/single-test.cmake)
  98       settestlabel(keytest/${_t} "key")
  99       set_tests_properties(keytest/${_t} PROPERTIES RUN_SERIAL ON)
 100     endforeach()
 101   endif()
 102 endif()
 103
 104 find_package(Perl)
 105
 106 macro(getoutputformats filepath varname)
 107   file(STRINGS "${filepath}" lines)
 108   set(out_formats "xhtml" "dvi" "dvi3" "pdf" "pdf2" "pdf3" "pdf4" "pdf5")
 109   if(NOT PERL_FOUND)
 110     list(REMOVE_ITEM out_formats "dvi3" "pdf4" "pdf5")
 111   endif()
 112   set(${varname} ${out_formats})
 113   foreach(_l ${lines})
 114     if(_l MATCHES "^\\\\default_output_format +\([^ ]+\)")
 115       if(CMAKE_MATCH_1 STREQUAL "default")
 116         set(found ${out_formats})
 117       elseif(CMAKE_MATCH_1 STREQUAL "pdf2")
 118         set(found "pdf2" "pdf4" "pdf5")
 119       elseif(CMAKE_MATCH_1 STREQUAL "xhtml")
 120         set(found "xhtml")
 121       else()
 122         set(found "xhtml" ${CMAKE_MATCH_1})
 123       endif()
 124       set(${varname} ${found})
 125       break()
 126     endif()
 127   endforeach()
 128 endmacro()
 129
 130 macro(maketestname testname reverted listreverted listignored)
 131   set(_idx -1)
 132   foreach(_itrx ${${listignored}})
 133     set(_itr "^${_itrx}$")
 134     if(${testname} MATCHES ${_itr})
 135       set(_idx 0)
 136       break()
 137     endif()
 138   endforeach()
 139   #list(FIND ${listignored} ${${testname}} _idx)
 140   if (${_idx} LESS 0)
 141     list(FIND ${listreverted} ${${testname}} _idx)
 142     if (${_idx} LESS 0)
 143       set(${reverted} 0)
 144     else()
 145       set(${reverted} 1)
 146       set(${testname} "INVERTED_SEE-README.ctest_${${testname}}")
 147     endif()
 148   else()
 149     set(${testname} "")
 150   endif()
 151 endmacro()
 152
 153 macro(loadTestList filename resList)
 154   # Create list of strings from a file without comments
 155   file(STRINGS ${filename} tempList)
 156   set(${resList})
 157   foreach(_l ${tempList})
 158     string(REGEX REPLACE "[ \t]*#.*" "" _newl "${_l}")
 159     if(_newl)
 160       list(APPEND ${resList} "${_newl}")
 161     endif()
 162   endforeach()
 163 endmacro()
 164
 165 loadTestList(revertedTests revertedTests)
 166 loadTestList(ignoredTests ignoredTests)
 167
 168 foreach(libsubfolder doc examples templates)
 169   set(LIBSUB_SRC_DIR "${TOP_SRC_DIR}/lib/${libsubfolder}")
 170   file(GLOB_RECURSE lyx_files RELATIVE "${LIBSUB_SRC_DIR}" "${LIBSUB_SRC_DIR}/*.lyx")
 171   list(SORT lyx_files)
 172   # Now create 2 lists. One for files in a language dir, one without
 173   set(lang_lyx_files)
 174   set(nolang_lyx_files)
 175   foreach(f ${lyx_files})
 176     string(REGEX MATCHALL "^[a-z][a-z](_[A-Z][A-Z])?\\/" _v ${f})
 177     if(_v)
 178       list(APPEND lang_lyx_files ${f})
 179     else()
 180       list(APPEND nolang_lyx_files ${f})
 181     endif()
 182   endforeach()
 183   foreach(f ${nolang_lyx_files} ${lang_lyx_files})
 184     # Strip extension
 185     string(REGEX REPLACE "\\.lyx$" "" f ${f})
 186     set(TestName "export/${libsubfolder}/${f}_lyx16")
 187     maketestname(TestName reverted revertedTests ignoredTests)
 188     if(TestName)
 189       add_test(NAME ${TestName}
 190         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 191         COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 192             -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 193             -Dlyx=$<TARGET_FILE:${_lyx}>
 194             -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 195             -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
 196             -Dformat=lyx16x
 197             -Dextension=16.lyx
 198             -Dfile=${f}
 199             -Dreverted=${reverted}
 200             -DTOP_SRC_DIR=${TOP_SRC_DIR}
 201             -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
 202             -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 203       setmarkedtestlabel(${TestName} ${reverted} "export")
 204     endif()
 205     if(LYX_PYTHON_EXECUTABLE)
 206       # For use of lyx2lyx we need the python executable
 207       set(TestName "lyx2lyx/${libsubfolder}/${f}")
 208       maketestname(TestName reverted revertedTests ignoredTests)
 209       if(TestName)
 210         add_test(NAME ${TestName}
 211           WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 212           COMMAND ${CMAKE_COMMAND}
 213             "-DLYX_PYTHON_EXECUTABLE=${LYX_PYTHON_EXECUTABLE}"
 214             "-DLYX2LYX=${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx"
 215             "-DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}"
 216             "-DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx"
 217             -P "${TOP_SRC_DIR}/development/autotests/lyx2lyxtest.cmake")
 218         setmarkedtestlabel(${TestName} ${reverted} "export")
 219       endif()
 220     endif()
 221     set(TestName "check_load/${libsubfolder}/${f}")
 222     maketestname(TestName reverted revertedTests ignoredTests)
 223     if(TestName)
 224       add_test(NAME ${TestName}
 225         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 226         COMMAND ${CMAKE_COMMAND} -DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx
 227           -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 228           -Dlyx=$<TARGET_FILE:${_lyx}>
 229           -DPARAMS_DIR=${TOP_SRC_DIR}/development/autotests
 230           -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 231           -P "${TOP_SRC_DIR}/development/autotests/check_load.cmake")
 232       setmarkedtestlabel(${TestName} ${reverted} "load")
 233     endif()
 234     getoutputformats("${LIBSUB_SRC_DIR}/${f}.lyx" formatlist)
 235     foreach(format ${formatlist})
 236       if(format MATCHES "dvi3|pdf4|pdf5")
 237         set(fonttypes "texF" "systemF")
 238       else()
 239         set(fonttypes "defaultF")
 240       endif()
 241       foreach(fonttype ${fonttypes})
 242         if(fonttype MATCHES "defaultF")
 243           set(TestName "export/${libsubfolder}/${f}_${format}")
 244         else()
 245           set(TestName "export/${libsubfolder}/${f}_${format}_${fonttype}")
 246         endif()
 247         maketestname(TestName reverted revertedTests ignoredTests)
 248         if(TestName)
 249           add_test(NAME ${TestName}
 250             WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 251             COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 252             -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 253             -Dlyx=$<TARGET_FILE:${_lyx}>
 254             -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 255             -Dformat=${format}
 256             -Dfonttype=${fonttype}
 257             -Dextension=${format}
 258             -Dfile=${f}
 259             -Dreverted=${reverted}
 260             -DTOP_SRC_DIR=${TOP_SRC_DIR}
 261             -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
 262             -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 263           setmarkedtestlabel(${TestName} ${reverted} "export")
 264         endif()
 265       endforeach()
 266     endforeach()
 267   endforeach()
 268 endforeach()
 269