development/Win32/packaging/installer/setup/install.nsh

   1 /*
   2
   3 install.nsh
   4
   5 Installation of program files, dictionaries and external components
   6
   7 */
   8
   9 #--------------------------------
  10 # Program files
  11
  12 Var PythonCompileFile
  13 Var PythonCompileReturn
  14
  15 Section -ProgramFiles SecProgramFiles
  16
  17   # if the $INSTDIR does not contain "LyX" we must add a subfolder to avoid that LyX will e.g.
  18   # be installed directly to C:\programs - the uninstaller will then delete the whole
  19   # C:\programs directory
  20   StrCpy $String $INSTDIR
  21   StrCpy $Search "LyX"
  22   Call StrPoint # function from LyXUtils.nsh
  23   ${if} $Pointer == "-1"
  24    StrCpy $INSTDIR "$INSTDIR\${APP_DIR}"
  25   ${endif}
  26
  27  !if ${SETUPTYPE} != BUNDLE
  28   # abort the installation if no LaTeX was found but should be used
  29   ${if} $PathLaTeX == ""
  30   ${andif} $State == "0"
  31    SetOutPath $TEMP # to be able to delete the $INSTDIR
  32    RMDir /r $INSTDIR
  33    Abort
  34   ${endif}
  35  !endif # end if != BUNDLE
  36
  37   # Install and register the core LyX files
  38
  39   # The macros are defined in filelists.nsh
  40   # the parameters are COMMAND DIRECTORY that form command '${COMMAND} "${DIRECTORY}files"
  41
  42   # Initializes the plug-ins dir ($PLUGINSDIR) if not already initialized.
  43   # $PLUGINSDIR is automatically deleted when the installer exits.
  44   InitPluginsDir
  45
  46   # Binaries
  47   SetOutPath "$INSTDIR\bin"
  48   !insertmacro FileListLyXBin File "${FILES_LYX}\bin\"
  49   !insertmacro FileListQtBin File "${FILES_QT}\bin\"
  50   !insertmacro FileListMSVC File "${FILES_MSVC}\"
  51   !insertmacro FileListNetpbmBin File "${FILES_NETPBM}\"
  52   !insertmacro FileListDTLBin File "${FILES_DTL}\"
  53   !insertmacro FileListRsvg File "${FILES_RSVG}\"
  54   !insertmacro FileListDvipostBin File "${FILES_DVIPOST}\"
  55   !insertmacro FileListPDFViewBin File "${FILES_PDFVIEW}\"
  56
  57   # Qt plugin DLLs
  58   SetOutPath "$INSTDIR\bin\imageformats"
  59   !insertmacro FileListQtImageformats File "${FILES_QT}\plugins\imageformats\"
  60   SetOutPath "$INSTDIR\bin\iconengines"
  61   !insertmacro FileListQtIconengines File "${FILES_QT}\plugins\iconengines\"
  62   SetOutPath "$INSTDIR\bin\platforms"
  63   !insertmacro FileListQtPlatforms File "${FILES_QT}\plugins\platforms\"
  64
  65   # Resources
  66   SetOutPath "$INSTDIR"
  67   # recursively copy all files under Resources
  68   File /r "${FILES_LYX}\Resources"
  69
  70   !if ${SETUPTYPE} == BUNDLE
  71
  72    # extract the Jabref and MiKTeX installer
  73    File /r "${FILES_LYX}\external"
  74
  75    # install MiKTeX if not already installed
  76    Call InstallMiKTeX # function from LaTeX.nsh
  77
  78   !endif # end if BUNDLE
  79
  80   # Python
  81   SetOutPath "$INSTDIR"
  82   # recursively copy all files under Python
  83   File /r "${FILES_PYTHON}"
  84   # register .py files if necessary
  85   ReadRegStr $0 SHCTX "Software\Classes\Python.File\shell\open\command" ""
  86   ${if} $0 == "" # if nothing was found
  87    WriteRegStr SHCTX "Software\Classes\Python.File\shell\open\command" "" '"$INSTDIR\Python\python.exe" "%1" %*'
  88    WriteRegStr SHCTX "Software\Classes\Python.File\DefaultIcon" "" "$INSTDIR\Python\DLLs\py.ico"
  89    WriteRegStr SHCTX "Software\Classes\.py" "" "Python.File"
  90    WriteRegStr SHCTX "Software\Classes\Python.File" "OnlyWithLyX" "Yes${APP_SERIES_KEY}" # special entry to test if they were registered by this LyX version
  91   ${endif}
  92
  93   # Compile all Pyton files to byte-code
  94   # The user using the scripts may not have write access
  95   FileOpen $PythonCompileFile "$INSTDIR\compilepy.py" w
  96   FileWrite $PythonCompileFile "import compileall$\r$\n"
  97   FileWrite $PythonCompileFile "compileall.compile_dir('$INSTDIR\python\Lib')$\r$\n"
  98   FileWrite $PythonCompileFile "compileall.compile_dir('$INSTDIR\Resources')$\r$\n"
  99   FileClose $PythonCompileFile
 100   DetailPrint $(TEXT_CONFIGURE_PYTHON)
 101   nsExec::ExecToLog '"$INSTDIR\python\python.exe" "$INSTDIR\compilepy.py"'
 102   Pop $PythonCompileReturn # Return value
 103   Delete "$INSTDIR\compilepy.py"
 104
 105   # Components of ImageMagick
 106   SetOutPath "$INSTDIR\imagemagick"
 107   File /r "${FILES_IMAGEMAGICK}\"
 108   !insertmacro FileListMSVC File "${FILES_MSVC}\"
 109   # register ImageMagick
 110   WriteRegStr SHCTX "SOFTWARE\Classes\Applications" "AutoRun" "$INSTDIR\imagemagick\convert.exe $$"
 111   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "BinPath" "$INSTDIR\imagemagick"
 112   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "CoderModulesPath" "$INSTDIR\imagemagick\modules\coders"
 113   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "ConfigurePath" "$INSTDIR\imagemagick"
 114   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "FilterModulesPath" "$INSTDIR\imagemagick\modules\filters"
 115   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "LibPath" "$INSTDIR\imagemagick"
 116   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "BinPath" "$INSTDIR\imagemagick"
 117   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "CoderModulesPath" "$INSTDIR\imagemagick\modules\coders"
 118   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "ConfigurePath" "$INSTDIR\imagemagick"
 119   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "FilterModulesPath" "$INSTDIR\imagemagick\modules\filters"
 120   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "LibPath" "$INSTDIR\imagemagick"
 121   WriteRegDWORD SHCTX "SOFTWARE\ImageMagick\Current" "QuantumDepth" 0x00000010
 122   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "Version" "${ImageMagickVersion}"
 123   WriteRegStr SHCTX "SOFTWARE\ImageMagick" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 124
 125   # Components of Ghostscript
 126   ${if} $GhostscriptPath == ""
 127    SetOutPath "$INSTDIR\ghostscript"
 128    File /r "${FILES_GHOSTSCRIPT}\"
 129    !insertmacro FileListMSVC File "${FILES_MSVC}\"
 130    StrCpy $GhostscriptPath "$INSTDIR\ghostscript\bin"
 131   ${endif}
 132
 133   !if ${SETUPTYPE} == BUNDLE
 134
 135    # install JabRef if not already installed, the user selected it
 136    # and if no BibTeX editor is installed
 137    ${if} $PathBibTeXEditor == ""
 138    ${andif} $InstallJabRef == "true"
 139     # launch installer
 140     MessageBox MB_OK|MB_ICONINFORMATION "$(JabRefInfo)" /SD IDOK
 141     IfSilent 0 +2
 142     ExecWait "$INSTDIR\${JabRefInstall} /S"
 143     ExecWait "$INSTDIR\${JabRefInstall}"
 144     # test if JabRef is now installed
 145     StrCpy $PathBibTeXEditor ""
 146     ${if} $MultiUser.Privileges == "Admin"
 147      ${orif} $MultiUser.Privileges == "Power"
 148      ReadRegStr $PathBibTeXEditor HKLM "Software\JabRef" "Path"
 149     ${else}
 150      ReadRegStr $PathBibTeXEditor HKCU "Software\JabRef" "Path"
 151      ${ifnot} ${FileExists} "$PathBibTeXEditor\${BIN_BIBTEXEDITOR}"
 152       StrCpy $PathBibTeXEditor ""
 153      ${endif}
 154     ${endif}
 155     ${if} $PathBibTeXEditor == ""
 156      MessageBox MB_OK|MB_ICONEXCLAMATION "$(JabRefError)" /SD IDOK
 157     ${else}
 158      # special entry that it was installed together with LyX
 159      # so that we can later uninstall it together with LyX
 160      ${if} $MultiUser.Privileges == "Admin"
 161      ${orif} $MultiUser.Privileges == "Power"
 162       WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 163       WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef" "UninstallString" "$PathBibTeXEditor\uninstall.exe"
 164      ${else}
 165       WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 166       WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef" "UninstallString" "$PathBibTeXEditor\uninstall.exe"
 167      ${endif}
 168     ${endif}
 169    ${endif} # end if PathBibTeXEditor
 170   !endif # end if BUNDLE
 171
 172    # install eLyXer
 173    SetOutPath "$INSTDIR\Python\Lib"
 174    !insertmacro FileListeLyXer File "${FILES_ELYXER}\"
 175
 176    # install unoconv
 177    SetOutPath "$INSTDIR\Python\Lib"
 178    !insertmacro FileListUnoConv File "${FILES_UNOCONV}\"
 179
 180   # install the LaTeX class files that are delivered with LyX to MiKTeX
 181   # and enable MiKTeX's automatic package installation
 182   ${if} $LaTeXInstalled == "MiKTeX"
 183    Call ConfigureMiKTeX # Function from LaTeX.nsh
 184   ${endif}
 185   # install the LaTeX class files that are delivered with LyX to TeXLive
 186   ${if} $LaTeXInstalled == "TeXLive"
 187    Call ConfigureTeXLive # Function from LaTeX.nsh
 188   ${endif}
 189
 190   # download dictionaries and thesaurus
 191   ${if} $DictCodes != ""
 192    Call InstallHunspellDictionaries # Function from dictionaries.nsh
 193   ${endif}
 194   ${if} $ThesCodes != ""
 195    Call InstallThesaurusDictionaries # Function from dictionaries.nsh
 196   ${endif}
 197   # finally delete the list of mirrors
 198   Delete "$INSTDIR\Resources\DictionaryMirrors.txt"
 199
 200   # Create uninstaller
 201   WriteUninstaller "$INSTDIR\${SETUP_UNINSTALLER}"
 202
 203 SectionEnd
 204
 205 #--------------------------------
 206 # Support code for file downloads
 207
 208 !macro DOWNLOAD_FILE RET ID FILENAME APPEND
 209
 210   # Downloads a file
 211
 212   # RET = Return value (OK if succesful)
 213   # ID = Name of the download in settings.nsh
 214   # FILENAME = Location to store file
 215   # APPEND = Filename to append to server location in settings.nsh
 216
 217   # Try first time
 218   NSISdl::download "${DOWNLOAD_${ID}}${APPEND}" "$PLUGINSDIR\${FILENAME}"
 219   Pop ${RET} # Return value (OK if succesful)
 220
 221   ${If} ${RET} != "success"
 222     ${AndIf} ${RET} != "cancel"
 223     # Download failed, try once again before giving up
 224     # (usally we get a different mirror)
 225     NSISdl::download "${DOWNLOAD_${ID}}${APPEND}" "$PLUGINSDIR\${FILENAME}"
 226     Pop ${RET}
 227   ${EndIf}
 228
 229 !macroend
 230
 231 #--------------------------------
 232 # External components
 233
 234 #Var PathAllUsers
 235 #Var PathCurrentUser
 236
 237 !macro EXTERNAL COMPONENT
 238
 239   # Download/Install the component
 240
 241   ${If} $Setup${COMPONENT} == ${TRUE}
 242
 243     StrCpy $Path${COMPONENT} "" ;A new one will be installed
 244
 245     !ifndef BUNDLESETUP_${COMPONENT}
 246       !insertmacro EXTERNAL_DOWNLOAD ${COMPONENT}
 247     !else
 248       !insertmacro EXTERNAL_INSTALL ${COMPONENT}
 249     !endif
 250
 251   ${EndIf}
 252
 253 !macroend
 254
 255 !macro EXTERNAL_RUNINSTALLER COMPONENT
 256
 257   # Run the installer application of the component that does the actual installation.
 258
 259   install_${COMPONENT}:
 260
 261     ExecWait '"$PLUGINSDIR\${COMPONENT}Setup.exe"'
 262
 263     # Updates the path environment variable of the installer process to the latest system value
 264 #    ReadRegStr $PathAllUsers HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" Path
 265 #    ReadRegStr $PathCurrentUser HKCU "Environment" Path
 266 #    System::Call 'kernel32::SetEnvironmentVariableA(t, t) i("Path", "$PathAllUsers;$PathCurrentUser").'
 267
 268     Call Search${COMPONENT}
 269
 270     ${If} $Path${COMPONENT} == ""
 271       MessageBox MB_YESNO|MB_ICONEXCLAMATION $(TEXT_NOTINSTALLED_${COMPONENT}) IDYES install_${COMPONENT}
 272     ${EndIf}
 273
 274     Delete "$PLUGINSDIR\${COMPONENT}Setup.exe"
 275
 276 !macroend
 277
 278 !macro EXTERNAL_DOWNLOAD COMPONENT
 279
 280   download_${COMPONENT}:
 281
 282     !insertmacro DOWNLOAD_FILE $DownloadResult "${COMPONENT}" "${COMPONENT}Setup.exe" ""
 283
 284     ${If} $DownloadResult != "success"
 285       ${AndIf} $DownloadResult != "cancel"
 286       # Download failed after trying twice - ask user
 287       MessageBox MB_YESNO|MB_ICONEXCLAMATION "$(TEXT_DOWNLOAD_FAILED_${COMPONENT}) ($DownloadResult)" IDYES download_${COMPONENT}
 288       Goto noinstall_${COMPONENT}
 289     ${EndIf}
 290
 291     !insertmacro EXTERNAL_RUNINSTALLER ${COMPONENT}
 292
 293   noinstall_${COMPONENT}:
 294
 295 !macroend
 296
 297 !macro EXTERNAL_INSTALL COMPONENT
 298
 299   # Extract
 300   File /oname=$PLUGINSDIR\${COMPONENT}Setup.exe ${FILES_BUNDLE}\${INSTALL_${COMPONENT}}
 301
 302   !insertmacro EXTERNAL_RUNINSTALLER ${COMPONENT}
 303
 304 !macroend
 305
 306
 307 # Sections for external components
 308
 309 #Section -LaTeX ExternalLaTeX
 310 #  !insertmacro EXTERNAL LaTeX
 311 #SectionEnd
 312
 313 /*Function InitExternal
 314
 315   # Get sizes of external component installers
 316
 317   #SectionGetSize ${ExternalLaTeX} $SizeLaTeX
 318
 319   # Add download size
 320
 321   !ifndef BUNDLESETUP_MIKTEX
 322     IntOp $SizeLaTeX $SizeLaTeX + ${SIZE_DOWNLOAD_LATEX}
 323   !endif
 324
 325 FunctionEnd*/