development/Win32/packaging/installer/setup/install.nsh

   1 /*
   2
   3 install.nsh
   4
   5 Installation of program files, dictionaries and external components
   6
   7 */
   8
   9 #--------------------------------
  10 # Program files
  11
  12 Var PythonCompileFile
  13 Var PythonCompileReturn
  14
  15 Section -ProgramFiles SecProgramFiles
  16
  17   # if the $INSTDIR does not contain "LyX" we must add a subfolder to avoid that LyX will e.g.
  18   # be installed directly to C:\programs - the uninstaller will then delete the whole
  19   # C:\programs directory
  20   StrCpy $String $INSTDIR
  21   StrCpy $Search "LyX"
  22   Call StrPoint # function from LyXUtils.nsh
  23   ${if} $Pointer == "-1"
  24    StrCpy $INSTDIR "$INSTDIR\${APP_DIR}"
  25   ${endif}
  26
  27  !if ${SETUPTYPE} != BUNDLE
  28   # abort the installation if no LaTeX was found but should be used
  29   ${if} $PathLaTeX == ""
  30   ${andif} $State == "0"
  31    SetOutPath $TEMP # to be able to delete the $INSTDIR
  32    RMDir /r $INSTDIR
  33    Abort
  34   ${endif}
  35  !endif # end if != BUNDLE
  36
  37   # Install and register the core LyX files
  38
  39   # The macros are defined in filelists.nsh
  40   # the parameters are COMMAND DIRECTORY that form command '${COMMAND} "${DIRECTORY}files"
  41
  42   # Initializes the plug-ins dir ($PLUGINSDIR) if not already initialized.
  43   # $PLUGINSDIR is automatically deleted when the installer exits.
  44   InitPluginsDir
  45
  46   # Binaries
  47   SetOutPath "$INSTDIR\bin"
  48   !insertmacro FileListLyXBin File "${FILES_LYX}\bin\"
  49   !insertmacro FileListQtBin File "${FILES_QT}\bin\"
  50   !insertmacro FileListMSVC File "${FILES_MSVC}\"
  51   !insertmacro FileListNetpbmBin File "${FILES_NETPBM}\"
  52   !insertmacro FileListDTLBin File "${FILES_DTL}\"
  53   !insertmacro FileListRsvg File "${FILES_RSVG}\"
  54   !insertmacro FileListDvipostBin File "${FILES_DVIPOST}\"
  55   !insertmacro FileListPDFViewBin File "${FILES_PDFVIEW}\"
  56
  57   # Qt plugin DLLs
  58   SetOutPath "$INSTDIR\bin\imageformats"
  59   !insertmacro FileListQtImageformats File "${FILES_QT}\plugins\imageformats\"
  60   SetOutPath "$INSTDIR\bin\iconengines"
  61   !insertmacro FileListQtIconengines File "${FILES_QT}\plugins\iconengines\"
  62   SetOutPath "$INSTDIR\bin\platforms"
  63   !insertmacro FileListQtPlatforms File "${FILES_QT}\plugins\platforms\"
  64
  65   # Resources
  66   SetOutPath "$INSTDIR"
  67   # recursively copy all files under Resources
  68   File /r "${FILES_LYX}\Resources"
  69
  70   !if ${SETUPTYPE} == BUNDLE
  71
  72    # extract the Jabref and MiKTeX installer
  73    File /r "${FILES_LYX}\external"
  74
  75    # install MiKTeX if not already installed
  76    Call InstallMiKTeX # function from LaTeX.nsh
  77
  78   !endif # end if BUNDLE
  79
  80   # Python
  81   SetOutPath "$INSTDIR"
  82   # recursively copy all files under Python
  83   File /r "${FILES_PYTHON}"
  84   # register .py files if necessary
  85   ReadRegStr $0 SHCTX "Software\Classes\Python.File\shell\open\command" ""
  86   ${if} $0 == "" # if nothing was found
  87    WriteRegStr SHCTX "Software\Classes\Python.File\shell\open\command" "" '"$INSTDIR\Python\python.exe" "%1" %*'
  88    WriteRegStr SHCTX "Software\Classes\Python.File\DefaultIcon" "" "$INSTDIR\Python\DLLs\py.ico"
  89    WriteRegStr SHCTX "Software\Classes\.py" "" "Python.File"
  90    WriteRegStr SHCTX "Software\Classes\Python.File" "OnlyWithLyX" "Yes${APP_SERIES_KEY}" # special entry to test if they were registered by this LyX version
  91   ${endif}
  92
  93   # Compile all Pyton files to byte-code
  94   # The user using the scripts may not have write access
  95   FileOpen $PythonCompileFile "$INSTDIR\compilepy.py" w
  96   FileWrite $PythonCompileFile "import compileall$\r$\n"
  97   FileWrite $PythonCompileFile "compileall.compile_dir('$INSTDIR\python\Lib')$\r$\n"
  98   FileWrite $PythonCompileFile "compileall.compile_dir('$INSTDIR\Resources')$\r$\n"
  99   FileClose $PythonCompileFile
 100   DetailPrint $(TEXT_CONFIGURE_PYTHON)
 101   nsExec::ExecToLog '"$INSTDIR\python\python.exe" "$INSTDIR\compilepy.py"'
 102   Pop $PythonCompileReturn # Return value
 103   Delete "$INSTDIR\compilepy.py"
 104
 105   # Components of ImageMagick
 106   SetOutPath "$INSTDIR\imagemagick"
 107   File /r "${FILES_IMAGEMAGICK}\"
 108   !insertmacro FileListMSVC File "${FILES_MSVC}\"
 109   # register ImageMagick
 110   WriteRegStr SHCTX "SOFTWARE\Classes\Applications" "AutoRun" "$INSTDIR\imagemagick\convert.exe $$"
 111   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "BinPath" "$INSTDIR\imagemagick"
 112   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "CoderModulesPath" "$INSTDIR\imagemagick\modules\coders"
 113   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "ConfigurePath" "$INSTDIR\imagemagick"
 114   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "FilterModulesPath" "$INSTDIR\imagemagick\modules\filters"
 115   WriteRegStr SHCTX "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "LibPath" "$INSTDIR\imagemagick"
 116   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "BinPath" "$INSTDIR\imagemagick"
 117   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "CoderModulesPath" "$INSTDIR\imagemagick\modules\coders"
 118   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "ConfigurePath" "$INSTDIR\imagemagick"
 119   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "FilterModulesPath" "$INSTDIR\imagemagick\modules\filters"
 120   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "LibPath" "$INSTDIR\imagemagick"
 121   WriteRegDWORD SHCTX "SOFTWARE\ImageMagick\Current" "QuantumDepth" 0x00000010
 122   WriteRegStr SHCTX "SOFTWARE\ImageMagick\Current" "Version" "${ImageMagickVersion}"
 123   WriteRegStr SHCTX "SOFTWARE\ImageMagick" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 124
 125   # Components of Ghostscript
 126   ${if} $GhostscriptPath == ""
 127    SetOutPath "$INSTDIR\ghostscript"
 128    File /r "${FILES_GHOSTSCRIPT}\"
 129    !insertmacro FileListMSVC File "${FILES_MSVC}\"
 130    StrCpy $GhostscriptPath "$INSTDIR\ghostscript\bin"
 131   ${endif}
 132
 133   !if ${SETUPTYPE} == BUNDLE
 134
 135    # install JabRef if not already installed, the user selected it
 136    # and if no BibTeX editor is installed
 137    ${if} $PathBibTeXEditor == ""
 138    ${andif} $InstallJabRef == "true"
 139     # launch installer
 140     MessageBox MB_OK|MB_ICONINFORMATION "$(JabRefInfo)" /SD IDOK
 141     IfSilent 0 +2
 142     ExecWait "$INSTDIR\${JabRefInstall} /S"
 143     ExecWait "$INSTDIR\${JabRefInstall}"
 144     # test if JabRef is now installed
 145     StrCpy $PathBibTeXEditor ""
 146     ${if} $MultiUser.Privileges == "Admin"
 147      ${orif} $MultiUser.Privileges == "Power"
 148      ReadRegStr $PathBibTeXEditor HKLM "SOFTWARE\Classes\JabRef\shell\open\command" ""
 149      StrCpy $PathBibTeXEditor $PathBibTeXEditor -17 # remove '\JabRef.exe" "%1"'
 150      StrCpy $PathBibTeXEditor $PathBibTeXEditor "" 1 # remove the leading quote
 151     ${else}
 152      # $Documents is the path to the documents folder of the current user (contains the user name)
 153      StrCpy $PathBibTeXEditor $Documents -10 # remove '\Documents'
 154      StrCpy $PathBibTeXEditor "$PathBibTeXEditor\JabRef"
 155      ${ifnot} ${FileExists} "$PathBibTeXEditor\${BIN_BIBTEXEDITOR}"
 156       StrCpy $PathBibTeXEditor ""
 157      ${endif}
 158     ${endif}
 159     ${if} $PathBibTeXEditor == ""
 160      MessageBox MB_OK|MB_ICONEXCLAMATION "$(JabRefError)" /SD IDOK
 161     ${else}
 162      # special entry that it was installed together with LyX
 163      # so that we can later uninstall it together with LyX
 164      ${if} $MultiUser.Privileges == "Admin"
 165      ${orif} $MultiUser.Privileges == "Power"
 166       WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 167       WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef" "UninstallString" "$PathBibTeXEditor\uninstall.exe"
 168      ${else}
 169       WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 170       WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\JabRef" "UninstallString" "$PathBibTeXEditor\uninstall.exe"
 171      ${endif}
 172     ${endif}
 173    ${endif} # end if PathBibTeXEditor
 174   !endif # end if BUNDLE
 175
 176    # install eLyXer
 177    SetOutPath "$INSTDIR\Python\Lib"
 178    !insertmacro FileListeLyXer File "${FILES_ELYXER}\"
 179
 180    # install unoconv
 181    SetOutPath "$INSTDIR\Python\Lib"
 182    !insertmacro FileListUnoConv File "${FILES_UNOCONV}\"
 183
 184   # install the LaTeX class files that are delivered with LyX to MiKTeX
 185   # and enable MiKTeX's automatic package installation
 186   ${if} $LaTeXInstalled == "MiKTeX"
 187    Call ConfigureMiKTeX # Function from LaTeX.nsh
 188   ${endif}
 189   # install the LaTeX class files that are delivered with LyX to TeXLive
 190   ${if} $LaTeXInstalled == "TeXLive"
 191    Call ConfigureTeXLive # Function from LaTeX.nsh
 192   ${endif}
 193
 194   # download dictionaries and thesaurus
 195   ${if} $DictCodes != ""
 196    Call InstallHunspellDictionaries # Function from dictionaries.nsh
 197   ${endif}
 198   ${if} $ThesCodes != ""
 199    Call InstallThesaurusDictionaries # Function from dictionaries.nsh
 200   ${endif}
 201   # finally delete the list of mirrors
 202   Delete "$INSTDIR\Resources\DictionaryMirrors.txt"
 203
 204   # Create uninstaller
 205   WriteUninstaller "$INSTDIR\${SETUP_UNINSTALLER}"
 206
 207 SectionEnd
 208
 209 #--------------------------------
 210 # Support code for file downloads
 211
 212 !macro DOWNLOAD_FILE RET ID FILENAME APPEND
 213
 214   # Downloads a file
 215
 216   # RET = Return value (OK if succesful)
 217   # ID = Name of the download in settings.nsh
 218   # FILENAME = Location to store file
 219   # APPEND = Filename to append to server location in settings.nsh
 220
 221   # Try first time
 222   NSISdl::download "${DOWNLOAD_${ID}}${APPEND}" "$PLUGINSDIR\${FILENAME}"
 223   Pop ${RET} # Return value (OK if succesful)
 224
 225   ${If} ${RET} != "success"
 226     ${AndIf} ${RET} != "cancel"
 227     # Download failed, try once again before giving up
 228     # (usally we get a different mirror)
 229     NSISdl::download "${DOWNLOAD_${ID}}${APPEND}" "$PLUGINSDIR\${FILENAME}"
 230     Pop ${RET}
 231   ${EndIf}
 232
 233 !macroend
 234
 235 #--------------------------------
 236 # External components
 237
 238 #Var PathAllUsers
 239 #Var PathCurrentUser
 240
 241 !macro EXTERNAL COMPONENT
 242
 243   # Download/Install the component
 244
 245   ${If} $Setup${COMPONENT} == ${TRUE}
 246
 247     StrCpy $Path${COMPONENT} "" ;A new one will be installed
 248
 249     !ifndef BUNDLESETUP_${COMPONENT}
 250       !insertmacro EXTERNAL_DOWNLOAD ${COMPONENT}
 251     !else
 252       !insertmacro EXTERNAL_INSTALL ${COMPONENT}
 253     !endif
 254
 255   ${EndIf}
 256
 257 !macroend
 258
 259 !macro EXTERNAL_RUNINSTALLER COMPONENT
 260
 261   # Run the installer application of the component that does the actual installation.
 262
 263   install_${COMPONENT}:
 264
 265     ExecWait '"$PLUGINSDIR\${COMPONENT}Setup.exe"'
 266
 267     # Updates the path environment variable of the installer process to the latest system value
 268 #    ReadRegStr $PathAllUsers HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" Path
 269 #    ReadRegStr $PathCurrentUser HKCU "Environment" Path
 270 #    System::Call 'kernel32::SetEnvironmentVariableA(t, t) i("Path", "$PathAllUsers;$PathCurrentUser").'
 271
 272     Call Search${COMPONENT}
 273
 274     ${If} $Path${COMPONENT} == ""
 275       MessageBox MB_YESNO|MB_ICONEXCLAMATION $(TEXT_NOTINSTALLED_${COMPONENT}) IDYES install_${COMPONENT}
 276     ${EndIf}
 277
 278     Delete "$PLUGINSDIR\${COMPONENT}Setup.exe"
 279
 280 !macroend
 281
 282 !macro EXTERNAL_DOWNLOAD COMPONENT
 283
 284   download_${COMPONENT}:
 285
 286     !insertmacro DOWNLOAD_FILE $DownloadResult "${COMPONENT}" "${COMPONENT}Setup.exe" ""
 287
 288     ${If} $DownloadResult != "success"
 289       ${AndIf} $DownloadResult != "cancel"
 290       # Download failed after trying twice - ask user
 291       MessageBox MB_YESNO|MB_ICONEXCLAMATION "$(TEXT_DOWNLOAD_FAILED_${COMPONENT}) ($DownloadResult)" IDYES download_${COMPONENT}
 292       Goto noinstall_${COMPONENT}
 293     ${EndIf}
 294
 295     !insertmacro EXTERNAL_RUNINSTALLER ${COMPONENT}
 296
 297   noinstall_${COMPONENT}:
 298
 299 !macroend
 300
 301 !macro EXTERNAL_INSTALL COMPONENT
 302
 303   # Extract
 304   File /oname=$PLUGINSDIR\${COMPONENT}Setup.exe ${FILES_BUNDLE}\${INSTALL_${COMPONENT}}
 305
 306   !insertmacro EXTERNAL_RUNINSTALLER ${COMPONENT}
 307
 308 !macroend
 309
 310
 311 # Sections for external components
 312
 313 #Section -LaTeX ExternalLaTeX
 314 #  !insertmacro EXTERNAL LaTeX
 315 #SectionEnd
 316
 317 /*Function InitExternal
 318
 319   # Get sizes of external component installers
 320
 321   #SectionGetSize ${ExternalLaTeX} $SizeLaTeX
 322
 323   # Add download size
 324
 325   !ifndef BUNDLESETUP_MIKTEX
 326     IntOp $SizeLaTeX $SizeLaTeX + ${SIZE_DOWNLOAD_LATEX}
 327   !endif
 328
 329 FunctionEnd*/