development/Win32/packaging/installer/setup/install.nsh

   1 /*
   2
   3 install.nsh
   4
   5 Installation of program files, dictionaries and external components
   6
   7 */
   8
   9 #--------------------------------
  10 # Program files
  11
  12 Var PythonCompileFile
  13 Var PythonCompileReturn
  14
  15 Section -ProgramFiles SecProgramFiles
  16
  17   # if the $INSTDIR does not contain "LyX" we must add a subfolder to avoid that LyX will e.g.
  18   # be installed directly to C:\programs - the uninstaller will then delete the whole
  19   # C:\programs directory
  20   StrCpy $String $INSTDIR
  21   StrCpy $Search "LyX"
  22   Call StrPoint # function from LyXUtils.nsh
  23   ${if} $Pointer == "-1"
  24    StrCpy $INSTDIR "$INSTDIR\${APP_DIR}"
  25   ${endif}
  26
  27  !if ${SETUPTYPE} != BUNDLE
  28   # abort the installation if no LaTeX was found but should be used
  29   ${if} $PathLaTeX == ""
  30   ${andif} $State == "0"
  31    SetOutPath $TEMP # to be able to delete the $INSTDIR
  32    RMDir /r $INSTDIR
  33    Abort
  34   ${endif}
  35  !endif # end if != BUNDLE
  36
  37   # Install and register the core LyX files
  38
  39   # The macros are defined in filelists.nsh
  40   # the parameters are COMMAND DIRECTORY that form command '${COMMAND} "${DIRECTORY}files"
  41
  42   # Initializes the plug-ins dir ($PLUGINSDIR) if not already initialized.
  43   # $PLUGINSDIR is automatically deleted when the installer exits.
  44   InitPluginsDir
  45
  46   # Binaries
  47   SetOutPath "$INSTDIR\bin"
  48   !insertmacro FileListLyXBin File "${FILES_LYX}\bin\"
  49   !insertmacro FileListQtBin File "${FILES_QT}\bin\"
  50   !insertmacro FileListMSVC File "${FILES_MSVC}\"
  51   !insertmacro FileListNetpbmBin File "${FILES_NETPBM}\"
  52   !insertmacro FileListDTLBin File "${FILES_DTL}\"
  53   !insertmacro FileListRsvg File "${FILES_RSVG}\"
  54   !insertmacro FileListDvipostBin File "${FILES_DVIPOST}\"
  55   !insertmacro FileListPDFViewBin File "${FILES_PDFVIEW}\"
  56
  57   # Qt plugin DLLs
  58   SetOutPath "$INSTDIR\bin\imageformats"
  59   !insertmacro FileListQtImageformats File "${FILES_QT}\plugins\imageformats\"
  60   SetOutPath "$INSTDIR\bin\iconengines"
  61   !insertmacro FileListQtIconengines File "${FILES_QT}\plugins\iconengines\"
  62   SetOutPath "$INSTDIR\bin\platforms"
  63   !insertmacro FileListQtPlatforms File "${FILES_QT}\plugins\platforms\"
  64
  65   # Resources
  66   SetOutPath "$INSTDIR"
  67   # recursively copy all files under Resources
  68   File /r "${FILES_LYX}\Resources"
  69
  70   !if ${SETUPTYPE} == BUNDLE
  71
  72    # extract the Jabref and MiKTeX installer
  73    File /r "${FILES_LYX}\external"
  74
  75    # install MiKTeX if not already installed
  76    Call InstallMiKTeX # function from LaTeX.nsh
  77
  78   !endif # end if BUNDLE
  79
  80   # Python
  81   SetOutPath "$INSTDIR"
  82   # recursively copy all files under Python
  83   File /r "${FILES_PYTHON}"
  84   # register .py files if necessary
  85   ReadRegStr $0 SHCTX "Software\Classes\Python.File\shell\open\command" ""
  86   ${if} $0 == "" # if nothing was found
  87    WriteRegStr SHCTX "Software\Classes\Python.File\shell\open\command" "" '"$INSTDIR\Python\python.exe" "%1" %*'
  88    WriteRegStr SHCTX "Software\Classes\Python.File\DefaultIcon" "" "$INSTDIR\Python\DLLs\py.ico"
  89    WriteRegStr SHCTX "Software\Classes\.py" "" "Python.File"
  90    WriteRegStr SHCTX "Software\Classes\Python.File" "OnlyWithLyX" "Yes${APP_SERIES_KEY}" # special entry to test if they were registered by this LyX version
  91   ${endif}
  92
  93   # Compile all Pyton files to byte-code
  94   # The user using the scripts may not have write access
  95   FileOpen $PythonCompileFile "$INSTDIR\compilepy.py" w
  96   FileWrite $PythonCompileFile "import compileall$\r$\n"
  97   FileWrite $PythonCompileFile "compileall.compile_dir('$INSTDIR\python\Lib')$\r$\n"
  98   FileWrite $PythonCompileFile "compileall.compile_dir('$INSTDIR\Resources')$\r$\n"
  99   FileClose $PythonCompileFile
 100   DetailPrint $(TEXT_CONFIGURE_PYTHON)
 101   nsExec::ExecToLog '"$INSTDIR\python\python.exe" "$INSTDIR\compilepy.py"'
 102   Pop $PythonCompileReturn # Return value
 103   Delete "$INSTDIR\compilepy.py"
 104
 105   # Components of ImageMagick
 106   SetOutPath "$INSTDIR\imagemagick"
 107   File /r "${FILES_IMAGEMAGICK}\"
 108   !insertmacro FileListMSVC File "${FILES_MSVC}\"
 109   # register ImageMagick
 110   WriteRegStr SHCTX "SOFTWARE\Classes\Applications" "AutoRun" "$INSTDIR\imagemagick\convert.exe $$"
 111   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "BinPath" "$INSTDIR\imagemagick"
 112   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "CoderModulesPath" "$INSTDIR\imagemagick\modules\coders"
 113   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "ConfigurePath" "$INSTDIR\imagemagick"
 114   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "FilterModulesPath" "$INSTDIR\imagemagick\modules\filters"
 115   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "LibPath" "$INSTDIR\imagemagick"
 116   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "BinPath" "$INSTDIR\imagemagick"
 117   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "CoderModulesPath" "$INSTDIR\imagemagick\modules\coders"
 118   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "ConfigurePath" "$INSTDIR\imagemagick"
 119   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "FilterModulesPath" "$INSTDIR\imagemagick\modules\filters"
 120   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "LibPath" "$INSTDIR\imagemagick"
 121   WriteRegDWORD SHCTX "SOFTWARE\ImageMagick\Current" "QuantumDepth" 0x00000010
 122   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "Version" "${ImageMagickVersion}"
 123   WriteRegStr SHCTX "SOFTWARE\ImageMagick" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 124
 125   # Components of Ghostscript
 126   ${if} $GhostscriptPath == ""
 127    SetOutPath "$INSTDIR\ghostscript"
 128    File /r "${FILES_GHOSTSCRIPT}\"
 129    !insertmacro FileListMSVC File "${FILES_MSVC}\"
 130    StrCpy $GhostscriptPath "$INSTDIR\ghostscript\bin"
 131   ${endif}
 132
 133   !if ${SETUPTYPE} == BUNDLE
 134
 135    # install JabRef if not already installed, the user selected it
 136    # and if no BibTeX editor is installed
 137    # due to an installer bug in the installer of JabRef version 3.x, we still install JabRef 2.11.1
 138    ${if} $PathBibTeXEditor == ""
 139    ${andif} $InstallJabRef == "true"
 140     # launch installer
 141     MessageBox MB_OK|MB_ICONINFORMATION "$(JabRefInfo)" /SD IDOK
 142     IfSilent 0 +2
 143     ExecWait "$INSTDIR\${JabRefInstall} /S"
 144     ExecWait "$INSTDIR\${JabRefInstall}"
 145     # test if JabRef is now installed
 146     StrCpy $PathBibTeXEditor ""
 147     ${if} $MultiUser.Privileges == "Admin"
 148      ${orif} $MultiUser.Privileges == "Power"
 149      ReadRegStr $PathBibTeXEditor HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef ${JabRefVersion}" "UninstallString"
 150      StrCpy $PathBibTeXEditor $PathBibTeXEditor -14 # remove "\uninstall.exe"
 151     ${else}
 152      # for non-admin users we can only check if it is in the start menu
 153      ReadRegStr $PathBibTeXEditor HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef ${JabRefVersion}" "StartMenu"
 154     ${endif}
 155     ${if} $PathBibTeXEditor == ""
 156      MessageBox MB_OK|MB_ICONEXCLAMATION "$(JabRefError)" /SD IDOK
 157     ${else}
 158      # special entry that it was installed together with LyX
 159      # so that we can later uninstall it together with LyX
 160      ${if} $MultiUser.Privileges == "Admin"
 161      ${orif} $MultiUser.Privileges == "Power"
 162       WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef ${JabRefVersion}" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 163      ${else}
 164       WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef ${JabRefVersion}" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 165      ${endif}
 166     ${endif}
 167    ${endif} # end if PathBibTeXEditor
 168   !endif # end if BUNDLE
 169
 170    # install eLyXer
 171    SetOutPath "$INSTDIR\Python\Lib"
 172    !insertmacro FileListeLyXer File "${FILES_ELYXER}\"
 173
 174    # install unoconv
 175    SetOutPath "$INSTDIR\Python\Lib"
 176    !insertmacro FileListUnoConv File "${FILES_UNOCONV}\"
 177
 178   # install the LaTeX class files that are delivered with LyX to MiKTeX
 179   # and enable MiKTeX's automatic package installation
 180   ${if} $LaTeXInstalled == "MiKTeX"
 181    Call ConfigureMiKTeX # Function from LaTeX.nsh
 182   ${endif}
 183   # install the LaTeX class files that are delivered with LyX to TeXLive
 184   ${if} $LaTeXInstalled == "TeXLive"
 185    Call ConfigureTeXLive # Function from LaTeX.nsh
 186   ${endif}
 187
 188   # download dictionaries and thesaurus
 189   ${if} $DictCodes != ""
 190    Call InstallHunspellDictionaries # Function from dictionaries.nsh
 191   ${endif}
 192   ${if} $ThesCodes != ""
 193    Call InstallThesaurusDictionaries # Function from dictionaries.nsh
 194   ${endif}
 195   # finally delete the list of mirrors
 196   Delete "$INSTDIR\Resources\DictionaryMirrors.txt"
 197
 198   # Create uninstaller
 199   WriteUninstaller "$INSTDIR\${SETUP_UNINSTALLER}"
 200
 201 SectionEnd
 202
 203 #--------------------------------
 204 # Support code for file downloads
 205
 206 !macro DOWNLOAD_FILE RET ID FILENAME APPEND
 207
 208   # Downloads a file
 209
 210   # RET = Return value (OK if succesful)
 211   # ID = Name of the download in settings.nsh
 212   # FILENAME = Location to store file
 213   # APPEND = Filename to append to server location in settings.nsh
 214
 215   # Try first time
 216   NSISdl::download "${DOWNLOAD_${ID}}${APPEND}" "$PLUGINSDIR\${FILENAME}"
 217   Pop ${RET} # Return value (OK if succesful)
 218
 219   ${If} ${RET} != "success"
 220     ${AndIf} ${RET} != "cancel"
 221     # Download failed, try once again before giving up
 222     # (usally we get a different mirror)
 223     NSISdl::download "${DOWNLOAD_${ID}}${APPEND}" "$PLUGINSDIR\${FILENAME}"
 224     Pop ${RET}
 225   ${EndIf}
 226
 227 !macroend
 228
 229 #--------------------------------
 230 # External components
 231
 232 #Var PathAllUsers
 233 #Var PathCurrentUser
 234
 235 !macro EXTERNAL COMPONENT
 236
 237   # Download/Install the component
 238
 239   ${If} $Setup${COMPONENT} == ${TRUE}
 240
 241     StrCpy $Path${COMPONENT} "" ;A new one will be installed
 242
 243     !ifndef BUNDLESETUP_${COMPONENT}
 244       !insertmacro EXTERNAL_DOWNLOAD ${COMPONENT}
 245     !else
 246       !insertmacro EXTERNAL_INSTALL ${COMPONENT}
 247     !endif
 248
 249   ${EndIf}
 250
 251 !macroend
 252
 253 !macro EXTERNAL_RUNINSTALLER COMPONENT
 254
 255   # Run the installer application of the component that does the actual installation.
 256
 257   install_${COMPONENT}:
 258
 259     ExecWait '"$PLUGINSDIR\${COMPONENT}Setup.exe"'
 260
 261     # Updates the path environment variable of the installer process to the latest system value
 262 #    ReadRegStr $PathAllUsers HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" Path
 263 #    ReadRegStr $PathCurrentUser HKCU "Environment" Path
 264 #    System::Call 'kernel32::SetEnvironmentVariableA(t, t) i("Path", "$PathAllUsers;$PathCurrentUser").'
 265
 266     Call Search${COMPONENT}
 267
 268     ${If} $Path${COMPONENT} == ""
 269       MessageBox MB_YESNO|MB_ICONEXCLAMATION $(TEXT_NOTINSTALLED_${COMPONENT}) IDYES install_${COMPONENT}
 270     ${EndIf}
 271
 272     Delete "$PLUGINSDIR\${COMPONENT}Setup.exe"
 273
 274 !macroend
 275
 276 !macro EXTERNAL_DOWNLOAD COMPONENT
 277
 278   download_${COMPONENT}:
 279
 280     !insertmacro DOWNLOAD_FILE $DownloadResult "${COMPONENT}" "${COMPONENT}Setup.exe" ""
 281
 282     ${If} $DownloadResult != "success"
 283       ${AndIf} $DownloadResult != "cancel"
 284       # Download failed after trying twice - ask user
 285       MessageBox MB_YESNO|MB_ICONEXCLAMATION "$(TEXT_DOWNLOAD_FAILED_${COMPONENT}) ($DownloadResult)" IDYES download_${COMPONENT}
 286       Goto noinstall_${COMPONENT}
 287     ${EndIf}
 288
 289     !insertmacro EXTERNAL_RUNINSTALLER ${COMPONENT}
 290
 291   noinstall_${COMPONENT}:
 292
 293 !macroend
 294
 295 !macro EXTERNAL_INSTALL COMPONENT
 296
 297   # Extract
 298   File /oname=$PLUGINSDIR\${COMPONENT}Setup.exe ${FILES_BUNDLE}\${INSTALL_${COMPONENT}}
 299
 300   !insertmacro EXTERNAL_RUNINSTALLER ${COMPONENT}
 301
 302 !macroend
 303
 304
 305 # Sections for external components
 306
 307 #Section -LaTeX ExternalLaTeX
 308 #  !insertmacro EXTERNAL LaTeX
 309 #SectionEnd
 310
 311 /*Function InitExternal
 312
 313   # Get sizes of external component installers
 314
 315   #SectionGetSize ${ExternalLaTeX} $SizeLaTeX
 316
 317   # Add download size
 318
 319   !ifndef BUNDLESETUP_MIKTEX
 320     IntOp $SizeLaTeX $SizeLaTeX + ${SIZE_DOWNLOAD_LATEX}
 321   !endif
 322
 323 FunctionEnd*/