development/autotests/CMakeLists.txt

   1 # This file is part of LyX, the document processor.
   2 # Licence details can be found in the file COPYING.
   3 #
   4 # Copyright (c) 2012 Kornel Benko kornel@lyx.org
   5 #
   6
   7 if(Q_WS_X11)
   8   set(Missing)
   9   set(XVFBDLIBS)
  10   # Make sure, the needed programs are in PATH
  11   find_program(PCREGREP_EXE "pcregrep")
  12   if (NOT PCREGREP_EXE)
  13     list(APPEND Missing "pcregrep")
  14   endif()
  15   find_program(WMCTRL_EXE "wmctrl")
  16   if(NOT WMCTRL_EXE)
  17     list(APPEND Missing "wmctrl")
  18   endif()
  19   # This is needed to build xvkbd
  20   # Programs pcregrep wmctrl and xvkbd are used in subsequent scripts
  21   # while testing
  22
  23   # Check for needed libraries for xvkbd
  24   # do not add autotests, if any of them is lacking
  25
  26   find_package(X11)
  27   if(NOT X11_FOUND)
  28     list(APPEND Missing "X11")
  29   endif()
  30   find_package(PkgConfig)
  31   if(PKG_CONFIG_FOUND)
  32     foreach(_lb "xaw7" "xmu" "xtst")
  33       pkg_check_modules(${_lb}LIB ${_lb})
  34       if(${_lb}LIB_LIBRARIES)
  35         list(APPEND XVFBDLIBS ${${_lb}LIB_LIBRARIES})
  36       else()
  37         list(APPEND Missing ${_lb})
  38       endif()
  39     endforeach()
  40   else()
  41     foreach(_lb "Xaw7" "Xmu")
  42       find_library(${_lb}LIB ${_lb})
  43       if(${_lb}LIB)
  44         list(APPEND XVFBDLIBS ${${_lb}LIB})
  45       else()
  46         list(APPEND Missing ${_lb})
  47       endif()
  48     endforeach()
  49     foreach(_lb Xt XTest X11)
  50       if(X11_${_lb}_LIB)
  51         list(APPEND XVFBDLIBS ${X11_${_lb}_LIB})
  52       else()
  53         list(APPEND Missing ${_lb})
  54       endif()
  55     endforeach()
  56   endif()
  57   if (XVFBDLIBS)
  58     list(REMOVE_DUPLICATES XVFBDLIBS)
  59   endif()
  60
  61   if(Missing)
  62     message(STATUS "Missing Libraries or programs to create xvkbd: ${Missing}")
  63     message(STATUS "cmake build is therefore omitting keytests")
  64   endif()
  65
  66   if(NOT Missing)
  67     project(keytest)
  68
  69     add_subdirectory(xvkbd)
  70
  71     set(KEYTEST "${CMAKE_CURRENT_SOURCE_DIR}/keytest.py")
  72     set(LYX_HOME "out-home")
  73     set(LYX_USERDIR "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}/.lyx")
  74     set(LOCALE_DIR "${CMAKE_CURRENT_BINARY_DIR}/locale")
  75     file(GLOB TESTST RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.txt")
  76     file(GLOB TESTSS RELATIVE "${CMAKE_CURRENT_SOURCE_DIR}" "*-in.sh")
  77     list(REMOVE_ITEM TESTST hello-world-in.txt first-time-in.txt)
  78     list(SORT TESTST)
  79     file(MAKE_DIRECTORY "${LYX_USERDIR}" "${LOCALE_DIR}")
  80
  81     foreach(_tf first-time-in.txt hello-world-in.txt ${TESTST})
  82       string(REGEX REPLACE "-in\\.(txt|sh)" "" _t ${_tf})
  83       add_test(NAME keytest/${_t}
  84         WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
  85         COMMAND ${CMAKE_COMMAND}
  86         -DAUTOTEST_ROOT=${TOP_SRC_DIR}/development/autotests
  87         -DPO_BUILD_DIR=${TOP_BINARY_DIR}/po
  88         -DKEYTEST_INFILE=${_tf}
  89         -DBINDIR=$<TARGET_FILE_DIR:${_lyx}>
  90         -DLYX=${_lyx}
  91         -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
  92         -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
  93         -DKEYTEST_OUTFILE=${_t}-out.txt
  94         -DPACKAGE=${PACKAGE}
  95         -DLOCALE_DIR=${LOCALE_DIR}
  96         -P ${TOP_SRC_DIR}/development/autotests/single-test.cmake)
  97     endforeach()
  98   endif()
  99 endif()
 100
 101 macro(getoutputformats filepath varname)
 102   file(STRINGS "${filepath}" lines)
 103   set(out_formats "xhtml" "pdf" "pdf2" "pdf5")
 104   set(${varname} ${out_formats})
 105   foreach(_l ${lines})
 106     if(_l MATCHES "^\\\\default_output_format +\([^ ]+\)")
 107       if(CMAKE_MATCH_1 STREQUAL "default")
 108         set(found ${out_formats})
 109       elseif(CMAKE_MATCH_1 STREQUAL "xhtml")
 110         set(found "xhtml")
 111       else()
 112         set(found "xhtml" ${CMAKE_MATCH_1})
 113       endif()
 114       set(${varname} ${found})
 115       break()
 116     endif()
 117   endforeach()
 118 endmacro()
 119
 120 macro(getreverted testname reverted listreverted)
 121   list(FIND ${listreverted} ${${testname}} _idx)
 122   if (${_idx} LESS 0)
 123     set(${reverted} 0)
 124   else()
 125     set(${reverted} 1)
 126     set(${testname} "INVERTED_SEE-README.ctest_${${testname}}")
 127   endif()
 128 endmacro()
 129
 130 foreach(libsubfolder doc examples templates)
 131   set(LIBSUB_SRC_DIR "${TOP_SRC_DIR}/lib/${libsubfolder}")
 132   file(GLOB_RECURSE lyx_files RELATIVE "${LIBSUB_SRC_DIR}" "${LIBSUB_SRC_DIR}/*.lyx")
 133   list(SORT lyx_files)
 134   # Now create 2 lists. One for files in a language dir, one without
 135   set(lang_lyx_files)
 136   set(nolang_lyx_files)
 137   foreach(f ${lyx_files})
 138     string(REGEX MATCHALL "^[a-z][a-z](_[A-Z][A-Z])?\\/" _v ${f})
 139     if(_v)
 140       list(APPEND lang_lyx_files ${f})
 141     else()
 142       list(APPEND nolang_lyx_files ${f})
 143     endif()
 144   endforeach()
 145   file(STRINGS "${CMAKE_CURRENT_SOURCE_DIR}/revertedTests" revertedTests)
 146   file(STRINGS "${CMAKE_CURRENT_SOURCE_DIR}/ignoredTests" ignoredTests)
 147   foreach(f ${nolang_lyx_files} ${lang_lyx_files})
 148     # Strip extension
 149     string(REGEX REPLACE "\\.lyx$" "" f ${f})
 150     set(TestName "export/${libsubfolder}/${f}_lyx16")
 151     getreverted(TestName reverted revertedTests)
 152     add_test(NAME ${TestName}
 153       WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 154       COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 155           -Dlyx=$<TARGET_FILE:${_lyx}>
 156           -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 157           -DLYX_USERDIR_VER=${LYX_USERDIR_VER}
 158           -Dformat=lyx16x
 159           -Dextension=16.lyx
 160           -Dfile=${f}
 161           -Dreverted=${reverted}
 162           -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 163     set(TestName "lyx2lyx/${libsubfolder}/${f}")
 164     getreverted(TestName reverted revertedTests)
 165     add_test(NAME ${TestName}
 166       WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 167       COMMAND ${CMAKE_COMMAND} -DLYX2LYX=${TOP_SRC_DIR}/lib/lyx2lyx/lyx2lyx
 168         -DLYXFILE=${LIBSUB_SRC_DIR}/${f}.lyx
 169         -P "${TOP_SRC_DIR}/development/autotests/lyx2lyxtest.cmake")
 170     getoutputformats("${LIBSUB_SRC_DIR}/${f}.lyx" formatlist)
 171     foreach(format ${formatlist})
 172       set(TestName "export/${libsubfolder}/${f}_${format}")
 173       list(FIND ignoredTests ${TestName} _idx)
 174       if (${_idx} LESS 0)
 175         getreverted(TestName reverted revertedTests)
 176         add_test(NAME ${TestName}
 177           WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}"
 178           COMMAND ${CMAKE_COMMAND} -DLYX_ROOT=${LIBSUB_SRC_DIR}
 179             -Dlyx=$<TARGET_FILE:${_lyx}>
 180             -DWORKDIR=${CMAKE_CURRENT_BINARY_DIR}/${LYX_HOME}
 181             -Dformat=${format}
 182             -Dextension=${format}
 183             -Dfile=${f}
 184             -Dreverted=${reverted}
 185             -P "${TOP_SRC_DIR}/development/autotests/export.cmake")
 186       endif()
 187     endforeach()
 188   endforeach()
 189 endforeach()
 190