development/Win32/packaging/installer/setup/uninstall.nsh

   1 /*
   2
   3 uninstall.nsh
   4
   5 Uninstall
   6
   7 */
   8
   9 Var FileAssociation
  10
  11 # ----------------------------------
  12
  13 Section "un.LyX" un.SecUnProgramFiles
  14
  15   SectionIn RO
  16   # LaTeX class files that were installed together with LyX
  17   # will not be uninstalled because other LyX versions will
  18   # need them and these few files don't harm to stay in LaTeX
  19
  20   # Binaries
  21   RMDir /r "$INSTDIR\bin"
  22
  23   # Resources
  24   RMDir /r "$INSTDIR\Resources"
  25
  26   # Python
  27   RMDir /r "$INSTDIR\python"
  28   ReadRegStr $0 SHCTX "Software\Classes\Python.File" "OnlyWithLyX" # test if it was registered by this LyX version
  29   ${if} $0 == "Yes${APP_SERIES_KEY}"
  30    DeleteRegKey SHCTX "Software\Classes\Python.File"
  31   ${endif}
  32
  33   # ImageMagick
  34   RMDir /r "$INSTDIR\imagemagick"
  35   ReadRegStr $0 SHCTX "SOFTWARE\ImageMagick" "OnlyWithLyX" # test if it was installed together with this LyX version
  36   ${if} $0 == "Yes${APP_SERIES_KEY}"
  37    WriteRegStr SHCTX "SOFTWARE\Classes\Applications" "AutoRun" ""
  38    DeleteRegKey SHCTX "Software\ImageMagick"
  39   ${endif}
  40
  41   # Components of Ghostscript
  42   RMDir /r "$INSTDIR\ghostscript"
  43
  44   # delete start menu folder
  45   ReadRegStr $0 SHCTX "${APP_UNINST_KEY}" "StartMenu"
  46   RMDir /r "$0"
  47   # delete desktop icon
  48   Delete "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk"
  49
  50   # remove file extension .lyx
  51   ReadRegStr $0 SHCTX "${APP_DIR_REGKEY}" "OnlyWithLyX" # test if they were registered by this LyX version
  52   ${if} $0 == "Yes${APP_SERIES_KEY}"
  53    ReadRegStr $R0 SHCTX "Software\Classes\${APP_EXT}" ""
  54    ${if} $R0 == "${APP_REGNAME_DOC}"
  55     #DeleteRegKey SHCTX "Software\Classes\${APP_EXT}13"
  56     #DeleteRegKey SHCTX "Software\Classes\${APP_EXT}14"
  57     #DeleteRegKey SHCTX "Software\Classes\${APP_EXT}15"
  58     #DeleteRegKey SHCTX "Software\Classes\${APP_EXT}16"
  59     #DeleteRegKey SHCTX "Software\Classes\${APP_EXT}20"
  60     #DeleteRegKey SHCTX "Software\Classes\${APP_EXT}21"
  61     DeleteRegKey SHCTX "Software\Classes\${APP_EXT}"
  62     #DeleteRegKey SHCTX "Software\Classes\${APP_REGNAME_DOC}"
  63    ${endif}
  64   ${endif}
  65   ${if} $MultiUser.Privileges == "Admin"
  66    DeleteRegKey HKCR "LyX.Document"
  67   ${endif}
  68
  69   # Uninstaller itself
  70   Delete "$INSTDIR\${SETUP_UNINSTALLER}"
  71
  72   # Application folder
  73   SetOutPath "$TEMP"
  74   RMDir /r "$INSTDIR"
  75
  76   # Registry keys
  77   DeleteRegKey SHCTX "${APP_REGKEY_SETUP}"
  78   DeleteRegKey SHCTX "${APP_REGKEY}"
  79   DeleteRegKey SHCTX "${APP_UNINST_KEY}"
  80   DeleteRegKey HKCR "Applications\lyx.exe"
  81
  82   # File associations
  83   ReadRegStr $FileAssociation SHELL_CONTEXT "Software\Classes\${APP_EXT}" ""
  84
  85   ${If} $FileAssociation == "${APP_REGNAME_DOC}"
  86      DeleteRegKey SHELL_CONTEXT "Software\Classes\${APP_EXT}"
  87   ${EndIf}
  88
  89   # clean other registry entries
  90   DeleteRegKey SHCTX "SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\${APP_NAME}.exe"
  91   DeleteRegKey SHCTX "SOFTWARE\${APP_REGKEY}"
  92
  93   # delete info that programs were installed together with LyX
  94   DeleteRegValue SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef ${JabRefVersion}" "OnlyWithLyX"
  95   DeleteRegValue SHCTX "SOFTWARE\MiKTeX.org\MiKTeX" "OnlyWithLyX"
  96
  97   # for texindy the path to the perl.exe must unfortunately be in Windows' PATH variable
  98   # so we have to remove it now
  99   ${if} $MultiUser.Privileges != "Admin"
 100   ${andif} $MultiUser.Privileges != "Power"
 101    # call the non-admin version
 102    ${un.EnvVarUpdate} $0 "PATH" "R" "HKCU" "$INSTDIR\Perl\bin"
 103   ${else}
 104    ${un.EnvVarUpdate} $0 "PATH" "R" "HKLM" "$INSTDIR\Perl\bin"
 105   ${endif}
 106
 107 SectionEnd
 108
 109 #---------------------------------
 110 # user preferences
 111 Section /o "un.$(UnLyXPreferencesTitle)" un.SecUnPreferences
 112
 113  # remove LyX's config files
 114  StrCpy $AppSubfolder ${APP_DIR_USERDATA}
 115  Call un.DelAppPathSub # function from LyXUtils.nsh
 116
 117 SectionEnd
 118
 119 #---------------------------------
 120 # MiKTeX
 121 Section /o "un.MiKTeX" un.SecUnMiKTeX
 122
 123  ${if} $LaTeXInstalled == "MiKTeX" # only uninstall MiKTeX when it was installed together with LyX
 124   ReadRegStr $1 SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\MiKTeX ${MiKTeXDeliveredVersion}" "UninstallString"
 125   ExecWait $1 # run MiKTeX's uninstaller
 126  ${endif}
 127
 128 SectionEnd
 129
 130 #---------------------------------
 131 # JabRef
 132 Section "un.JabRef" un.SecUnJabRef
 133
 134  ${if} $JabRefInstalled == "Yes" # only uninstall JabRef when it was installed together with LyX
 135   ${If} $MultiUser.Privileges == "Admin"
 136   ${OrIf} $MultiUser.Privileges == "Power"
 137    ReadRegStr $1 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef ${JabRefVersion}" "UninstallString"
 138    IfSilent 0 +2
 139    ExecWait "$1 /S" # run JabRef's uninstaller
 140    ExecWait "$1" # run JabRef's uninstaller
 141   ${else}
 142    # in this case we can only read the start menu location and then start the linked uninstaller
 143    ReadRegStr $1 HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef ${JabRefVersion}" "StartMenu"
 144    StrCpy $1 "$1\Uninstall JabRef "${JabRefVersion}".lnk"
 145    ExecShell "" "$1" # run JabRef's uninstaller
 146   ${endif}
 147  ${endif}
 148
 149 SectionEnd
 150
 151 #---------------------------------
 152 # Section descriptions
 153 !insertmacro MUI_UNFUNCTION_DESCRIPTION_BEGIN
 154 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecUnMiKTeX} "$(SecUnMiKTeXDescription)"
 155 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecUnJabRef} "$(SecUnJabRefDescription)"
 156 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecUnPreferences} "$(SecUnPreferencesDescription)"
 157 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecUnProgramFiles} "$(SecUnProgramFilesDescription)"
 158 !insertmacro MUI_UNFUNCTION_DESCRIPTION_END
 159
 160 #Section "un.User Preferences and Custom Files" un.SecUserFiles
 161 #
 162 #  SetShellVarContext current
 163 #  RMDir /r "$APPDATA\${APP_DIR_USERDATA}"
 164 #
 165 #SectionEnd