development/Win32/packaging/installer/setup/configure.nsh

   1 /*
   2
   3 configure.nsh
   4
   5 Write registry information and configure LyX
   6
   7 */
   8
   9 Var DistFile
  10 Var PathPrefix
  11
  12 !define SHORTCUT '${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"'
  13
  14 #--------------------------------
  15 # File associations
  16
  17 Section -FileAssociations
  18
  19   # Associate .lyx files with LyX for current user of all users
  20
  21   # Write information about file type
  22   !define REG_FILETYPE 'WriteRegStr SHELL_CONTEXT "Software\Classes\${APP_REGNAME_DOC}'
  23
  24   ${REG_FILETYPE}" "" "${APP_NAME} Document"
  25   ${REG_FILETYPE}\DefaultIcon" "" "$INSTDIR\bin\LyXLauncher.exe,0"
  26   ${REG_FILETYPE}\Shell\open\command" "" '"$INSTDIR\${APP_RUN}" "%1"'
  27
  28   !define REG_FILEEXT 'WriteRegStr SHELL_CONTEXT "Software\Classes\${APP_EXT}"'
  29
  30   ${REG_FILEEXT} "" "${APP_REGNAME_DOC}"
  31   ${REG_FILEEXT} "Content Type" "${APP_MIME_TYPE}"
  32
  33   # Refresh shell
  34   ${RefreshShellIcons}
  35
  36 SectionEnd
  37
  38 #--------------------------------
  39 # Registry information
  40
  41 Section -InstallData
  42
  43   # Registry information
  44   WriteRegStr SHELL_CONTEXT ${APP_REGKEY} "" $INSTDIR
  45   WriteRegStr SHELL_CONTEXT ${APP_REGKEY} "Version" "${APP_VERSION_NUMBER}"
  46
  47   WriteRegStr SHELL_CONTEXT ${APP_REGKEY_SETUP} "LaTeX Path" $PathLaTeX
  48
  49   # Start Menu shortcut
  50   # There is only one shortcut to the application, so it should be in the main group
  51   SetOutPath "$INSTDIR\bin"
  52   CreateShortCut "$SMPROGRAMS\${SHORTCUT}
  53
  54   # Uninstaller information
  55   !define REG_UNINSTALL 'WriteRegStr SHELL_CONTEXT "Software\Microsoft\Windows\CurrentVersion\Uninstall\${SETUP_UNINSTALLER_KEY}"'
  56
  57   ${If} $MultiUser.InstallMode == "CurrentUser"
  58     ${REG_UNINSTALL} "DisplayName" "${APP_NAME} ${APP_VERSION} $(TEXT_INSTALL_CURRENTUSER)"
  59   ${Else}
  60     ${REG_UNINSTALL} "DisplayName" "${APP_NAME} ${APP_VERSION}"
  61   ${EndIf}
  62
  63   ${REG_UNINSTALL} "UninstallString" '"$INSTDIR\${SETUP_UNINSTALLER}"'
  64   ${REG_UNINSTALL} "DisplayVersion" "${APP_VERSION}"
  65   ${REG_UNINSTALL} "DisplayIcon" "$INSTDIR\bin\LyXLauncher,0"
  66   ${REG_UNINSTALL} "URLUpdateInfo" "http://www.lyx.org/"
  67   ${REG_UNINSTALL} "URLInfoAbout" "http://www.lyx.org/about/"
  68   ${REG_UNINSTALL} "Publisher" "LyX Team"
  69   ${REG_UNINSTALL} "HelpLink" "http://www.lyx.org/internet/mailing.php"
  70
  71 SectionEnd
  72
  73 #--------------------------------
  74 # Write LyX configuration file
  75
  76 Section -Configure
  77
  78   # Set path prefix in lyxrc.dist
  79
  80   # Install standard lyxrc.dist file
  81   SetOutPath "$INSTDIR\Resources"
  82   File "${FILES_DEPS}\Resources\lyxrc.dist"
  83
  84   # Append path prefix
  85   FileOpen $DistFile "$INSTDIR\Resources\lxrc.dist" a
  86
  87   StrCpy $PathPrefix "$LyXDir\bin;$LyXDir\python;$LyXDir\imagemagick;$LyXDir\ghostscript"
  88
  89   ${If} $PathLaTeX != ""
  90     StrCpy $PathPrefix "$PathPrefix;$PathLaTeX"
  91   ${EndIf}
  92   ${If} $PathBibTeXEditor != ""
  93     StrCpy $PathPrefix "$PathPrefix;$PathBibTeXEditor"
  94   ${EndIf}
  95
  96   FileWrite $DistFile '\path_prefix "$PathPrefix"$\r$\n'
  97
  98   FileClose $DistFile
  99
 100 SectionEnd
 101
 102 #--------------------------------
 103 # LaTeX files
 104
 105 Var UpdateFNDBReturn
 106
 107 Section -LaTeXFiles
 108
 109   # Install files in local root
 110
 111   ${If} $PathLaTeXLocal != ""
 112     # dvipost
 113     SetOutPath "$PathLaTeXLocal\tex\latex\dvipost"
 114     File "${FILES_DVIPOST_PKG}\dvipost.sty"
 115     # LyX files in Resources\tex
 116     SetOutPath "$PathLaTeXLocal\tex\latex\lyx"
 117     CopyFiles /SILENT "$INSTDIR\Resources\tex\*.*" "$PathLaTeXLocal\tex\latex\lyx"
 118   ${EndIf}
 119
 120   # Update file name database
 121
 122   ${If} $PathLaTeX != ""
 123     DetailPrint $(TEXT_CONFIGURE_MIKTEXFNDB)
 124     nsExec::ExecToLog '"$PathLaTeX\initexmf.exe" --update-fndb'
 125     Pop $UpdateFNDBReturn # Return value
 126   ${EndIf}
 127
 128 SectionEnd
 129
 130 #--------------------------------
 131 # Postscript printer for metafile to EPS converter
 132
 133 Section -PSPrinter
 134
 135   ${If} $MultiUser.Privileges == "Admin"
 136     ${OrIf} $MultiUser.Privileges == "Power"
 137
 138     # Delete printer
 139     ExecWait '$PrinterConf /q /dl /n "Metafile to EPS Converter"'
 140     # Install printer and driver
 141     ExecWait '$PrinterConf /if /f "$WINDIR\inf\ntprint.inf" /b "Metafile to EPS Converter" /r "FILE:" /m "MS Publisher Imagesetter"'
 142     # Restore DEVMODE with proper settings
 143     ExecWait '$PrinterConf /q /Sr /n "Metafile to EPS Converter" /a "$INSTDIR\bin\metafile2eps.dat" g'
 144
 145   ${EndIf}
 146
 147 SectionEnd
 148
 149 #--------------------------------
 150 # Run the LyX configure.py script, so MiKTeX can download its packages
 151
 152 Var ConfigureReturn
 153
 154 Section -ConfigureScript
 155
 156   SetOutPath "$INSTDIR\Resources"
 157   DetailPrint $(TEXT_CONFIGURE_LYX)
 158   nsExec::ExecToLog '"$INSTDIR\python\python.exe" "$INSTDIR\Resources\configure.py"'
 159   Pop $ConfigureReturn # Return value
 160
 161 SectionEnd
 162
 163 #--------------------------------
 164 # Desktop shortcut
 165
 166 Function CheckDesktopShortcut
 167
 168   # Enable desktop icon creation when there is an icon already
 169   # Old shortcuts need to be updated
 170
 171   ${If} ${FileExists} "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk"
 172     ${NSD_SetState} $mui.FinishPage.ShowReadme ${BST_CHECKED}
 173   ${EndIf}
 174
 175 FunctionEnd
 176
 177 Function CreateDesktopShortcut
 178
 179   # Desktop icon creation is an option on the finish page
 180   SetOutPath "$INSTDIR\bin"
 181   CreateShortCut "$DESKTOP\${SHORTCUT}
 182
 183 FunctionEnd