development/Win32/packaging/installer/setup/install.nsh

   1 /*
   2
   3 install.nsh
   4
   5 Installation of program files, dictionaries and external components
   6
   7 */
   8
   9 #--------------------------------
  10 # Program files
  11
  12 Var PythonCompileFile
  13 Var PythonCompileReturn
  14 #Var DownloadResult
  15
  16 Section -ProgramFiles SecProgramFiles
  17
  18   # Install and register the core LyX files
  19
  20   # The macros are defined in filelists.nsh
  21   # the parameters are COMMAND DIRECTORY that form command '${COMMAND} "${DIRECTORY}files"
  22
  23   # Initializes the plug-ins dir ($PLUGINSDIR) if not already initialized.
  24   # $PLUGINSDIR is automatically deleted when the installer exits.
  25   InitPluginsDir
  26
  27   # Binaries
  28   SetOutPath "$INSTDIR\bin"
  29   !insertmacro FileListLyXBin File "${FILES_LYX}\bin\"
  30   !insertmacro FileListQtBin File "${FILES_QT}\bin\"
  31   !insertmacro FileListQtImageformats File "${FILES_QT}\plugins\imageformats\"
  32   !insertmacro FileListDll File "${FILES_DEPS}\bin\"
  33   !insertmacro FileListMSVC File "${FILES_MSVC}\"
  34   !insertmacro FileListNetpbmBin File "${FILES_NETPBM}\"
  35   !insertmacro FileListDTLBin File "${FILES_DTL}\"
  36   !insertmacro FileListDvipostBin File "${FILES_DVIPOST}\"
  37   !insertmacro FileListPDFViewBin File "${FILES_PDFVIEW}\"
  38   !insertmacro FileListPDFToolsBin File "${FILES_PDFTOOLS}\"
  39   !insertmacro FileListMetaFile2EPS File "${FILES_METAFILE2EPS}\"
  40
  41   # Resources
  42   SetOutPath "$INSTDIR"
  43   # recursively copy all files under Resources
  44   File /r "${FILES_LYX}\Resources"
  45
  46   !if ${SETUPTYPE} == BUNDLE
  47
  48    # extract the Jabref and MiKTeX installer
  49    File /r "${FILES_LYX}\external"
  50
  51    # install MiKTeX if not already installed
  52    Call InstallMiKTeX # function from LaTeX.nsh
  53
  54   !endif # end if BUNDLE
  55
  56   # Python
  57   SetOutPath "$INSTDIR"
  58   # recursively copy all files under Python
  59   File /r "${FILES_PYTHON}"
  60
  61   # Compile all Pyton files to byte-code
  62   # The user using the scripts may not have write access
  63   FileOpen $PythonCompileFile "$INSTDIR\compilepy.py" w
  64   FileWrite $PythonCompileFile "import compileall$\r$\n"
  65   FileWrite $PythonCompileFile "compileall.compile_dir('$INSTDIR\python\Lib')$\r$\n"
  66   FileWrite $PythonCompileFile "compileall.compile_dir('$INSTDIR\Resources')$\r$\n"
  67   FileClose $PythonCompileFile
  68   DetailPrint $(TEXT_CONFIGURE_PYTHON)
  69   nsExec::ExecToLog '"$INSTDIR\python\python.exe" "$INSTDIR\compilepy.py"'
  70   Pop $PythonCompileReturn # Return value
  71   Delete "$INSTDIR\compilepy.py"
  72
  73   # Components of ImageMagick
  74   SetOutPath "$INSTDIR\imagemagick"
  75   File /r "${FILES_IMAGEMAGICK}\"
  76   !insertmacro FileListMSVC File "${FILES_MSVC}\"
  77   # register ImageMagick
  78   WriteRegStr SHCTX "SOFTWARE\Classes\Applications" "AutoRun" "$INSTDIR\imagemagick\convert.exe $$"
  79   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "BinPath" "$INSTDIR\imagemagick"
  80   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "CoderModulesPath" "$INSTDIR\imagemagick\modules\coders"
  81   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "ConfigurePath" "$INSTDIR\imagemagick"
  82   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "FilterModulesPath" "$INSTDIR\imagemagick\modules\filters"
  83   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "LibPath" "$INSTDIR\imagemagick"
  84   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "BinPath" "$INSTDIR\imagemagick"
  85   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "CoderModulesPath" "$INSTDIR\imagemagick\modules\coders"
  86   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "ConfigurePath" "$INSTDIR\imagemagick"
  87   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "FilterModulesPath" "$INSTDIR\imagemagick\modules\filters"
  88   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "LibPath" "$INSTDIR\imagemagick"
  89   WriteRegDWORD SHCTX "SOFTWARE\ImageMagick\Current" "QuantumDepth" 0x00000010
  90   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "Version" "${ImageMagickVersion}"
  91
  92   # Components of Ghostscript
  93   ${if} $GhostscriptPath == ""
  94    SetOutPath "$INSTDIR\ghostscript"
  95    File /r "${FILES_GHOSTSCRIPT}\"
  96    !insertmacro FileListMSVC File "${FILES_MSVC}\"
  97    StrCpy $GhostscriptPath "$INSTDIR\ghostscript\bin"
  98   ${endif}
  99
 100   !if ${SETUPTYPE} == BUNDLE
 101
 102    # install JabRef if not already installed and the user selected it
 103    # if no BibTeX editor is installed
 104    ${if} $PathBibTeXEditor == ""
 105     ${if} $InstallJabRef == "true"
 106      # launch installer
 107      MessageBox MB_OK|MB_ICONINFORMATION "$(JabRefInfo)"
 108      ExecWait "$INSTDIR\${JabRefInstall}"
 109      # test if JabRef is now installed
 110      StrCpy $PathBibTeXEditor ""
 111      ReadRegStr $PathBibTeXEditor HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef ${JabRefVersion}" "UninstallString"
 112      ${if} $PathBibTeXEditor == ""
 113       MessageBox MB_OK|MB_ICONEXCLAMATION "$(JabRefError)"
 114      ${else}
 115       WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef ${JabRefVersion}" "OnlyWithLyX" "Yes${APP_SERIES_KEY}" # special entry to tell the uninstaller that it was installed with LyX
 116      ${endif}
 117     ${endif}
 118    ${endif}
 119   !endif # end if BUNDLE
 120
 121    # install eLyXer
 122    SetOutPath "$INSTDIR\Python\Lib"
 123    !insertmacro FileListeLyXer File "${FILES_ELYXER}\"
 124
 125    # install unoconv
 126    SetOutPath "$INSTDIR\Python\Lib"
 127    !insertmacro FileListUnoConv File "${FILES_UNOCONV}\"
 128
 129   # install the LaTeX class files that are delivered with LyX
 130   # and enable MiKTeX's automatic package installation
 131   ${if} $LaTeXInstalled == "MiKTeX"
 132    Call ConfigureMiKTeX # Function from LaTeX.nsh
 133   ${endif}
 134
 135   # Create uninstaller
 136   WriteUninstaller "$INSTDIR\${SETUP_UNINSTALLER}"
 137
 138 SectionEnd
 139
 140 #--------------------------------
 141 # Support code for file downloads
 142
 143 !macro DOWNLOAD_FILE RET ID FILENAME APPEND
 144
 145   # Downloads a file
 146
 147   # RET = Return value (OK if succesful)
 148   # ID = Name of the download in settings.nsh
 149   # FILENAME = Location to store file
 150   # APPEND = Filename to append to server location in settings.nsh
 151
 152   # Try first time
 153   NSISdl::download "${DOWNLOAD_${ID}}${APPEND}" "$PLUGINSDIR\${FILENAME}"
 154   Pop ${RET} # Return value (OK if succesful)
 155
 156   ${If} ${RET} != "success"
 157     ${AndIf} ${RET} != "cancel"
 158     # Download failed, try once again before giving up
 159     # (usally we get a different mirror)
 160     NSISdl::download "${DOWNLOAD_${ID}}${APPEND}" "$PLUGINSDIR\${FILENAME}"
 161     Pop ${RET}
 162   ${EndIf}
 163
 164 !macroend
 165
 166 #--------------------------------
 167 # Extenral components
 168
 169 #Var PathAllUsers
 170 #Var PathCurrentUser
 171
 172 !macro EXTERNAL COMPONENT
 173
 174   # Download/Install the component
 175
 176   ${If} $Setup${COMPONENT} == ${TRUE}
 177
 178     StrCpy $Path${COMPONENT} "" ;A new one will be installed
 179
 180     !ifndef BUNDLESETUP_${COMPONENT}
 181       !insertmacro EXTERNAL_DOWNLOAD ${COMPONENT}
 182     !else
 183       !insertmacro EXTERNAL_INSTALL ${COMPONENT}
 184     !endif
 185
 186   ${EndIf}
 187
 188 !macroend
 189
 190 !macro EXTERNAL_RUNINSTALLER COMPONENT
 191
 192   # Run the installer application of the component that does the actual installation.
 193
 194   install_${COMPONENT}:
 195
 196     ExecWait '"$PLUGINSDIR\${COMPONENT}Setup.exe"'
 197
 198     # Updates the path environment variable of the installer process to the latest system value
 199 #    ReadRegStr $PathAllUsers HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" Path
 200 #    ReadRegStr $PathCurrentUser HKCU "Environment" Path
 201 #    System::Call 'kernel32::SetEnvironmentVariableA(t, t) i("Path", "$PathAllUsers;$PathCurrentUser").'
 202
 203     Call Search${COMPONENT}
 204
 205     ${If} $Path${COMPONENT} == ""
 206       MessageBox MB_YESNO|MB_ICONEXCLAMATION $(TEXT_NOTINSTALLED_${COMPONENT}) IDYES install_${COMPONENT}
 207     ${EndIf}
 208
 209     Delete "$PLUGINSDIR\${COMPONENT}Setup.exe"
 210
 211 !macroend
 212
 213 !macro EXTERNAL_DOWNLOAD COMPONENT
 214
 215   download_${COMPONENT}:
 216
 217     !insertmacro DOWNLOAD_FILE $DownloadResult "${COMPONENT}" "${COMPONENT}Setup.exe" ""
 218
 219     ${If} $DownloadResult != "success"
 220       ${AndIf} $DownloadResult != "cancel"
 221       # Download failed after trying twice - ask user
 222       MessageBox MB_YESNO|MB_ICONEXCLAMATION "$(TEXT_DOWNLOAD_FAILED_${COMPONENT}) ($DownloadResult)" IDYES download_${COMPONENT}
 223       Goto noinstall_${COMPONENT}
 224     ${EndIf}
 225
 226     !insertmacro EXTERNAL_RUNINSTALLER ${COMPONENT}
 227
 228   noinstall_${COMPONENT}:
 229
 230 !macroend
 231
 232 !macro EXTERNAL_INSTALL COMPONENT
 233
 234   # Extract
 235   File /oname=$PLUGINSDIR\${COMPONENT}Setup.exe ${FILES_BUNDLE}\${INSTALL_${COMPONENT}}
 236
 237   !insertmacro EXTERNAL_RUNINSTALLER ${COMPONENT}
 238
 239 !macroend
 240
 241
 242 # Sections for external components
 243
 244 #Section -LaTeX ExternalLaTeX
 245 #  !insertmacro EXTERNAL LaTeX
 246 #SectionEnd
 247
 248 /*Function InitExternal
 249
 250   # Get sizes of external component installers
 251
 252   #SectionGetSize ${ExternalLaTeX} $SizeLaTeX
 253
 254   # Add download size
 255
 256   !ifndef BUNDLESETUP_MIKTEX
 257     IntOp $SizeLaTeX $SizeLaTeX + ${SIZE_DOWNLOAD_LATEX}
 258   !endif
 259
 260 FunctionEnd*/