]> git.lyx.org Git - features.git/blob - development/Win32/packaging/installer/setup/configure.nsh
installer: default to LyX 2.1's LyXRC format
[features.git] / development / Win32 / packaging / installer / setup / configure.nsh
1 /*
2
3 configure.nsh
4
5 Write registry information and configure LyX
6
7 */
8
9 Var PathPrefix
10
11 #!define SHORTCUT '${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"'
12
13 #--------------------------------
14 # Registry information
15
16 Section -InstallData
17
18   # Registry information
19   WriteRegStr SHCTX ${APP_REGKEY} "" $INSTDIR
20   WriteRegStr SHCTX ${APP_REGKEY} "Version" "${APP_VERSION_NUMBER}"
21   WriteRegStr SHCTX ${APP_REGKEY_SETUP} "LaTeX Path" $PathLaTeX
22   
23   # Start Menu shortcut
24   SetOutPath "$INSTDIR\bin" # this is the folder in which the shortcut is executed
25   CreateDirectory "$SMPROGRAMS\$StartmenuFolder"
26   CreateShortCut "$SMPROGRAMS\$StartmenuFolder\${APP_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"
27   # Link to www.lyx.org and to the Wiki
28   WriteINIStr "$SMPROGRAMS\$StartmenuFolder\${APP_WEBPAGE_INFO}.url" "InternetShortcut" "URL" "${APP_WEBPAGE}"
29   WriteINIStr "$SMPROGRAMS\$StartmenuFolder\${APP_WIKI_INFO}.url" "InternetShortcut" "URL" "${APP_WIKI}"
30   # create desktop icon
31   ${if} $CreateDesktopIcon == "true"
32    SetOutPath "$INSTDIR\bin"
33    CreateShortCut "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"
34   ${endif}
35   
36   # Uninstaller information
37   ${If} $MultiUser.InstallMode == "CurrentUser"
38     WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayName" "${APP_NAME} ${APP_VERSION} $(TEXT_INSTALL_CURRENTUSER)"
39   ${Else}
40     WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayName" "${APP_NAME} ${APP_VERSION}"
41   ${EndIf}
42   
43   WriteRegStr SHCTX ${APP_UNINST_KEY} "UninstallString" '"$INSTDIR\${SETUP_UNINSTALLER}"'
44   WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayVersion" "${APP_VERSION}"
45   WriteRegStr SHCTX ${APP_UNINST_KEY} "DisplayIcon" "$INSTDIR\bin\lyx,0"
46   WriteRegStr SHCTX ${APP_UNINST_KEY} "URLUpdateInfo" "http://www.lyx.org/"
47   WriteRegStr SHCTX ${APP_UNINST_KEY} "URLInfoAbout" "http://www.lyx.org/about/"
48   WriteRegStr SHCTX ${APP_UNINST_KEY} "Publisher" "LyX Team"
49   WriteRegStr SHCTX ${APP_UNINST_KEY} "HelpLink" "http://www.lyx.org/internet/mailing.php"
50   WriteRegDWORD SHCTX ${APP_UNINST_KEY} "NoModify" 0x00000001
51   WriteRegDWORD SHCTX ${APP_UNINST_KEY} "NoRepair" 0x00000001
52   WriteRegStr SHCTX ${APP_UNINST_KEY} "StartMenu" "$SMPROGRAMS\$StartmenuFolder"
53   
54   # if we install over an existing version, remove the old uninstaller information
55   ${if} $OldVersionNumber != ""
56    DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}$OldVersionNumber"
57    # also delete in the case of an emergency release
58    DeleteRegKey SHCTX "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}$OldVersionNumber1"
59   ${endif}
60   
61 SectionEnd
62
63 #--------------------------------
64 # Write LyX configuration file
65
66 Section -Configure
67
68   # Associate .lyx files with LyX for current user of all users
69
70   ${if} $CreateFileAssociations == "true"
71    WriteRegStr SHCTX "${APP_DIR_REGKEY}" "" "$INSTDIR\${APP_RUN}"
72   ${endif}
73
74   # Write information about file type
75   #!define REG_FILETYPE 'WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}"'
76   
77   ${if} $CreateFileAssociations == "true"
78    WriteRegStr SHCTX "${APP_DIR_REGKEY}" "OnlyWithLyX" "Yes${APP_SERIES_KEY}" # special entry to test if they were registered by this LyX version
79    WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}" "" "${APP_NAME} Document"
80    WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}\DefaultIcon" "" "$INSTDIR\${APP_RUN},0"
81    WriteRegStr SHCTX "Software\Classes\${APP_REGNAME_DOC}\Shell\open\command" "" '"$INSTDIR\${APP_RUN}" "%1"'
82    WriteRegStr SHCTX "Software\Classes\${APP_EXT}" "" "${APP_REGNAME_DOC}"
83    WriteRegStr SHCTX "Software\Classes\${APP_EXT}" "Content Type" "${APP_MIME_TYPE}"
84    # .lyx13
85    WriteRegStr SHCTX "Software\Classes\${APP_EXT}13" "" "${APP_REGNAME_DOC}"
86    WriteRegStr SHCTX "Software\Classes\${APP_EXT}13" "Content Type" "${APP_MIME_TYPE}"
87    # .lyx14
88    WriteRegStr SHCTX "Software\Classes\${APP_EXT}14" "" "${APP_REGNAME_DOC}"
89    WriteRegStr SHCTX "Software\Classes\${APP_EXT}14" "Content Type" "${APP_MIME_TYPE}"
90    # .lyx15
91    WriteRegStr SHCTX "Software\Classes\${APP_EXT}15" "" "${APP_REGNAME_DOC}"
92    WriteRegStr SHCTX "Software\Classes\${APP_EXT}15" "Content Type" "${APP_MIME_TYPE}"
93    # .lyx16
94    WriteRegStr SHCTX "Software\Classes\${APP_EXT}16" "" "${APP_REGNAME_DOC}"
95    WriteRegStr SHCTX "Software\Classes\${APP_EXT}16" "Content Type" "${APP_MIME_TYPE}"
96    # .lyx20 don't set this, because this is designed to be opened with LyX 2.0.x
97   
98    # Refresh shell
99    ${RefreshShellIcons}
100   ${endif}
101   
102   # Install standard lyxrc.dist file
103   #SetOutPath "$INSTDIR\Resources"
104   #File "${FILES_DEPS}\Resources\lyxrc.dist"
105
106   # create the path prefix
107   # $$ represents a literal $ in an NSIS string
108   StrCpy $PathPrefix "$$LyXDir\bin;$$LyXDir\Python;$$LyXDir\Python\Lib;$$LyXDir\imagemagick"
109   
110   ${if} $PathLaTeX != ""
111     StrCpy $PathPrefix "$PathPrefix;$PathLaTeX"
112   ${EndIf}
113   ${if} $PSVPath != ""
114     StrCpy $PathPrefix "$PathPrefix;$PSVPath"
115   ${endif}
116   ${if} $EditorPath != ""
117     StrCpy $PathPrefix "$PathPrefix;$EditorPath"
118   ${endif}
119   ${if} $ImageEditorPath != ""
120     StrCpy $PathPrefix "$PathPrefix;$ImageEditorPath"
121   ${endif}
122   ${if} $GhostscriptPath != ""
123    StrCpy $PathPrefix "$PathPrefix;$GhostscriptPath"
124   ${endif}
125   ${if} $SVGPath != ""
126    StrCpy $PathPrefix "$PathPrefix;$SVGPath"
127   ${endif}
128   ${if} $GnumericPath != ""
129    StrCpy $PathPrefix "$PathPrefix;$GnumericPath"
130   ${endif}
131   ${if} $PathBibTeXEditor != ""
132     StrCpy $PathPrefix "$PathPrefix;$PathBibTeXEditor"
133   ${EndIf}
134   ${if} $LilyPondPath != ""
135    StrCpy $PathPrefix "$PathPrefix;$LilyPondPath"
136   ${endif}
137   
138   # Set the path prefix in lyxrc.dist
139   ClearErrors
140   Delete "$INSTDIR\Resources\lyxrc.dist"
141   FileOpen $R1 "$INSTDIR\Resources\lyxrc.dist" w
142   # set the format to the latest LyXRC format
143   FileWrite $R1 'Format 14$\r$\n'
144   # set some general things
145   FileWrite $R1 '\screen_zoom 120$\r$\n'
146   ${if} "$PathPrefix" != ""
147    FileWrite $R1 '\path_prefix "$PathPrefix"$\r$\n'
148   ${endif}
149   
150   # set path to eLyXer
151   FileWrite $R1 '\converter "lyx" "html" "python -tt \"$INSTDIR\Python\Lib\elyxer.py\" --directory $$$$r $$$$i $$$$o" ""$\r$\n\
152                  \converter "lyx" "wordhtml" "python -tt \"$INSTDIR\Python\Lib\elyxer.py\" --html --directory $$$$r $$$$i $$$$o" ""$\r$\n'
153   
154   # use pdfview for all types of PDF files
155   FileWrite $R1 '\format "pdf5" "pdf" "PDF (LuaTeX)" "u" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
156                  \format "pdf4" "pdf" "PDF (XeTeX)" "X" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
157                  \format "pdf3" "pdf" "PDF (dvipdfm)" "m" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
158                  \format "pdf2" "pdf" "PDF (pdflatex)" "F" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n\
159                  \format "pdf" "pdf" "PDF (ps2pdf)" "P" "pdfview" "" "document,vector,menu=export" "application/pdf"$\r$\n'
160
161   # if LilyPondPath was found
162   # we need to add these entris because python scripts can only be executed
163   # if the full path is given
164   ${if} $LilyPondPath != ""
165    FileWrite $R1 '\format "lilypond-book" "lytex" "LilyPond book (LaTeX)" "" "" "auto" "document,menu=export"$\r$\n\
166                   \converter "lilypond-book" "pdflatex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --pdf --latex-program=pdflatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
167                   \converter "lilypond-book" "xetex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --pdf --latex-program=xelatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
168                   \converter "lilypond-book" "luatex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --pdf --latex-program=lualatex --lily-output-dir=ly-pdf $$$$i" ""$\r$\n\
169                   \converter "lilypond-book" "latex" "python \"$LilyPondPath\\lilypond-book.py\" --safe --lily-output-dir=ly-eps $$$$i" ""$\r$\n'
170   ${endif}
171   FileClose $R1
172   IfErrors 0 +2
173    MessageBox MB_OK|MB_ICONEXCLAMATION "$(ModifyingConfigureFailed)"
174   ClearErrors
175
176 SectionEnd
177
178 #--------------------------------
179 # Postscript printer for metafile to EPS converter
180
181 Section -PSPrinter
182
183   ${if} $MultiUser.Privileges == "Admin"
184   ${orif} $MultiUser.Privileges == "Power"
185    # Delete printer
186    ExecWait '$PrinterConf /q /dl /n "Metafile to EPS Converter"'
187    # Install printer and driver
188    ExecWait '$PrinterConf /if /f "$WINDIR\inf\ntprint.inf" /b "Metafile to EPS Converter" /r "FILE:" /m "MS Publisher Imagesetter"'
189   ${else}
190    MessageBox MB_OK|MB_ICONINFORMATION "$(MetafileNotAvailable)"
191   ${endif}
192
193 SectionEnd
194
195 #--------------------------------
196 # Run the LyX configure.py script, so MiKTeX can download its packages
197
198 Var ConfigureReturn
199
200 Section -ConfigureScript
201
202   SetOutPath "$INSTDIR\Resources"
203   
204   # ask to update MiKTeX
205   ${if} $LaTeXInstalled == "MiKTeX"
206    Call UpdateMiKTeX # function from latex.nsh
207    # install all necessary packages at once
208    DetailPrint $(TEXT_CONFIGURE_LYX)
209    ${if} $MultiUser.Privileges != "Admin"
210    ${andif} $MultiUser.Privileges != "Power"
211     # call the non-admin version
212     nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--verbose" "--install-some=$INSTDIR\Resources\Packages.txt"'
213    ${else}
214     ${if} $MiKTeXUser != "HKCU" # call the admin version
215      nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--admin" "--verbose" "--install-some=$INSTDIR\Resources\Packages.txt"'
216     ${else}
217      nsExec::ExecToLog '"$PathLaTeX\mpm.exe" "--verbose" "--install-some=$INSTDIR\Resources\Packages.txt"'
218     ${endif}
219    ${endif}
220   ${endif}
221   
222   DetailPrint $(TEXT_CONFIGURE_LYX)
223   nsExec::ExecToLog '"$INSTDIR\Python\python.exe" "$INSTDIR\Resources\configure.py"'
224   # $ConfigureReturn is "0" if successful, otherwise "1"
225   Pop $ConfigureReturn # Return value
226
227 SectionEnd
228
229 #--------------------------------
230 # Desktop shortcut
231
232 Function StartLyX
233
234   # run LyX in a command line window to give the users feedback about
235   # the time consuming LaTeX package installation
236   
237   #Exec 'cmd /K " "$INSTDIR\bin\lyx.exe""'
238   Exec "$INSTDIR\${APP_RUN}"
239
240 FunctionEnd
241
242 /*Function CheckDesktopShortcut
243
244   # Enable desktop icon creation when there is an icon already
245   # Old shortcuts need to be updated
246   
247   ${If} ${FileExists} "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk"
248     ${NSD_SetState} $mui.FinishPage.ShowReadme ${BST_CHECKED}
249   ${EndIf}
250
251 FunctionEnd
252
253 Function CreateDesktopShortcut
254
255   # Desktop icon creation is an option on the finish page
256   SetOutPath "$INSTDIR\bin"
257   CreateShortCut "$DESKTOP\${APP_NAME} ${APP_SERIES_NAME}.lnk" "$INSTDIR\${APP_RUN}" "" "$INSTDIR\${APP_RUN}" "" "" "" "${APP_INFO}"
258
259 FunctionEnd*/
260