development/Win32/packaging/installer2/src/main.nsh

   1 #-------------------------------------------------------------
   2 # - - - - - - - - - - - - Preamble - - - - - - - - - - - - - -
   3 #-------------------------------------------------------------
   4
   5   # Do a Cyclic Redundancy Check to make sure the installer
   6   # was not corrupted by the download.
   7   CRCCheck force
   8   # Make the installer as small as possible
   9   SetCompressor /SOLID lzma
  10   # Make it a Unicode installer
  11   Unicode true
  12   # Enable support for high DPI resolution
  13   ManifestDPIAware true
  14
  15   Name "LyX ${APP_VERSION}" # Name of the Program to be displayed during installation
  16   BrandingText " " # Remove branding text ('Nullsoft Install System vX.XX')
  17
  18   # ===== Variables =====
  19
  20     Var LatexPath # Used to store path to "latex.exe"
  21     Var StartMenuFolder # Used to store the start menu folder
  22     Var pathPrefix
  23
  24     # FIXME Variables needed due to "old" set of language strings, delete
  25     Var LaTeXInstalled
  26     Var LaTeXName
  27     Var OldVersionNumber
  28     Var AppPre
  29     Var AppSuff
  30     # R3
  31
  32     # FIXME Compile time constants needed due to "old" set of language strings, delete
  33     !define APP_SERIES_KEY2 ${APP_VERSION}
  34     !define APP_DIR_USERDATA "LyX${VERSION_MAJOR}.${VERSION_MINOR}"
  35
  36   # ========= Multiuser settings =========
  37
  38     !define MULTIUSER_MUI # Multiuser uses modern UI 2
  39     !define MULTIUSER_EXECUTIONLEVEL Highest # Can install with any privileges (admin, user)
  40     !if ${APP_ARCHITECTURE} = 64
  41       !define MULTIUSER_USE_PROGRAMFILES64 # Install 64 bit program in "Program files" instead of "Program files (x86)"
  42     !endif
  43
  44     !define MULTIUSER_INSTALLMODE_COMMANDLINE # Allow setting installmode in commandline (/AllUsers or /CurrentUser)
  45
  46     # Set default install mode based on a non empty registry entry (if exists in HKLM, then all users, if HKCU then current user)
  47     !define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_KEY "SOFTWARE\LyX"
  48     !define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_VALUENAME "InstDir${VERSION_MAJOR}${VERSION_MINOR}"
  49
  50     !define MULTIUSER_INSTALLMODE_INSTDIR "LyX ${VERSION_MAJOR}.${VERSION_MINOR}" # Default install dir if not over-installing
  51
  52     # Retrieve default install location from following registry entry (HKCU/HKLM  is chosen automatically)
  53     !define MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_KEY "SOFTWARE\LyX"
  54     !define MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_VALUENAME "InstDir${VERSION_MAJOR}${VERSION_MINOR}"
  55
  56     !include MultiUser.nsh # Header file: Installer configuration for multi-user Windows environments
  57     # When MULTIUSER_INSTALLMODE_COMMANDLINE is defined, MultiUser.nsh defines ${StrStr} and ${UnStrStr} functions
  58
  59   # ============= Modern UI 2 general settings ===============
  60
  61     #!include MUI2.nsh # included in MultiUser # Header file for creating modern looking installer
  62     !define MUI_ABORTWARNING # Show a message box with a warning when the user wants to close the installer.
  63     !define MUI_ICON "..\installer\icons\lyx.ico" # FIXME path # The icon for the installer.
  64     !define MUI_UNICON "..\installer\icons\lyx.ico" # FIXME path # The icon for the uninstaller
  65     !define MUI_HEADERIMAGE # Display an image on the header of the page.
  66     !define MUI_HEADERIMAGE_BITMAP "..\installer\graphics\header.bmp" # FIXME path # Header image source
  67     !define MUI_HEADERIMAGE_RIGHT # Display header image on the right and not left
  68     !define MUI_WELCOMEFINISHPAGE_BITMAP "..\installer\graphics\wizard.bmp" # FIXME path # Source for image on welcome and finish page of the installer
  69     !define MUI_UNWELCOMEFINISHPAGE_BITMAP "..\installer\graphics\wizard.bmp" # FIXME path # Source for image on welcome and finish page of the uninstaller
  70
  71   # ======== Pages definitions ==========
  72
  73     # Installer
  74
  75     !define MUI_WELCOMEPAGE_TEXT $(TEXT_WELCOME) # Use custom welcome text
  76     !insertmacro MUI_PAGE_WELCOME # Welcome page
  77
  78     !insertmacro MUI_PAGE_LICENSE "..\installer\license.rtf" # FIXME path # License page
  79
  80     !define MUI_PAGE_CUSTOMFUNCTION_PRE PrepareShellCTX # Prepare shell context before the multiuser page is created, so that the installer searches for default install folder in the right context (x64/x32)
  81     !insertmacro MULTIUSER_PAGE_INSTALLMODE # Multiuser page
  82
  83     !define MUI_PAGE_CUSTOMFUNCTION_LEAVE VerifyInstDir # Custom leave-function for directory page to verify installdir
  84     !insertmacro MUI_PAGE_DIRECTORY # Directory page (where to install)
  85
  86     !define MUI_PAGE_CUSTOMFUNCTION_PRE DefaultDesktopFileAssoc # Custom pre-function for components page to search for already present dictionaries (in dictionaries.nsh)
  87     !insertmacro MUI_PAGE_COMPONENTS # Components page (what to install)
  88
  89     # Default startmenu folder if registry contains no information from a previous installment, same as the default install dir
  90     !define MUI_STARTMENUPAGE_DEFAULTFOLDER "${MULTIUSER_INSTALLMODE_INSTDIR}"
  91     # Define registry entry to store the startmenu folder, also reads this entry in as default startmenu folder in case of over-installing
  92     !define MUI_STARTMENUPAGE_REGISTRY_ROOT "SHCTX" # Context dependent on what the user chooses on multiuser page
  93     !define MUI_STARTMENUPAGE_REGISTRY_KEY "SOFTWARE\LyX"
  94     !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "SMDir${VERSION_MAJOR}${VERSION_MINOR}"
  95     !define MUI_PAGE_CUSTOMFUNCTION_PRE PrepareShellCTX # Prepare shell context before the startmenu page is created, so that the installer searches for default startmenu folder in the right context
  96     !define MUI_PAGE_CUSTOMFUNCTION_SHOW RetrieveSMState # Custom show-function for startmenu page to disable startmenu dir creation in case of over-installment where previously disabled
  97     !insertmacro MUI_PAGE_STARTMENU startmenuPage $StartMenuFolder # Page to choose start menu folder entry, the folder is stored in VARIABLE
  98
  99     # Latexfolder page
 100     !include "src\CustomPages\LaTeXFolder.nsdinc"
 101     Page custom LatexFolder_Show LatexFolder_Leave
 102
 103     !insertmacro MUI_PAGE_INSTFILES # Progress page
 104
 105     !define MUI_FINISHPAGE_SHOWREADME # Showreadme-checkbox appears
 106     !define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED # Showreadme-checkbox disabled by default
 107     !define MUI_FINISHPAGE_SHOWREADME_FUNCTION StartLyX # Custom function for the showreadme-checkbox (start latex instead of show readme)
 108     !define MUI_FINISHPAGE_SHOWREADME_TEXT $(FinishPageRun) # Custom text for the label on the showreadme-checkbox
 109     !define MUI_FINISHPAGE_LINK $(TEXT_FINISH_WEBSITE) # Text for the link on the bottom of finish page
 110     !define MUI_FINISHPAGE_LINK_LOCATION "https://www.lyx.org/" # Website opens by clicking on the link on finish page
 111     !insertmacro MUI_PAGE_FINISH # Finish page
 112
 113     # Uninstaller
 114
 115     !insertmacro MUI_UNPAGE_WELCOME # Welcome page
 116     !insertmacro MUI_UNPAGE_CONFIRM # Confirmation page
 117
 118     !define MUI_PAGE_CUSTOMFUNCTION_PRE un.ComponentsPre # Custom function for components page to prepare strings for the description of a section
 119     !insertmacro MUI_UNPAGE_COMPONENTS # Components page
 120
 121     !insertmacro MUI_UNPAGE_INSTFILES # Progress page
 122     !insertmacro MUI_UNPAGE_FINISH # Finish page
 123
 124   # ======= Other includes =======
 125
 126     !include "src\lang\TranslatedLanguages.nsh" # languages strings
 127
 128     #!include LogicLib.nsh # included in MUI2 # Allows using logic commands (such as ${If}..${Else}..${EndIf})
 129     #!include LangFile.nsh # included in MUI2 # Header file to create language files that can be included with a single command.
 130     !include x64.nsh # Header file to check if target system is 64 bit or not with ${RunningX64}, also defines ${DisableX64FSRedirection} and ${EnableX64FSRedirection}
 131     !include NSISList.nsh # Header file to create and work with lists in NSIS (plugin)
 132
 133     #!include StrFunc.nsh # included in MultiUser # Provides some additional string functions
 134     ${StrRep} # Define this function from StrFunc.nsh for further use
 135     ${StrStrAdv} # Define this function from StrFunc.nsh for further use
 136     ${UnStrStrAdv} # Define this function from StrFunc.nsh for further use
 137     ${UnStrRep} # Define this function from StrFunc.nsh for further use
 138
 139   # ========= Installer Attributes ===========
 140
 141     VIProductVersion "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_REVISION}.${VERSION_BUILD}" # Must be X.X.X.X format
 142     VIAddVersionKey /LANG=${LANG_ENGLISH} "ProductName" "LyX"
 143     VIAddVersionKey /LANG=${LANG_ENGLISH} "ProductVersion" "LyX ${APP_VERSION} installer"
 144     VIAddVersionKey /LANG=${LANG_ENGLISH} "FileVersion" "${APP_VERSION}"
 145     VIAddVersionKey /LANG=${LANG_ENGLISH} "FileDescription" "LyX - The Document Processor"
 146     VIAddVersionKey /LANG=${LANG_ENGLISH} "LegalCopyright" "LyX is Copyright © 1995 by Matthias Ettrich, 1995-${COPYRIGHT_YEAR} by the LyX Team"
 147     VIAddVersionKey /LANG=${LANG_ENGLISH} "CompanyName" "LyX Team"
 148     VIAddVersionKey /LANG=${LANG_ENGLISH} "LegalTrademarks" ""
 149
 150 #-------------------------------------------------------------
 151 # - - - - - - - - - - Helper Functions - - - - - - - - - - - -
 152 #-------------------------------------------------------------
 153
 154   # Forward declarations
 155
 156   !macro SearchAllRegistry resultVar resultStateIdx resultRegIdx subKey searchFor startStateIdx startRegIdx
 157     Push ${subKey}
 158     Push ${searchFor}
 159     Push ${startStateIdx}
 160     Push ${startRegIdx}
 161     Call SearchAllRegistry
 162     Pop ${resultStateIdx}
 163     Pop ${resultRegIdx}
 164     Pop ${resultVar}
 165   !macroend
 166
 167   !define SearchAllRegistry "!insertmacro SearchAllRegistry"
 168
 169   !macro SearchRegistry resultVar resultRegIdx subKey searchFor startRegIdx
 170     Push ${subKey}
 171     Push ${searchFor}
 172     Push ${startRegIdx}
 173     Call SearchRegistry
 174     Pop ${resultRegIdx}
 175     Pop ${resultVar}
 176   !macroend
 177
 178   !define SearchRegistry "!insertmacro SearchRegistry"
 179
 180   # Functions
 181
 182   Function SearchAllRegistry
 183     Exch $9 # startRegIdx
 184     Exch
 185     Exch $8 # startStateIdx
 186     Exch 2
 187     Exch $7 # searchFor
 188     Exch 3
 189     Exch $6 # subKey
 190     Push $5
 191
 192     ${Do}
 193       ${Select} $8
 194         ${Case} 0
 195           SetShellVarContext all
 196           ${If} ${RunningX64}
 197             SetRegView 64
 198           ${Else}
 199             IntOp $8 $8 + 1
 200           ${EndIf}
 201         ${Case} 1
 202           SetShellVarContext all
 203           ${If} ${RunningX64}
 204             SetRegView 32
 205           ${EndIf}
 206         ${Case} 2
 207           SetShellVarContext current
 208           ${If} ${RunningX64}
 209             SetRegView 64
 210           ${Else}
 211             IntOp $8 $8 + 1
 212           ${EndIf}
 213         ${Case} 3
 214           SetShellVarContext current
 215           ${If} ${RunningX64}
 216             SetRegView 32
 217           ${EndIf}
 218       ${EndSelect}
 219       ${SearchRegistry} $5 $9 $6 $7 $9
 220       ${If} $5 != ""
 221         ${Break}
 222       ${EndIf}
 223       IntOp $8 $8 + 1
 224       StrCpy $9 0
 225     ${LoopUntil} $8 >= 4
 226
 227     Exch $5 # resultVar
 228     Exch 4
 229     Pop $7
 230     Pop $6
 231     Exch $9 # resultRegIdx
 232     Exch
 233     Exch $8 # resultStateIdx
 234   FunctionEnd
 235
 236   Function SearchRegistry
 237     Exch $9 # startRegIdx
 238     Exch
 239     Exch $8 # searchFor
 240     Exch 2
 241     Exch $7 #subKey
 242     Push $6
 243     Push $5
 244
 245     ${Do}
 246       EnumRegKey $6 SHCTX $7 $9
 247       ${StrStr} $5 $6 $8
 248       IntOp $9 $9 + 1
 249       ${If} $5 != ""
 250         ${Break}
 251       ${EndIf}
 252     ${LoopUntil} $6 == ""
 253
 254     Exch $5 # resultVar
 255     Exch 4
 256     Pop $8
 257     Pop $6
 258     Pop $7
 259     Exch $9 # resultRegIdx
 260   FunctionEnd
 261
 262   !macro PrepareShellCTX
 263     ${if} $MultiUser.InstallMode == "CurrentUser"
 264       SetShellVarContext current
 265     ${Else}
 266       SetShellVarContext all
 267     ${EndIf}
 268     ${If} ${RunningX64}
 269       SetRegView ${APP_ARCHITECTURE}
 270     ${EndIf}
 271   !macroend
 272
 273   Function PrepareShellCTX
 274     !insertmacro PrepareShellCTX
 275   FunctionEnd
 276
 277   Function un.PrepareShellCTX
 278     !insertmacro PrepareShellCTX
 279   FunctionEnd
 280
 281 #-------------------------------------------------------------
 282 # - - - - - - - - - - - - Sections - - - - - - - - - - - - - -
 283 #-------------------------------------------------------------
 284
 285 # ============ Installer Page Functions ============
 286
 287 Function .onInit # Callback function, called at the very beginning, when user double clicks on the installer
 288
 289   !if ${APP_ARCHITECTURE} = 64 # If 64 bit installer
 290     # Abort if not 64 bit Windows
 291     ${IfNot} ${RunningX64}
 292       MessageBox MB_OK|MB_ICONSTOP "Cannot install a 64 bit application on 32 bit Windows, please use the 32 bit installer" /SD IDOK
 293       Quit
 294     ${EndIf}
 295   !EndIf
 296
 297   # Check Windows version
 298   ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" CurrentVersion
 299   ${if} $0 S<= "6.0" # Atleast Win7 is needed
 300     MessageBox MB_OK|MB_ICONSTOP "LyX ${APP_VERSION} requires Windows 7 or newer." /SD IDOK
 301     Quit
 302   ${endif}
 303
 304   Call PrepareShellCTX # MULTIUSER_INIT should search in the right registry view
 305   !insertmacro MULTIUSER_INIT # Verify multiuser privileges
 306
 307   # Check if the same version of LyX is installed anywhere (admin/user, x64/x32) on the computer
 308   StrCpy $1 0
 309   StrCpy $2 0
 310   ${DoUntil} $1 >= 4
 311     ${SearchAllRegistry} $0 $1 $2 "SOFTWARE\LyX" ${APP_VERSION_DOTLESS} $1 $2 # Helper Function from above
 312     ${If} $0 == ${APP_VERSION_DOTLESS}
 313       ReadRegStr $0 SHCTX "SOFTWARE\LYX\$0" ""
 314       ${If} ${FileExists} "$0\Uninstall-LyX.exe"
 315         ${IfCmd} MessageBox MB_YESNO|MB_DEFBUTTON2|MB_ICONEXCLAMATION "$(AlreadyInstalled)" /SD IDNO IDNO ${||} Quit ${|}
 316       ${Else}
 317         DeleteRegKey SHCTX "SOFTWARE\LYX\$0"
 318       ${EndIf}
 319     ${EndIf}
 320   ${Loop}
 321
 322   # Check if a newer version of the same LyX series is installed anywhere (admin/user, x64/x32) on the computer
 323   StrCpy $1 0
 324   StrCpy $2 0
 325   ${DoUntil} $1 >= 4
 326     ${SearchAllRegistry} $R9 $1 $2 "SOFTWARE\LyX" "${VERSION_MAJOR}${VERSION_MINOR}" $1 $2 # Helper Function from above
 327     StrCpy $OldVersionNumber $R9 # FIXME remove
 328     ${If} $R9 S> ${APP_VERSION_DOTLESS} # $R9 is used in $(NewerInstalled)
 329       ReadRegStr $0 SHCTX "SOFTWARE\LYX\$0" ""
 330       ${If} ${FileExists} "$0\Uninstall-LyX.exe"
 331         MessageBox MB_OK|MB_ICONSTOP "$(NewerInstalled)" /SD IDOK
 332         Quit
 333       ${Else}
 334         DeleteRegKey SHCTX "SOFTWARE\LYX\$0"
 335       ${EndIf}
 336     ${EndIf}
 337   ${Loop}
 338 FunctionEnd
 339
 340 Function CheckIfRunning # Check that LyX in $INSTDIR is not currently running, called from Function VerifyInstDir and Section -CheckSilent (if silentinstall)
 341   ${If} ${RunningX64}
 342     ${DisableX64FSRedirection} # We need the following process to be 64 bit on 64 bit system
 343   ${EndIf}
 344   nsExec::ExecToStack "powershell (Get-Process LyX).Path"
 345   Pop $0 # Exit code
 346   Pop $0 # Result string
 347   ${If} ${RunningX64}
 348     ${EnableX64FSRedirection} # Need to be anabled asap or installer might crash
 349   ${EndIf}
 350   ${StrStr} $0 $0 "$INSTDIR\bin\LyX.exe"
 351   ${If} $0 != ""
 352     MessageBox MB_OK|MB_ICONSTOP "$(UnInstallRunning)" /SD IDOK
 353     Abort # Abort leaving the page (when called from the page callback) / Abort install (when called from the section)
 354   ${EndIf}
 355 FunctionEnd
 356
 357 Function VerifyInstDir # Custom Function, called when leaving directory page
 358   # if the $INSTDIR does not contain "LyX" we must add a subfolder to avoid that LyX will e.g.
 359   # be installed directly to "C:\Program Files" - the uninstaller will then delete the whole
 360   # "C:\Program Files" directory
 361   ${StrStr} $0 $INSTDIR LyX
 362   ${If} $0 == ""
 363     StrCpy $INSTDIR "$INSTDIR\${MULTIUSER_INSTALLMODE_INSTDIR}" # Append e.g. "LyX 2.3" to $INSTDIR
 364     ${NSD_SetText} $mui.DirectoryPage.Directory $INSTDIR # Refresh Textbox
 365     Abort # Abort leaving the page
 366   ${EndIf}
 367
 368   Call CheckIfRunning
 369 FunctionEnd
 370
 371 Function RetrieveSMState # Custom function, called after the Startmenu page has been created
 372   ${IfNot} ${FileExists} "$INSTDIR\Uninstall-LyX.exe"
 373     Return # Not over-installing
 374   ${EndIf}
 375
 376   Call PrepareShellCTX # Helper function from above
 377   ReadRegStr $0 SHCTX "SOFTWARE\LyX" "SMDir${VERSION_MAJOR}${VERSION_MINOR}"
 378   ${If} $0 == ""
 379     ${If} ${Silent}
 380       StrCpy $StartMenuFolder ">$StartMenuFolder"
 381     ${Else}
 382       GetDlgItem $0 $mui.StartMenuPage 1005 # Get the HWND of the checkbox, MUI2 does not provide variable for that
 383       ${NSD_GetState} $0 $1
 384       ${If} $1 = ${BST_UNCHECKED}
 385         SendMessage $0 ${BM_CLICK} 0 0 # NSIS delivers no other possibility here other than to send a click event to the checkbox
 386       ${EndIf}
 387     ${EndIf}
 388   ${EndIf}
 389 FunctionEnd
 390
 391 Function LatexFolder_Show # Custom Function, called before showing the LaTeXFolder page to create it
 392   Call FindLatex # detect latex
 393   Pop $0 # Result string from FindLatex
 394   # $0 should contain the path to latex.exe, it is used in the fnc_LaTeXFolder_Create
 395   ${StrStr} $1 $0 "\latex.exe"
 396   ${If} $1 != "" # If latex was actually found
 397     ${StrRep} $0 $0 $1 ""
 398     # $R9 is used in $(EnterLaTeXFolder) on the page
 399     ${StrStr} $1 $0 "\miktex\bin"
 400     ${If} $1 != ""
 401       StrCpy $R9 "MiKTeX"
 402     ${Else}
 403       StrCpy $R9 "TeXLive"
 404     ${EndIf}
 405     StrCpy $LaTeXName $R9 # FIXME remove
 406     StrCpy $1 $(EnterLaTeXFolder) # $1 is used on the page
 407   ${Else}
 408     StrCpy $1 $(EnterLaTeXFolderNone)
 409   ${EndIf}
 410   ${StrRep} $1 $1 "\r\n" "$\r$\n" # FIXME remove
 411
 412   Call fnc_LaTeXFolder_Show # In LaTeXFolder.nsdinc, defined by NSIS Dialog Designer
 413 FunctionEnd
 414
 415 Function FindLatex # Searches latex.exe, called from pre and leave functions of latexfolder page
 416   # Find "LaTeX Path" value in registry written by a previous installment of the same LyX series, prioritized, because could be user preference
 417   Call PrepareShellCTX
 418   ${If} ${RunningX64}
 419     SetRegView 64
 420   ${EndIf}
 421   StrCpy $1 0
 422   StrCpy $2 0
 423   ${DoUntil} $2 > 1
 424     ${SearchRegistry} $0 $1 "SOFTWARE\LyX" "${VERSION_MAJOR}${VERSION_MINOR}" $1
 425     ${If} $0 != ""
 426       ReadRegStr $0 SHCTX "SOFTWARE\LyX\$0" "LaTeX Path"
 427       StrCpy $0 "$0\latex.exe"
 428       ${If} ${FileExists} $0
 429         Push $0
 430         Return
 431       ${EndIf}
 432     ${ElseIf} ${RunningX64}
 433       IntOp $2 $2 + 1
 434       SetRegView 32
 435     ${Else}
 436       ${Break}
 437     ${EndIf}
 438   ${Loop}
 439
 440   nsExec::ExecToStack "where latex.exe" # Ask CMD to find "latex.exe" for us, works if latexpath is added to PATH
 441   Pop $0 # Exit code: 0 = success, 1 = fail
 442   ${If} $0 = 0
 443     Return
 444   ${EndIf}
 445   Pop $0 # If search failed, this is garbage, otherwise path to latex
 446
 447   # Search the registry for TexLive
 448   StrCpy $1 0
 449   StrCpy $2 0
 450   ${DoUntil} $1 >= 4
 451     ${SearchAllRegistry} $0 $1 $2 "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" "TeXLive" $1 $2 # Helper Function from above
 452     ReadRegStr $0 SHCTX "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\$0" "UninstallString"
 453     ${StrRep} $0 $0 '"' ""
 454     ${StrRep} $0 $0 "tlpkg\installer\uninst.bat" "bin\win32\latex.exe" # TeXLive is not 64 bit yet
 455     ${If} ${FileExists} $0
 456       Push $0
 457       Return
 458     ${EndIf}
 459   ${Loop}
 460
 461   # Search the registry for MiKTex
 462   StrCpy $1 0
 463   StrCpy $2 0
 464   ${DoUntil} $1 >= 4
 465     ${SearchAllRegistry} $0 $1 $2 "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" "MiKTeX" $1 $2 # Helper Function from above
 466     ReadRegStr $0 SHCTX "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\$0" "InstallLocation"
 467     StrCpy $0 "$0\miktex\bin\latex.exe"
 468     ${If} ${FileExists} $0
 469       Push $0
 470       Return
 471     ${EndIf}
 472     ${If} ${RunningX64} # MiKTeX can also be x64
 473       ${StrRep} $0 $0 "latex.exe" "x64\latex.exe"
 474       ${If} ${FileExists} $0
 475         Push $0
 476         Return
 477       ${EndIf}
 478     ${EndIf}
 479   ${Loop}
 480
 481   # No latex was found
 482   Push "C:\"
 483
 484 FunctionEnd
 485
 486 Function LatexFolder_Leave # Custom function, called when trying to leave LatexFolder page to verify that "latex.exe" really exists in the given path
 487   ${NSD_GetText} $hCtl_LaTeXFolder_DirRequest1_Txt $LatexPath
 488   ${NSD_GetState} $hCtl_LaTeXFolder_CheckBox1 $0
 489
 490   ${If} $0 = ${BST_CHECKED}
 491     StrCpy $LatexPath ""
 492   ${ElseIfNot} ${FileExists} "$LatexPath\latex.exe"
 493     MessageBox MB_OK $(InvalidLaTeXFolder)
 494     Call FindLatex # Search for latex again
 495     Pop $0 # Result string from FindLatex
 496     ${StrStrAdv} $0 $0 "\latex.exe" ">" "<" "0" "0" "0" # Get everything before "\latex.exe"
 497     ${NSD_SetText} $hCtl_LaTeXFolder_DirRequest1_Txt $0 # Refresh textbox
 498     Abort # Abort leaving the page
 499   ${EndIf}
 500 FunctionEnd
 501
 502 # ========= Installer Sections =========
 503
 504 Section -CheckSilent # This section checks if it's a silent install and calls needed callback- and custom-pagefunctions, which are not called in this case
 505   ${IfNot} ${Silent}
 506     Return
 507   ${EndIf}
 508
 509   # .onInit is called
 510
 511   Call CheckIfRunning
 512
 513   Call RetrieveSMState
 514
 515   Call FindLatex # Search for latex
 516   Pop $0 # Result string from FindLatex
 517   ${StrStrAdv} $0 $0 "\latex.exe" ">" "<" "0" "0" "0" # Get everything before "\latex.exe"
 518   ${If} ${FileExists} "$0\latex.exe"
 519     StrCpy $LatexPath $0
 520   ${Else}
 521     MessageBox MB_OK $(InvalidLaTeXFolder)
 522     Quit
 523   ${EndIf}
 524
 525   Call DefaultDesktopFileAssoc
 526 SectionEnd
 527
 528 Section -UninstallOld
 529   ${If} ${FileExists} "$INSTDIR\Uninstall-LyX.exe"
 530     ${GetFileVersion} "$INSTDIR\Uninstall-LyX.exe" $0
 531     StrCpy $0 $0 3 # get only the first 3 chars, e.g. "2.3"
 532     ${If} $0 != "${VERSION_MAJOR}.${VERSION_MINOR}"
 533       ExecWait "$INSTDIR\Uninstall-LyX.exe /S _?=$INSTDIR" # silently uninstall old LyX
 534       Delete "$INSTDIR\Uninstall-LyX.exe"
 535     ${EndIf}
 536   ${EndIf}
 537 SectionEnd
 538
 539 Section -OverInstallReg # If over-installing, we need to delete the registry keys written by the previous installment
 540   Call PrepareShellCTX # Helper function from above
 541   StrCpy $1 0
 542   ${Do}
 543     EnumRegKey $2 SHCTX "SOFTWARE\LyX" $1
 544     ${StrStr} $3 $2 "${VERSION_MAJOR}${VERSION_MINOR}"
 545     ReadRegStr $0 SHCTX "SOFTWARE\LyX\$3" ""
 546     ${If} $0 == $INSTDIR
 547       DeleteRegKey SHCTX "SOFTWARE\LyX\$3"
 548       DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX$3"
 549     ${EndIf}
 550     IntOp $1 $1 + 1
 551   ${LoopUntil} $2 == ""
 552 SectionEnd
 553
 554 Section -ProgramFiles
 555
 556   # Install the core LyX files
 557
 558   # Initializes the plug-ins dir ($PLUGINSDIR) if not already initialized.
 559   # $PLUGINSDIR is automatically deleted when the installer exits.
 560   InitPluginsDir
 561
 562   # Binaries
 563   SetOutPath "$INSTDIR\bin"
 564   File "${FILES_LYX}\bin\LyX.exe"
 565   File "${FILES_LYX}\bin\tex2lyx.exe"
 566   # Visual C++ redistributable (if native build)
 567   File "${FILES_DEPS}\bin\concrt140.dll"
 568   File "${FILES_DEPS}\bin\msvcp140.dll"
 569   File "${FILES_DEPS}\bin\msvcp140_1.dll"
 570   File "${FILES_DEPS}\bin\vcamp140.dll"
 571   File "${FILES_DEPS}\bin\vccorlib140.dll"
 572   File "${FILES_DEPS}\bin\vcomp140.dll"
 573   File "${FILES_DEPS}\bin\vcruntime140.dll"
 574   !if ${APP_ARCHITECTURE} = 64
 575     File "${FILES_DEPS}\bin\vcruntime140_1.dll"
 576   !endif
 577   # MinGW redistributable (if cross platform with MinGW)
 578   #File "${FILES_DEPS}\bin\iconv.dll"
 579   #File "${FILES_DEPS}\bin\libbz2-1.dll"
 580   #File "${FILES_DEPS}\bin\libfreetype-6.dll"
 581   #File "${FILES_DEPS}\bin\libgcc_s_sjlj-1.dll"
 582   #File "${FILES_DEPS}\bin\libglib-2.0-0.dll"
 583   #File "${FILES_DEPS}\bin\libharfbuzz-0.dll"
 584   #File "${FILES_DEPS}\bin\libintl-8.dll"
 585   #File "${FILES_DEPS}\bin\libjpeg-62.dll"
 586   #File "${FILES_DEPS}\bin\libpcre-1.dll"
 587   #File "${FILES_DEPS}\bin\libpcre2-16-0.dll"
 588   #File "${FILES_DEPS}\bin\libpng16-16.dll"
 589   #File "${FILES_DEPS}\bin\libstdc++-6.dll"
 590   #File "${FILES_DEPS}\bin\libtiff-5.dll"
 591   #File "${FILES_DEPS}\bin\libwinpthread-1.dll"
 592   #File "${FILES_DEPS}\bin\libwebp-7.dll"
 593   #File "${FILES_DEPS}\bin\libwebpdemux-2.dll"
 594   #File "${FILES_DEPS}\bin\zlib1.dll"
 595   # Netpbm
 596   File "${FILES_DEPS}\bin\libnetpbm10.dll"
 597   File "${FILES_DEPS}\bin\pnmcrop.exe"
 598   # Rsvg
 599   File "${FILES_DEPS}\bin\rsvg-convert.exe"
 600   # Pdfview
 601   File "${FILES_DEPS}\bin\pdfview.exe"
 602   # Qt libraries
 603   File "${FILES_QT}\bin\Qt5Concurrent.dll"
 604   File "${FILES_QT}\bin\Qt5Core.dll"
 605   File "${FILES_QT}\bin\Qt5Gui.dll"
 606   File "${FILES_QT}\bin\Qt5Network.dll"
 607   File "${FILES_QT}\bin\Qt5OpenGL.dll"
 608   File "${FILES_QT}\bin\Qt5PrintSupport.dll"
 609   File "${FILES_QT}\bin\Qt5Svg.dll"
 610   File "${FILES_QT}\bin\Qt5Widgets.dll"
 611   File "${FILES_QT}\bin\Qt5WinExtras.dll"
 612
 613   # Qt plugin DLLs
 614   SetOutPath "$INSTDIR\bin\imageformats"
 615   File "${FILES_QT}\bin\imageformats\qgif.dll"
 616   File "${FILES_QT}\bin\imageformats\qico.dll"
 617   File "${FILES_QT}\bin\imageformats\qjpeg.dll"
 618   File "${FILES_QT}\bin\imageformats\qsvg.dll"
 619   File "${FILES_QT}\bin\imageformats\qicns.dll"
 620   File "${FILES_QT}\bin\imageformats\qtiff.dll"
 621   File "${FILES_QT}\bin\imageformats\qwbmp.dll"
 622   File "${FILES_QT}\bin\imageformats\qwebp.dll"
 623
 624   SetOutPath "$INSTDIR\bin\iconengines"
 625   File "${FILES_QT}\bin\iconengines\qsvgicon.dll"
 626
 627   SetOutPath "$INSTDIR\bin\platforms"
 628   File "${FILES_QT}\bin\platforms\qminimal.dll"
 629   File "${FILES_QT}\bin\platforms\qwindows.dll"
 630
 631   SetOutPath "$INSTDIR\bin\styles"
 632   File "${FILES_QT}\bin\styles\qwindowsvistastyle.dll"
 633
 634   # Resources
 635   SetOutPath "$INSTDIR\Resources"
 636   # recursively copy all files under Resources
 637   File /r "${FILES_LYX}\Resources\"
 638   File /r "${FILES_DEPS}\Resources\" # Already present files will be skiped
 639
 640   # Python
 641   SetOutPath "$INSTDIR\Python"
 642   # recursively copy all files under Python
 643   File /r "${FILES_DEPS}\Python\"
 644
 645   # Components of ImageMagick
 646   SetOutPath "$INSTDIR\imagemagick"
 647   File /r "${FILES_DEPS}\imagemagick\"
 648
 649   # Components of Ghostscript
 650   SetOutPath "$INSTDIR\ghostscript"
 651   File /r "${FILES_DEPS}\ghostscript\"
 652
 653   # Install unoconv
 654   SetOutPath "$INSTDIR\Python\Lib"
 655   File "${FILES_DEPS}\bin\unoconv.py"
 656
 657   WriteUninstaller "$INSTDIR\Uninstall-LyX.exe"
 658 SectionEnd
 659
 660 Section -TexRessources # Section installs cls files from Ressources\tex and updates latex filebase
 661   # First make sure that latex was found in LatexFolder_Leave function
 662   ${If} $LatexPath == ""
 663     Return
 664   ${EndIf}
 665
 666   # Miktex or Texlive?
 667   ${StrStr} $0 $LatexPath "\miktex\bin"
 668   ${If} $0 == "" # TexLive
 669     ${StrRep} $0 $LatexPath "\bin\win32" "\texmf-dist\tex\latex\lyx"
 670     ${If} ${FileExists} "$0\broadway.cls"
 671       Return
 672     ${EndIf}
 673     CopyFiles /SILENT "$INSTDIR\Resources\tex\*.*" $0
 674     ExecWait '$LatexPath\texhash' # Update package file list
 675
 676   ${Else} # Miktex
 677     ${StrRep} $0 $LatexPath $0 "\tex\latex\lyx"
 678     ${If} ${FileExists} "$0\broadway.cls"
 679       Return
 680     ${EndIf}
 681     CopyFiles /SILENT "$INSTDIR\Resources\tex\*.*" $0 # First try to put into Miktex install dir
 682
 683     ${IfNot} ${FileExists} "$0\broadway.cls" # Check if copying succeeded
 684       # Didn't suceed to put into install dir, put into users dir
 685       nsExec::ExecToStack "$LatexPath\mpm.exe --version" # get the Miktex version
 686       Pop $0 # Exit code
 687       Pop $0 # Result
 688       ${StrStrAdv} $0 $0 "MiKTeX Package Manager " ">" ">" "0" "0" "0" # $0 contains "2.9.7420 ......" now (everything after "MiKTeX Package Manager ")
 689       ${StrStrAdv} $0 $0 "." ">" "<" "0" "1" "0" # $0 contains "2.9" now (everything before the second dot)
 690       SetShellVarContext current
 691       ${If} ${FileExists} "$APPDATA\MiKTeX\$0\tex\latex\lyx\broadway.cls" # UserInstall-dir can not be changed in Miktex currently, so this should work
 692         Return
 693       ${EndIf}
 694       CopyFiles /SILENT "$INSTDIR\Resources\tex\*.*" "$APPDATA\MiKTeX\$0\tex\latex\lyx" # Put into user install dir
 695     ${EndIf}
 696
 697     # Update package file list
 698     nsExec::ExecToLog "$LatexPath\initexmf.exe --admin --update-fndb" # Try as admin
 699     Pop $0 # Exit code
 700     ${If} $0 <> 0 # Not successful
 701       nsExec::ExecToLog "$LatexPath\initexmf.exe --update-fndb" # Do as user
 702       Pop $0
 703     ${EndIf}
 704   ${EndIf}
 705 SectionEnd
 706
 707 Section -CompilePython
 708   # Compile all Python files to byte-code
 709   # The user using the scripts may not have write access
 710   FileOpen $R0 "$INSTDIR\compilepy.py" w
 711   FileWrite $R0 "import compileall$\r$\n"
 712   FileWrite $R0 "compileall.compile_dir('$INSTDIR\python\Lib')$\r$\n"
 713   FileWrite $R0 "compileall.compile_dir('$INSTDIR\Resources')$\r$\n"
 714   FileClose $R0
 715   DetailPrint $(TEXT_CONFIGURE_PYTHON)
 716   nsExec::ExecToLog '"$INSTDIR\python\python.exe" "$INSTDIR\compilepy.py"'
 717   Pop $0 # Exit code
 718   Delete "$INSTDIR\compilepy.py"
 719 SectionEnd
 720
 721 Section -LyxrcDist
 722   StrCpy $pathPrefix "$LatexPath;$$LyXDir\bin;$$LyXDir\Python;$$LyXDir\Python\Lib;$$LyXDir\imagemagick;$$LyXDir\ghostscript\bin"
 723
 724   # Find additional software and add their install locations to the path_prefix
 725   # This list contains all software, which write the string value "InstallLocation" in their corresponding keys in "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"
 726   # To add additional software matching this requirement, just append it to the string after "${List.Append} editors "
 727   ${List.Create} editors
 728   ${List.Append} editors "jEdit,PSPad,WinShell,TeXnicCenter,WinEdt"
 729   ${List.Count} $R1 editors
 730   IntOp $R1 $R1 - 1
 731   ${For} $R2 0 $R1
 732     ${List.Get} $0 editors $R2
 733     ${SearchAllRegistry} $0 $1 $1 "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" $0 0 0 # Helper Function from above
 734     ReadRegStr $0 SHCTX "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\$0" "InstallLocation"
 735     ${If} $0 != ""
 736       StrCpy $1 $0 "" -1 # Get the last char
 737       ${If} $1 == "\" # If ends with "\"
 738         StrCpy $0 $0 -1 # Remove "\"
 739       ${EndIf}
 740       StrCpy $pathPrefix "$pathPrefix;$0"
 741     ${EndIf}
 742   ${Next}
 743   ${List.Destroy} editors
 744
 745   # Following Software does not create "InstallLocation"
 746   # Vim
 747   ${SearchAllRegistry} $0 $1 $1 "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" "Vim" 0 0 # Helper Function from above
 748   ReadRegStr $0 SHCTX "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\$0" "DisplayIcon"
 749   ${StrStrAdv} $0 $0 "\gvim.exe" ">" "<" "0" "0" "0" # get everything before "\gvim.exe"
 750   ${If} $0 != ""
 751     StrCpy $pathPrefix "$pathPrefix;$0"
 752   ${EndIf}
 753
 754   # JabRef, Hard to locate, JabRef uses MSI installer, lets try to find it through the .bib extension
 755   SetShellVarContext all
 756   ${If} ${RunningX64}
 757     SetRegView 64
 758   ${EndIf}
 759   ${For} $R1 0 1 # Try as admin and then as user
 760     ReadRegStr $0 SHCTX "SOFTWARE\Classes\.bib" ""
 761     ReadRegStr $0 SHCTX "Software\Classes\$0\shell\open\command" ""
 762     ${StrRep} $0 $0 '"' "" # Remove quotes
 763     ${StrStrAdv} $0 $0 "\JabRef.exe" ">" "<" "0" "0" "0" # Get everything before "\JabRef.exe"
 764     ${If} ${FileExists} "$0\JabRef.exe"
 765       StrCpy $pathPrefix "$pathPrefix;$0"
 766       ${Break}
 767     ${EndIf}
 768     SetShellVarContext current # Retry as user
 769   ${Next}
 770
 771   # Gnumeric
 772   SetShellVarContext all
 773   ${If} ${RunningX64}
 774     SetRegView 64
 775   ${EndIf}
 776   ${For} $R1 0 1 # Try as admin and then as user
 777     ReadRegStr $0 SHCTX "Software\Classes\Applications\gnumeric.exe\shell\Open\command" ""
 778     ${StrRep} $0 $0 '"' "" # Remove quotes
 779     ${StrStrAdv} $0 $0 "\gnumeric.exe" ">" "<" "0" "0" "0" # Get everything before "\gnumeric.exe"
 780     ${If} $0 != ""
 781       StrCpy $pathPrefix "$pathPrefix;$0"
 782       ${Break}
 783     ${EndIf}
 784     SetShellVarContext current # Retry as user
 785   ${Next}
 786
 787   # Pandoc, same as JabRef, can only attempt to ask cmd if added to PATH, the user can't disable that while installing pandoc though
 788   nsExec::ExecToStack "where pandoc.exe"
 789   Pop $1 # Exit code
 790   Pop $0 # Return sring
 791   ${If} $1 = 0
 792     ${StrStrAdv} $0 $0 "\pandoc.exe" ">" "<" "0" "0" "0" # Get everything before "\pandoc.exe"
 793     ${If} $0 != ""
 794       StrCpy $pathPrefix "$pathPrefix;$0"
 795     ${EndIf}
 796   ${EndIf}
 797
 798   ${Map.Create} softwarePathsMap # Create a map (NSISList plugin) to temp store paths of 3rd party software
 799
 800   # LilyPond
 801   ${SearchAllRegistry} $0 $1 $1 "SOFTWARE" "LilyPond" 0 0 # Helper Function from above
 802   ReadRegStr $0 SHCTX "SOFTWARE\$0" "Install_Dir"
 803   ${If} $0 != ""
 804     StrCpy $pathPrefix "$pathPrefix;$0\usr\bin"
 805     ${Map.Set} softwarePathsMap "LilyPond" "$0\usr\bin"
 806   ${EndIf}
 807
 808   # Gimp
 809   ${SearchAllRegistry} $2 $1 $1 "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" "GIMP" 0 0 # Helper Function from above
 810   ReadRegStr $0 SHCTX "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\$2" "InstallLocation"
 811   ${If} $0 != ""
 812     StrCpy $pathPrefix "$pathPrefix;$0bin" # Install Location ends with '\' for Gimp in Registry
 813     ReadRegStr $0 SHCTX "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\$2" "DisplayIcon"
 814     ${StrStrAdv} $0 $0 ".exe" ">" "<" "0" "0" "0" # Get everything before the ".exe"
 815     ${StrStrAdv} $0 $0 "\" "<" ">" "0" "0" "0" # Get everything after the last "\", $0 contains "gimp-10" now
 816     ${Map.Set} softwarePathsMap "ImageEditor" $0
 817   ${EndIf}
 818
 819   # Krita
 820   ${SearchAllRegistry} $0 $1 $1 "SOFTWARE" "Krita" 0 0 # Helper Function from above
 821   ReadRegStr $0 SHCTX "SOFTWARE\$0" "InstallLocation"
 822   ${If} $0 != ""
 823     StrCpy $pathPrefix "$pathPrefix;$0\bin"
 824     ${Map.Set} softwarePathsMap "ImageEditor" "krita"
 825   ${EndIf}
 826
 827   # Photoshop
 828   SetShellVarContext all
 829   ${If} ${RunningX64}
 830     SetRegView 64
 831   ${EndIf}
 832   ${For} $R1 0 1 # Try as admin and then as user
 833     ReadRegStr $0 SHCTX "Software\Classes\Applications\Photoshop.exe\shell\Open\command" ""
 834     ${StrRep} $0 $0 '"' "" # Remove quotes
 835     ${StrStrAdv} $0 $0 "\photoshop.exe" ">" "<" "0" "0" "0" # Get everything before "\photoshop.exe"
 836     ${If} $0 != ""
 837       StrCpy $pathPrefix "$pathPrefix;$0"
 838       ${Break}
 839     ${EndIf}
 840     SetShellVarContext current # Retry as user
 841   ${Next}
 842
 843   ClearErrors
 844
 845   FileOpen $R0 "$INSTDIR\Resources\lyxrc.dist" a
 846   FileSeek $R0 0 END
 847   # set some general things
 848   FileWrite $R0 '\screen_zoom 120$\r$\n'
 849
 850   FileWrite $R0 '\path_prefix "$pathPrefix"$\r$\n'
 851
 852   # use pdfview for all types of PDF files
 853   FileWrite $R0 '\format "pdf5" "pdf" "PDF (LuaTeX)" "u" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
 854                 \format "pdf4" "pdf" "PDF (XeTeX)" "X" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
 855                 \format "pdf3" "pdf" "PDF (dvipdfm)" "m" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
 856                 \format "pdf2" "pdf" "PDF (pdflatex)" "F" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
 857                 \format "pdf" "pdf" "PDF (ps2pdf)" "P" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n'
 858
 859   # If krita or gimp was found previously
 860   ${Map.Get} $0 softwarePathsMap "ImageEditor"
 861   ${If} $0 != "__NULL" # If "ImageEditor" is set in map
 862     FileWrite $R0 '\format "gif" "gif" "GIF" "" "auto" "$0" "" "image/gif"$\r$\n\
 863                   \format "jpg" "jpg, jpeg" "JPEG" "" "auto" "$0" "" "image/jpeg"$\r$\n\
 864                   \format "png" "png" "PNG" "" "auto" "$0" "" "image/x-png"$\r$\n'
 865   ${EndIf}
 866
 867   FileWrite $R0 '\converter "wmf" "eps" "magick -density 300 $$$$i $$$$o" ""$\r$\n\
 868     \converter "emf" "eps" "magick -density 300 $$$$i $$$$o" ""$\r$\n'
 869
 870   # If LilyPond was found previously
 871   ${Map.Get} $0 softwarePathsMap "LilyPond"
 872   ${If} $0 != "__NULL" # If "LilyPond" is set in map
 873     FileWrite $R0 '\format "lilypond-book" "lytex" "LilyPond book (LaTeX)" "" "" "auto" "document,menu=export" ""$\r$\n\
 874                   \converter "lilypond-book" "pdflatex" "python \"$0\\lilypond-book.py\" --safe --pdf --latex-program=pdflatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
 875                   \converter "lilypond-book" "xetex" "python \"$0\\lilypond-book.py\" --safe --pdf --latex-program=xelatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
 876                   \converter "lilypond-book" "luatex" "python \"$0\\lilypond-book.py\" --safe --pdf --latex-program=lualatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
 877                   \converter "lilypond-book" "latex" "python \"$0\\lilypond-book.py\" --safe --lily-output-dir=ly-eps $$$$i" ""$\r$\n'
 878   ${EndIf}
 879
 880   ${Map.Destroy} softwarePathsMap
 881
 882   FileClose $R0
 883
 884   ${If} ${Errors}
 885     MessageBox MB_OK|MB_ICONEXCLAMATION "$(ModifyingConfigureFailed)" /SD IDOK
 886     ClearErrors
 887   ${EndIf}
 888 SectionEnd
 889
 890 Section "$(SecFileAssocTitle)" SecFileAssoc # Registry information to assiciate ".lyx" extension with this LyX installation
 891   Call PrepareShellCTX # Helper function from above
 892
 893   WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\App Paths\LyX.exe" "" "$INSTDIR\bin\LyX.exe" # Writes in both 64 and 32 bit registry
 894   WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\App Paths\LyX.exe" "Version" ${APP_VERSION} # Writes in both 64 and 32 bit registry
 895
 896   WriteRegStr SHCTX "Software\Classes\.lyx" "" "LyX.Document"
 897   WriteRegStr SHCTX "Software\Classes\.lyx" "Content Type" "application/lyx"
 898
 899   WriteRegStr SHCTX "Software\Classes\LyX.Document" "" "LyX Document"
 900   WriteRegStr SHCTX "Software\Classes\LyX.Document\DefaultIcon" "" "$INSTDIR\bin\LyX.exe,1"
 901   WriteRegStr SHCTX "Software\Classes\LyX.Document\Shell\open\command" "" '"$INSTDIR\bin\LyX.exe" "%1"'
 902
 903   # we need to update also the automatically created entry about the lyx.exe
 904   # otherwise .lyx-files will could be opened with an older LyX version
 905   ReadRegStr $0 SHCTX "Software\Classes\Applications\LyX.exe\shell\open\command" ""
 906   ${if} $0 != "" # if something was found
 907     WriteRegStr SHCTX "Software\Classes\Applications\LyX.exe\shell\open\command" "" '"$INSTDIR\bin\LyX.exe" "%1"'
 908   ${endif}
 909
 910   WriteRegStr SHCTX "SOFTWARE\LyX" "FileAssoc${VERSION_MAJOR}${VERSION_MINOR}" $INSTDIR # Save user preference for over-installing
 911 SectionEnd
 912
 913 Section "$(SecDesktopTitle)" SecDesktop
 914   SetOutPath "$INSTDIR\bin" # Need to set this so that the shortcut to lyx.exe is executed in the bin folder
 915   CreateShortCut "$DESKTOP\LyX ${VERSION_MAJOR}.${VERSION_MINOR}.lnk" "$INSTDIR\bin\LyX.exe" "" "" "" "" "" "LyX - The Document Processor" # Last parameter is the comment of the shortcut
 916   Call PrepareShellCTX
 917   WriteRegStr SHCTX "SOFTWARE\LyX" "Desktop${VERSION_MAJOR}${VERSION_MINOR}" $INSTDIR # Save user preference for over-installing
 918 SectionEnd
 919
 920 Section -StartMenuFolder # Creates starm menu shortcut and website links to lyx website and lyx wiki
 921   Call PrepareShellCTX # Helper function from above, need to call be before the following macro, because the macro writes registry string (storing the default startmenu folder)
 922   !insertmacro MUI_STARTMENU_WRITE_BEGIN startmenuPage # This macro also assures that the folder is not empty for us
 923     SetOutPath "$INSTDIR\bin" # Need to set this so that the shortcut to lyx.exe is executed in the bin folder
 924     CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 925     CreateShortCut "$SMPROGRAMS\$StartMenuFolder\LyX.lnk" "$INSTDIR\bin\LyX.exe" "" "" "" "" "" "LyX - The Document Processor" # Last parameter is the comment of the shortcut
 926     SetOutPath $INSTDIR
 927     CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Uninstall LyX.lnk" "$INSTDIR\Uninstall-LyX.exe"
 928     WriteINIStr "$SMPROGRAMS\$StartMenuFolder\LyX Website.url" "InternetShortcut" "URL" "https://www.lyx.org/"
 929     WriteINIStr "$SMPROGRAMS\$StartMenuFolder\LyX Wiki.url" "InternetShortcut" "URL" "https://wiki.lyx.org"
 930   !insertmacro MUI_STARTMENU_WRITE_END
 931 SectionEnd
 932
 933 !include "src\dictionaries.nsh"
 934
 935 Section -SoftwareRegistry # Registry information in "SOFTWARE" subkey
 936   Call PrepareShellCTX # Helper function from above
 937
 938   ReadRegStr $0 SHCTX "SOFTWARE\LyX" "latestVersion"
 939   ${If} $0 S< ${APP_VERSION_DOTLESS}
 940     WriteRegStr SHCTX "SOFTWARE\LyX" "latestVersion" ${APP_VERSION_DOTLESS}
 941   ${EndIf}
 942   WriteRegStr SHCTX "SOFTWARE\LyX\${APP_VERSION_DOTLESS}" "" $INSTDIR
 943   WriteRegStr SHCTX "SOFTWARE\LyX\${APP_VERSION_DOTLESS}" "LaTeX Path" $LatexPath
 944   WriteRegStr SHCTX "SOFTWARE\LyX" "InstDir${VERSION_MAJOR}${VERSION_MINOR}" $INSTDIR # Remember install dir for the next over-installment of the same series
 945 SectionEnd
 946
 947 Section -UninstallInfoRegistry # Registry information in "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" subkey
 948   Call PrepareShellCTX # Helper function from above
 949
 950   ${If} $MultiUser.InstallMode == "AllUsers"
 951     WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "DisplayName" "LyX ${APP_VERSION}"
 952   ${Else}
 953     WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "DisplayName" "LyX ${APP_VERSION} $(TEXT_INSTALL_CURRENTUSER)"
 954   ${EndIf}
 955
 956   WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "UninstallString" '"$INSTDIR\Uninstall-LyX.exe"'
 957   WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "DisplayVersion" "${APP_VERSION}"
 958   WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "VersionMajor" "${VERSION_MAJOR}"
 959   WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "VersionMinor" "${VERSION_MINOR}"
 960   WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "DisplayIcon" "$INSTDIR\bin\LyX.exe"
 961   WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "URLUpdateInfo" "https://www.lyx.org/"
 962   WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "URLInfoAbout" "https://www.lyx.org/AboutLyX"
 963   WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "Publisher" "LyX Team"
 964   WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "HelpLink" "https://www.lyx.org/MailingLists"
 965   WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "NoModify" 0x00000001
 966   WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "NoRepair" 0x00000001
 967   WriteRegStr SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "InstallLocation" "$INSTDIR"
 968
 969   ${GetSize} "$INSTDIR" "/S=0K" $0 $1 $2
 970   IntFmt $0 "0x%08X" $0
 971   WriteRegDWORD SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}" "EstimatedSize" $0
 972 SectionEnd
 973
 974 !if ${VERSION_MINOR} > 0 # Only valid for minor releases of the same major release (e.g. not valid for 3.0)
 975   Section -CopyOldPreferences # Searches user's preferences (userdir) from previous minor release and copies it if necessary
 976     Call PrepareShellCTX
 977     SetShellVarContext current # Otherwise $APPDATA would return C:\ProgrammData instead of C:\Users\username\AppData\Roaming
 978
 979     IntOp $0 ${VERSION_MINOR} - 1 # only check the direct previous minor release
 980     ${If} ${FileExists} "$APPDATA\LyX${VERSION_MAJOR}.$0\lyxrc.defaults"
 981     ${AndIfNot} ${FileExists} "$APPDATA\LyX${VERSION_MAJOR}.${VERSION_MINOR}\lyxrc.defaults"
 982       CopyFiles /SILENT "$APPDATA\LyX${VERSION_MAJOR}.$0\*.*" "$APPDATA\LyX${VERSION_MAJOR}.${VERSION_MINOR}"
 983     ${EndIf}
 984   SectionEnd
 985 !endif
 986
 987 Section -ConfigureScript # Runs the configure.py script
 988
 989   # Manipulate PATH environment of the running installer process, so that configure.py can find all the stuff needed
 990   ReadEnvStr $0 "PATH"
 991   ${StrRep} $pathPrefix $pathPrefix "$$LyXDir" "$INSTDIR"
 992   System::Call 'Kernel32::SetEnvironmentVariable(t "PATH", t "$pathPrefix;$0")'
 993
 994   Call PrepareShellCTX
 995   SetShellVarContext current # Otherwise $APPDATA would return C:\ProgrammData instead of C:\Users\username\AppData\Roaming
 996   SetOutPath "$APPDATA\LyX${VERSION_MAJOR}.${VERSION_MINOR}" # Need to run configure from the user dir, because it creates .lst files and some folders.
 997
 998   ${StrStr} $0 $LatexPath "\miktex\bin"
 999   # R9 is used in $(TEXT_CONFIGURE_LYX)
1000   ${If} $0 == "" # TexLive
1001     StrCpy $R9 "TeXLive"
1002   ${Else}
1003     StrCpy $R9 "MiKTeX"
1004   ${EndIf}
1005   StrCpy $LaTeXInstalled $R9 # FIXME remove
1006   DetailPrint $(TEXT_CONFIGURE_LYX) # Uses R9 to display the name of the installed latex distribution
1007
1008   nsExec::ExecToLog '"$INSTDIR\Python\python.exe" "$INSTDIR\Resources\configure.py"'
1009   Pop $0 # Return value
1010 SectionEnd
1011
1012 Function DefaultDesktopFileAssoc # Custom function, called before the components page, reads the states of SecDesktop and SecFileAssoc from registry (if overinstalling) and sets them
1013
1014   Call CheckDictionaries # Search for already installed dictionaries, in dictionaries.nsh
1015
1016   ${IfNot} ${FileExists} "$INSTDIR\Uninstall-LyX.exe"
1017     Return # Not over-installing
1018   ${EndIf}
1019
1020   Call PrepareShellCTX
1021   ReadRegStr $0 SHCTX "SOFTWARE\LyX" "FileAssoc${VERSION_MAJOR}${VERSION_MINOR}"
1022   ${If} $0 == ""
1023     SectionSetFlags ${SecFileAssoc} 0 # 0 means unselected
1024   ${EndIf}
1025   ReadRegStr $0 SHCTX "SOFTWARE\LyX" "Desktop${VERSION_MAJOR}${VERSION_MINOR}"
1026   ${If} $0 == ""
1027     SectionSetFlags ${SecDesktop} 0 # 0 means unselected
1028   ${EndIf}
1029 FunctionEnd
1030
1031 Function StartLyX
1032   ShellExecAsUser::ShellExecAsUser "" "$INSTDIR\bin\LyX.exe"
1033 FunctionEnd
1034
1035 # Installer Section Descriptions
1036
1037 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
1038   !insertmacro MUI_DESCRIPTION_TEXT ${SecFileAssoc} "$(SecFileAssocDescription)"
1039   !insertmacro MUI_DESCRIPTION_TEXT ${SecDesktop} "$(SecDesktopDescription)"
1040   !insertmacro MUI_DESCRIPTION_TEXT ${SecDictionaries} "$(SecDictionariesDescription)" # In dictionaries.nsh
1041   !insertmacro MUI_DESCRIPTION_TEXT ${SecThesaurus} "$(SecThesaurusDescription)" # In dictionaries.nsh
1042 !insertmacro MUI_FUNCTION_DESCRIPTION_END
1043
1044 # ===== Uninstaller ======
1045
1046 Function un.onInit # Callback function, called when the uninstaller initializes
1047   # Check that LyX is not currently running
1048   ${If} ${RunningX64}
1049     ${DisableX64FSRedirection} # We need the following process to be 64 bit on 64 bit system
1050   ${EndIf}
1051   nsExec::ExecToStack "powershell (Get-Process LyX).Path"
1052   Pop $0 # Exit code
1053   Pop $0 # Result string
1054   ${If} ${RunningX64}
1055     ${EnableX64FSRedirection} # Need to be enabled asap or installer might crash
1056   ${EndIf}
1057   ${UnStrStr} $0 $0 "$INSTDIR\bin\LyX.exe"
1058   ${If} $0 != ""
1059     MessageBox MB_OK|MB_ICONSTOP "$(UnInstallRunning)" /SD IDOK
1060     Quit # Quit uninstaller
1061   ${EndIf}
1062
1063   Call un.PrepareShellCTX
1064   !insertmacro MULTIUSER_UNINIT
1065
1066   # Ascertain whether the user has sufficient privileges to uninstall.
1067   # abort when LyX was installed with admin permissions but the user doesn't have administrator privileges
1068   Call un.PrepareShellCTX # Helperfunction from above
1069   ReadRegStr $0 HKLM "SOFTWARE\LyX\${APP_VERSION_DOTLESS}" ""
1070   ${If} $0 == $INSTDIR
1071     ${If} $MultiUser.Privileges != "Admin"
1072     ${AndIf} $MultiUser.Privileges != "Power"
1073       MessageBox MB_OK|MB_ICONSTOP "$(UnNotAdminLabel)" /SD IDOK
1074       Abort
1075     ${Else}
1076       StrCpy $MultiUser.InstallMode "AllUsers"
1077     ${EndIf}
1078   ${Else}
1079     ReadRegStr $0 HKCU "SOFTWARE\LyX\${APP_VERSION_DOTLESS}" ""
1080     ${If} $0 == ""
1081       MessageBox MB_OK|MB_ICONEXCLAMATION "$(UnNotInRegistryLabel)" /SD IDOK
1082     ${Else}
1083       StrCpy $MultiUser.InstallMode "CurrentUser"
1084     ${EndIf}
1085   ${EndIf}
1086
1087   # question message if the user really wants to uninstall LyX
1088   ${IfCmd} MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "$(UnReallyRemoveLabel)" /SD IDYES IDNO ${||} Quit ${|}
1089 FunctionEnd
1090
1091 Function un.ComponentsPre # Callback Function, called before the components page is loaded
1092   # R9 and R8 are used in $(SecUnPreferencesDescription)
1093   SetShellVarContext current
1094   ${UnStrStrAdv} $R9 $PROFILE "\" "<" "<" "0" "0" "0" # Get everything before the last "\" of $PROFILE ("C:\Users\username") -> $R9: "C:\Users"
1095   StrCpy $AppPre $R9 # FIXME remove
1096   ${UnStrRep} $R8 $APPDATA "$PROFILE\" "" # "C:\Users\username\" gets replaced with "" in "C:\Users\username\AppData\Roaming" -> $R8: "Appdata\Roaming"
1097   StrCpy $AppSuff $R8 # FIXME remove
1098 FunctionEnd
1099
1100 Section "un.LyX" un.SecUnProgramFiles # Deletes files in $INSTDIR and registry entries
1101   SectionIn RO
1102   # LaTeX class files that were installed together with LyX
1103   # will not be uninstalled because other LyX versions will
1104   # need them and these few files don't harm to stay in LaTeX
1105
1106   Call un.PrepareShellCTX # Helperfunction from above
1107
1108   # Subfolders and unistaller
1109   RMDir /r "$INSTDIR\bin"
1110   RMDir /r "$INSTDIR\Resources"
1111   RMDir /r "$INSTDIR\Python"
1112   RMDir /r "$INSTDIR\imagemagick"
1113   RMDir /r "$INSTDIR\ghostscript"
1114   Delete "$INSTDIR\Uninstall-LyX.exe"
1115   # Install directory
1116   SetOutPath $PLUGINSDIR
1117   RMDir $INSTDIR
1118
1119   # Startmenu
1120   !insertmacro MUI_STARTMENU_GETFOLDER startmenuPage $StartMenuFolder # Reads registry value written with macro MUI_STARTMENU_WRITE_BEGIN
1121   ShellLink::GetShortCutTarget "$SMPROGRAMS\$StartMenuFolder\LyX.lnk" # Check if the shortcut really is pointing to the current installation
1122   Pop $0
1123   ${IfNot} ${FileExists} $0 # If still exists, then belongs to another lyx installment, so don't delete
1124     RMDir /r "$SMPROGRAMS\$StartMenuFolder"
1125     DeleteRegValue SHCTX "SOFTWARE\LyX" "SMDir${VERSION_MAJOR}${VERSION_MINOR}"
1126   ${EndIf}
1127
1128   # Desktop icon
1129   ShellLink::GetShortCutTarget "$DESKTOP\LyX ${VERSION_MAJOR}.${VERSION_MINOR}.lnk"
1130   Pop $0
1131   ${UnStrStr} $0 $0 $INSTDIR
1132   ${If} $0 != ""
1133     Delete "$DESKTOP\LyX ${VERSION_MAJOR}.${VERSION_MINOR}.lnk"
1134   ${EndIf}
1135   ReadRegStr $0 SHCTX "SOFTWARE\LyX" "Desktop${VERSION_MAJOR}${VERSION_MINOR}"
1136   ${If} $0 == $INSTDIR
1137     DeleteRegValue SHCTX "SOFTWARE\LyX" "Desktop${VERSION_MAJOR}${VERSION_MINOR}"
1138   ${EndIf}
1139
1140   # File association
1141   ReadRegStr $0 SHCTX "Software\Classes\LyX.Document\DefaultIcon" ""
1142   ${UnStrStr} $0 $0 $INSTDIR
1143   ${If} $0 != ""
1144     DeleteRegKey SHCTX "Software\Classes\LyX.Document"
1145     DeleteRegKey SHCTX "Software\Classes\.lyx"
1146   ${EndIf}
1147   ReadRegStr $0 SHCTX "Software\Microsoft\Windows\CurrentVersion\App Paths\LyX.exe" ""
1148   ${UnStrStr} $0 $0 $INSTDIR
1149   ${If} $0 != ""
1150     DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\App Paths\LyX.exe" # Deletes key in both 64 and 32 bit registry
1151   ${EndIf}
1152   ReadRegStr $0 SHCTX "SOFTWARE\LyX" "FileAssoc${VERSION_MAJOR}${VERSION_MINOR}"
1153   ${If} $0 == $INSTDIR
1154     DeleteRegValue SHCTX "SOFTWARE\LyX" "FileAssoc${VERSION_MAJOR}${VERSION_MINOR}"
1155   ${EndIf}
1156   DeleteRegKey SHCTX "Software\Classes\Applications\LyX.exe"
1157
1158   # Uninstaller info registry
1159   DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\LyX${APP_VERSION_DOTLESS}"
1160
1161   # Software registry
1162   DeleteRegKey SHCTX "SOFTWARE\LyX\${APP_VERSION_DOTLESS}"
1163   DeleteRegValue SHCTX "SOFTWARE\LyX" "latestVersion"
1164   ReadRegStr $0 SHCTX "SOFTWARE\LyX" "InstDir${VERSION_MAJOR}${VERSION_MINOR}"
1165   ${If} $0 == $INSTDIR
1166     DeleteRegValue SHCTX "SOFTWARE\LyX" "InstDir${VERSION_MAJOR}${VERSION_MINOR}"
1167   ${EndIf}
1168   DeleteRegValue SHCTX "SOFTWARE\LyX" "latestVersion"
1169   # Now that "latestVersion" is gone we need to find if there is another (newest) LyX version installed and write it's verion to "latestVersion"
1170   # The keys in the registry are sorted alphabetically, so we dont need to compare, the latest found will be the newest version
1171   StrCpy $0 0
1172   StrCpy $1 ""
1173   ${Do}
1174     StrCpy $2 $1
1175     EnumRegKey $2 SHCTX "SOFTWARE\LyX" $0
1176     IntOp $0 $0 + 1
1177   ${LoopUntil} $1 == ""
1178   ${If} $2 != ""
1179     WriteRegStr SHCTX "SOFTWARE\LyX" "latestVersion" $2
1180   ${EndIf}
1181   DeleteRegKey /ifempty SHCTX "SOFTWARE\LyX"
1182 SectionEnd
1183
1184 Section /o "un.$(UnLyXPreferencesTitle)" un.SecUnPreferences # Deletes user preferences folders for all users (if admin) and registry entry made by LyX to HKCU
1185   Call un.PrepareShellCTX
1186   SetShellVarContext current
1187   # If installed as user, only delete folder and registry key of current user
1188   ${If} $MultiUser.InstallMode == "CurrentUser"
1189     RMDir /r "$APPDATA\LyX${VERSION_MAJOR}.${VERSION_MINOR}"
1190
1191   ${Else} # If installed as admin, things are a little more complicated
1192     ${UnStrStrAdv} $2 $PROFILE "\" "<" ">" "0" "0" "0" # Get everything after the last "\" of $PROFILE ("C:\Users\username") -> $2: "username"
1193     ${UnStrStrAdv} $3 $PROFILE "\" "<" "<" "0" "0" "0" # Get everything before the last "\" of $PROFILE ("C:\Users\username") -> $3: "C:\Users"
1194     ClearErrors
1195     FindFirst $1 $0 "$3\*" # Find any folder/file in "C:\Users"
1196     ${DoUntil} ${Errors} # Errors are set while FindFirst/FindNext if the search is completed (there are no more files)
1197       ${UnStrRep} $0 $APPDATA $2 $0 # Replace "username" in $APPDATA ("C:\Users\username\AppData\Roaming") with what was found
1198       ${If} ${FileExists} "$0\LyX${VERSION_MAJOR}.${VERSION_MINOR}\*" # Check if anything exists in the LyX userdir
1199         RMDir /r "$0\LyX${VERSION_MAJOR}.${VERSION_MINOR}"
1200       ${EndIf}
1201       FindNext $1 $0
1202     ${Loop}
1203     FindClose $1
1204   ${EndIf}
1205
1206   # Can only delete for current user, because Admin can't access registry of other users
1207   DeleteRegKey HKCU "Software\LyX\LyX${VERSION_MAJOR}.${VERSION_MINOR}"
1208   DeleteRegKey /ifempty HKCU "Software\LyX"
1209 SectionEnd
1210
1211 # Uninstaller Section Descriptions
1212
1213 !insertmacro MUI_UNFUNCTION_DESCRIPTION_BEGIN
1214   !insertmacro MUI_DESCRIPTION_TEXT ${un.SecUnProgramFiles} "$(SecUnProgramFilesDescription)"
1215   !insertmacro MUI_DESCRIPTION_TEXT ${un.SecUnPreferences} "$(SecUnPreferencesDescription)"
1216 !insertmacro MUI_UNFUNCTION_DESCRIPTION_END