configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/lyx.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 AC_ARG_WITH(lyx-suffix,
  15   [  --with-lyx-suffix       install lyx files as lyx-<suffix>],
  16   [lyxname="lyx-$withval"
  17    program_suffix=-$withval],
  18   [lyxname=lyx])
  19
  20 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  21
  22 # The list of languages known to LyX
  23 # This is needed by GNU gettext
  24 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  25
  26 AC_PREFIX_PROGRAM(lyx)
  27
  28 # fix the value of the prefixes.
  29 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  30 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  31
  32 ### Set the execute permissions of the various scripts correctly
  33 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  34   chmod 755 ${srcdir}/${file}
  35 done
  36
  37 ### Check for programs
  38 AC_PROG_MAKE_SET
  39 AC_PROG_INSTALL
  40 #AC_PROG_RANLIB
  41 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  42 if test "x$KPSEWHICH" = xkpsewhich ; then
  43     AC_DEFINE(HAVE_KPSEWHICH, 1,
  44     [Define this if you have the kpsewhich program working on your system.])
  45 fi
  46
  47 # Work around a problem in automake 1.4: when invoking install-strip,
  48 # INSTALL_PROGRAM is changed to 'install -s', and since
  49 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  50 # which returns an error condition when stripping fails.
  51 INSTALL_SCRIPT='${INSTALL}'
  52
  53 ### we will also need a C compiler to compile GNU gettext
  54 AC_PROG_CC
  55
  56 ### check for special systems
  57 AC_ISC_POSIX
  58 AC_AIX
  59 LYX_HPUX
  60 LYX_SUNOS4
  61 LYX_SCO
  62
  63 ### Check for program extensions (.exe or nothing)
  64 AC_EXEEXT
  65
  66 ### check which frontend we want to use
  67 LYX_USE_FRONTEND
  68 dnl The code below is not in a macro, because this would cause big
  69 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  70 case "$lyx_use_frontend" in
  71   gnome)
  72     GNOME_INIT
  73     GNOME_COMPILE_WARNINGS
  74     GNOME_X_CHECKS
  75 esac
  76
  77 ### Check for a C++ compiler
  78 AC_LANG_CPLUSPLUS
  79 LYX_PROG_CXX
  80 AC_PROG_CXXCPP
  81 AC_DISABLE_SHARED
  82 AC_LIBTOOL_WIN32_DLL
  83 AM_PROG_LIBTOOL
  84
  85 ### Some checks on what the C++ compiler can(not) do
  86 LYX_CXX_MUTABLE
  87 LYX_CXX_PARTIAL
  88 LYX_CXX_EXPLICIT
  89 dnl we do not use stl stack, or at least not on gcc 2.7, which was the
  90 dnl cause for this test.
  91 dnl LYX_CXX_STL_STACK
  92 LYX_CXX_STL_STRING
  93 LYX_CXX_GOOD_STD_STRING
  94 LYX_CXX_NAMESPACES
  95 LYX_CXX_CHEADERS
  96 LYX_CXX_GLOBAL_CSTD
  97 LYX_STD_COUNT
  98 dnl we disable rtti for now
  99 dnl LYX_CXX_RTTI
 100 AC_CHECK_HEADERS(ostream istream sstream locale)
 101 LYX_CXX_STL_MODERN_STREAMS
 102
 103 ### We need a regex implementation, so we provide our own if none is found.
 104 LYX_REGEX
 105
 106 ### Library Files
 107 dnl by testing these we check if it is ok to have
 108 dnl -lc and -lm as args to the compiler
 109 AC_CHECK_LIB(m, sin)
 110 AC_CHECK_LIB(c, fopen)
 111
 112 ### Add extra directories to check for libraries.
 113 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 114 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 115 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 116
 117 ### Add extra directories to check for include files.
 118 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 119 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 120 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 121
 122 ### Add both includes and libraries
 123 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 124 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 125 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 126   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 127
 128 ### Check for the -liberty library
 129 test "x$GXX" = xyes && lyx_use_liberty=yes
 130 AC_ARG_WITH(liberty,
 131   [  --without-liberty       do not try to link against libiberty.a],
 132   [lyx_use_liberty=$withval])
 133 if test x$lyx_use_liberty = xyes; then
 134   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 135   AC_CHECK_LIB(iberty,main)
 136 fi
 137
 138 ### Check which libsigc++ we're using
 139 LYX_WITH_SIGC
 140
 141 ### Check if we want pspell libraries
 142 CHECK_WITH_PSPELL
 143
 144 ### Check for X libraries
 145 # Check for the pt library (for SCO, needed for X)
 146 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 147 # The real thing.
 148 AC_PATH_XTRA
 149 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 150 # Since solaris X headers use int as implicit return type and modern
 151 # gcc's do not like that, let's use -isystem instead of -I.
 152 # We should test for gcc version and see whether it supports -isystem,
 153 # but since at least gcc 2.6.x supports it and it is still too old for
 154 # us, it seems we are safe.
 155 if test -n "$GXX" ; then
 156   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 157 fi
 158 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 159
 160 ## Check whether X is new enough to handle the input method stuff
 161 AC_CHECK_FUNCS(XOpenIM)
 162
 163 ### check which frontend we want to use
 164 #LYX_USE_FRONTEND
 165 dnl The code below is not in a macro, because this would cause big
 166 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 167 case "$lyx_use_frontend" in
 168   kde)
 169     KDE_DO_IT_ALL
 170     FRONTEND="kde"
 171     FRONTEND_GUILIB="\${top_builddir}/src/frontends/kde/libkde.la"
 172     FRONTEND_LDFLAGS="\$(QT_LDFLAGS) \$(KDE_LDFLAGS)"
 173     FRONTEND_INCLUDES="-I\${srcdir}/kde \$(QT_INCLUDES) \$(KDE_INCLUDES)"
 174     FRONTEND_LIBS="\$(KDE_LIBS)";;
 175   xforms)
 176   # for now don't set it for xforms as this is always entered
 177     FRONTEND=""
 178     FRONTEND_GUILIB="\${top_builddir}/src/frontends/xforms/libxforms.la";;
 179   gnome)
 180     AM_PATH_GTKMM(1.2.1,,
 181         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 182     AM_PATH_GNOMEMM
 183
 184     FRONTEND="gnome"
 185     FRONTEND_GUILIB="\${top_builddir}/src/frontends/gnome/libgnome.la"
 186     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 187     FRONTEND_INCLUDES="-I\${srcdir}/gnome \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 188     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS)";;
 189   *)
 190     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 191 esac
 192
 193 ### Check for xforms and xpm (only if X has been found).
 194 if test "$have_x" = yes ; then
 195 # We surely need these two libraries and want to check carefully the
 196 # version numbers...
 197 LYX_PATH_XPM
 198 LYX_PATH_XFORMS
 199 AC_SUBST(LYX_LIBS)
 200 else
 201 LYX_ERROR(dnl
 202 [Cannot find X window libraries and/or headers. Check your installation.
 203    If you use a Linux system, check that you have installed
 204    the development tools.])
 205 fi
 206
 207 ### Setup GNU gettext
 208 dnl GNU gettext is written in C
 209 AC_LANG_C
 210 # Some tests that may be useful for gettext
 211 AC_C_CONST
 212 AC_C_INLINE
 213 # Do the real setup now
 214 AM_GNU_GETTEXT
 215 # a hack for those who try to change LyX, but do not have gettext installed
 216 case  "${XGETTEXT}" in
 217  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 218 esac
 219
 220 AC_SUBST(LINGUAS)
 221
 222 AC_LANG_CPLUSPLUS
 223
 224 # some standard header files
 225 AC_HEADER_DIRENT
 226 AC_HEADER_MAJOR
 227 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 228
 229 # some annoying header files
 230 #LYX_PATH_HEADER(stl_string_fwd.h)
 231 LYX_STL_STRING_FWD
 232
 233 # some standard structures
 234 AC_HEADER_STAT
 235 AC_HEADER_TIME
 236 AC_STRUCT_ST_BLKSIZE
 237 AC_STRUCT_ST_BLOCKS
 238 AC_STRUCT_ST_RDEV
 239
 240 # some standard types
 241 AC_TYPE_MODE_T
 242 AC_TYPE_OFF_T
 243 AC_TYPE_PID_T
 244 AC_TYPE_SIGNAL
 245 AC_TYPE_SIZE_T
 246 AC_TYPE_UID_T
 247
 248 # some functions we'd like to have
 249 AC_ARG_WITH(broken-headers,
 250     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 251     [lyx_broken_headers=$withval])
 252 if test "x$lyx_broken_headers" = "xyes"; then
 253   lyx_flags="$lyx_flags broken-headers"
 254   AC_DEFINE(BROKEN_HEADERS, 1,
 255     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 256 fi
 257 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo snprintf vsnprintf)
 258 AC_CHECK_FUNCS(mkstemp mktemp)
 259
 260 dnl Until this is fixed in autoconf we provide our own version
 261 LYX_FUNC_SELECT_ARGTYPES
 262
 263 dnl check whether we have to work around solaris broken putenv()
 264 LYX_FUNC_PUTENV_ARGTYPE
 265
 266 # SunOS 4.1.3 does not have strerror and atexit
 267 AC_REPLACE_FUNCS(strerror atexit)
 268
 269 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 270
 271 ### and now some special lyx flags.
 272 AC_ARG_ENABLE(assertions,
 273   [  --enable-assertions     add runtime sanity checks in the program],,
 274   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 275         enable_assertions=yes;
 276     else
 277         enable_assertions=no;
 278     fi;])
 279 if test "x$enable_assertions" = xyes ; then
 280    lyx_flags="$lyx_flags assertions"
 281    AC_DEFINE(ENABLE_ASSERTIONS,1,
 282     [Define if you want assertions to be enabled in the code])
 283 fi
 284
 285 ### Finish the work.
 286 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 287 AC_OUTPUT([Makefile \
 288        development/lyx.spec \
 289        lib/Makefile \
 290        intl/Makefile \
 291        po/Makefile.in \
 292        boost/Makefile \
 293        src/Makefile \
 294        src/mathed/Makefile \
 295        src/graphics/Makefile \
 296        src/insets/Makefile \
 297        src/support/Makefile \
 298        src/frontends/Makefile \
 299        src/frontends/support/Makefile \
 300        src/frontends/xforms/Makefile \
 301        src/frontends/kde/Makefile \
 302        src/frontends/kde/moc/Makefile \
 303        src/frontends/kde/dlg/Makefile \
 304        src/frontends/kde/dlg/moc/Makefile \
 305        src/frontends/gnome/Makefile \
 306 ],  [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 307
 308
 309 cat <<EOF
 310
 311 Configuration:
 312   Source code location:       ${srcdir}
 313   C++ Compiler:                   ${CXX}
 314   C++ Compiler flags:             ${CXXFLAGS}
 315   C   Compiler:                   ${CC}
 316   C   Compiler flags:             ${CFLAGS}
 317   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 318   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 319   Special flags:              ${lyx_flags}
 320
 321 EOF
 322
 323 # Display a final warning if there has been a LYX_ERROR
 324 LYX_CHECK_ERRORS