development/autotests/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6
   7 set(LYX_HOME "out-home")
   8 set(LOCALE_DIR "${CMAKE_CURRENT_BINARY_DIR}/locale")
   9 file(MAKE_DIRECTORY "${LOCALE_DIR}" "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}")
  10
  11 if(Q_WS_X11)
  12   set(Missing)
  13   set(XVFBDLIBS)
  14   # Make sure, the needed programs are in PATH
  15   find_program(PCREGREP_EXE "pcregrep")
  16   if (NOT PCREGREP_EXE)
  17     list(APPEND Missing "pcregrep")
  18   endif()
  19   find_program(WMCTRL_EXE "wmctrl")
  20   if(NOT WMCTRL_EXE)
  21     list(APPEND Missing "wmctrl")
  22   endif()
  23   # This is needed to build xvkbd
  24   # Programs pcregrep wmctrl and xvkbd are used in subsequent scripts
  25   # while testing
  26
  27   # Check for needed libraries for xvkbd
  28   # do not add autotests, if any of them is lacking
  29
  30   find_package(X11)
  31   if(NOT X11_FOUND)
  32     list(APPEND Missing "X11")
  33   endif()
  34   find_package(PkgConfig)
  35   if(PKG_CONFIG_FOUND)
  36     foreach(_lb "xaw7" "xmu" "xtst")
  37       pkg_check_modules(${_lb}LIB ${_lb})
  38       if(${_lb}LIB_LIBRARIES)
  39         list(APPEND XVFBDLIBS ${${_lb}LIB_LIBRARIES})
  40       else()
  41         list(APPEND Missing ${_lb})
  42       endif()
  43     endforeach()
  44   else()
  45     foreach(_lb "Xaw7" "Xmu")
  46       find_library(${_lb}LIB ${_lb})
  47       if(${_lb}LIB)
  48         list(APPEND XVFBDLIBS ${${_lb}LIB})
  49       else()
  50         list(APPEND Missing ${_lb})
  51       endif()
  52     endforeach()
  53     foreach(_lb Xt XTest X11)
  54       if(X11_${_lb}_LIB)
  55         list(APPEND XVFBDLIBS ${X11_${_lb}_LIB})
  56       else()
  57         list(APPEND Missing ${_lb})
  58       endif()
  59     endforeach()
  60   endif()
  61   if (XVFBDLIBS)
  62     list(REMOVE_DUPLICATES XVFBDLIBS)
  63   endif()
  64
  65   if(Missing)
  66     message(STATUS "Missing Libraries or programs to create xvkbd: ${Missing}")
  67     message(STATUS "cmake build is therefore omitting keytests")
  68   endif()
  69
  70   if(NOT Missing)
  71     project(keytest)
  72
  73     add_subdirectory(xvkbd)
  74
  75     set(KEYTEST "${CMAKE_CURRENT_SOURCE_DIR}/keytest.py")
  76     file(GLOB TESTST RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.txt")
  77     file(GLOB TESTSS RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.sh")
  78     list(REMOVE_ITEM TESTST hello-world-in.txt first-time-in.txt)
  79     list(SORT TESTST)
  80
  81     foreach(_tf first-time-in.txt hello-world-in.txt ${TESTST})
  82       string(REGEX REPLACE "-in\\.(txt|sh)" "" _t ${_tf})
  83       add_test(NAME keytest/${_t}
  84         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
  85         COMMAND ${CMAKE_COMMAND}
  86         -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
  87         -DAUTOTEST_ROOT=${TOP_SRC_DIR}/development/autotests
  88         -DPO_BUILD_DIR=${TOP_BINARY_DIR}/po
  89         -DKEYTEST_INFILE=${_tf}
  90         -DBINDIR=$<TARGET_FILE_DIR:${_lyx}>
  91         -DLYX=${_lyx}
  92         -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
  93         -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
  94         -DKEYTEST_OUTFILE=${_t}-out.txt
  95         -DPACKAGE=${PACKAGE}
  96         -DLOCALE_DIR=${LOCALE_DIR}
  97         -P ${TOP_SRC_DIR}/development/autotests/single-test.cmake)
  98       settestlabel(keytest/${_t} "key")
  99       set_tests_properties(keytest/${_t} PROPERTIES RUN_SERIAL ON)
 100     endforeach()
 101   endif()
 102 endif()
 103
 104 find_package(Perl)
 105
 106 macro(getoutputformats filepath varname)
 107   file(STRINGS "${filepath}" lines)
 108   set(out_formats "xhtml" "dvi" "dvi3" "pdf" "pdf2" "pdf3" "pdf4" "pdf5")
 109   if(NOT PERL_FOUND)
 110     list(REMOVE_ITEM out_formats "dvi3" "pdf4" "pdf5")
 111   endif()
 112   set(${varname} ${out_formats})
 113   foreach(_l ${lines})
 114     if(_l MATCHES "^\\\\default_output_format +\([^ ]+\)")
 115       if(CMAKE_MATCH_1 STREQUAL "default")
 116         set(found ${out_formats})
 117       elseif(CMAKE_MATCH_1 STREQUAL "xhtml")
 118         set(found "xhtml")
 119       else()
 120         set(found "xhtml" ${CMAKE_MATCH_1})
 121       endif()
 122       set(${varname} ${found})
 123       break()
 124     endif()
 125   endforeach()
 126 endmacro()
 127
 128 macro(maketestname testname reverted listreverted listignored)
 129   list(FIND ${listignored} ${${testname}} _idx)
 130   if (${_idx} LESS 0)
 131     list(FIND ${listreverted} ${${testname}} _idx)
 132     if (${_idx} LESS 0)
 133       set(${reverted} 0)
 134     else()
 135       set(${reverted} 1)
 136       set(${testname} "INVERTED_SEE-README.ctest_${${testname}}")
 137     endif()
 138   else()
 139     set(${testname} "")
 140   endif()
 141 endmacro()
 142
 143 macro(loadTestList filename resList)
 144   # Create list of strings from a file without comments
 145   file(STRINGS ${filename} tempList)
 146   set(${resList})
 147   foreach(_l ${tempList})
 148     string(REGEX REPLACE "[ \t]*#.*" "" _newl "${_l}")
 149     if(_newl)
 150       list(APPEND ${resList} "${_newl}")
 151     endif()
 152   endforeach()
 153 endmacro()
 154
 155 loadTestList(revertedTests revertedTests)
 156 loadTestList(ignoredTests ignoredTests)
 157
 158 foreach(libsubfolder doc examples templates)
 159   set(LIBSUB_SRC_DIR "${TOP_SRC_DIR}/lib/${libsubfolder}")
 160   file(GLOB_RECURSE lyx_files RELATIVE "${LIBSUB_SRC_DIR}" "${LIBSUB_SRC_DIR}/*.lyx")
 161   list(SORT lyx_files)
 162   # Now create 2 lists. One for files in a language dir, one without
 163   set(lang_lyx_files)
 164   set(nolang_lyx_files)
 165   foreach(f ${lyx_files})
 166     string(REGEX MATCHALL "^[a-z][a-z](_[A-Z][A-Z])?\\/" _v ${f})
 167     if(_v)
 168       list(APPEND lang_lyx_files ${f})
 169     else()
 170       list(APPEND nolang_lyx_files ${f})
 171     endif()
 172   endforeach()
 173   foreach(f ${nolang_lyx_files} ${lang_lyx_files})
 174     # Strip extension
 175     string(REGEX REPLACE "\\.lyx$" "" f ${f})
 176     set(TestName "export/${libsubfolder}/${f}_lyx16")
 177     maketestname(TestName reverted revertedTests ignoredTests)
 178     if(TestName)
 179       add_test(NAME ${TestName}
 180         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 181         COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 182             -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 183             -Dlyx=$<TARGET_FILE:${_lyx}>
 184             -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 185             -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
 186             -Dformat=lyx16x
 187             -Dextension=16.lyx
 188             -Dfile=${f}
 189             -Dreverted=${reverted}
 190             -DTOP_SRC_DIR=${TOP_SRC_DIR}
 191             -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
 192             -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 193       setmarkedtestlabel(${TestName} ${reverted} "export")
 194     endif()
 195     set(TestName "lyx2lyx/${libsubfolder}/${f}")
 196     maketestname(TestName reverted revertedTests ignoredTests)
 197     if(TestName)
 198       add_test(NAME ${TestName}
 199         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 200         COMMAND ${CMAKE_COMMAND} -DLYX2LYX=${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx
 201           -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 202           -DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx
 203           -P "${TOP_SRC_DIR}/development/autotests/lyx2lyxtest.cmake")
 204       setmarkedtestlabel(${TestName} ${reverted} "export")
 205     endif()
 206     set(TestName "check_load/${libsubfolder}/${f}")
 207     maketestname(TestName reverted revertedTests ignoredTests)
 208     if(TestName)
 209       add_test(NAME ${TestName}
 210         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 211         COMMAND ${CMAKE_COMMAND} -DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx
 212           -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 213           -Dlyx=$<TARGET_FILE:${_lyx}>
 214           -DPARAMS_DIR=${TOP_SRC_DIR}/development/autotests
 215           -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 216           -P "${TOP_SRC_DIR}/development/autotests/check_load.cmake")
 217       setmarkedtestlabel(${TestName} ${reverted} "load")
 218     endif()
 219     getoutputformats("${LIBSUB_SRC_DIR}/${f}.lyx" formatlist)
 220     foreach(format ${formatlist})
 221       set(TestName "export/${libsubfolder}/${f}_${format}")
 222       maketestname(TestName reverted revertedTests ignoredTests)
 223       if(TestName)
 224         add_test(NAME ${TestName}
 225           WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 226           COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 227             -DLYX_TESTS_USERDIR=${LYX_TESTS_USERDIR}
 228             -Dlyx=$<TARGET_FILE:${_lyx}>
 229             -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 230             -Dformat=${format}
 231             -Dextension=${format}
 232             -Dfile=${f}
 233             -Dreverted=${reverted}
 234             -DTOP_SRC_DIR=${TOP_SRC_DIR}
 235             -DPERL_EXECUTABLE=${PERL_EXECUTABLE}
 236             -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 237         setmarkedtestlabel(${TestName} ${reverted} "export")
 238       endif()
 239     endforeach()
 240   endforeach()
 241 endforeach()
 242