development/Win32/packaging/installer/setup/configure.nsh

   1 /*
   2
   3 configure.nsh
   4
   5 Write registry information and configure LyX
   6
   7 */
   8
   9 Var DistFile
  10 Var PathPrefix
  11
  12 !define SHORTCUT '${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"'
  13
  14 #--------------------------------
  15 # File associations
  16
  17 Section -FileAssociations
  18
  19   # Associate .lyx files with LyX for current user of all users
  20
  21   # Write information about file type
  22   !define REG_FILETYPE 'WriteRegStr SHELL_CONTEXT "Software\Classes\${APP_REGNAME_DOC}'
  23
  24   ${REG_FILETYPE}" "" "${APP_NAME} Document"
  25   ${REG_FILETYPE}\DefaultIcon" "" "$INSTDIR\bin\lyx_doc_32x32.ico"
  26   ${REG_FILETYPE}\Shell\open\command" "" '"$INSTDIR\${APP_RUN}" "%1"'
  27
  28   !define REG_FILEEXT 'WriteRegStr SHELL_CONTEXT "Software\Classes\${APP_EXT}"'
  29
  30   ${REG_FILEEXT} "" "${APP_REGNAME_DOC}"
  31   ${REG_FILEEXT} "Content Type" "${APP_MIME_TYPE}"
  32
  33   # Refresh shell
  34   System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) (${SHCNE_ASSOCCHANGED}, ${SHCNF_IDLIST}, 0, 0)'
  35
  36 SectionEnd
  37
  38 #--------------------------------
  39 # Registry information
  40
  41 Section -InstallData
  42
  43   # Registry information
  44   WriteRegStr SHELL_CONTEXT ${APP_REGKEY} "" $INSTDIR
  45   WriteRegStr SHELL_CONTEXT ${APP_REGKEY} "Version" "${APP_VERSION}"
  46
  47   WriteRegStr SHELL_CONTEXT ${APP_REGKEY_SETUP} "LaTeX Path" $PathLaTeX
  48   WriteRegStr SHELL_CONTEXT ${APP_REGKEY_SETUP} "ImageMagick Path" $PathImageMagick
  49   WriteRegStr SHELL_CONTEXT ${APP_REGKEY_SETUP} "Ghostscript Path" $PathGhostscript
  50   WriteRegStr SHELL_CONTEXT ${APP_REGKEY_SETUP} "LyX Language" $LangName
  51
  52   # Start Menu shortcut
  53   # There is only one shortcut to the application, so it should be in the main group
  54   CreateShortCut "$SMPROGRAMS\${SHORTCUT}
  55
  56   # Uninstaller information
  57   !define REG_UNINSTALL 'WriteRegStr SHELL_CONTEXT "Software\Microsoft\Windows\CurrentVersion\Uninstall\${SETUP_UNINSTALLER_KEY}"'
  58
  59   ${If} $MultiUser.InstallMode == "CurrentUser"
  60     ${REG_UNINSTALL} "DisplayName" "${APP_NAME} ${APP_VERSION} $(TEXT_INSTALL_CURRENTUSER)"
  61   ${Else}
  62     ${REG_UNINSTALL} "DisplayName" "${APP_NAME} ${APP_VERSION}"
  63   ${EndIf}
  64
  65   ${REG_UNINSTALL} "UninstallString" '"$INSTDIR\${SETUP_UNINSTALLER}"'
  66   ${REG_UNINSTALL} "DisplayVersion" "${APP_VERSION}"
  67   ${REG_UNINSTALL} "DisplayIcon" "$INSTDIR\bin\lyx_32x32.ico"
  68   ${REG_UNINSTALL} "URLUpdateInfo" "http://www.lyx.org/"
  69   ${REG_UNINSTALL} "URLInfoAbout" "http://www.lyx.org/about/"
  70   ${REG_UNINSTALL} "Publisher" "LyX Team"
  71   ${REG_UNINSTALL} "HelpLink" "http://www.lyx.org/internet/mailing.php"
  72
  73 SectionEnd
  74
  75 #--------------------------------
  76 # Write LyX configuration file
  77
  78 Section -Configure
  79
  80   # Windows specific configuration in lyxrc.dist
  81
  82   Delete "$INSTDIR\Resources\lyxrc.dist"
  83   FileOpen $DistFile "$INSTDIR\Resources\lyxrc.dist" w
  84
  85   # Path prefix
  86
  87   StrCpy $PathPrefix "$INSTDIR\bin;$INSTDIR\python"
  88
  89   ${If} $PathLaTeX != ""
  90     StrCpy $PathPrefix "$PathPrefix;$PathLaTeX"
  91   ${EndIf}
  92   ${If} $PathGhostscript != ""
  93     StrCpy $PathPrefix "$PathPrefix;$PathGhostscript"
  94   ${EndIf}
  95   ${If} $PathImageMagick != ""
  96     StrCpy $PathPrefix "$PathPrefix;$PathImageMagick"
  97   ${EndIf}
  98
  99   FileWrite $DistFile '\path_prefix "$PathPrefix"$\r$\n'
 100
 101   # Default screen fonts
 102   FileWrite $DistFile '\screen_font_roman "Times New Roman"$\r$\n'
 103   FileWrite $DistFile '\screen_font_sans "Arial"$\r$\n'
 104   FileWrite $DistFile '\screen_font_typewriter "Courier New"$\r$\n'
 105   FileWrite $DistFile '\preview_scale_factor 1.0$\r$\n' # Fit instant preview font size to screen fonts
 106   # PDF view helper
 107   FileWrite $DistFile '\format "pdf" "pdf" "PDF (ps2pdf)" "P" "pdfview" "" "document,vector"$\r$\n'
 108   FileWrite $DistFile '\format "pdf2" "pdf" "PDF (pdflatex)" "F" "pdfview" "" "document,vector"$\r$\n'
 109   FileWrite $DistFile '\format "pdf3" "pdf" "PDF (dvipdfm)" "m" "pdfview" "" "document,vector"$\r$\n'
 110
 111   FileClose $DistFile
 112
 113   # Set language
 114   WriteRegStr SHELL_CONTEXT ${APP_REGKEY_SETTINGS} "Language" $LangISOCode
 115
 116 SectionEnd
 117
 118 #--------------------------------
 119 # dvipost package
 120
 121 Var UpdateFNDBReturn
 122
 123 Section -dvipost
 124
 125   # Install package in local root
 126
 127   ${if} $PathLaTeXLocal != ""
 128     SetOutPath "$PathLaTeXLocal\tex\latex\dvipost"
 129     File "${FILES_DVIPOST_PKG}\dvipost.sty"
 130   ${endif}
 131
 132   # Update file name database
 133
 134   ${if} $PathLaTeX != ""
 135     nsExec::Exec '"$PathLaTeX\initexmf.exe" --update-fndb'
 136     Pop $UpdateFNDBReturn # Return value
 137   ${endif}
 138
 139 SectionEnd
 140
 141
 142 #--------------------------------
 143 # Postscript printer for metafile to EPS converter
 144
 145 Section -PSPrinter
 146
 147   ${If} $MultiUser.Privileges != "Admin"
 148     ${OrIf} $MultiUser.Privileges != "Power"
 149
 150     # Delete printer
 151     ExecWait '$PrinterConf /q /dl /n "Metafile to EPS Converter"'
 152
 153     # Delete printer driver
 154     ExecWait '$PrinterConf /q /dd /m "Metafile to EPS Converter"'
 155
 156     # Install printer and driver
 157     ExecWait '$PrinterConf /q /if /f "$INSTDIR\PSPrinter\metafile2eps.inf" /r "FILE:" /m "Metafile to EPS Converter"'
 158
 159     # Restore DEVMODE with proper settings
 160     ExecWait '$PrinterConf /q /Sr /n "Metafile to EPS Converter" /a "$INSTDIR\PSPrinter\metafile2eps.dat" g'
 161
 162   ${EndIf}
 163
 164 SectionEnd
 165
 166 #--------------------------------
 167 # Desktop shortcut
 168
 169 Function CheckDesktopShortcut
 170
 171   # Enable desktop icon creation when there is an icon already
 172   # Old shortcuts need to be updated
 173
 174   ${If} ${FileExists} "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk"
 175     ${NSD_SetState} $mui.FinishPage.ShowReadme ${BST_CHECKED}
 176   ${EndIf}
 177
 178 FunctionEnd
 179
 180 Function CreateDesktopShortcut
 181
 182   # Desktop icon creation is an option on the finish page
 183
 184   CreateShortCut "$DESKTOP\${SHORTCUT}
 185
 186 FunctionEnd