development/Win32/packaging/installer/setup/configure.nsh

   1 /*
   2
   3 configure.nsh
   4
   5 Write registry information and configure LyX
   6
   7 */
   8
   9 Var PathPrefix
  10
  11 #!define SHORTCUT '${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"'
  12
  13 #--------------------------------
  14 # Registry information
  15
  16 Section -InstallData
  17
  18   # Registry information
  19   WriteRegStr SHCTX ${APP_REGKEY} "" $INSTDIR
  20   WriteRegStr SHCTX ${APP_REGKEY} "Version" "${APP_VERSION_NUMBER}"
  21   WriteRegStr SHCTX ${APP_REGKEY_SETUP} "LaTeX Path" $PathLaTeX
  22
  23   # Start Menu shortcut
  24   SetOutPath "$INSTDIR\bin" # this is the folder in which the shortcut is executed
  25   CreateDirectory "$SMPROGRAMS\$StartmenuFolder"
  26   CreateShortCut "$SMPROGRAMS\$StartmenuFolder\${APP_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"
  27   # Link to www.lyx.org and to the Wiki
  28   WriteINIStr "$SMPROGRAMS\$StartmenuFolder\${APP_WEBPAGE_INFO}.url" "InternetShortcut" "URL" "${APP_WEBPAGE}"
  29   WriteINIStr "$SMPROGRAMS\$StartmenuFolder\${APP_WIKI_INFO}.url" "InternetShortcut" "URL" "${APP_WIKI}"
  30   # create desktop icon
  31   ${if} $CreateDesktopIcon == "true"
  32    SetOutPath "$INSTDIR\bin"
  33    CreateShortCut "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"
  34   ${endif}
  35
  36   # Uninstaller information
  37   ${If} $MultiUser.InstallMode == "CurrentUser"
  38     WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayName" "${APP_NAME} ${APP_VERSION} $(TEXT_INSTALL_CURRENTUSER)"
  39   ${Else}
  40     WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayName" "${APP_NAME} ${APP_VERSION}"
  41   ${EndIf}
  42
  43   WriteRegStr SHCTX ${APP_UNINST_KEY} "UninstallString" '"$INSTDIR\${SETUP_UNINSTALLER}"'
  44   WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayVersion" "${APP_VERSION}"
  45   WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayIcon" "$INSTDIR\bin\lyx,0"
  46   WriteRegStr SHCTX ${APP_UNINST_KEY} "URLUpdateInfo" "http://www.lyx.org/"
  47   WriteRegStr SHCTX ${APP_UNINST_KEY} "URLInfoAbout" "http://www.lyx.org/about/"
  48   WriteRegStr SHCTX ${APP_UNINST_KEY} "Publisher" "LyX Team"
  49   WriteRegStr SHCTX ${APP_UNINST_KEY} "HelpLink" "http://www.lyx.org/internet/mailing.php"
  50   WriteRegDWORD SHCTX ${APP_UNINST_KEY} "NoModify" 0x00000001
  51   WriteRegDWORD SHCTX ${APP_UNINST_KEY} "NoRepair" 0x00000001
  52   WriteRegStr SHCTX ${APP_UNINST_KEY} "StartMenu" "$SMPROGRAMS\$StartmenuFolder"
  53
  54   # if we install over an existing version, remove the old uninstaller information
  55   ${if} $OldVersionNumber != ""
  56    DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}$OldVersionNumber"
  57    # also delete in the case of an emergency release
  58    DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}$OldVersionNumber1"
  59   ${endif}
  60
  61 SectionEnd
  62
  63 #--------------------------------
  64 # Write LyX configuration file
  65
  66 Section -Configure
  67
  68   # Associate .lyx files with LyX for current user of all users
  69
  70   ${if} $CreateFileAssociations == "true"
  71    WriteRegStr SHCTX "${APP_DIR_REGKEY}" "" "$INSTDIR\${APP_RUN}"
  72   ${endif}
  73
  74   # Write information about file type
  75   #!define REG_FILETYPE 'WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}"'
  76
  77   ${if} $CreateFileAssociations == "true"
  78    WriteRegStr SHCTX "${APP_DIR_REGKEY}" "OnlyWithLyX" "Yes${APP_SERIES_KEY}" # special entry to test if they were registered by this LyX version
  79    WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}" "" "${APP_NAME} Document"
  80    WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}\DefaultIcon" "" "$INSTDIR\${APP_RUN},0"
  81    WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}\Shell\open\command" "" '"$INSTDIR\${APP_RUN}" "%1"'
  82    WriteRegStr SHCTX "Software\Classes\${APP_EXT}" "" "${APP_REGNAME_DOC}"
  83    WriteRegStr SHCTX "Software\Classes\${APP_EXT}" "Content Type" "${APP_MIME_TYPE}"
  84    # .lyx13
  85    WriteRegStr SHCTX "Software\Classes\${APP_EXT}13" "" "${APP_REGNAME_DOC}"
  86    WriteRegStr SHCTX "Software\Classes\${APP_EXT}13" "Content Type" "${APP_MIME_TYPE}"
  87    # .lyx14
  88    WriteRegStr SHCTX "Software\Classes\${APP_EXT}14" "" "${APP_REGNAME_DOC}"
  89    WriteRegStr SHCTX "Software\Classes\${APP_EXT}14" "Content Type" "${APP_MIME_TYPE}"
  90    # .lyx15
  91    WriteRegStr SHCTX "Software\Classes\${APP_EXT}15" "" "${APP_REGNAME_DOC}"
  92    WriteRegStr SHCTX "Software\Classes\${APP_EXT}15" "Content Type" "${APP_MIME_TYPE}"
  93    # .lyx16 don't set this, because this is designed to be opened with LyX 1.6.x
  94
  95    # Refresh shell
  96    ${RefreshShellIcons}
  97   ${endif}
  98
  99   # Set path prefix in lyxrc.dist
 100
 101   # Install standard lyxrc.dist file
 102   #SetOutPath "$INSTDIR\Resources"
 103   #File "${FILES_DEPS}\Resources\lyxrc.dist"
 104
 105   # create the path prefix
 106   # $$ represents a literal $ in an NSIS string
 107   StrCpy $PathPrefix "$$LyXDir\bin;$$LyXDir\Python;$$LyXDir\Python\Lib;$$LyXDir\imagemagick"
 108
 109   ${if} $PathLaTeX != ""
 110     StrCpy $PathPrefix "$PathPrefix;$PathLaTeX"
 111   ${EndIf}
 112   ${if} $PSVPath != ""
 113     StrCpy $PathPrefix "$PathPrefix;$PSVPath"
 114   ${endif}
 115   ${if} $EditorPath != ""
 116     StrCpy $PathPrefix "$PathPrefix;$EditorPath"
 117   ${endif}
 118   ${if} $ImageEditorPath != ""
 119     StrCpy $PathPrefix "$PathPrefix;$ImageEditorPath"
 120   ${endif}
 121   ${if} $GhostscriptPath != ""
 122    StrCpy $PathPrefix "$PathPrefix;$GhostscriptPath"
 123   ${endif}
 124   ${if} $SVGPath != ""
 125    StrCpy $PathPrefix "$PathPrefix;$SVGPath"
 126   ${endif}
 127   ${if} $GnumericPath != ""
 128    StrCpy $PathPrefix "$PathPrefix;$GnumericPath"
 129   ${endif}
 130   ${if} $PathBibTeXEditor != ""
 131     StrCpy $PathPrefix "$PathPrefix;$PathBibTeXEditor"
 132   ${EndIf}
 133   ${if} $LilyPondPath != ""
 134    StrCpy $PathPrefix "$PathPrefix;$LilyPondPath"
 135   ${endif}
 136
 137   # Set the path prefix in lyxrc.dist
 138   ClearErrors
 139   Delete "$INSTDIR\Resources\lyxrc.dist"
 140   FileOpen $R1 "$INSTDIR\Resources\lyxrc.dist" w
 141   # set the format
 142   FileWrite $R1 'Format 1$\r$\n'
 143   # set some general things
 144   FileWrite $R1 '\screen_zoom 120$\r$\n'
 145   ${if} "$PathPrefix" != ""
 146    FileWrite $R1 '\path_prefix "$PathPrefix"$\r$\n'
 147   ${endif}
 148
 149   # set path to eLyXer
 150   FileWrite $R1 '\converter "lyx" "html" "python -tt \"$INSTDIR\Python\Lib\elyxer.py\" --directory $$$$r $$$$i $$$$o" ""$\r$\n\
 151                  \converter "lyx" "wordhtml" "python -tt \"$INSTDIR\Python\Lib\elyxer.py\" --html --directory $$$$r $$$$i $$$$o" ""'
 152
 153   # use pdfview for all types of PDF files
 154   FileWrite $R1 '\format "pdf5" "pdf" "PDF (LuaTeX)" "u" "pdfview" "" "document,vector,menu=export"$\r$\n\
 155                  \format "pdf4" "pdf" "PDF (XeTeX)" "X" "pdfview" "" "document,vector,menu=export"$\r$\n\
 156                  \format "pdf3" "pdf" "PDF (dvipdfm)" "m" "pdfview" "" "document,vector,menu=export"$\r$\n\
 157                  \format "pdf2" "pdf" "PDF (pdflatex)" "F" "pdfview" "" "document,vector,menu=export"$\r$\n\
 158                  \format "pdf" "pdf" "PDF (ps2pdf)" "P" "pdfview" "" "document,vector,menu=export"$\r$\n'
 159
 160   # if LilyPondPath was found
 161   # we need to add these entris because python scripts can only be executed
 162   # if the full path is given
 163   ${if} $LilyPondPath != ""
 164    FileWrite $R1 '\format "lilypond-book" "lytex" "LilyPond book (LaTeX)" "" "" "auto" "document,menu=export"$\r$\n\
 165                   \converter "lilypond-book" "pdflatex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --pdf --latex-program=pdflatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
 166                   \converter "lilypond-book" "xetex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --pdf --latex-program=xelatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
 167                   \converter "lilypond-book" "luatex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --pdf --latex-program=lualatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
 168                   \converter "lilypond-book" "latex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --lily-output-dir=ly-eps $$$$i" ""$\r$\n'
 169   ${endif}
 170   FileClose $R1
 171   IfErrors 0 +2
 172    MessageBox MB_OK|MB_ICONEXCLAMATION "$(ModifyingConfigureFailed)"
 173   ClearErrors
 174
 175 SectionEnd
 176
 177 #--------------------------------
 178 # Postscript printer for metafile to EPS converter
 179
 180 Section -PSPrinter
 181
 182   ${if} $MultiUser.Privileges == "Admin"
 183   ${orif} $MultiUser.Privileges == "Power"
 184    # Delete printer
 185    ExecWait '$PrinterConf /q /dl /n "Metafile to EPS Converter"'
 186    # Install printer and driver
 187    ExecWait '$PrinterConf /if /f "$WINDIR\inf\ntprint.inf" /b "Metafile to EPS Converter" /r "FILE:" /m "MS Publisher Imagesetter"'
 188   ${else}
 189    MessageBox MB_OK|MB_ICONINFORMATION "$(MetafileNotAvailable)"
 190   ${endif}
 191
 192 SectionEnd
 193
 194 #--------------------------------
 195 # Run the LyX configure.py script, so MiKTeX can download its packages
 196
 197 Var ConfigureReturn
 198
 199 Section -ConfigureScript
 200
 201   SetOutPath "$INSTDIR\Resources"
 202
 203   # ask to update MiKTeX
 204   ${if} $LaTeXInstalled == "MiKTeX"
 205    Call UpdateMiKTeX # function from latex.nsh
 206    # install all necessary packages at once
 207    DetailPrint $(TEXT_CONFIGURE_LYX)
 208    ${if} $MultiUser.Privileges != "Admin"
 209    ${andif} $MultiUser.Privileges != "Power"
 210     # call the non-admin version
 211     nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--verbose" "--install-some=$INSTDIR\Resources\Packages.txt"'
 212    ${else}
 213     ${if} $MiKTeXUser != "HKCU" # call the admin version
 214      nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--admin" "--verbose" "--install-some=$INSTDIR\Resources\Packages.txt"'
 215     ${else}
 216      nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--verbose" "--install-some=$INSTDIR\Resources\Packages.txt"'
 217     ${endif}
 218    ${endif}
 219   ${endif}
 220
 221   DetailPrint $(TEXT_CONFIGURE_LYX)
 222   nsExec::ExecToLog '"$INSTDIR\Python\python.exe" "$INSTDIR\Resources\configure.py"'
 223   # $ConfigureReturn is "0" if successful, otherwise "1"
 224   Pop $ConfigureReturn # Return value
 225
 226 SectionEnd
 227
 228 #--------------------------------
 229 # Desktop shortcut
 230
 231 Function StartLyX
 232
 233   # run LyX in a command line window to give the users feedback about
 234   # the time consuming LaTeX package installation
 235
 236   #Exec 'cmd /K " "$INSTDIR\bin\lyx.exe""'
 237   Exec "$INSTDIR\${APP_RUN}"
 238
 239 FunctionEnd
 240
 241 /*Function CheckDesktopShortcut
 242
 243   # Enable desktop icon creation when there is an icon already
 244   # Old shortcuts need to be updated
 245
 246   ${If} ${FileExists} "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk"
 247     ${NSD_SetState} $mui.FinishPage.ShowReadme ${BST_CHECKED}
 248   ${EndIf}
 249
 250 FunctionEnd
 251
 252 Function CreateDesktopShortcut
 253
 254   # Desktop icon creation is an option on the finish page
 255   SetOutPath "$INSTDIR\bin"
 256   CreateShortCut "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"
 257
 258 FunctionEnd*/
 259