development/autotests/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6
   7 set(LYX_HOME "out-home")
   8 set(LOCALE_DIR "${CMAKE_CURRENT_BINARY_DIR}/locale")
   9 file(MAKE_DIRECTORY "${LOCALE_DIR}" "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}")
  10
  11 if(Q_WS_X11)
  12   set(Missing)
  13   set(XVFBDLIBS)
  14   # Make sure, the needed programs are in PATH
  15   find_program(PCREGREP_EXE "pcregrep")
  16   if (NOT PCREGREP_EXE)
  17     list(APPEND Missing "pcregrep")
  18   endif()
  19   find_program(WMCTRL_EXE "wmctrl")
  20   if(NOT WMCTRL_EXE)
  21     list(APPEND Missing "wmctrl")
  22   endif()
  23   # This is needed to build xvkbd
  24   # Programs pcregrep wmctrl and xvkbd are used in subsequent scripts
  25   # while testing
  26
  27   # Check for needed libraries for xvkbd
  28   # do not add autotests, if any of them is lacking
  29
  30   find_package(X11)
  31   if(NOT X11_FOUND)
  32     list(APPEND Missing "X11")
  33   endif()
  34   find_package(PkgConfig)
  35   if(PKG_CONFIG_FOUND)
  36     foreach(_lb "xaw7" "xmu" "xtst")
  37       pkg_check_modules(${_lb}LIB ${_lb})
  38       if(${_lb}LIB_LIBRARIES)
  39         list(APPEND XVFBDLIBS ${${_lb}LIB_LIBRARIES})
  40       else()
  41         list(APPEND Missing ${_lb})
  42       endif()
  43     endforeach()
  44   else()
  45     foreach(_lb "Xaw7" "Xmu")
  46       find_library(${_lb}LIB ${_lb})
  47       if(${_lb}LIB)
  48         list(APPEND XVFBDLIBS ${${_lb}LIB})
  49       else()
  50         list(APPEND Missing ${_lb})
  51       endif()
  52     endforeach()
  53     foreach(_lb Xt XTest X11)
  54       if(X11_${_lb}_LIB)
  55         list(APPEND XVFBDLIBS ${X11_${_lb}_LIB})
  56       else()
  57         list(APPEND Missing ${_lb})
  58       endif()
  59     endforeach()
  60   endif()
  61   if (XVFBDLIBS)
  62     list(REMOVE_DUPLICATES XVFBDLIBS)
  63   endif()
  64
  65   if(Missing)
  66     message(STATUS "Missing Libraries or programs to create xvkbd: ${Missing}")
  67     message(STATUS "cmake build is therefore omitting keytests")
  68   endif()
  69
  70   if(NOT Missing)
  71     project(keytest)
  72
  73     add_subdirectory(xvkbd)
  74
  75     set(KEYTEST "${CMAKE_CURRENT_SOURCE_DIR}/keytest.py")
  76     file(GLOB TESTST RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.txt")
  77     file(GLOB TESTSS RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.sh")
  78     list(REMOVE_ITEM TESTST hello-world-in.txt first-time-in.txt)
  79     list(SORT TESTST)
  80
  81     foreach(_tf first-time-in.txt hello-world-in.txt ${TESTST})
  82       string(REGEX REPLACE "-in\\.(txt|sh)" "" _t ${_tf})
  83       add_test(NAME keytest/${_t}
  84         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
  85         COMMAND ${CMAKE_COMMAND}
  86         -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
  87         -DAUTOTEST_ROOT=${TOP_SRC_DIR}/development/autotests
  88         -DPO_BUILD_DIR=${TOP_BINARY_DIR}/po
  89         -DKEYTEST_INFILE=${_tf}
  90         -DBINDIR=$<TARGET_FILE_DIR:${_lyx}>
  91         -DLYX=${_lyx}
  92         -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
  93         -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
  94         -DKEYTEST_OUTFILE=${_t}-out.txt
  95         -DPACKAGE=${PACKAGE}
  96         -DLOCALE_DIR=${LOCALE_DIR}
  97         -P ${TOP_SRC_DIR}/development/autotests/single-test.cmake)
  98       settestlabel(keytest/${_t} "key")
  99       set_tests_properties(keytest/${_t} PROPERTIES RUN_SERIAL ON)
 100     endforeach()
 101   endif()
 102 endif()
 103
 104 find_package(Perl)
 105
 106 if(PERL_FOUND)
 107   set(DVI_FORMATS "dvi" "dvi3")
 108   set(PDF_FORMATS "pdf" "pdf2" "pdf3" "pdf4" "pdf5")
 109 else()
 110   set(DVI_FORMATS "dvi")
 111   set(PDF_FORMATS "pdf" "pdf2" "pdf3")
 112 endif()
 113
 114 macro(getoutputformats filepath varname)
 115   file(STRINGS "${filepath}" lines)
 116   # What should we test, if default_output_format is not defined?
 117   # For now we test everything ...
 118   set(out_formats "xhtml" ${DVI_FORMATS} ${PDF_FORMATS})
 119   foreach(_l ${lines})
 120     if(_l MATCHES "^\\\\default_output_format +\([^ ]+\)")
 121       set(_format ${CMAKE_MATCH_1})
 122       if(_format STREQUAL "default")
 123         set(out_formats "xhtml" ${DVI_FORMATS} ${PDF_FORMATS})
 124       elseif(_format MATCHES "pdf")
 125         set(found "xhtml" ${PDF_FORMATS})
 126       elseif(_format MATCHES "dvi")
 127         set(out_formats "xhtml" ${DVI_FORMATS})
 128       else()
 129         # Respect all other output formats
 130         # like "eps3", "xhtml"
 131         set(out_formats ${_format})
 132       endif()
 133       break()
 134     endif()
 135   endforeach()
 136   set(${varname} ${out_formats})
 137 endmacro()
 138
 139 macro(maketestname testname reverted listreverted listignored)
 140   set(_idx -1)
 141   foreach(_itrx ${${listignored}})
 142     set(_itr "^${_itrx}$")
 143     if(${testname} MATCHES ${_itr})
 144       set(_idx 0)
 145       break()
 146     endif()
 147   endforeach()
 148   #list(FIND ${listignored} ${${testname}} _idx)
 149   if (${_idx} LESS 0)
 150     list(FIND ${listreverted} ${${testname}} _idx)
 151     if (${_idx} LESS 0)
 152       set(${reverted} 0)
 153     else()
 154       set(${reverted} 1)
 155       set(${testname} "INVERTED_SEE-README.ctest_${${testname}}")
 156     endif()
 157   else()
 158     set(${testname} "")
 159   endif()
 160 endmacro()
 161
 162 macro(loadTestList filename resList)
 163   # Create list of strings from a file without comments
 164   file(STRINGS ${filename} tempList)
 165   set(${resList})
 166   foreach(_l ${tempList})
 167     string(REGEX REPLACE "[ \t]*#.*" "" _newl "${_l}")
 168     if(_newl)
 169       list(APPEND ${resList} "${_newl}")
 170     endif()
 171   endforeach()
 172 endmacro()
 173
 174 loadTestList(revertedTests revertedTests)
 175 loadTestList(ignoredTests ignoredTests)
 176
 177 foreach(libsubfolder doc examples templates)
 178   set(LIBSUB_SRC_DIR "${TOP_SRC_DIR}/lib/${libsubfolder}")
 179   file(GLOB_RECURSE lyx_files RELATIVE "${LIBSUB_SRC_DIR}" "${LIBSUB_SRC_DIR}/*.lyx")
 180   list(SORT lyx_files)
 181   # Now create 2 lists. One for files in a language dir, one without
 182   set(lang_lyx_files)
 183   set(nolang_lyx_files)
 184   foreach(f ${lyx_files})
 185     string(REGEX MATCHALL "^[a-z][a-z](_[A-Z][A-Z])?\\/" _v ${f})
 186     if(_v)
 187       list(APPEND lang_lyx_files ${f})
 188     else()
 189       list(APPEND nolang_lyx_files ${f})
 190     endif()
 191   endforeach()
 192   foreach(f ${nolang_lyx_files} ${lang_lyx_files})
 193     # Strip extension
 194     string(REGEX REPLACE "\\.lyx$" "" f ${f})
 195     set(TestName "export/${libsubfolder}/${f}_lyx16")
 196     maketestname(TestName reverted revertedTests ignoredTests)
 197     if(TestName)
 198       add_test(NAME ${TestName}
 199         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 200         COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 201             -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 202             -Dlyx=$<TARGET_FILE:${_lyx}>
 203             -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 204             -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
 205             -Dformat=lyx16x
 206             -Dextension=16.lyx
 207             -Dfile=${f}
 208             -Dreverted=${reverted}
 209             -DTOP_SRC_DIR=${TOP_SRC_DIR}
 210             -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
 211             -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 212       setmarkedtestlabel(${TestName} ${reverted} "export")
 213     endif()
 214     if(LYX_PYTHON_EXECUTABLE)
 215       # For use of lyx2lyx we need the python executable
 216       set(TestName "lyx2lyx/${libsubfolder}/${f}")
 217       maketestname(TestName reverted revertedTests ignoredTests)
 218       if(TestName)
 219         add_test(NAME ${TestName}
 220           WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 221           COMMAND ${CMAKE_COMMAND}
 222             "-DLYX_PYTHON_EXECUTABLE=${LYX_PYTHON_EXECUTABLE}"
 223             "-DLYX2LYX=${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx"
 224             "-DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}"
 225             "-DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx"
 226             -P "${TOP_SRC_DIR}/development/autotests/lyx2lyxtest.cmake")
 227         setmarkedtestlabel(${TestName} ${reverted} "export")
 228       endif()
 229     endif()
 230     set(TestName "check_load/${libsubfolder}/${f}")
 231     maketestname(TestName reverted revertedTests ignoredTests)
 232     if(TestName)
 233       add_test(NAME ${TestName}
 234         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 235         COMMAND ${CMAKE_COMMAND} -DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx
 236           -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 237           -Dlyx=$<TARGET_FILE:${_lyx}>
 238           -DPARAMS_DIR=${TOP_SRC_DIR}/development/autotests
 239           -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 240           -P "${TOP_SRC_DIR}/development/autotests/check_load.cmake")
 241       setmarkedtestlabel(${TestName} ${reverted} "load")
 242     endif()
 243     getoutputformats("${LIBSUB_SRC_DIR}/${f}.lyx" formatlist)
 244     foreach(format ${formatlist})
 245       if(format MATCHES "dvi3|pdf4|pdf5")
 246         set(fonttypes "texF" "systemF")
 247       else()
 248         set(fonttypes "defaultF")
 249       endif()
 250       foreach(fonttype ${fonttypes})
 251         if(fonttype MATCHES "defaultF")
 252           set(TestName "export/${libsubfolder}/${f}_${format}")
 253         else()
 254           set(TestName "export/${libsubfolder}/${f}_${format}_${fonttype}")
 255         endif()
 256         maketestname(TestName reverted revertedTests ignoredTests)
 257         if(TestName)
 258           add_test(NAME ${TestName}
 259             WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 260             COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 261             -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 262             -Dlyx=$<TARGET_FILE:${_lyx}>
 263             -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 264             -Dformat=${format}
 265             -Dfonttype=${fonttype}
 266             -Dextension=${format}
 267             -Dfile=${f}
 268             -Dreverted=${reverted}
 269             -DTOP_SRC_DIR=${TOP_SRC_DIR}
 270             -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
 271             -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 272           setmarkedtestlabel(${TestName} ${reverted} "export")
 273         endif()
 274       endforeach()
 275     endforeach()
 276   endforeach()
 277 endforeach()
 278