development/Win32/packaging/installer/LyXWinInstaller/InstallActions-complete.nsh

   1 # this file contains the main installer section
   2
   3 # The '-' makes the section invisible.
   4 Section "-Installation actions" SecInstallation
   5
   6   # dummy actions to avoid NSIS warnings
   7   StrCpy $FileName ""
   8   StrCpy $NewString ""
   9   StrCpy $OldString ""
  10
  11   # extract all files
  12   SetOutPath "$INSTDIR"
  13   File /r "${PRODUCT_SOURCEDIR}\bin"
  14   File /r "${PRODUCT_SOURCEDIR}\etc"
  15   File /r "${PRODUCT_SOURCEDIR}\Resources"
  16   File /r "${PRODUCT_SOURCEDIR}\external"
  17
  18   # install MiKTeX if not already installed
  19   Call MiKTeX
  20
  21   # install Ghostscript if not already installed
  22   Call Ghostscript
  23
  24   # install ImageMagick if not already installed
  25   Call ImageMagick
  26
  27   # install Aspell if not already installed
  28   Call InstallAspell # function from Aspell.nsh
  29
  30   # install Aiksaurus if not already installed
  31   Call Aiksaurus
  32
  33   # install GSview if not already installed and the user selected it
  34   Call PostScript
  35
  36   # install JabRef if not already installed and the user selected it
  37   Call BibTeX
  38
  39   # install the LaTeX class files that are delivered with LyX
  40   # and enable MiKTeX's automatic package installation
  41   Call ConfigureMiKTeX # Function from LaTeX.nsh
  42
  43   # install Aspell dictionaries
  44   ${if} $LangCode == "nb_NO"
  45    StrCpy $LangCode "no_NO" # we only have a norwegian dictionary available
  46   ${endif}
  47   Call InstallAspellDictionary # function from Aspell.nsh
  48
  49   # configure LyX
  50   Call ConfigureLyX # Function from ConfigLyX.nsh
  51
  52   # delete unnecessary files
  53   ${if} $DelPythonFiles == "True"
  54    Delete $INSTDIR\bin\python.exe
  55    Delete $INSTDIR\bin\python25.dll
  56    Delete $INSTDIR\bin\Python-License.txt
  57    RMDir /r $INSTDIR\bin\Lib
  58    RMDir /r $INSTDIR\bin\DLLs
  59   ${endif}
  60   RMDir /r $INSTDIR\external
  61
  62   # create Uninstaller
  63   WriteUninstaller "${PRODUCT_UNINSTALL_EXE}"
  64
  65   # run LyX's configure script
  66   # create a bat-file to start configure in a console window so that the user see the progress
  67   # of the configuration and to have a signal when the configuration is ready to start LyX
  68   # this is important when LyX is installed together with MiKTeX or when LyX is installed for the first
  69   # time on a computer, because the installation of missing LaTeX-files required by LyX could last minutes
  70   # a batch file is needed because simply calling ExecWait '"$PythonPath\python.exe" "$INSTDIR\Resources\configure.py"'
  71   # creates the config files in $PythonPath
  72   ${if} $PythonPath == ""
  73    StrCpy $PythonPath "$INSTDIR\bin"
  74   ${endif}
  75   StrCpy $1 $INSTDIR 2 # get drive letter
  76   FileOpen $R1 "$INSTDIR\Resources\configLyX.bat" w
  77   FileWrite $R1 '$1$\r$\n\
  78                  cd $INSTDIR\Resources\$\r$\n\
  79                  "$PythonPath\python.exe" configure.py'
  80   FileClose $R1
  81   MessageBox MB_OK|MB_ICONINFORMATION "$(LatexConfigInfo)"
  82   ExecWait '"$INSTDIR\Resources\configLyX.bat"'
  83   Delete "$INSTDIR\Resources\configLyX.bat"
  84
  85   # ask to update MiKTeX
  86   ${if} $MiKTeXInstalled == "yes"
  87    MessageBox MB_YESNO|MB_ICONINFORMATION "$(MiKTeXInfo)" IDYES UpdateNow IDNO UpdateLater
  88    UpdateNow:
  89     StrCpy $0 $LaTeXPath -4 # remove "\bin"
  90     ExecWait '"$LaTeXPath\copystart.exe" "$0\config\update.dat"' # run MiKTeX's update wizard
  91    UpdateLater:
  92   ${endif}
  93
  94   # save MiKTeX's install path to be able to remove LyX's LaTeX-files in the uninstaller
  95   FileOpen $R1 "$INSTDIR\Resources\uninstallPaths.dat" w
  96   FileWrite $R1 '$LaTeXPath'
  97   FileClose $R1
  98
  99   # prepare variables for uninstaller
 100   StrCpy $MiKTeXVersionVar ${MiKTeXDeliveredVersion}
 101   StrCpy $JabRefVersionVar ${JabRefVersion}
 102
 103 SectionEnd
 104
 105 # -------------------------------------------
 106
 107 Function MiKTeX
 108
 109 # install MiKTeX if not already installed
 110   ${if} $LatexPath == ""
 111    # launch MiKTeX's installer
 112    MessageBox MB_OK|MB_ICONINFORMATION "$(LatexInfo)"
 113    ExecWait ${MiKTeXInstall}
 114    # test if MiKTeX is installed
 115    ReadRegStr $String HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path"
 116    StrCpy $Search "miktex"
 117    Call LaTeXCheck
 118    ${if} $LatexPath == ""
 119     StrCpy $MiKTeXUser "HKCU"
 120     ReadRegStr $String HKCU "Environment" "Path"
 121     StrCpy $Search "miktex"
 122     Call LaTeXCheck
 123    ${endif}
 124    ${if} $LatexPath != ""
 125     # set package repository (MiKTeX's primary package repository)
 126     WriteRegStr HKLM "SOFTWARE\MiKTeX.org\MiKTeX" "OnlyWithLyX" "Yes${PRODUCT_VERSION_SHORT}" # special entry to tell the uninstaller that it was installed with LyX
 127     StrCpy $MiKTeXInstalled "yes"
 128     ${if} $MiKTeXUser != "HKCU"
 129      StrCpy $MiKTeXPath "$LatexPath" -11
 130      #MessageBox MB_OK|MB_ICONINFORMATION "$(MiKTeXPathInfo)" # info that MiKTeX's installation folder must have write permissions for all users to work properly
 131     ${endif}
 132    ${else}
 133     MessageBox MB_OK|MB_ICONSTOP "$(LatexError1)"
 134     SetOutPath $TEMP # to be able to delete the $INSTDIR
 135     RMDir /r $INSTDIR
 136     Abort
 137    ${endif} # endif $LatexPath != ""
 138   ${endif}
 139
 140 FunctionEnd
 141
 142 # -------------------------------------------
 143
 144 Function Ghostscript
 145
 146   # if GhostScript is not installed
 147   ${if} $GhostscriptPath == ""
 148    # register Ghostscript
 149    WriteRegStr HKLM "SOFTWARE\GPL Ghostscript\${GhostscriptVersion}" "GS_DLL" "${GhostscriptDir}\bin\gsdll32.dll"
 150    WriteRegStr HKLM "SOFTWARE\GPL Ghostscript\${GhostscriptVersion}" "GS_LIB" "${GhostscriptDir}\lib;${GhostscriptDir}\fonts;${GhostscriptDir}\Resource"
 151
 152    WriteRegStr HKLM "SOFTWARE\GPL Ghostscript" "OnlyWithLyX" "Yes${PRODUCT_VERSION_SHORT}" # special entry to tell the uninstaller that it was installed with LyX
 153    StrCpy $GhostscriptPath "${GhostscriptDir}\bin"
 154   ${else}
 155    # delete unnecessary files
 156    RMDir /r ${GhostscriptDir}
 157   ${endif}
 158
 159 FunctionEnd
 160
 161 # -------------------------------------------
 162
 163 Function ImageMagick
 164
 165   # if ImageMagick is not installed
 166   ${if} $ImageMagickPath == ""
 167    # register ImageMagick
 168    WriteRegStr HKLM "SOFTWARE\Classes\Applications" "AutoRun" "${ImageMagickDir}\convert.exe $$"
 169    WriteRegStr HKLM "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "BinPath" "${ImageMagickDir}"
 170    WriteRegStr HKLM "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "CoderModulesPath" "${ImageMagickDir}\modules\coders"
 171    WriteRegStr HKLM "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "ConfigurePath" "${ImageMagickDir}\config"
 172    WriteRegStr HKLM "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "FilterModulesPath" "${ImageMagickDir}\modules\filters"
 173    WriteRegStr HKLM "SOFTWARE\ImageMagick\${ImageMagickVersion}\Q:16" "LibPath" "${ImageMagickDir}"
 174
 175    WriteRegStr HKLM "SOFTWARE\ImageMagick\Current" "BinPath" "${ImageMagickDir}"
 176    WriteRegStr HKLM "SOFTWARE\ImageMagick\Current" "CoderModulesPath" "${ImageMagickDir}\modules\coders"
 177    WriteRegStr HKLM "SOFTWARE\ImageMagick\Current" "ConfigurePath" "${ImageMagickDir}\config"
 178    WriteRegStr HKLM "SOFTWARE\ImageMagick\Current" "FilterModulesPath" "${ImageMagickDir}\modules\filters"
 179    WriteRegStr HKLM "SOFTWARE\ImageMagick\Current" "LibPath" "${ImageMagickDir}"
 180    WriteRegDWORD HKLM "SOFTWARE\ImageMagick\Current" "QuantumDepth" 0x00000010
 181    WriteRegStr HKLM "SOFTWARE\ImageMagick\Current" "Version" "${ImageMagickVersion}"
 182
 183    WriteRegStr HKLM "Software\ImageMagick" "OnlyWithLyX" "Yes${PRODUCT_VERSION_SHORT}" # special entry to tell the uninstaller that it was installed with LyX
 184    StrCpy $ImageMagickPath ${ImageMagickDir}
 185   ${else}
 186    # delete unnecessary files
 187    RMDir /r ${ImageMagickDir}
 188   ${endif}
 189
 190 FunctionEnd
 191
 192 # -------------------------------------------
 193
 194 Function Aiksaurus
 195
 196   # if Aiksaurus is not installed
 197   ${if} $AiksaurusPath == ""
 198    # extract Aiksaurus' program files
 199    SetOutPath "$INSTDIR\external"
 200    File /r "${PRODUCT_SOURCEDIR}\${AiksaurusInstall}"
 201    # copy the files and register Aiksaurus
 202    CopyFiles "$INSTDIR\${AiksaurusInstall}" "$APPDATA"
 203 #   WriteRegStr HKLM "Software\Aiksaurus" "OnlyWithLyX" "Yes${PRODUCT_VERSION_SHORT}" # special entry to tell the uninstaller that it was installed with LyX
 204 #   WriteRegStr HKLM "Software\Aiksaurus" "Data Path" "${AiksaurusDir}"
 205   ${endif}
 206
 207 FunctionEnd
 208
 209 # -------------------------------------------
 210
 211 Function PostScript
 212
 213 # if no PostScript viewer is installed
 214   ${if} $PSVPath == ""
 215    ${if} $InstallGSview == "true"
 216     # launch installer
 217     MessageBox MB_OK|MB_ICONINFORMATION "$(GSviewInfo)"
 218     ExecWait "$INSTDIR\${GSviewInstall}"
 219     # test if GSview is installed
 220     StrCpy $PSVPath ""
 221     ReadRegStr $PSVPath HKLM "Software\Microsoft\Windows\CurrentVersion\App Paths\gsview32.exe" "Path"
 222     ${if} $PSVPath == ""
 223      MessageBox MB_OK|MB_ICONEXCLAMATION "$(GSviewError)"
 224     ${endif}
 225    ${endif}
 226   ${endif}
 227
 228 FunctionEnd
 229
 230 # -------------------------------------------
 231
 232 Function BibTeX
 233
 234 # if no BibTeX editor is installed
 235   ${if} $BibTeXEditorPath == ""
 236    ${if} $InstallJabRef == "true"
 237     # launch installer
 238     MessageBox MB_OK|MB_ICONINFORMATION "$(JabRefInfo)"
 239     ExecWait "$INSTDIR\${JabRefInstall}"
 240     # test if JabRef is installed
 241     StrCpy $BibTeXEditorPath ""
 242     ReadRegStr $BibTeXEditorPath HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${JabRefVersion}" "UninstallString"
 243     ${if} $BibTeXEditorPath == ""
 244      MessageBox MB_OK|MB_ICONEXCLAMATION "$(JabRefError)"
 245     ${else}
 246      WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${JabRefVersion}" "OnlyWithLyX" "Yes${PRODUCT_VERSION_SHORT}" # special entry to tell the uninstaller that it was installed with LyX
 247     ${endif}
 248    ${endif}
 249   ${endif}
 250
 251 FunctionEnd
 252