configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/lyx.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 AC_ARG_WITH(lyxname,
  15   [  --with-lyxname          the name under which lyx will be installed],
  16   [lyxname=$withval],[lyxname=lyx])
  17
  18 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  19
  20 # The list of languages known to LyX
  21 # This is needed by GNU gettext
  22 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  23
  24 AC_PREFIX_PROGRAM(lyx)
  25
  26 # fix the value of the prefixes.
  27 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  28 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  29
  30 ### Set the execute permissions of the various scripts correctly
  31 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  32   chmod 755 ${srcdir}/${file}
  33 done
  34
  35 ### Check for programs
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 #AC_PROG_RANLIB
  39 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  40 if test "x$KPSEWHICH" = xkpsewhich ; then
  41     AC_DEFINE(HAVE_KPSEWHICH, 1,
  42     [Define this if you have the kpsewhich program working on your system.])
  43 fi
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### check which frontend we want to use
  65 LYX_USE_FRONTEND
  66 dnl The code below is not in a macro, because this would cause big
  67 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  68 case "$lyx_use_frontend" in
  69   gnome)
  70     GNOME_INIT
  71     GNOME_COMPILE_WARNINGS
  72     GNOME_X_CHECKS
  73 esac
  74
  75 ### Check for a C++ compiler
  76 AC_LANG_CPLUSPLUS
  77 LYX_PROG_CXX
  78 AC_PROG_CXXCPP
  79 AC_DISABLE_SHARED
  80 AC_LIBTOOL_WIN32_DLL
  81 AM_PROG_LIBTOOL
  82
  83 ### Some checks on what the C++ compiler can(not) do
  84 LYX_CXX_MUTABLE
  85 LYX_CXX_PARTIAL
  86 LYX_CXX_EXPLICIT
  87 dnl we do not use stl stack, or at least not on gcc 2.7, which was the
  88 dnl cause for this test.
  89 dnl LYX_CXX_STL_STACK
  90 LYX_CXX_STL_STRING
  91 LYX_CXX_GOOD_STD_STRING
  92 LYX_CXX_NAMESPACES
  93 LYX_CXX_CHEADERS
  94 LYX_STD_COUNT
  95 dnl we disable rtti for now
  96 dnl LYX_CXX_RTTI
  97 AC_CHECK_HEADERS(ostream istream sstream locale)
  98 LYX_CXX_STL_MODERN_STREAMS
  99
 100 ### We need a regex implementation, so we provide our own if none is found.
 101 LYX_REGEX
 102
 103 ### Library Files
 104 dnl by testing these we check if it is ok to have
 105 dnl -lc and -lm as args to the compiler
 106 AC_CHECK_LIB(m, sin)
 107 AC_CHECK_LIB(c, fopen)
 108
 109 ### Add extra directories to check for libraries.
 110 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 111 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 112 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 113
 114 ### Add extra directories to check for include files.
 115 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 116 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 117 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 118
 119 ### Add both includes and libraries
 120 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 121 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 122 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 123   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 124
 125 ### Check for the -liberty library
 126 test "x$GXX" = xyes && lyx_use_liberty=yes
 127 AC_ARG_WITH(liberty,
 128   [  --without-liberty       do not try to link against libiberty.a],
 129   [lyx_use_liberty=$withval])
 130 if test x$lyx_use_liberty = xyes; then
 131   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 132   AC_CHECK_LIB(iberty,main)
 133 fi
 134
 135 ### Check which libsigc++ we're using
 136 LYX_WITH_SIGC
 137
 138 ### Check if we want pspell libraries
 139 CHECK_WITH_PSPELL
 140
 141 ### Check for X libraries
 142 # Check for the pt library (for SCO, needed for X)
 143 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 144 # The real thing.
 145 AC_PATH_XTRA
 146 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 147 # Since solaris X headers use int as implicit return type and modern
 148 # gcc's do not like that, let's use -isystem instead of -I.
 149 # We should test for gcc version and see whether it supports -isystem,
 150 # but since at least gcc 2.6.x supports it and it is still too old for
 151 # us, it seems we are safe.
 152 if test -n "$GXX" ; then
 153   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 154 fi
 155 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 156
 157 ## Check whether X is new enough to handle the input method stuff
 158 AC_CHECK_FUNCS(XOpenIM)
 159
 160 ### check which frontend we want to use
 161 #LYX_USE_FRONTEND
 162 dnl The code below is not in a macro, because this would cause big
 163 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 164 case "$lyx_use_frontend" in
 165   kde)
 166     KDE_DO_IT_ALL
 167     FRONTEND="kde"
 168     FRONTEND_GUILIB="\${top_builddir}/src/frontends/kde/libkde.la"
 169     FRONTEND_LDFLAGS="\$(QT_LDFLAGS) \$(KDE_LDFLAGS)"
 170     FRONTEND_INCLUDES="-I\${srcdir}/kde \$(QT_INCLUDES) \$(KDE_INCLUDES)"
 171     FRONTEND_LIBS="\$(KDE_LIBS)";;
 172   xforms)
 173   # for now don't set it for xforms as this is always entered
 174     FRONTEND=""
 175     FRONTEND_GUILIB="\${top_builddir}/src/frontends/xforms/libxforms.la";;
 176   gnome)
 177     AM_PATH_GTKMM(1.2.1,,
 178         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 179     AM_PATH_GNOMEMM
 180
 181     FRONTEND="gnome"
 182     FRONTEND_GUILIB="\${top_builddir}/src/frontends/gnome/libgnome.la"
 183     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 184     FRONTEND_INCLUDES="-I\${srcdir}/gnome \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 185     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS)";;
 186   *)
 187     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 188 esac
 189
 190 ### Check for xforms and xpm (only if X has been found).
 191 if test "$have_x" = yes ; then
 192 # We surely need these two libraries and want to check carefully the
 193 # version numbers...
 194 LYX_PATH_XPM
 195 LYX_PATH_XFORMS
 196 AC_SUBST(LYX_LIBS)
 197 else
 198 LYX_ERROR(dnl
 199 [Cannot find X window libraries and/or headers. Check your installation.
 200    If you use a Linux system, check that you have installed
 201    the development tools.])
 202 fi
 203
 204 ### Setup GNU gettext
 205 dnl GNU gettext is written in C
 206 AC_LANG_C
 207 # Some tests that may be useful for gettext
 208 AC_C_CONST
 209 AC_C_INLINE
 210 # Do the real setup now
 211 AM_GNU_GETTEXT
 212 # a hack for those who try to change LyX, but do not have gettext installed
 213 case  "${XGETTEXT}" in
 214  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 215 esac
 216
 217 AC_SUBST(LINGUAS)
 218
 219 AC_LANG_CPLUSPLUS
 220
 221 # some standard header files
 222 AC_HEADER_DIRENT
 223 AC_HEADER_MAJOR
 224 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 225
 226 # some annoying header files
 227 #LYX_PATH_HEADER(stl_string_fwd.h)
 228 LYX_STL_STRING_FWD
 229
 230 # some standard structures
 231 AC_HEADER_STAT
 232 AC_HEADER_TIME
 233 AC_STRUCT_ST_BLKSIZE
 234 AC_STRUCT_ST_BLOCKS
 235 AC_STRUCT_ST_RDEV
 236
 237 # some standard types
 238 AC_TYPE_MODE_T
 239 AC_TYPE_OFF_T
 240 AC_TYPE_PID_T
 241 AC_TYPE_SIGNAL
 242 AC_TYPE_SIZE_T
 243 AC_TYPE_UID_T
 244
 245 # some functions we'd like to have
 246 AC_ARG_WITH(broken-headers,
 247     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 248     [lyx_broken_headers=$withval])
 249 if test "x$lyx_broken_headers" = "xyes"; then
 250   lyx_flags="$lyx_flags broken-headers"
 251   AC_DEFINE(BROKEN_HEADERS, 1,
 252     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 253 fi
 254 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo)
 255
 256 dnl Until this is fixed in autoconf we provide our own version
 257 LYX_FUNC_SELECT_ARGTYPES
 258
 259 dnl check whether we have to work around solaris broken putenv()
 260 LYX_FUNC_PUTENV_ARGTYPE
 261
 262 # SunOS 4.1.3 does not have strerror and atexit
 263 AC_REPLACE_FUNCS(strerror atexit)
 264
 265 ### and now some special lyx flags.
 266 AC_ARG_ENABLE(assertions,
 267   [  --enable-assertions     add runtime sanity checks in the program],,
 268   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 269         enable_assertions=yes;
 270     else
 271         enable_assertions=no;
 272     fi;])
 273 if test "x$enable_assertions" = xyes ; then
 274    lyx_flags="$lyx_flags assertions"
 275    AC_DEFINE(ENABLE_ASSERTIONS,1,
 276     [Define if you want assertions to be enabled in the code])
 277 fi
 278
 279 ### Finish the work.
 280 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 281 AC_OUTPUT([Makefile \
 282        development/lyx.spec \
 283        lib/Makefile \
 284        intl/Makefile \
 285        po/Makefile.in \
 286        boost/Makefile \
 287        src/Makefile \
 288        src/mathed/Makefile \
 289        src/graphics/Makefile \
 290        src/insets/Makefile \
 291        src/support/Makefile \
 292        src/xtl/Makefile \
 293        src/frontends/Makefile \
 294        src/frontends/xforms/Makefile \
 295        src/frontends/kde/Makefile \
 296        src/frontends/gnome/Makefile \
 297 ],  [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 298
 299
 300 cat <<EOF
 301
 302 Configuration:
 303   Source code location:       ${srcdir}
 304   C++ Compiler:                   ${CXX}
 305   C++ Compiler flags:             ${CXXFLAGS}
 306   C   Compiler:                   ${CC}
 307   C   Compiler flags:             ${CFLAGS}
 308   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 309   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 310   Special flags:              ${lyx_flags}
 311
 312 EOF
 313
 314 # Display a final warning if there has been a LYX_ERROR
 315 LYX_CHECK_ERRORS