development/Win32/packaging/installer/components/core.nsh

   1 /*
   2
   3 LyX Core
   4 Binaries, Resources, Python, Aspell
   5
   6 */
   7
   8 ;--------------------------------
   9 ;Sections
  10
  11 Section -Core SecCore
  12
  13   ;Install and register the core LyX files
  14
  15   InitPluginsDir
  16
  17   ;Binaries
  18
  19   SetOutPath "$INSTDIR\bin"
  20
  21   File "${FILES_LAUNCHER}\lyx.exe"
  22   File /oname=lyxc.exe "${FILES_LYX}\bin\lyx.exe"
  23
  24   !insertmacro FileListLyXBin File "${FILES_LYX}\bin\"
  25   !insertmacro FileListQtBin File "${FILES_QT}\bin\"
  26
  27   !insertmacro FileListDllMSVCBin File "${FILES_DEPS}\bin\"
  28   !insertmacro FileListMSVCBin File "${FILES_MSVC}\"
  29   !insertmacro FileListMSVCManifest File "..\"
  30
  31   !insertmacro FileListNetpbmBin File "${FILES_NETPBM}\"
  32   !insertmacro FileListDvipostBin File "${FILES_DVIPOST}\"
  33   !insertmacro FileListDTLBin File "${FILES_DTL}\"
  34   !insertmacro FileListPDFViewBin File "${FILES_PDFVIEW}\"
  35   !insertmacro FileListPDFToolsBin File "${FILES_PDFTOOLS}\"
  36
  37   ;Icons
  38
  39   SetOutPath "$INSTDIR\bin"
  40   !insertmacro FileListLyXIcons File "${FILES_ICONS}\"
  41
  42   ;Resources
  43
  44   SetOutPath "$INSTDIR"
  45   File /r "${FILES_LYX}\Resources"
  46   SetOutPath "$INSTDIR\Resources\fonts"
  47   !insertmacro FileListFonts File "${FILES_FONTS}\"
  48
  49   ;Components of Python
  50
  51   SetOutPath "$INSTDIR\python"
  52   !insertmacro FileListPythonBin File "${FILES_PYTHON}\"
  53   SetOutPath "$INSTDIR\python"
  54   !insertmacro FileListPythonDll File "${FILES_WINDOWS}\System32\"
  55   !insertmacro FileListUnicodeDll File "${FILES_PYTHON}\DLLs\"
  56   SetOutPath "$INSTDIR\python\Lib"
  57   !insertmacro FileListPythonLib File "${FILES_PYTHON}\Lib\"
  58   SetOutPath "$INSTDIR\python\Lib\encodings"
  59   !insertmacro FileListPythonLibEncodings File "${FILES_PYTHON}\Lib\encodings\"
  60
  61   ;Aspell
  62
  63   File /oname=$PLUGINSDIR\AspellData.exe "${FILES_ASPELLDATA}\AspellData.exe"
  64
  65   ${if} $CurrentUserInstall == ${TRUE}
  66     ExecWait '"$PLUGINSDIR\AspellData.exe" /S /CurrentUser'
  67   ${else}
  68     ExecWait '"$PLUGINSDIR\AspellData.exe" /S /AllUsers'
  69   ${endif}
  70
  71   Delete "$PLUGINSDIR\AspellData.exe"
  72
  73   ;Aiksarus data
  74
  75   SetOutPath "$INSTDIR\aiksaurus"
  76   !insertmacro FileListAiksaurusData File "${FILES_AIKSAURUS}\"
  77
  78   ;Helper DLLs for NSIS-based tools
  79
  80   SetOutPath "$INSTDIR\bin"
  81   !insertmacro FileListNSISPluginsStandard File "${NSISDIR}\Plugins\"
  82   !insertmacro FileListNSISPlugins File "${FILES_NSISPLUGINS}\"
  83
  84   ;Create uninstaller
  85   WriteUninstaller "$INSTDIR\${SETUP_UNINSTALLER}"
  86
  87 SectionEnd