development/Win32/packaging/installer/include/LaTeX.nsh

   1 /*
   2 LaTeX.nsh
   3
   4 Handling of LaTeX distributions
   5 */
   6
   7 # This script contains the following functions:
   8 #
   9 # - LaTeXActions (checks if MiKTeX or TeXLive is installed)
  10 #
  11 # - InstallMiKTeX (installs MiKTeX if not already installed),
  12 #   only for bunlde installer, uses:
  13 #    LaTeXCheck # function from LyXUtils.nsh
  14 #
  15 # - ConfigureMiKTeX
  16 #   (installs the LaTeX class files that are delivered with LyX,
  17 #    a Perl interpreter for splitindex and pdfcrop
  18 #    and enable MiKTeX's automatic package installation)
  19 #
  20 # - ConfigureTeXLive
  21 #   (installs the LaTeX class files that are delivered with LyX)
  22 #
  23 # - UpdateMiKTeX (asks to update MiKTeX)
  24
  25 # ---------------------------------------
  26
  27 Function LaTeXActions
  28  # checks if MiKTeX or TeXLive is installed
  29
  30   StrCpy $Is64bit "false"
  31
  32   ${if} ${RunningX64}
  33    SetRegView 64 # the PATH is in the 64bit registry section
  34   ${endif}
  35   # test if MiKTeX is installed
  36   # reads the PATH variable via the registry because NSIS' "$%Path%" variable is not updated when the PATH changes
  37   ReadRegStr $String HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path"
  38   StrCpy $Search "miktex"
  39   Call LaTeXCheck # sets the path to the latex.exe to $PathLaTeX # Function from LyXUtils.nsh
  40
  41   StrCpy $String $PathLaTeX
  42   StrCpy $Search "x64" # search if it is 64bit MiKTeX
  43   Call StrPoint # Function from LyXUtils.nsh
  44   ${if} $Pointer != "-1" # if something was found
  45    StrCpy $Is64bit "true"
  46   ${endif}
  47
  48   # check for 32bit MiKTeX
  49   ${if} $PathLaTeX != ""
  50   ${andif} $Is64bit != "true"
  51    ${if} ${RunningX64}
  52     SetRegView 32
  53    ${endif}
  54    # check if MiKTeX 2.8 or newer is installed
  55    StrCpy $0 0
  56    loop32:
  57     EnumRegKey $1 HKLM "SOFTWARE\MiKTeX.org\MiKTeX" $0 # check the last subkey
  58     StrCmp $1 "" done32
  59     StrCpy $String $1
  60     IntOp $0 $0 + 1
  61     Goto loop32
  62    done32:
  63    ${if} $String == "2.8"
  64     StrCpy $MiKTeXVersion "2.8"
  65     StrCpy $LaTeXName "MiKTeX 2.8"
  66    ${endif}
  67    ${if} $String == "2.9"
  68     StrCpy $MiKTeXVersion "2.9"
  69     StrCpy $LaTeXName "MiKTeX 2.9"
  70    ${endif}
  71   ${endif}
  72
  73   # check for 64bit MiKTeX
  74   ${if} $LaTeXName == ""
  75    ${if} ${RunningX64}
  76     SetRegView 64
  77    ${endif}
  78    # check if MiKTeX 2.8 or newer is installed
  79    StrCpy $0 0
  80    loop64:
  81     EnumRegKey $1 HKLM "SOFTWARE\MiKTeX.org\MiKTeX" $0 # check the last subkey
  82     StrCmp $1 "" done64
  83     StrCpy $String $1
  84     IntOp $0 $0 + 1
  85     Goto loop64
  86    done64:
  87    ${if} $String == "2.8"
  88     StrCpy $MiKTeXVersion "2.8"
  89     StrCpy $LaTeXName "MiKTeX 2.8"
  90    ${endif}
  91    ${if} $String == "2.9"
  92     StrCpy $MiKTeXVersion "2.9"
  93     StrCpy $LaTeXName "MiKTeX 2.9"
  94    ${endif}
  95   ${endif}
  96
  97   ${if} $PathLaTeX != ""
  98    StrCpy $MiKTeXUser "HKLM" # needed later to configure MiKTeX
  99   ${else} # check if MiKTeX is installed only for the current user
 100    ${if} ${RunningX64}
 101     SetRegView 64 # the PATH is in the 64bit registry section
 102    ${endif}
 103    ReadRegStr $String HKCU "Environment" "Path"
 104    StrCpy $Search "miktex"
 105    Call LaTeXCheck # function from LyXUtils.nsh
 106    ${if} $PathLaTeX != ""
 107     StrCpy $MiKTeXUser "HKCU"
 108    ${endif}
 109   ${endif}
 110   ${if} $LaTeXName == "" # check for the MiKTeX version
 111    StrCpy $0 0
 112    loopB:
 113     EnumRegKey $1 HKCU "SOFTWARE\MiKTeX.org\MiKTeX" $0 # check the last subkey
 114     StrCmp $1 "" doneB
 115     StrCpy $String $1
 116     IntOp $0 $0 + 1
 117     Goto loopB
 118    doneB:
 119    ${if} $String == "2.8"
 120     StrCpy $MiKTeXVersion "2.8"
 121     StrCpy $LaTeXName "MiKTeX 2.8"
 122    ${endif}
 123    ${if} $String == "2.9"
 124     StrCpy $MiKTeXVersion "2.9"
 125     StrCpy $LaTeXName "MiKTeX 2.9"
 126    ${endif}
 127   ${endif}
 128
 129   ${if} $PathLaTeX != ""
 130    StrCpy $String $PathLaTeX
 131    StrCpy $Search "x64" # search if it is 64bit MiKTeX
 132    Call StrPoint # Function from LyXUtils.nsh
 133    ${if} $Pointer != "-1" # if something was found
 134     StrCpy $Is64bit "true"
 135    ${endif}
 136    StrCpy $LaTeXInstalled "MiKTeX"
 137    # on some installations the path ends with a "\" on some not
 138    # therefore assure that we remove it if it exists
 139    StrCpy $0 $PathLaTeX "" -1
 140    ${if} $0 == "\"
 141     StrCpy $PathLaTeX "$PathLaTeX" -1 # delete "\"
 142    ${endif}
 143   ${endif}
 144
 145   # test if TeXLive is installed
 146   # TeXLive can be installed so that it appears in the PATH variable and/or only as current user.
 147   # The safest method is to first check for the PATH because this is independent of the TeXLive version.
 148   ${if} ${RunningX64}
 149    SetRegView 64 # the PATH is in the 64bit registry section
 150   ${endif}
 151   ${if} $PathLaTeX == ""
 152    ReadRegStr $String HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path"
 153    StrCpy $Search "TeXLive"
 154    Call LaTeXCheck # function from LyXUtils.nsh
 155   ${endif}
 156   # check for the current user Path variable
 157   ${if} $PathLaTeX == ""
 158    ReadRegStr $String HKCU "Environment" "Path"
 159    StrCpy $Search "texlive"
 160    StrCpy $2 "TeXLive"
 161    Call LaTeXCheck # function from LyXUtils.nsh
 162   ${endif}
 163   # check if it was installed to the system
 164   ${if} ${RunningX64}
 165    SetRegView 32 # TeXLive is a 32bit application
 166   ${endif}
 167   ${if} $PathLaTeX == ""
 168    ReadRegStr $String HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2015" "UninstallString"
 169    ${if} $String == ""
 170     ReadRegStr $String HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2015" "UninstallString"
 171    ${endif}
 172    ${if} $String != ""
 173     StrCpy $String $String -28 # remove '\tlpkg\installer\uninst.bat"'
 174     StrCpy $String $String "" 1 # remove the leading quote
 175    ${endif}
 176    StrCpy $PathLaTeX "$String\bin\win32"
 177    # check if the latex.exe exists in the $PathLaTeX folder
 178    !insertmacro FileCheck $5 "latex.exe" "$PathLaTeX" # macro from LyXUtils.nsh
 179    ${if} $5 == "False"
 180     StrCpy $PathLaTeX ""
 181    ${endif}
 182   ${endif}
 183   # finally set the name
 184   ${if} $PathLaTeX != ""
 185   ${andif} $LaTeXName != "MiKTeX 2.8"
 186   ${andif} $LaTeXName != "MiKTeX 2.9"
 187    StrCpy $LaTeXInstalled "TeXLive"
 188    ReadRegStr $String HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2015" "DisplayVersion"
 189    ${if} $String == ""
 190     ReadRegStr $String HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2015" "DisplayVersion"
 191    ${endif}
 192    ${if} $String == ""
 193     ReadRegStr $String HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2014" "DisplayVersion"
 194    ${endif}
 195    ${if} $String == ""
 196     ReadRegStr $String HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2014" "DisplayVersion"
 197    ${endif}
 198    ${if} $String != ""
 199     StrCpy $LaTeXName "TeXLive $String"
 200    ${else}
 201     StrCpy $LaTeXName "TeXLive"
 202    ${endif}
 203   ${endif}
 204
 205 FunctionEnd
 206
 207 # -------------------------------------------
 208
 209 !if ${SETUPTYPE} == BUNDLE
 210
 211  Function InstallMiKTeX
 212   # installs MiKTeX if not already installed
 213
 214   ${if} $PathLaTeX == ""
 215    # launch MiKTeX's installer
 216    MessageBox MB_OK|MB_ICONINFORMATION "$(LatexInfo)" /SD IDOK
 217    MessageBox MB_OK|MB_ICONINFORMATION "${MiKTeXInstall} --shared"
 218    ${if} $MultiUser.Privileges != "Admin"
 219    ${andif} $MultiUser.Privileges != "Power"
 220     # call the non-admin version
 221     ExecWait ${MiKTeXInstall}
 222    ${else}
 223     ExecWait "${MiKTeXInstall} --shared"
 224    ${endif}
 225    # test if MiKTeX is installed
 226    Call LaTeXActions
 227    ${if} ${RunningX64}
 228     SetRegView 32 # we install the 32bit version of MiKTeX
 229    ${endif}
 230    ${if} $PathLaTeX != ""
 231     # special entry that it was installed together with LyX
 232     # so that we can later uninstall it together with LyX
 233     ${if} $MiKTeXUser == "HKCU"
 234      WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 235     ${else}
 236      WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 237     ${endif}
 238     StrCpy $LaTeXInstalled "MiKTeX"
 239     StrCpy $MiKTeXVersion ${MiKTeXDeliveredVersion}
 240    ${else}
 241     MessageBox MB_OK|MB_ICONSTOP "$(LatexError1)" /SD IDOK
 242     SetOutPath $TEMP # to be able to delete the $INSTDIR
 243     RMDir /r $INSTDIR
 244     Abort
 245    ${endif} # endif $PathLaTeX != ""
 246   ${endif}
 247
 248   FunctionEnd
 249
 250 !endif # endif ${SETUPTYPE} == BUNDLE
 251
 252 # ------------------------------
 253
 254 Function ConfigureMiKTeX
 255  # installs the LaTeX class files that are delivered with LyX,
 256  # a Perl interpreter for splitindex and pdfcrop
 257  # and enable MiKTeX's automatic package installation
 258
 259  # install LyX's LaTeX class and style files and a Perl interpreter
 260  ${if} $PathLaTeX != ""
 261   ${if} $MultiUser.Privileges == "Admin"
 262   ${orif} $MultiUser.Privileges == "Power"
 263    ${if} $Is64bit == "true"
 264     StrCpy $PathLaTeXLocal "$PathLaTeX" -15 # delete "\miktex\bin\x64"
 265    ${else}
 266     StrCpy $PathLaTeXLocal "$PathLaTeX" -11 # delete "\miktex\bin"
 267    ${endif}
 268   ${else}
 269    StrCpy $PathLaTeXLocal "$APPDATA\MiKTeX\$MiKTeXVersion"
 270   ${endif}
 271
 272   # only install the LyX packages if they are not already installed
 273   ${ifnot} ${FileExists} "$PathLaTeXLocal\tex\latex\lyx\broadway.cls"
 274    # dvipost
 275    SetOutPath "$PathLaTeXLocal\tex\latex\dvipost"
 276    File "${FILES_DVIPOST_PKG}\dvipost.sty"
 277    # files in Resources\tex
 278    SetOutPath "$PathLaTeXLocal\tex\latex\lyx"
 279    CopyFiles /SILENT "$INSTDIR\Resources\tex\*.*" "$PathLaTeXLocal\tex\latex\lyx"
 280   ${endif}
 281   # Belarusian support
 282   ${ifnot} ${FileExists} "$PathLaTeXLocal\tex\generic\babel\belarusian.ldf"
 283    SetOutPath "$PathLaTeXLocal\tex\generic\babel"
 284    File "${FILES_DVIPOST_PKG}\belarusian.ldf"
 285    File "${FILES_DVIPOST_PKG}\belarusian.sty"
 286   ${endif}
 287   # Hungarian support
 288   # this is a replacement therefore do this in every case
 289   SetOutPath "$PathLaTeXLocal\tex\generic\babel"
 290   File "${FILES_DVIPOST_PKG}\magyar.ldf"
 291
 292   # install a Perl interpreter for splitindex and pdfcrop
 293   SetOutPath "$INSTDIR"
 294   # recursively copy all files under Perl
 295   File /r "${FILES_PERL}"
 296
 297   # refresh MiKTeX's file name database (do this always to assure everything is in place)
 298   ${if} $MultiUser.Privileges != "Admin"
 299   ${andif} $MultiUser.Privileges != "Power"
 300    # call the non-admin version
 301    nsExec::ExecToLog "$PathLaTeX\initexmf --update-fndb"
 302   ${else}
 303    ${if} $MiKTeXUser != "HKCU" # call the admin version
 304     nsExec::ExecToLog "$PathLaTeX\initexmf --admin --update-fndb"
 305    ${else}
 306     nsExec::ExecToLog "$PathLaTeX\initexmf --update-fndb"
 307    ${endif}
 308   ${endif}
 309   Pop $UpdateFNDBReturn # Return value
 310
 311  ${endif} # end if $PathLaTeX != ""
 312
 313   # enable package installation without asking (1 = Yes, 0 = No, 2 = Ask me first) and
 314   # if there is not package repository (MiKTeX's primary package repository) then set it
 315   ${if} ${RunningX64}
 316   ${andif} $Is64bit == "true"
 317    SetRegView 64
 318   ${else}
 319    SetRegView 32
 320   ${endif}
 321   ${if} $MiKTeXUser == "HKCU" # if only for current user
 322    # if AutoInstall is set to "0" we can assume that this was set purposly since the default is "1"
 323    ReadRegStr $2 HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoInstall"
 324    ${if} $2 == "0"
 325     Goto NoAutoInstall
 326    ${endif}
 327    WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoInstall" "1"
 328    ReadRegStr $1 HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository"
 329    ${if} $1 == ""
 330     WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository" "${MiKTeXRepo}"
 331     WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RepositoryType" "remote"
 332    ${endif}
 333   ${else}
 334    # if AutoInstall is set to "0" we can assume that this was set purposly since the default is "1"
 335    ReadRegStr $2 HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoInstall"
 336    ${if} $2 == "0"
 337     Goto NoAutoInstall
 338    ${endif}
 339    WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoInstall" "1"
 340    ReadRegStr $1 HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository"
 341    ${if} $1 == ""
 342     WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository" "${MiKTeXRepo}"
 343     WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RepositoryType" "remote"
 344    ${endif}
 345    # we need to state that missing packages should be installed for all users too
 346    WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoAdmin" "t"
 347   ${endif}
 348   NoAutoInstall:
 349
 350   # update MiKTeX's package file list
 351   ExecWait '$PathLaTeX\mpm.exe --update-fndb'
 352
 353   # we must return to 32bit because LyX is a 32bit application
 354   SetRegView 32
 355
 356 FunctionEnd
 357
 358 # ------------------------------
 359
 360 Function ConfigureTeXLive
 361  # installs the LaTeX class files that are delivered with LyX
 362  # (TeXLive comes already with a Perl interpreter.)
 363
 364  ${if} $PathLaTeX != ""
 365   StrCpy $PathLaTeXLocal "$PathLaTeX" -10 # delete "\bin\win32"
 366
 367   # only install the LyX packages if they are not already installed
 368   ${ifnot} ${FileExists} "$PathLaTeXLocal\texmf-dist\tex\latex\lyx\broadway.cls"
 369    # dvipost
 370    SetOutPath "$PathLaTeXLocal\texmf-dist\tex\latex\dvipost"
 371    File "${FILES_DVIPOST_PKG}\dvipost.sty"
 372    # files in Resources\tex
 373    SetOutPath "$PathLaTeXLocal\texmf-dist\tex\latex\lyx"
 374    CopyFiles /SILENT "$INSTDIR\Resources\tex\*.*" "$PathLaTeXLocal\texmf-dist\tex\latex\lyx"
 375   ${endif}
 376  ${endif}
 377
 378  # update TeXLive's package file list
 379  ExecWait '$PathLaTeX\texhash'
 380
 381  # update TeXLive
 382  ExecWait '$PathLaTeX\tlmgr update --all'
 383
 384 FunctionEnd
 385
 386 # ------------------------------
 387
 388 Function UpdateMiKTeX
 389  # asks to update MiKTeX
 390
 391   MessageBox MB_YESNO|MB_ICONINFORMATION "$(MiKTeXInfo)" /SD IDNO IDYES UpdateNow IDNO UpdateLater
 392   UpdateNow:
 393   # the update wizard is started by the miktex-update.exe
 394   ${if} $MultiUser.Privileges != "Admin"
 395   ${andif} $MultiUser.Privileges != "Power"
 396    # call the non-admin version
 397     ExecWait '"$PathLaTeX\internal\miktex-update.exe"'
 398   ${else}
 399    ${if} $MiKTeXUser != "HKCU" # call the admin version
 400     ExecWait '"$PathLaTeX\internal\miktex-update_admin.exe"'
 401    ${else}
 402      ExecWait '"$PathLaTeX\internal\miktex-update.exe"'
 403    ${endif}
 404   ${endif}
 405   UpdateLater:
 406
 407 FunctionEnd
 408