development/Win32/packaging/installer/include/LaTeX.nsh

   1 /*
   2 LaTeX.nsh
   3
   4 Handling of LaTeX distributions
   5 */
   6
   7 # This script contains the following functions:
   8 #
   9 # - LaTeXActions (checks if MiKTeX or TeXLive is installed)
  10 #
  11 # - InstallMiKTeX (installs MiKTeX if not already installed),
  12 #   only for bunlde installer, uses:
  13 #    LaTeXCheck # function from LyXUtils.nsh
  14 #
  15 # - ConfigureMiKTeX
  16 #   (installs the LaTeX class files that are delivered with LyX,
  17 #    a Perl interpreter for splitindex and pdfcrop
  18 #    and enable MiKTeX's automatic package installation)
  19 #
  20 # - ConfigureTeXLive
  21 #   (installs the LaTeX class files that are delivered with LyX)
  22 #
  23 # - UpdateMiKTeX (asks to update MiKTeX)
  24
  25 # ---------------------------------------
  26
  27 Function LaTeXActions
  28  # checks if MiKTeX or TeXLive is installed
  29
  30   StrCpy $Is64bit "false"
  31
  32   ${if} ${RunningX64}
  33    SetRegView 64 # the PATH is in the 64bit registry section
  34   ${endif}
  35   # test if MiKTeX is installed
  36   # reads the PATH variable via the registry because NSIS' "$%Path%" variable is not updated when the PATH changes
  37   ReadRegStr $String HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path"
  38   StrCpy $Search "miktex"
  39   Call LaTeXCheck # sets the path to the latex.exe to $PathLaTeX # Function from LyXUtils.nsh
  40
  41   StrCpy $String $PathLaTeX
  42   StrCpy $Search "x64" # search if it is 64bit MiKTeX
  43   Call StrPoint # Function from LyXUtils.nsh
  44   ${if} $Pointer != "-1" # if something was found
  45    StrCpy $Is64bit "true"
  46   ${endif}
  47
  48   # check for 32bit MiKTeX
  49   ${if} $PathLaTeX != ""
  50   ${andif} $Is64bit != "true"
  51    ${if} ${RunningX64}
  52     SetRegView 32
  53    ${endif}
  54    # check if MiKTeX 2.8 or newer is installed
  55    StrCpy $0 0
  56    loop32:
  57     EnumRegKey $1 HKLM "SOFTWARE\MiKTeX.org\MiKTeX" $0 # check the last subkey
  58     StrCmp $1 "" done32
  59     StrCpy $String $1
  60     IntOp $0 $0 + 1
  61     Goto loop32
  62    done32:
  63    ${if} $String == "2.8"
  64     StrCpy $MiKTeXVersion "2.8"
  65     StrCpy $LaTeXName "MiKTeX 2.8"
  66    ${endif}
  67    ${if} $String == "2.9"
  68     StrCpy $MiKTeXVersion "2.9"
  69     StrCpy $LaTeXName "MiKTeX 2.9"
  70    ${endif}
  71   ${endif}
  72
  73   # check for 64bit MiKTeX
  74   ${if} $LaTeXName == ""
  75    ${if} ${RunningX64}
  76     SetRegView 64
  77    ${endif}
  78    # check if MiKTeX 2.8 or newer is installed
  79    StrCpy $0 0
  80    loop64:
  81     EnumRegKey $1 HKLM "SOFTWARE\MiKTeX.org\MiKTeX" $0 # check the last subkey
  82     StrCmp $1 "" done64
  83     StrCpy $String $1
  84     IntOp $0 $0 + 1
  85     Goto loop64
  86    done64:
  87    ${if} $String == "2.8"
  88     StrCpy $MiKTeXVersion "2.8"
  89     StrCpy $LaTeXName "MiKTeX 2.8"
  90    ${endif}
  91    ${if} $String == "2.9"
  92     StrCpy $MiKTeXVersion "2.9"
  93     StrCpy $LaTeXName "MiKTeX 2.9"
  94    ${endif}
  95   ${endif}
  96
  97   ${if} $PathLaTeX != ""
  98    StrCpy $MiKTeXUser "HKLM" # needed later to configure MiKTeX
  99   ${else} # check if MiKTeX is installed only for the current user
 100    ${if} ${RunningX64}
 101     SetRegView 64 # the PATH is in the 64bit registry section
 102    ${endif}
 103    ReadRegStr $String HKCU "Environment" "Path"
 104    StrCpy $Search "miktex"
 105    Call LaTeXCheck # function from LyXUtils.nsh
 106    ${if} $PathLaTeX != ""
 107     StrCpy $MiKTeXUser "HKCU"
 108    ${endif}
 109   ${endif}
 110   ${if} $LaTeXName == "" # check for the MiKTeX version
 111    StrCpy $0 0
 112    loopB:
 113     EnumRegKey $1 HKCU "SOFTWARE\MiKTeX.org\MiKTeX" $0 # check the last subkey
 114     StrCmp $1 "" doneB
 115     StrCpy $String $1
 116     IntOp $0 $0 + 1
 117     Goto loopB
 118    doneB:
 119    ${if} $String == "2.8"
 120     StrCpy $MiKTeXVersion "2.8"
 121     StrCpy $LaTeXName "MiKTeX 2.8"
 122    ${endif}
 123    ${if} $String == "2.9"
 124     StrCpy $MiKTeXVersion "2.9"
 125     StrCpy $LaTeXName "MiKTeX 2.9"
 126    ${endif}
 127   ${endif}
 128
 129   ${if} $PathLaTeX != ""
 130    StrCpy $String $PathLaTeX
 131    StrCpy $Search "x64" # search if it is 64bit MiKTeX
 132    Call StrPoint # Function from LyXUtils.nsh
 133    ${if} $Pointer != "-1" # if something was found
 134     StrCpy $Is64bit "true"
 135    ${endif}
 136    StrCpy $LaTeXInstalled "MiKTeX"
 137    # on some installations the path ends with a "\" on some not
 138    # therefore assure that we remove it if it exists
 139    StrCpy $0 $PathLaTeX "" -1
 140    ${if} $0 == "\"
 141     StrCpy $PathLaTeX "$PathLaTeX" -1 # delete "\"
 142    ${endif}
 143   ${endif}
 144
 145   # test if TeXLive is installed
 146   # TeXLive can be installed so that it appears in the PATH variable and/or only as current user.
 147   # The safest method is to first check for the PATH because this is independent of the TeXLive version.
 148   ${if} ${RunningX64}
 149    SetRegView 64 # the PATH is in the 64bit registry section
 150   ${endif}
 151   ${if} $PathLaTeX == ""
 152    ReadRegStr $String HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path"
 153    StrCpy $Search "TeXLive"
 154    Call LaTeXCheck # function from LyXUtils.nsh
 155   ${endif}
 156   # check for the current user Path variable
 157   ${if} $PathLaTeX == ""
 158    ReadRegStr $String HKCU "Environment" "Path"
 159    StrCpy $Search "texlive"
 160    StrCpy $2 "TeXLive"
 161    Call LaTeXCheck # function from LyXUtils.nsh
 162   ${endif}
 163   # check if it was installed to the system
 164   ${if} ${RunningX64}
 165    SetRegView 32 # TeXLive is a 32bit application
 166   ${endif}
 167   ${if} $PathLaTeX == ""
 168    ReadRegStr $String HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2012" "UninstallString"
 169    ${if} $String == ""
 170     ReadRegStr $String HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2012" "UninstallString"
 171    ${endif}
 172    ${if} $String != ""
 173     StrCpy $String $String -28 # remove '\tlpkg\installer\uninst.bat"'
 174     StrCpy $String $String "" 1 # remove the leading quote
 175    ${endif}
 176    StrCpy $PathLaTeX "$String\bin\win32"
 177    # check if the latex.exe exists in the $PathLaTeX folder
 178    !insertmacro FileCheck $5 "latex.exe" "$PathLaTeX" # macro from LyXUtils.nsh
 179    ${if} $5 == "False"
 180     StrCpy $PathLaTeX ""
 181    ${endif}
 182   ${endif}
 183   # finally set the name
 184   ${if} $PathLaTeX != ""
 185   ${andif} $LaTeXName != "MiKTeX 2.8"
 186   ${andif} $LaTeXName != "MiKTeX 2.9"
 187    StrCpy $LaTeXInstalled "TeXLive"
 188    ReadRegStr $String HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2012" "DisplayVersion"
 189    ${if} $String == ""
 190     ReadRegStr $String HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2012" "DisplayVersion"
 191    ${endif}
 192    ${if} $String != ""
 193     StrCpy $LaTeXName "TeXLive $String"
 194    ${else}
 195     StrCpy $LaTeXName "TeXLive"
 196    ${endif}
 197   ${endif}
 198
 199 FunctionEnd
 200
 201 # -------------------------------------------
 202
 203 !if ${SETUPTYPE} == BUNDLE
 204
 205  Function InstallMiKTeX
 206   # installs MiKTeX if not already installed
 207
 208   ${if} $PathLaTeX == ""
 209    # launch MiKTeX's installer
 210    MessageBox MB_OK|MB_ICONINFORMATION "$(LatexInfo)" /SD IDOK
 211    MessageBox MB_OK|MB_ICONINFORMATION "${MiKTeXInstall} --shared"
 212    ${if} $MultiUser.Privileges != "Admin"
 213    ${andif} $MultiUser.Privileges != "Power"
 214     # call the non-admin version
 215     ExecWait ${MiKTeXInstall}
 216    ${else}
 217     ExecWait "${MiKTeXInstall} --shared"
 218    ${endif}
 219    # test if MiKTeX is installed
 220    Call LaTeXActions
 221    ${if} ${RunningX64}
 222     SetRegView 32 # we install the 32bit version of MiKTeX
 223    ${endif}
 224    ${if} $PathLaTeX != ""
 225     # special entry that it was installed together with LyX
 226     # so that we can later uninstall it together with LyX
 227     ${if} $MiKTeXUser == "HKCU"
 228      WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 229     ${else}
 230      WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 231     ${endif}
 232     StrCpy $LaTeXInstalled "MiKTeX"
 233     StrCpy $MiKTeXVersion ${MiKTeXDeliveredVersion}
 234    ${else}
 235     MessageBox MB_OK|MB_ICONSTOP "$(LatexError1)" /SD IDOK
 236     SetOutPath $TEMP # to be able to delete the $INSTDIR
 237     RMDir /r $INSTDIR
 238     Abort
 239    ${endif} # endif $PathLaTeX != ""
 240   ${endif}
 241
 242   FunctionEnd
 243
 244 !endif # endif ${SETUPTYPE} == BUNDLE
 245
 246 # ------------------------------
 247
 248 Function ConfigureMiKTeX
 249  # installs the LaTeX class files that are delivered with LyX,
 250  # a Perl interpreter for splitindex and pdfcrop
 251  # and enable MiKTeX's automatic package installation
 252
 253  # install LyX's LaTeX class and style files and a Perl interpreter
 254  ${if} $PathLaTeX != ""
 255   ${if} $MultiUser.Privileges == "Admin"
 256   ${orif} $MultiUser.Privileges == "Power"
 257    ${if} $Is64bit == "true"
 258     StrCpy $PathLaTeXLocal "$PathLaTeX" -15 # delete "\miktex\bin\x64"
 259    ${else}
 260     StrCpy $PathLaTeXLocal "$PathLaTeX" -11 # delete "\miktex\bin"
 261    ${endif}
 262   ${else}
 263    StrCpy $PathLaTeXLocal "$APPDATA\MiKTeX\$MiKTeXVersion"
 264   ${endif}
 265
 266   # only install the LyX packages if they are not already installed
 267   ${ifnot} ${FileExists} "$PathLaTeXLocal\tex\latex\lyx\broadway.cls"
 268    # dvipost
 269    SetOutPath "$PathLaTeXLocal\tex\latex\dvipost"
 270    File "${FILES_DVIPOST_PKG}\dvipost.sty"
 271    # files in Resources\tex
 272    SetOutPath "$PathLaTeXLocal\tex\latex\lyx"
 273    CopyFiles /SILENT "$INSTDIR\Resources\tex\*.*" "$PathLaTeXLocal\tex\latex\lyx"
 274   ${endif}
 275   # Belarusian support
 276   ${ifnot} ${FileExists} "$PathLaTeXLocal\tex\generic\babel\belarusian.ldf"
 277    SetOutPath "$PathLaTeXLocal\tex\generic\babel"
 278    File "${FILES_DVIPOST_PKG}\belarusian.ldf"
 279    File "${FILES_DVIPOST_PKG}\belarusian.sty"
 280   ${endif}
 281   # Hungarian support
 282   # this is a replacement therefore do this in every case
 283   SetOutPath "$PathLaTeXLocal\tex\generic\babel"
 284   File "${FILES_DVIPOST_PKG}\magyar.ldf"
 285
 286   # install a Perl interpreter for splitindex and pdfcrop
 287   SetOutPath "$INSTDIR"
 288   # recursively copy all files under Perl
 289   File /r "${FILES_PERL}"
 290
 291   # refresh MiKTeX's file name database (do this always to assure everything is in place)
 292   ${if} $MultiUser.Privileges != "Admin"
 293   ${andif} $MultiUser.Privileges != "Power"
 294    # call the non-admin version
 295    nsExec::ExecToLog "$PathLaTeX\initexmf --update-fndb"
 296   ${else}
 297    ${if} $MiKTeXUser != "HKCU" # call the admin version
 298     nsExec::ExecToLog "$PathLaTeX\initexmf --admin --update-fndb"
 299    ${else}
 300     nsExec::ExecToLog "$PathLaTeX\initexmf --update-fndb"
 301    ${endif}
 302   ${endif}
 303   Pop $UpdateFNDBReturn # Return value
 304
 305  ${endif} # end if $PathLaTeX != ""
 306
 307   # enable package installation without asking (1 = Yes, 0 = No, 2 = Ask me first) and
 308   # if there is not package repository (MiKTeX's primary package repository) then set it
 309   ${if} ${RunningX64}
 310   ${andif} $Is64bit == "true"
 311    SetRegView 64
 312   ${else}
 313    SetRegView 32
 314   ${endif}
 315   ${if} $MiKTeXUser == "HKCU" # if only for current user
 316    # if AutoInstall is set to "0" we can assume that this was set purposly since the default is "1"
 317    ReadRegStr $2 HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoInstall"
 318    ${if} $2 == "0"
 319     Goto NoAutoInstall
 320    ${endif}
 321    WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoInstall" "1"
 322    ReadRegStr $1 HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository"
 323    ${if} $1 == ""
 324     WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository" "${MiKTeXRepo}"
 325     WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RepositoryType" "remote"
 326    ${endif}
 327   ${else}
 328    # if AutoInstall is set to "0" we can assume that this was set purposly since the default is "1"
 329    ReadRegStr $2 HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoInstall"
 330    ${if} $2 == "0"
 331     Goto NoAutoInstall
 332    ${endif}
 333    WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoInstall" "1"
 334    ReadRegStr $1 HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository"
 335    ${if} $1 == ""
 336     WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository" "${MiKTeXRepo}"
 337     WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RepositoryType" "remote"
 338    ${endif}
 339    # we need to state that missing packages should be installed for all users too
 340    WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoAdmin" "t"
 341   ${endif}
 342   NoAutoInstall:
 343
 344   # update MiKTeX's package file list
 345   ExecWait '$PathLaTeX\mpm.exe --update-fndb'
 346
 347   # we must return to 32bit because LyX is a 32bit application
 348   SetRegView 32
 349
 350 FunctionEnd
 351
 352 # ------------------------------
 353
 354 Function ConfigureTeXLive
 355  # installs the LaTeX class files that are delivered with LyX
 356  # (TeXLive comes already with a Perl interpreter.)
 357
 358  ${if} $PathLaTeX != ""
 359   StrCpy $PathLaTeXLocal "$PathLaTeX" -10 # delete "\bin\win32"
 360
 361   # only install the LyX packages if they are not already installed
 362   ${ifnot} ${FileExists} "$PathLaTeXLocal\texmf-dist\tex\latex\lyx\broadway.cls"
 363    # dvipost
 364    SetOutPath "$PathLaTeXLocal\texmf-dist\tex\latex\dvipost"
 365    File "${FILES_DVIPOST_PKG}\dvipost.sty"
 366    # files in Resources\tex
 367    SetOutPath "$PathLaTeXLocal\texmf-dist\tex\latex\lyx"
 368    CopyFiles /SILENT "$INSTDIR\Resources\tex\*.*" "$PathLaTeXLocal\texmf-dist\tex\latex\lyx"
 369   ${endif}
 370  ${endif}
 371
 372  # update TeXLive's package file list
 373  ExecWait '$PathLaTeX\texhash'
 374
 375  # update TeXLive
 376  ExecWait '$PathLaTeX\tlmgr update --all'
 377
 378 FunctionEnd
 379
 380 # ------------------------------
 381
 382 Function UpdateMiKTeX
 383  # asks to update MiKTeX
 384
 385   MessageBox MB_YESNO|MB_ICONINFORMATION "$(MiKTeXInfo)" /SD IDNO IDYES UpdateNow IDNO UpdateLater
 386   UpdateNow:
 387   # the update wizard is started by the miktex-update.exe
 388   ${if} $MultiUser.Privileges != "Admin"
 389   ${andif} $MultiUser.Privileges != "Power"
 390    # call the non-admin version
 391     ExecWait '"$PathLaTeX\internal\miktex-update.exe"'
 392   ${else}
 393    ${if} $MiKTeXUser != "HKCU" # call the admin version
 394     ExecWait '"$PathLaTeX\internal\miktex-update_admin.exe"'
 395    ${else}
 396      ExecWait '"$PathLaTeX\internal\miktex-update.exe"'
 397    ${endif}
 398   ${endif}
 399   UpdateLater:
 400
 401 FunctionEnd
 402