development/autotests/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6
   7 if(Q_WS_X11)
   8   set(Missing)
   9   set(XVFBDLIBS)
  10   # Make sure, the needed programs are in PATH
  11   find_program(PCREGREP_EXE "pcregrep")
  12   if (NOT PCREGREP_EXE)
  13     list(APPEND Missing "pcregrep")
  14   endif()
  15   find_program(WMCTRL_EXE "wmctrl")
  16   if(NOT WMCTRL_EXE)
  17     list(APPEND Missing "wmctrl")
  18   endif()
  19   # This is needed to build xvkbd
  20   # Programs pcregrep wmctrl and xvkbd are used in subsequent scripts
  21   # while testing
  22
  23   # Check for needed libraries for xvkbd
  24   # do not add autotests, if any of them is lacking
  25
  26   find_package(X11)
  27   if(NOT X11_FOUND)
  28     list(APPEND Missing "X11")
  29   endif()
  30   find_package(PkgConfig)
  31   if(PKG_CONFIG_FOUND)
  32     foreach(_lb "xaw7" "xmu" "xtst")
  33       pkg_check_modules(${_lb}LIB ${_lb})
  34       if(${_lb}LIB_LIBRARIES)
  35         list(APPEND XVFBDLIBS ${${_lb}LIB_LIBRARIES})
  36       else()
  37         list(APPEND Missing ${_lb})
  38       endif()
  39     endforeach()
  40   else()
  41     foreach(_lb "Xaw7" "Xmu")
  42       find_library(${_lb}LIB ${_lb})
  43       if(${_lb}LIB)
  44         list(APPEND XVFBDLIBS ${${_lb}LIB})
  45       else()
  46         list(APPEND Missing ${_lb})
  47       endif()
  48     endforeach()
  49     foreach(_lb Xt XTest X11)
  50       if(X11_${_lb}_LIB)
  51         list(APPEND XVFBDLIBS ${X11_${_lb}_LIB})
  52       else()
  53         list(APPEND Missing ${_lb})
  54       endif()
  55     endforeach()
  56   endif()
  57   if (XVFBDLIBS)
  58     list(REMOVE_DUPLICATES XVFBDLIBS)
  59   endif()
  60
  61   if(Missing)
  62     message(STATUS "Missing Libraries or programs to create xvkbd: ${Missing}")
  63     message(STATUS "cmake build is therefore omitting autotests")
  64   endif()
  65
  66   if(NOT Missing)
  67     project(autotests)
  68
  69     add_subdirectory(xvkbd)
  70
  71     set(KEYTEST "${CMAKE_CURRENT_SOURCE_DIR}/keytest.py")
  72     set(LYX_HOME "out-home")
  73     set(LYX_USERDIR "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}/.lyx")
  74     set(LOCALE_DIR "${CMAKE_CURRENT_BINARY_DIR}/locale")
  75     file(GLOB TESTST RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.txt")
  76     file(GLOB TESTSS RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.sh")
  77     list(REMOVE_ITEM TESTST hello-world-in.txt first-time-in.txt)
  78     list(SORT TESTST)
  79     file(MAKE_DIRECTORY "${LYX_USERDIR}" "${LOCALE_DIR}")
  80
  81     foreach(_tf first-time-in.txt hello-world-in.txt ${TESTST})
  82       string(REGEX REPLACE "-in\\.(txt|sh)" "" _t ${_tf})
  83       add_test(NAME autotests/${_t}
  84         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
  85         COMMAND ${CMAKE_COMMAND}
  86         -DAUTOTEST_ROOT=${TOP_SRC_DIR}/development/autotests
  87         -DPO_BUILD_DIR=${TOP_BINARY_DIR}/po
  88         -DKEYTEST_INFILE=${_tf}
  89         -DBINDIR=$<TARGET_FILE_DIR:${_lyx}>
  90         -DLYX=${_lyx}
  91         -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
  92         -DKEYTEST_OUTFILE=${_t}-out.txt
  93         -DPACKAGE=${PACKAGE}
  94         -DLOCALE_DIR=${LOCALE_DIR}
  95         -P ${TOP_SRC_DIR}/development/autotests/single-test.cmake)
  96     endforeach()
  97   endif()
  98 endif()
  99
 100 macro(getoutputformats filepath varname)
 101   file(STRINGS "${filepath}" lines)
 102   set(out_formats "xhtml" "pdf" "pdf2" "pdf5")
 103   set(${varname} ${out_formats})
 104   foreach(_l ${lines})
 105     if(_l MATCHES "^\\\\default_output_format +\([^ ]+\)")
 106       if(CMAKE_MATCH_1 STREQUAL "default")
 107         set(found ${out_formats})
 108       elseif(CMAKE_MATCH_1 STREQUAL "xhtml")
 109         set(found "xhtml")
 110       else()
 111         set(found "xhtml" ${CMAKE_MATCH_1})
 112       endif()
 113       set(${varname} ${found})
 114       break()
 115     endif()
 116   endforeach()
 117 endmacro()
 118
 119 macro(getreverted testname reverted listreverted)
 120   list(FIND ${listreverted} ${${testname}} _idx)
 121   if (${_idx} LESS 0)
 122     set(${reverted} 0)
 123   else()
 124     set(${reverted} 1)
 125     set(${testname} "INVERTED_SEE-README.ctest_${${testname}}")
 126   endif()
 127 endmacro()
 128
 129 foreach(libsubfolder doc examples templates)
 130   set(LIBSUB_SRC_DIR "${TOP_SRC_DIR}/lib/${libsubfolder}")
 131   file(GLOB_RECURSE lyx_files RELATIVE "${LIBSUB_SRC_DIR}" "${LIBSUB_SRC_DIR}/*.lyx")
 132   list(SORT lyx_files)
 133   # Now create 2 lists. One for files in a language dir, one without
 134   set(lang_lyx_files)
 135   set(nolang_lyx_files)
 136   foreach(f ${lyx_files})
 137     string(REGEX MATCHALL "^[a-z][a-z](_[A-Z][A-Z])?\\/" _v ${f})
 138     if(_v)
 139       list(APPEND lang_lyx_files ${f})
 140     else()
 141       list(APPEND nolang_lyx_files ${f})
 142     endif()
 143   endforeach()
 144   file(STRINGS "${CMAKE_CURRENT_SOURCE_DIR}/revertedTests" revertedTests)
 145   foreach(f ${nolang_lyx_files} ${lang_lyx_files})
 146     # Strip extension
 147     string(REGEX REPLACE "\\.lyx$" "" f ${f})
 148     set(TestName "export/${libsubfolder}/${f}_lyx16")
 149     getreverted(TestName reverted revertedTests)
 150     add_test(NAME ${TestName}
 151       WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 152       COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 153           -Dlyx=$<TARGET_FILE:${_lyx}>
 154           -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 155           -Dformat=lyx16x
 156           -Dextension=16.lyx
 157           -Dfile=${f}
 158           -Dreverted=${reverted}
 159           -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 160     getoutputformats("${LIBSUB_SRC_DIR}/${f}.lyx" formatlist)
 161     foreach(format ${formatlist})
 162       set(TestName "export/${libsubfolder}/${f}_${format}")
 163       getreverted(TestName reverted revertedTests)
 164       add_test(NAME ${TestName}
 165         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 166         COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 167             -Dlyx=$<TARGET_FILE:${_lyx}>
 168             -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 169             -Dformat=${format}
 170             -Dextension=${format}
 171             -Dfile=${f}
 172             -Dreverted=${reverted}
 173             -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 174     endforeach()
 175   endforeach()
 176 endforeach()
 177