development/autotests/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6
   7 set(LYX_HOME "out-home")
   8 set(LOCALE_DIR "${CMAKE_CURRENT_BINARY_DIR}/locale")
   9 file(MAKE_DIRECTORY "${LOCALE_DIR}" "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}")
  10
  11 if(QT_USES_X11)
  12   set(Missing)
  13   set(XVFBDLIBS)
  14   # Make sure, the needed programs are in PATH
  15   find_program(PCREGREP_EXE "pcregrep")
  16   if (NOT PCREGREP_EXE)
  17     list(APPEND Missing "pcregrep")
  18   endif()
  19   find_program(WMCTRL_EXE "wmctrl")
  20   if(NOT WMCTRL_EXE)
  21     list(APPEND Missing "wmctrl")
  22   endif()
  23   # This is needed to build xvkbd
  24   # Programs pcregrep wmctrl and xvkbd are used in subsequent scripts
  25   # while testing
  26
  27   # Check for needed libraries for xvkbd
  28   # do not add autotests, if any of them is lacking
  29
  30   find_package(X11)
  31   if(NOT X11_FOUND)
  32     list(APPEND Missing "X11")
  33   endif()
  34   find_package(PkgConfig)
  35   if(PKG_CONFIG_FOUND)
  36     foreach(_lb "xaw7" "xmu" "xtst")
  37       pkg_check_modules(${_lb}LIB ${_lb})
  38       if(${_lb}LIB_LIBRARIES)
  39         list(APPEND XVFBDLIBS ${${_lb}LIB_LIBRARIES})
  40       else()
  41         list(APPEND Missing ${_lb})
  42       endif()
  43     endforeach()
  44   else()
  45     foreach(_lb "Xaw7" "Xmu")
  46       find_library(${_lb}LIB ${_lb})
  47       if(${_lb}LIB)
  48         list(APPEND XVFBDLIBS ${${_lb}LIB})
  49       else()
  50         list(APPEND Missing ${_lb})
  51       endif()
  52     endforeach()
  53     foreach(_lb Xt XTest X11)
  54       if(X11_${_lb}_LIB)
  55         list(APPEND XVFBDLIBS ${X11_${_lb}_LIB})
  56       else()
  57         list(APPEND Missing ${_lb})
  58       endif()
  59     endforeach()
  60   endif()
  61   if (XVFBDLIBS)
  62     list(REMOVE_DUPLICATES XVFBDLIBS)
  63   endif()
  64
  65   if(Missing)
  66     message(STATUS "Missing Libraries or programs to create xvkbd: ${Missing}")
  67     message(STATUS "cmake build is therefore omitting keytests")
  68   endif()
  69
  70   find_program(XVKBD_EXE NAMES "xvkbd")
  71   if (XVKBD_EXE MATCHES "NOTFOUND")
  72     message(STATUS "Missing xvkbd, omitting keytests")
  73     list(APPEND Missing "xvkbd")
  74   endif()
  75
  76   if(Missing OR NOT LYX_ENABLE_KEYTESTS)
  77     set(_runtest FALSE)
  78   else()
  79     project(keytest)
  80
  81     #add_subdirectory(xvkbd)
  82
  83     set(_runtest TRUE)
  84     set(KEYTEST "${CMAKE_CURRENT_SOURCE_DIR}/keytest.py")
  85     file(GLOB TESTST RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.txt")
  86     file(GLOB TESTSS RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.sh")
  87     set(_firsttxt first-time-in.txt hello-world-in.txt)
  88     foreach(_f ${_firsttxt})
  89       list(FIND TESTST ${_f} _ff)
  90       if(NOT _ff GREATER -1)
  91         set(_runtest FALSE)
  92         break()
  93       endif()
  94     endforeach()
  95     list(REMOVE_ITEM TESTST ${_firsttxt})
  96     list(SORT TESTST)
  97   endif()
  98   if(_runtest)
  99     foreach(_tf ${_firsttxt} ${TESTST})
 100       string(REGEX REPLACE "-in\\.(txt|sh)" "" _t ${_tf})
 101       add_test(NAME keytest/${_t}
 102         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 103         COMMAND ${CMAKE_COMMAND}
 104         -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 105         -DAUTOTEST_ROOT=${TOP_SRC_DIR}/development/autotests
 106         -DPO_BUILD_DIR=${TOP_BINARY_DIR}/po
 107         -DKEYTEST_INFILE=${_tf}
 108         -DBINDIR=$<TARGET_FILE_DIR:${_lyx}>
 109         -DLYX=${_lyx}
 110         -DXVKBD_EXE=${XVKBD_EXE}
 111         -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 112         -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
 113         -DKEYTEST_OUTFILE=${_t}-out.txt
 114         -DPACKAGE=${PACKAGE}
 115         -DFRONTEND=${LYX_USE_QT}
 116         -DLOCALE_DIR=${LOCALE_DIR}
 117         -P ${TOP_SRC_DIR}/development/autotests/single-test.cmake)
 118       settestlabel(keytest/${_t} "key")
 119       set_tests_properties(keytest/${_t} PROPERTIES RUN_SERIAL ON)
 120     endforeach()
 121   endif()
 122 endif()
 123
 124 if (LYX_ENABLE_EXPORT_TESTS)
 125   set(lyx_ignored_count 0)
 126   include(${TOP_SRC_DIR}/development/autotests/ExportTests.cmake)
 127   message(STATUS "Number of ignored export tests now ${lyx_ignored_count}")
 128   set(LYX_ignored_count ${lyx_ignored_count} PARENT_SCOPE)
 129 endif()