development/Win32/packaging/installer/include/lang.nsh

   1 /*
   2
   3 Translations for installer and LyX itself
   4
   5 */
   6
   7 !macro LanguageList COMMAND
   8
   9   #List of supported LyX languages with ISO code and language identifier
  10   #To be used as input for other macros
  11
  12   ${COMMAND} "Bokmål" nb_NO 1044
  13   ${COMMAND} "Ce\9atina" cs_CZ 1029
  14   ${COMMAND} "Dansk" da_DK 1030
  15   ${COMMAND} "Deutsch" de_DE 1031
  16   ${COMMAND} "English" en_EN 1033
  17   ${COMMAND} "Español" es_ES 1034
  18   ${COMMAND} "Euskara" eu_EU 1069
  19   ${COMMAND} "Français" fr_FR 1036
  20   ${COMMAND} "Italiano" it_IT 1057
  21   ${COMMAND} "Magyar" hu_HU 1038
  22   ${COMMAND} "Nynorsk" nn_NO 2068
  23   ${COMMAND} "Polski" pl_PL 1045
  24   ${COMMAND} "Russian" ru_RU 1049
  25   ${COMMAND} "Slovencina" sk_SK 1060
  26   ${COMMAND} "Suomi" fi_FI 1035
  27   ${COMMAND} "Türkçe" tr_TR 1055
  28
  29 !macroend
  30
  31 !macro LanguageString name text
  32
  33   !ifndef "${name}"
  34     !define "${name}" "${text}"
  35   !endif
  36
  37 !macroend
  38
  39 !macro LanguageStringAdd lang_name name
  40
  41   #Takes a define and puts that into a language string
  42   LangString "${name}" "${LANG_${lang_name}}" "${${name}}"
  43   !undef "${name}"
  44
  45 !macroend
  46
  47 !macro LanguageStringCreateExternal component
  48
  49   ${LanguageStringAdd} TEXT_EXTERNAL_${component}_TITLE
  50   ${LanguageStringAdd} TEXT_EXTERNAL_${component}_SUBTITLE
  51   ${LanguageStringAdd} TEXT_EXTERNAL_${component}_INFO_${SETUPTYPE_NAME}
  52   ${LanguageStringAdd} TEXT_EXTERNAL_${component}_${SETUPTYPE_NAME}
  53   ${LanguageStringAdd} TEXT_EXTERNAL_${component}_FOLDER
  54   ${LanguageStringAdd} TEXT_EXTERNAL_${component}_FOLDER_INFO
  55   ${LanguageStringAdd} TEXT_EXTERNAL_${component}_NONE
  56   ${LanguageStringAdd} TEXT_EXTERNAL_${component}_NOTFOUND
  57
  58 !macroend
  59
  60 !macro LanguageStringCreate lang_name
  61
  62   #Creates all language strings
  63   !insertmacro ReDef LanguageStringAdd '!insertmacro LanguageStringAdd "${lang_name}"'
  64
  65   ${LanguageStringAdd} TEXT_NO_PRIVILEDGES
  66
  67   ${LanguageStringAdd} TEXT_INSTALL_CURRENTUSER
  68
  69   ${LanguageStringAdd} TEXT_WELCOME_${SETUPTYPE_NAME}
  70
  71   ${LanguageStringAdd} TEXT_USER_TITLE
  72   ${LanguageStringAdd} TEXT_USER_SUBTITLE
  73   ${LanguageStringAdd} TEXT_USER_INFO
  74   ${LanguageStringAdd} TEXT_USER_CURRENT
  75   ${LanguageStringAdd} TEXT_USER_ALL
  76
  77   ${LanguageStringAdd} TEXT_REINSTALL_TITLE
  78   ${LanguageStringAdd} TEXT_REINSTALL_SUBTITLE
  79   ${LanguageStringAdd} TEXT_REINSTALL_INFO
  80   ${LanguageStringAdd} TEXT_REINSTALL_ENABLE
  81
  82   ${LanguageStringAdd} TEXT_EXTERNAL_NOPRIVILEDGES
  83
  84   !insertmacro LanguageStringCreateExternal LaTeX
  85   !insertmacro LanguageStringCreateExternal ImageMagick
  86   !insertmacro LanguageStringCreateExternal Ghostscript
  87
  88   ${LanguageStringAdd} TEXT_VIEWER_TITLE
  89   ${LanguageStringAdd} TEXT_VIEWER_SUBTITLE
  90   ${LanguageStringAdd} TEXT_VIEWER_INFO_${SETUPTYPE_NAME}
  91   ${LanguageStringAdd} TEXT_VIEWER_${SETUPTYPE_NAME}
  92
  93   ${LanguageStringAdd} TEXT_DICT_TITLE
  94   ${LanguageStringAdd} TEXT_DICT_SUBTITLE
  95   ${LanguageStringAdd} TEXT_DICT_TOP
  96   ${LanguageStringAdd} TEXT_DICT_LIST
  97
  98   ${LanguageStringAdd} TEXT_LANGUAGE_TITLE
  99   ${LanguageStringAdd} TEXT_LANGUAGE_SUBTITLE
 100   ${LanguageStringAdd} TEXT_LANGUAGE_INFO
 101
 102   !ifndef SETUPTYPE_BUNDLE
 103     ${LanguageStringAdd} TEXT_DOWNLOAD_FAILED_LATEX
 104     ${LanguageStringAdd} TEXT_DOWNLOAD_FAILED_IMAGEMAGICK
 105     ${LanguageStringAdd} TEXT_DOWNLOAD_FAILED_GHOSTSCRIPT
 106     ${LanguageStringAdd} TEXT_DOWNLOAD_FAILED_VIEWER
 107   !endif
 108   ${LanguageStringAdd} TEXT_DOWNLOAD_FAILED_DICT
 109
 110   ${LanguageStringAdd} TEXT_NOTINSTALLED_LATEX
 111   ${LanguageStringAdd} TEXT_NOTINSTALLED_IMAGEMAGICK
 112   ${LanguageStringAdd} TEXT_NOTINSTALLED_GHOSTSCRIPT
 113   ${LanguageStringAdd} TEXT_NOTINSTALLED_VIEWER
 114   ${LanguageStringAdd} TEXT_NOTINSTALLED_DICT
 115
 116   ${LanguageStringAdd} TEXT_FINISH_DESKTOP
 117   ${LanguageStringAdd} TEXT_FINISH_WEBSITE
 118
 119   ${LanguageStringAdd} UNTEXT_WELCOME
 120
 121 !macroend
 122
 123 !macro IncludeLang langname
 124
 125   !ifndef DICT_NAME
 126     !define DICT_NAME $R1
 127   !endif
 128
 129   #Include both NSIS/LyX language file
 130
 131   !insertmacro MUI_LANGUAGE "${langname}"
 132
 133   !include "lang\${langname}.nsh"
 134   !include "lang\English.nsh" ;Use English for missing strings in translation
 135
 136   !insertmacro LanguageStringCreate "${langname}"
 137
 138 !macroend