development/Win32/packaging/installer/setup/configure.nsh

   1 /*
   2
   3 configure.nsh
   4
   5 Write registry information and configure LyX
   6
   7 */
   8
   9 Var PathPrefix
  10
  11 #!define SHORTCUT '${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"'
  12
  13 #--------------------------------
  14 # Registry information
  15
  16 Section -InstallData
  17
  18   # Registry information
  19   WriteRegStr SHCTX ${APP_REGKEY} "" $INSTDIR
  20   WriteRegStr SHCTX ${APP_REGKEY} "Version" "${APP_VERSION_NUMBER}"
  21   WriteRegStr SHCTX ${APP_REGKEY_SETUP} "LaTeX Path" $PathLaTeX
  22
  23   # Start Menu shortcut
  24   SetOutPath "$INSTDIR\bin" # this is the folder in which the shortcut is executed
  25   # we must assure that the folder is not empty (happens on silent install and can accidentally happen)
  26   ${if} $StartmenuFolder == ""
  27    StrCpy $StartmenuFolder "${APP_DIR}"
  28   ${endif}
  29   CreateDirectory "$SMPROGRAMS\$StartmenuFolder"
  30   CreateShortCut "$SMPROGRAMS\$StartmenuFolder\${APP_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"
  31   # Link to www.lyx.org and to the Wiki
  32   WriteINIStr "$SMPROGRAMS\$StartmenuFolder\${APP_WEBPAGE_INFO}.url" "InternetShortcut" "URL" "${APP_WEBPAGE}"
  33   WriteINIStr "$SMPROGRAMS\$StartmenuFolder\${APP_WIKI_INFO}.url" "InternetShortcut" "URL" "${APP_WIKI}"
  34   # create desktop icon
  35   ${if} $CreateDesktopIcon == "true"
  36    SetOutPath "$INSTDIR\bin"
  37    CreateShortCut "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"
  38   ${endif}
  39
  40   # Uninstaller information
  41   ${If} $MultiUser.InstallMode == "CurrentUser"
  42     WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayName" "${APP_NAME} ${APP_VERSION} $(TEXT_INSTALL_CURRENTUSER)"
  43   ${Else}
  44     WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayName" "${APP_NAME} ${APP_VERSION}"
  45   ${EndIf}
  46
  47   WriteRegStr SHCTX ${APP_UNINST_KEY} "UninstallString" '"$INSTDIR\${SETUP_UNINSTALLER}"'
  48   WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayVersion" "${APP_VERSION}"
  49   WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayIcon" "$INSTDIR\bin\lyx,0"
  50   WriteRegStr SHCTX ${APP_UNINST_KEY} "URLUpdateInfo" "http://www.lyx.org/"
  51   WriteRegStr SHCTX ${APP_UNINST_KEY} "URLInfoAbout" "http://www.lyx.org/about/"
  52   WriteRegStr SHCTX ${APP_UNINST_KEY} "Publisher" "LyX Team"
  53   WriteRegStr SHCTX ${APP_UNINST_KEY} "HelpLink" "http://www.lyx.org/internet/mailing.php"
  54   WriteRegDWORD SHCTX ${APP_UNINST_KEY} "NoModify" 0x00000001
  55   WriteRegDWORD SHCTX ${APP_UNINST_KEY} "NoRepair" 0x00000001
  56   WriteRegStr SHCTX ${APP_UNINST_KEY} "StartMenu" "$SMPROGRAMS\$StartmenuFolder"
  57
  58   # if we install over an older existing version, remove the old uninstaller information
  59   ${if} $OldVersionNumber < ${APP_SERIES_KEY}
  60    DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}$OldVersionNumber"
  61    # also delete in the case of an emergency release
  62    DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}$OldVersionNumber1"
  63   ${endif}
  64
  65 SectionEnd
  66
  67 #--------------------------------
  68 # Write LyX configuration file
  69
  70 Section -Configure
  71
  72   # Associate .lyx files with LyX for current user or all users
  73
  74   ${if} $CreateFileAssociations == "true"
  75    WriteRegStr SHCTX "${APP_DIR_REGKEY}" "" "$INSTDIR\${APP_RUN}"
  76   ${endif}
  77
  78   # Write information about file type
  79   #!define REG_FILETYPE 'WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}"'
  80
  81   ${if} $CreateFileAssociations == "true"
  82    WriteRegStr SHCTX "${APP_DIR_REGKEY}" "OnlyWithLyX" "Yes${APP_SERIES_KEY}" # special entry to test if they were registered by this LyX version
  83    WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}" "" "${APP_NAME} Document"
  84    WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}\DefaultIcon" "" "$INSTDIR\${APP_RUN},0"
  85    WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}\Shell\open\command" "" '"$INSTDIR\${APP_RUN}" "%1"'
  86    # we need to update also the automatically created entry about the lyx.exe
  87    # otherwise .lyx-files will could be opened with an older LyX version
  88    ReadRegStr $0 SHCTX "Software\Classes\Applications\${BIN_LYX}\shell\open\command" ""
  89    ${if} $0 != "" # if something was found
  90     WriteRegStr SHCTX "Software\Classes\Applications\${BIN_LYX}\shell\open\command" "" '"$INSTDIR\${APP_RUN}" "%1"'
  91    ${endif}
  92    # .lyx
  93    WriteRegStr SHCTX "Software\Classes\${APP_EXT}" "" "${APP_REGNAME_DOC}"
  94    WriteRegStr SHCTX "Software\Classes\${APP_EXT}" "Content Type" "${APP_MIME_TYPE}"
  95    # .lyx13
  96    WriteRegStr SHCTX "Software\Classes\${APP_EXT}13" "" "${APP_REGNAME_DOC}"
  97    WriteRegStr SHCTX "Software\Classes\${APP_EXT}13" "Content Type" "${APP_MIME_TYPE}"
  98    # .lyx14
  99    WriteRegStr SHCTX "Software\Classes\${APP_EXT}14" "" "${APP_REGNAME_DOC}"
 100    WriteRegStr SHCTX "Software\Classes\${APP_EXT}14" "Content Type" "${APP_MIME_TYPE}"
 101    # .lyx15
 102    WriteRegStr SHCTX "Software\Classes\${APP_EXT}15" "" "${APP_REGNAME_DOC}"
 103    WriteRegStr SHCTX "Software\Classes\${APP_EXT}15" "Content Type" "${APP_MIME_TYPE}"
 104    # .lyx16
 105    WriteRegStr SHCTX "Software\Classes\${APP_EXT}16" "" "${APP_REGNAME_DOC}"
 106    WriteRegStr SHCTX "Software\Classes\${APP_EXT}16" "Content Type" "${APP_MIME_TYPE}"
 107    # .lyx20 don't set this, because this is designed to be opened with LyX 2.0.x
 108
 109    # Refresh shell
 110    ${RefreshShellIcons}
 111   ${endif}
 112
 113   # Install standard lyxrc.dist file
 114   #SetOutPath "$INSTDIR\Resources"
 115   #File "${FILES_DEPS}\Resources\lyxrc.dist"
 116
 117   # create the path prefix
 118   # $$ represents a literal $ in an NSIS string
 119   StrCpy $PathPrefix "$$LyXDir\bin;$$LyXDir\Python;$$LyXDir\Python\Lib;$$LyXDir\Perl\bin;$$LyXDir\imagemagick"
 120
 121   ${if} $PathLaTeX != ""
 122     StrCpy $PathPrefix "$PathPrefix;$PathLaTeX"
 123   ${EndIf}
 124   ${if} $PSVPath != ""
 125     StrCpy $PathPrefix "$PathPrefix;$PSVPath"
 126   ${endif}
 127   ${if} $EditorPath != ""
 128     StrCpy $PathPrefix "$PathPrefix;$EditorPath"
 129   ${endif}
 130   ${if} $ImageEditorPath != ""
 131     StrCpy $PathPrefix "$PathPrefix;$ImageEditorPath"
 132   ${endif}
 133   ${if} $GhostscriptPath != ""
 134    StrCpy $PathPrefix "$PathPrefix;$GhostscriptPath"
 135   ${endif}
 136   ${if} $SVGPath != ""
 137    StrCpy $PathPrefix "$PathPrefix;$SVGPath"
 138   ${endif}
 139   ${if} $GnumericPath != ""
 140    StrCpy $PathPrefix "$PathPrefix;$GnumericPath"
 141   ${endif}
 142   ${if} $PathBibTeXEditor != ""
 143     StrCpy $PathPrefix "$PathPrefix;$PathBibTeXEditor"
 144   ${EndIf}
 145   ${if} $LilyPondPath != ""
 146    StrCpy $PathPrefix "$PathPrefix;$LilyPondPath"
 147   ${endif}
 148
 149   # Set the path prefix in lyxrc.dist
 150   ClearErrors
 151   Delete "$INSTDIR\Resources\lyxrc.dist"
 152   FileOpen $R1 "$INSTDIR\Resources\lyxrc.dist" w
 153   # set the format to the latest LyXRC format
 154   FileWrite $R1 'Format 15$\r$\n'
 155   # set some general things
 156   FileWrite $R1 '\screen_zoom 120$\r$\n'
 157   ${if} "$PathPrefix" != ""
 158    FileWrite $R1 '\path_prefix "$PathPrefix"$\r$\n'
 159   ${endif}
 160
 161   # set path to eLyXer
 162   FileWrite $R1 '\converter "lyx" "html" "python -tt \"$INSTDIR\Python\Lib\elyxer.py\" --directory $$$$r $$$$i $$$$o" ""$\r$\n\
 163                  \converter "lyx" "wordhtml" "python -tt \"$INSTDIR\Python\Lib\elyxer.py\" --html --directory $$$$r $$$$i $$$$o" ""$\r$\n'
 164
 165   # use pdfview for all types of PDF files
 166   FileWrite $R1 '\format "pdf5" "pdf" "PDF (LuaTeX)" "u" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
 167                  \format "pdf4" "pdf" "PDF (XeTeX)" "X" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
 168                  \format "pdf3" "pdf" "PDF (dvipdfm)" "m" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
 169                  \format "pdf2" "pdf" "PDF (pdflatex)" "F" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
 170                  \format "pdf" "pdf" "PDF (ps2pdf)" "P" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n'
 171
 172   # if LilyPondPath was found
 173   # we need to add these entris because python scripts can only be executed
 174   # if the full path is given
 175   ${if} $LilyPondPath != ""
 176    FileWrite $R1 '\format "lilypond-book" "lytex" "LilyPond book (LaTeX)" "" "" "auto" "document,menu=export" ""$\r$\n\
 177                   \converter "lilypond-book" "pdflatex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --pdf --latex-program=pdflatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
 178                   \converter "lilypond-book" "xetex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --pdf --latex-program=xelatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
 179                   \converter "lilypond-book" "luatex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --pdf --latex-program=lualatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
 180                   \converter "lilypond-book" "latex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --lily-output-dir=ly-eps $$$$i" ""$\r$\n'
 181   ${endif}
 182   FileClose $R1
 183   IfErrors 0 +2
 184    MessageBox MB_OK|MB_ICONEXCLAMATION "$(ModifyingConfigureFailed)" /SD IDOK
 185   ClearErrors
 186
 187 SectionEnd
 188
 189 #--------------------------------
 190 # Postscript printer for metafile to EPS converter
 191
 192 Section -PSPrinter
 193
 194   ${if} $MultiUser.Privileges == "Admin"
 195   ${orif} $MultiUser.Privileges == "Power"
 196    # Delete printer
 197    ExecWait '$PrinterConf /q /dl /n "Metafile to EPS Converter"'
 198    # Install printer and driver
 199    ExecWait '$PrinterConf /if /f "$WINDIR\inf\ntprint.inf" /b "Metafile to EPS Converter" /r "FILE:" /m "MS Publisher Imagesetter"'
 200   ${else}
 201    MessageBox MB_OK|MB_ICONINFORMATION "$(MetafileNotAvailable)" /SD IDOK
 202   ${endif}
 203
 204 SectionEnd
 205
 206 #--------------------------------
 207 # Run the LyX configure.py script, so MiKTeX can download its packages
 208
 209 Var ConfigureReturn
 210
 211 Section -ConfigureScript
 212
 213   SetOutPath "$INSTDIR\Resources"
 214
 215   # ask to update MiKTeX
 216   ${if} $LaTeXInstalled == "MiKTeX"
 217    Call UpdateMiKTeX # function from latex.nsh
 218    # install all necessary packages at once because this is much faster then to install the packages one by one
 219    # NOTE: the babelpackages-txt list is only necessary for LyX 2.1.2 ans 2.1.3 because of the restructuration
 220    # of babel in MiKTeX. This can be removed for LyX 2.1.4
 221    DetailPrint $(TEXT_CONFIGURE_LYX)
 222    ${if} $MultiUser.Privileges != "Admin"
 223    ${andif} $MultiUser.Privileges != "Power"
 224     # call the non-admin version
 225     # at first we need to synchronize the package database
 226     nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--verbose" "--update-db"'
 227     nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--verbose" "--install-some=$INSTDIR\Resources\Packages.txt"'
 228     nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--verbose" "--install-some=$INSTDIR\Resources\babel-Packages.txt"'
 229    ${else}
 230     ${if} $MiKTeXUser != "HKCU" # call the admin version
 231      nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--admin" "--verbose" "--update-db"'
 232      nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--admin" "--verbose" "--install-some=$INSTDIR\Resources\Packages.txt"'
 233      nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--admin" "--verbose" "--install-some=$INSTDIR\Resources\babel-Packages.txt"'
 234     ${else}
 235      nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--verbose" "--update-db"'
 236      nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--verbose" "--install-some=$INSTDIR\Resources\Packages.txt"'
 237      nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--verbose" "--install-some=$INSTDIR\Resources\babel-Packages.txt"'
 238     ${endif}
 239    ${endif}
 240   ${endif}
 241
 242   DetailPrint $(TEXT_CONFIGURE_LYX)
 243   nsExec::ExecToLog '"$INSTDIR\Python\python.exe" "$INSTDIR\Resources\configure.py"'
 244   # $ConfigureReturn is "0" if successful, otherwise "1"
 245   Pop $ConfigureReturn # Return value
 246
 247 SectionEnd
 248
 249 #--------------------------------
 250 # Desktop shortcut
 251
 252 Function StartLyX
 253
 254   # run LyX in a command line window to give the users feedback about
 255   # the time consuming LaTeX package installation
 256
 257   #Exec 'cmd /K " "$INSTDIR\bin\lyx.exe""'
 258   Exec "$INSTDIR\${APP_RUN}"
 259
 260 FunctionEnd
 261
 262 /*Function CheckDesktopShortcut
 263
 264   # Enable desktop icon creation when there is an icon already
 265   # Old shortcuts need to be updated
 266
 267   ${If} ${FileExists} "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk"
 268     ${NSD_SetState} $mui.FinishPage.ShowReadme ${BST_CHECKED}
 269   ${EndIf}
 270
 271 FunctionEnd
 272
 273 Function CreateDesktopShortcut
 274
 275   # Desktop icon creation is an option on the finish page
 276   SetOutPath "$INSTDIR\bin"
 277   CreateShortCut "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"
 278
 279 FunctionEnd*/
 280