development/Win32/packaging/installer/include/LaTeX.nsh

   1 /*
   2 LaTeX.nsh
   3
   4 Handling of LaTeX distributions
   5 */
   6
   7 # This script contains the following functions:
   8 #
   9 # - LaTeXActions (checks if MiKTeX or TeXLive is installed)
  10 #
  11 # - InstallMiKTeX (installs MiKTeX if not already installed),
  12 #   only for bunlde installer, uses:
  13 #    LaTeXCheck # function from LyXUtils.nsh
  14 #
  15 # - ConfigureMiKTeX
  16 #   (installs the LaTeX class files that are delivered with LyX,
  17 #    a Perl interpreter for splitindex
  18 #    and enable MiKTeX's automatic package installation)
  19 #
  20 # - ConfigureTeXLive
  21 #   (installs the LaTeX class files that are delivered with LyX)
  22 #
  23 # - UpdateMiKTeX (asks to update MiKTeX)
  24
  25 # ---------------------------------------
  26
  27 Function LaTeXActions
  28  # checks if MiKTeX or TeXLive is installed
  29
  30   StrCpy $Is64bit "false"
  31
  32   ${if} ${RunningX64}
  33    SetRegView 64 # the PATH is in the 64bit registry section
  34   ${endif}
  35   # test if MiKTeX is installed
  36   # reads the PATH variable via the registry because NSIS' "$%Path%" variable is not updated when the PATH changes
  37   ReadRegStr $String HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path"
  38   StrCpy $Search "miktex"
  39   Call LaTeXCheck # sets the path to the latex.exe to $PathLaTeX # Function from LyXUtils.nsh
  40
  41   StrCpy $String $PathLaTeX
  42   StrCpy $Search "x64" # search if it is 64bit MiKTeX
  43   Call StrPoint # Function from LyXUtils.nsh
  44   ${if} $Pointer != "-1" # if something was found
  45    StrCpy $Is64bit "true"
  46   ${endif}
  47
  48   # check for 32bit MiKTeX
  49   ${if} $PathLaTeX != ""
  50   ${andif} $Is64bit != "true"
  51    ${if} ${RunningX64}
  52     SetRegView 32
  53    ${endif}
  54    # check if MiKTeX 2.8 or newer is installed
  55    StrCpy $0 0
  56    loop32:
  57     EnumRegKey $1 HKLM "SOFTWARE\MiKTeX.org\MiKTeX" $0 # check the last subkey
  58     StrCmp $1 "" done32
  59     StrCpy $String $1
  60     IntOp $0 $0 + 1
  61     Goto loop32
  62    done32:
  63    ${if} $String == "2.8"
  64     StrCpy $MiKTeXVersion "2.8"
  65     StrCpy $LaTeXName "MiKTeX 2.8"
  66    ${endif}
  67    ${if} $String == "2.9"
  68     StrCpy $MiKTeXVersion "2.9"
  69     StrCpy $LaTeXName "MiKTeX 2.9"
  70    ${endif}
  71   ${endif}
  72
  73   # check for 64bit MiKTeX
  74   ${if} $LaTeXName == ""
  75    ${if} ${RunningX64}
  76     SetRegView 64
  77    ${endif}
  78    # check if MiKTeX 2.8 or newer is installed
  79    StrCpy $0 0
  80    loop64:
  81     EnumRegKey $1 HKLM "SOFTWARE\MiKTeX.org\MiKTeX" $0 # check the last subkey
  82     StrCmp $1 "" done64
  83     StrCpy $String $1
  84     IntOp $0 $0 + 1
  85     Goto loop64
  86    done64:
  87    ${if} $String == "2.8"
  88     StrCpy $MiKTeXVersion "2.8"
  89     StrCpy $LaTeXName "MiKTeX 2.8"
  90    ${endif}
  91    ${if} $String == "2.9"
  92     StrCpy $MiKTeXVersion "2.9"
  93     StrCpy $LaTeXName "MiKTeX 2.9"
  94    ${endif}
  95   ${endif}
  96
  97   ${if} $PathLaTeX != ""
  98    StrCpy $MiKTeXUser "HKLM" # needed later to configure MiKTeX
  99   ${else} # check if MiKTeX is installed only for the current user
 100    ${if} ${RunningX64}
 101     SetRegView 64 # the PATH is in the 64bit registry section
 102    ${endif}
 103    ReadRegStr $String HKCU "Environment" "Path"
 104    StrCpy $Search "miktex"
 105    Call LaTeXCheck # function from LyXUtils.nsh
 106    ${if} $PathLaTeX != ""
 107     StrCpy $MiKTeXUser "HKCU"
 108    ${endif}
 109   ${endif}
 110   ${if} $LaTeXName == "" # check for the MiKTeX version
 111    StrCpy $0 0
 112    loopB:
 113     EnumRegKey $1 HKCU "SOFTWARE\MiKTeX.org\MiKTeX" $0 # check the last subkey
 114     StrCmp $1 "" doneB
 115     StrCpy $String $1
 116     IntOp $0 $0 + 1
 117     Goto loopB
 118    doneB:
 119    ${if} $String == "2.8"
 120     StrCpy $MiKTeXVersion "2.8"
 121     StrCpy $LaTeXName "MiKTeX 2.8"
 122    ${endif}
 123    ${if} $String == "2.9"
 124     StrCpy $MiKTeXVersion "2.9"
 125     StrCpy $LaTeXName "MiKTeX 2.9"
 126    ${endif}
 127   ${endif}
 128
 129   ${if} $PathLaTeX != ""
 130    StrCpy $String $PathLaTeX
 131    StrCpy $Search "x64" # search if it is 64bit MiKTeX
 132    Call StrPoint # Function from LyXUtils.nsh
 133    ${if} $Pointer != "-1" # if something was found
 134     StrCpy $Is64bit "true"
 135    ${endif}
 136    StrCpy $LaTeXInstalled "MiKTeX"
 137    # on some installations the path ends with a "\" on some not
 138    # therefore assure that we remove it if it exists
 139    StrCpy $0 $PathLaTeX "" -1
 140    ${if} $0 == "\"
 141     StrCpy $PathLaTeX "$PathLaTeX" -1 # delete "\"
 142    ${endif}
 143   ${endif}
 144
 145   # test if TeXLive is installed
 146   # TeXLive can be installed so that it appears in the PATH variable and/or only as current user.
 147   # The safest method is to first check for the PATH because this is independent of the TeXLive version.
 148   ${if} ${RunningX64}
 149    SetRegView 64 # the PATH is in the 64bit registry section
 150   ${endif}
 151   ${if} $PathLaTeX == ""
 152    ReadRegStr $String HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path"
 153    StrCpy $Search "TeXLive"
 154    Call LaTeXCheck # function from LyXUtils.nsh
 155   ${endif}
 156   # check for the current user Path variable
 157   ${if} $PathLaTeX == ""
 158    ReadRegStr $String HKCU "Environment" "Path"
 159    StrCpy $Search "texlive"
 160    StrCpy $2 "TeXLive"
 161    Call LaTeXCheck # function from LyXUtils.nsh
 162   ${endif}
 163   # check if it was installed to the system
 164   ${if} ${RunningX64}
 165    SetRegView 32 # TeXLive is a 32bit application
 166   ${endif}
 167   ${if} $PathLaTeX == ""
 168    ReadRegStr $String HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2012" "UninstallString"
 169    ${if} $String == ""
 170     ReadRegStr $String HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2012" "UninstallString"
 171    ${endif}
 172    ${if} $String != ""
 173     StrCpy $String $String -28 # remove '\tlpkg\installer\uninst.bat"'
 174     StrCpy $String $String "" 1 # remove the leading quote
 175    ${endif}
 176    StrCpy $PathLaTeX "$String\bin\win32"
 177    # check if the latex.exe exists in the $PathLaTeX folder
 178    !insertmacro FileCheck $5 "latex.exe" "$PathLaTeX" # macro from LyXUtils.nsh
 179    ${if} $5 == "False"
 180     StrCpy $PathLaTeX ""
 181    ${endif}
 182   ${endif}
 183   # finally set the name
 184   ${if} $PathLaTeX != ""
 185   ${andif} $LaTeXName != "MiKTeX 2.8"
 186   ${andif} $LaTeXName != "MiKTeX 2.9"
 187    StrCpy $LaTeXInstalled "TeXLive"
 188    ReadRegStr $String HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2012" "DisplayVersion"
 189    ${if} $String == ""
 190     ReadRegStr $String HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\TeXLive2012" "DisplayVersion"
 191    ${endif}
 192    ${if} $String != ""
 193     StrCpy $LaTeXName "TeXLive $String"
 194    ${else}
 195     StrCpy $LaTeXName "TeXLive"
 196    ${endif}
 197   ${endif}
 198
 199 FunctionEnd
 200
 201 # -------------------------------------------
 202
 203 !if ${SETUPTYPE} == BUNDLE
 204
 205  Function InstallMiKTeX
 206   # installs MiKTeX if not already installed
 207
 208   ${if} $PathLaTeX == ""
 209    # launch MiKTeX's installer
 210    MessageBox MB_OK|MB_ICONINFORMATION "$(LatexInfo)"
 211    ExecWait ${MiKTeXInstall}
 212    # test if MiKTeX is installed
 213    Call LaTeXActions
 214    ${if} ${RunningX64}
 215     SetRegView 32 # we install the 32bit version of MiKTeX
 216    ${endif}
 217    ${if} $PathLaTeX != ""
 218     # special entry that it was installed together with LyX
 219     # so that we can later uninstall it together with LyX
 220     ${if} $MiKTeXUser == "HKCU"
 221      WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 222     ${else}
 223      WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX" "OnlyWithLyX" "Yes${APP_SERIES_KEY}"
 224     ${endif}
 225     StrCpy $LaTeXInstalled "MiKTeX"
 226     StrCpy $MiKTeXVersion ${MiKTeXDeliveredVersion}
 227    ${else}
 228     MessageBox MB_OK|MB_ICONSTOP "$(LatexError1)"
 229     SetOutPath $TEMP # to be able to delete the $INSTDIR
 230     RMDir /r $INSTDIR
 231     Abort
 232    ${endif} # endif $PathLaTeX != ""
 233   ${endif}
 234
 235   FunctionEnd
 236
 237 !endif # endif ${SETUPTYPE} == BUNDLE
 238
 239 # ------------------------------
 240
 241 Function ConfigureMiKTeX
 242  # installs the LaTeX class files that are delivered with LyX,
 243  # a Perl interpreter for splitindex
 244  # and enable MiKTeX's automatic package installation
 245
 246  # install LyX's LaTeX class and style files and a Perl interpreter
 247  ${if} $PathLaTeX != ""
 248   ${if} $MultiUser.Privileges == "Admin"
 249   ${orif} $MultiUser.Privileges == "Power"
 250    ${if} $Is64bit == "true"
 251     StrCpy $PathLaTeXLocal "$PathLaTeX" -15 # delete "\miktex\bin\x64"
 252    ${else}
 253     StrCpy $PathLaTeXLocal "$PathLaTeX" -11 # delete "\miktex\bin"
 254    ${endif}
 255   ${else}
 256    StrCpy $PathLaTeXLocal "$APPDATA\MiKTeX\$MiKTeXVersion"
 257   ${endif}
 258
 259   # only install the LyX packages if they are not already installed
 260   ${ifnot} ${FileExists} "$PathLaTeXLocal\tex\latex\lyx\broadway.cls"
 261    # dvipost
 262    SetOutPath "$PathLaTeXLocal\tex\latex\dvipost"
 263    File "${FILES_DVIPOST_PKG}\dvipost.sty"
 264    # files in Resources\tex
 265    SetOutPath "$PathLaTeXLocal\tex\latex\lyx"
 266    CopyFiles /SILENT "$INSTDIR\Resources\tex\*.*" "$PathLaTeXLocal\tex\latex\lyx"
 267   ${endif}
 268
 269   # only install a Perl interpreter if it is not already installed
 270   # this is only possible if MikTeX _and_ LyX is installed with the same privileges
 271   ${if} ${RunningX64}
 272    SetRegView 32 # FIXME: recheck this if the 64bit version of MiKTeX is out of beta state
 273   ${endif}
 274   ReadRegStr $0 HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\MiKTeX $MiKTeXVersion" "DisplayVersion"
 275   ${if} $MultiUser.Privileges != "Admin"
 276   ${andif} $MultiUser.Privileges != "Power"
 277    ${if} $0 == ""
 278     ${ifnot} ${FileExists} "$PathLaTeX\perl.exe"
 279      MessageBox MB_OK|MB_ICONINFORMATION "$(MultipleIndexesNotAvailable)"
 280     ${endif}
 281    ${else}
 282     ${ifnot} ${FileExists} "$PathLaTeX\perl.exe"
 283      ${if} $Is64bit == "true"
 284       StrCpy $3 "$PathLaTeX" -15 # delete "\miktex\bin\x64"
 285      ${else}
 286       StrCpy $3 "$PathLaTeX" -11 # delete "\miktex\bin"
 287      ${endif}
 288      SetOutPath "$3"
 289      File /r ${FILES_MIKTEX}
 290      # move the files to the correct location for 64bit
 291      ${if} $Is64bit == "true"
 292       CopyFiles /SILENT /FILESONLY "$3\miktex\bin\*.*" "$PathLaTeX"
 293       Delete "$3\miktex\bin\*.*"
 294       CreateDirectory "$3\miktex\bin\lib"
 295       CopyFiles /SILENT "$3\miktex\lib\*.*" "$3\miktex\bin\lib"
 296       RMDir /r "$3\miktex\lib"
 297      ${endif}
 298     ${endif}
 299    ${endif}
 300   ${else}
 301    ${ifnot} ${FileExists} "$PathLaTeX\perl.exe"
 302     SetOutPath "$PathLaTeXLocal"
 303     File /r ${FILES_MIKTEX}
 304     # move the files to the correct location for 64bit
 305     ${if} $Is64bit == "true"
 306      CopyFiles /SILENT /FILESONLY "$PathLaTeXLocal\miktex\bin\*.*" "$PathLaTeX"
 307      Delete "$PathLaTeXLocal\miktex\bin\*.*"
 308      CreateDirectory "$PathLaTeXLocal\miktex\bin\lib"
 309      CopyFiles /SILENT "$PathLaTeXLocal\miktex\lib\*.*" "$PathLaTeXLocal\miktex\bin\lib"
 310      RMDir /r "$PathLaTeXLocal\miktex\lib"
 311     ${endif}
 312    ${endif}
 313   ${endif}
 314
 315   # refresh MiKTeX's file name database (do this always to assure everything is in place)
 316   ${if} $MultiUser.Privileges != "Admin"
 317   ${andif} $MultiUser.Privileges != "Power"
 318    # call the non-admin version
 319    nsExec::ExecToLog "$PathLaTeX\initexmf --update-fndb"
 320   ${else}
 321    ${if} $MiKTeXUser != "HKCU" # call the admin version
 322     nsExec::ExecToLog "$PathLaTeX\initexmf --admin --update-fndb"
 323    ${else}
 324     nsExec::ExecToLog "$PathLaTeX\initexmf --update-fndb"
 325    ${endif}
 326   ${endif}
 327   Pop $UpdateFNDBReturn # Return value
 328
 329  ${endif} # end if $PathLaTeX != ""
 330
 331   # enable package installation without asking (1 = Yes, 0 = No, 2 = Ask me first) and
 332   # if there is not package repository (MiKTeX's primary package repository) then set it
 333   ${if} ${RunningX64}
 334   ${andif} $Is64bit == "true"
 335    SetRegView 64
 336   ${else}
 337    SetRegView 32
 338   ${endif}
 339   ${if} $MiKTeXUser == "HKCU" # if only for current user
 340    WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoInstall" "1"
 341    ReadRegStr $1 HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository"
 342    ${if} $1 == ""
 343     WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository" "${MiKTeXRepo}"
 344     WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RepositoryType" "remote"
 345    ${endif}
 346   ${else}
 347    WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoInstall" "1"
 348    ReadRegStr $1 HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository"
 349    ${if} $1 == ""
 350     WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RemoteRepository" "${MiKTeXRepo}"
 351     WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "RepositoryType" "remote"
 352    ${endif}
 353    # we need to state that missing packages should be installed for all users too
 354    WriteRegStr HKCU "SOFTWARE\MiKTeX.org\MiKTeX\$MiKTeXVersion\MPM" "AutoAdmin" "t"
 355   ${endif}
 356
 357   # update MiKTeX's package file list
 358   ExecWait '$PathLaTeX\mpm.exe --update-fndb'
 359
 360   # we must return to 32bit because LyX is a 32bit application
 361   SetRegView 32
 362
 363 FunctionEnd
 364
 365 # ------------------------------
 366
 367 Function ConfigureTeXLive
 368  # installs the LaTeX class files that are delivered with LyX
 369  # (TeXLive comes already with a Perl interpreter.)
 370
 371  ${if} $PathLaTeX != ""
 372   StrCpy $PathLaTeXLocal "$PathLaTeX" -10 # delete "\bin\win32"
 373
 374   # only install the LyX packages if they are not already installed
 375   ${ifnot} ${FileExists} "$PathLaTeXLocal\texmf-dist\tex\latex\lyx\broadway.cls"
 376    # dvipost
 377    SetOutPath "$PathLaTeXLocal\texmf-dist\tex\latex\dvipost"
 378    File "${FILES_DVIPOST_PKG}\dvipost.sty"
 379    # files in Resources\tex
 380    SetOutPath "$PathLaTeXLocal\texmf-dist\tex\latex\lyx"
 381    CopyFiles /SILENT "$INSTDIR\Resources\tex\*.*" "$PathLaTeXLocal\texmf-dist\tex\latex\lyx"
 382   ${endif}
 383  ${endif}
 384
 385  # update TeXLive's package file list
 386  ExecWait '$PathLaTeX\texhash'
 387
 388  # update TeXLive
 389  ExecWait '$PathLaTeX\tlmgr update --all'
 390
 391 FunctionEnd
 392
 393 # ------------------------------
 394
 395 Function UpdateMiKTeX
 396  # asks to update MiKTeX
 397
 398   MessageBox MB_YESNO|MB_ICONINFORMATION "$(MiKTeXInfo)" IDYES UpdateNow IDNO UpdateLater
 399   UpdateNow:
 400   # the update wizard is started by the miktex-update.exe
 401   ${if} $MultiUser.Privileges != "Admin"
 402   ${andif} $MultiUser.Privileges != "Power"
 403    # call the non-admin version
 404     ExecWait '"$PathLaTeX\internal\miktex-update.exe"'
 405   ${else}
 406    ${if} $MiKTeXUser != "HKCU" # call the admin version
 407     ExecWait '"$PathLaTeX\internal\miktex-update_admin.exe"'
 408    ${else}
 409      ExecWait '"$PathLaTeX\internal\miktex-update.exe"'
 410    ${endif}
 411   ${endif}
 412   UpdateLater:
 413
 414 FunctionEnd
 415