development/Win32/packaging/AltInstaller/ConfigLyX.nsh

   1 Function ConfigureLyX
   2  # configures LyX
   3
   4   # create the PathPrefix
   5   StrCpy $PathPrefix "$INSTDIR\bin"
   6   ${if} $PythonPath != ""
   7     StrCpy $PathPrefix "$PathPrefix;$PythonPath"
   8   ${endif}
   9   ${if} $LatexPath != ""
  10     StrCpy $PathPrefix "$PathPrefix;$LatexPath"
  11   ${endif}
  12   ${if} $GhostscriptPath != ""
  13     StrCpy $PathPrefix "$PathPrefix;$GhostscriptPath"
  14   ${endif}
  15   ${if} $ImageMagickPath != ""
  16     StrCpy $PathPrefix "$PathPrefix;$ImageMagickPath"
  17   ${endif}
  18   ${if} $PSVPath != ""
  19     StrCpy $PathPrefix "$PathPrefix;$PSVPath"
  20   ${endif}
  21   ${if} $EditorPath != ""
  22     StrCpy $PathPrefix "$PathPrefix;$EditorPath"
  23   ${endif}
  24   ${if} $ImageEditorPath != ""
  25     StrCpy $PathPrefix "$PathPrefix;$ImageEditorPath"
  26   ${endif}
  27   ${if} $SVGPath != ""
  28    StrCpy $PathPrefix "$PathPrefix;$SVGPath"
  29   ${endif}
  30   ${if} $WMFPath != ""
  31    StrCpy $PathPrefix "$PathPrefix;$WMFPath"
  32   ${endif}
  33
  34   # Set the path prefix in lyxrc.dist
  35   ClearErrors
  36   Delete "$INSTDIR\Resources\lyxrc.dist"
  37   FileOpen $R1 "$INSTDIR\Resources\lyxrc.dist" w
  38   # set some general things
  39   FileWrite $R1 '\screen_zoom "120"$\r$\n\
  40                  \accept_compound true$\r$\n\
  41                  \gui_language $LangNameLyX$\r$\n'
  42   ${if} "$PathPrefix" != ""
  43    FileWrite $R1 '\path_prefix "$PathPrefix"$\r$\n'
  44   ${endif}
  45   # if Acrobat or Adobe Reader is used
  46   ${if} $Acrobat == "Yes" # used for Acrobat / Adobe Reader
  47    FileWrite $R1 '\format "pdf3" "pdf" "PDF (dvipdfm)" "m" "pdfview" "" "document,vector"$\r$\n\
  48                   \format "pdf2" "pdf" "PDF (pdflatex)" "F" "pdfview" "" "document,vector"$\r$\n\
  49                   \format "pdf" "pdf" "PDF (ps2pdf)" "P" "pdfview" "" "document,vector"$\r$\n'
  50   ${endif}
  51   # if a SVG to PDF converter ws found (e.g. Inkscape)
  52   ${if} $SVGPath != ""
  53    FileWrite $R1 '\format "svg" "svg" "SVG" "" "inkscape --file=$$$$i" "inkscape --file=$$$$i" "vector"$\r$\n\
  54                   \converter "svg" "png" "inkscape --without-gui --file=$$$$i --export-png=$$$$o" ""$\r$\n\
  55                   \converter "svg" "pdf" "inkscape --file=$$$$p/$$$$i --export-area-drawing --without-gui --export-pdf=$$$$p/$$$$o" ""$\r$\n\
  56                   \converter "svg" "eps" "inkscape --file=$$$$p/$$$$i --export-area-drawing --without-gui --export-eps=$$$$p/$$$$o" ""'
  57   ${endif}
  58   FileClose $R1
  59   IfErrors 0 +2
  60    MessageBox MB_OK|MB_ICONEXCLAMATION "$(ModifyingConfigureFailed)"
  61   ClearErrors
  62
  63   # register LyX
  64   ${if} $CreateFileAssociations == "true"
  65    WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "${PRODUCT_EXE}"
  66   ${endif}
  67   WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "RootKey" "$ProductRootKey"
  68   WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayName" "${PRODUCT_NAME} ${PRODUCT_VERSION}"
  69   WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "UninstallString" "${PRODUCT_UNINSTALL_EXE}"
  70   WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayIcon" "${PRODUCT_EXE}"
  71   WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
  72   WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "StartMenu" "$SMPROGRAMS\$StartmenuFolder"
  73   WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "URLUpdateInfo" "${PRODUCT_INFO_URL}"
  74   WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_ABOUT_URL}"
  75   WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "Publisher" "LyX Team"
  76   WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "HelpLink" "${PRODUCT_HELP_LINK}"
  77   WriteRegDWORD SHCTX "${PRODUCT_UNINST_KEY}" "NoModify" 0x00000001
  78   WriteRegDWORD SHCTX "${PRODUCT_UNINST_KEY}" "NoRepair" 0x00000001
  79
  80   # create start menu entry
  81   SetOutPath "$INSTDIR\bin"
  82   CreateDirectory "$SMPROGRAMS\$StartmenuFolder"
  83   CreateShortCut "$SMPROGRAMS\$StartmenuFolder\${PRODUCT_NAME}.lnk" "${PRODUCT_BAT}" "" "${PRODUCT_EXE}"
  84   SetOutPath "$INSTDIR"
  85   CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Uninstall.lnk" "${PRODUCT_UNINSTALL_EXE}"
  86
  87   # create desktop icon
  88   ${if} $CreateDesktopIcon == "true"
  89    SetOutPath "$INSTDIR\bin"
  90    CreateShortCut "$DESKTOP\LyX ${PRODUCT_VERSION}.lnk" "${PRODUCT_BAT}" "" "${PRODUCT_EXE}"
  91   ${endif}
  92
  93   # register the extension .lyx
  94   ${if} $CreateFileAssociations == "true"
  95    WriteRegStr SHCTX "${PRODUCT_DIR_REGKEY}" "OnlyWithLyX" "Yes${PRODUCT_VERSION_SHORT}" # special entry to test if they were registered by this LyX version
  96    # write informations about file type
  97    WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}" "" "${PRODUCT_NAME} Document"
  98    WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}\DefaultIcon" "" "${PRODUCT_EXE}"
  99    WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}\Shell\open\command" "" '"${PRODUCT_BAT}" "%1"'
 100    # write informations about file extensions
 101    WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}" "" "${PRODUCT_REGNAME}"
 102    WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}" "Content Type" "${PRODUCT_MIME_TYPE}"
 103    # .lyx13
 104    WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}13" "" "${PRODUCT_REGNAME}"
 105    WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}13" "Content Type" "${PRODUCT_MIME_TYPE}"
 106    # .lyx14
 107    WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}14" "" "${PRODUCT_REGNAME}"
 108    WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}14" "Content Type" "${PRODUCT_MIME_TYPE}"
 109    # .lyx15 don't set this, because this is designed to be opened with LyX 1.5.x
 110    #WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}15" "" "${PRODUCT_REGNAME}"
 111    #WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}15" "Content Type" "${PRODUCT_MIME_TYPE}"
 112    # .lyx16 don't set this, because this is designed to be opened with LyX 1.6.x
 113    #WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}16" "" "${PRODUCT_REGNAME}"
 114    #WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}16" "Content Type" "${PRODUCT_MIME_TYPE}"
 115    # refresh shell
 116    System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) (${SHCNE_ASSOCCHANGED}, ${SHCNF_IDLIST}, 0, 0)'
 117   ${endif}
 118
 119   # delete unnecessary files
 120   ${if} $DelPythonFiles == "True"
 121    Delete $INSTDIR\bin\python.exe
 122    Delete $INSTDIR\bin\python26.dll
 123    Delete $INSTDIR\bin\Python-License.txt
 124    RMDir /r $INSTDIR\bin\Lib
 125    RMDir /r $INSTDIR\bin\DLLs
 126   ${endif}
 127   RMDir /r $INSTDIR\external
 128
 129   # create a bat-file to start configure in a console window so that the user see the progress
 130   # of the configuration and to have a signal when the configuration is ready to start LyX
 131   # this is important when LyX is installed together with MiKTeX or when LyX is installed for the first
 132   # time on a computer, because the installation of missing LaTeX-files required by LyX could last minutes
 133   # a batch file is needed because simply calling
 134   # ExecWait '"$PythonPath\python.exe" "$INSTDIR\Resources\configure.py"'
 135   # creates the config files in $PythonPath
 136   ${if} $PythonPath == ""
 137    StrCpy $PythonPath "$INSTDIR\bin"
 138   ${endif}
 139   StrCpy $1 $INSTDIR 2 # get drive letter
 140   FileOpen $R1 "$INSTDIR\Resources\configLyX.bat" w
 141   FileWrite $R1 '$1$\r$\n\
 142                  cd $INSTDIR\Resources\$\r$\n\
 143                  "$PythonPath\python.exe" configure.py'
 144   FileClose $R1
 145
 146 FunctionEnd
 147