configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/lyx.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 AC_ARG_WITH(lyxname,
  15   [  --with-lyxname          the name under which lyx will be installed],
  16   [lyxname=$withval],[lyxname=lyx])
  17
  18 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  19
  20 # The list of languages known to LyX
  21 # This is needed by GNU gettext
  22 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  23
  24 AC_PREFIX_PROGRAM(lyx)
  25
  26 # fix the value of the prefixes.
  27 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  28 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  29
  30 ### Set the execute permissions of the various scripts correctly
  31 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  32   chmod 755 ${srcdir}/${file}
  33 done
  34
  35 ### Check for programs
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 #AC_PROG_RANLIB
  39 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  40 if test "x$KPSEWHICH" = xkpsewhich ; then
  41     AC_DEFINE(HAVE_KPSEWHICH, 1,
  42     [Define this if you have the kpsewhich program working on your system.])
  43 fi
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### Check for a C++ compiler
  65 AC_LANG_CPLUSPLUS
  66 LYX_PROG_CXX
  67 AC_PROG_CXXCPP
  68 AC_DISABLE_SHARED
  69 AC_LIBTOOL_WIN32_DLL
  70 AM_PROG_LIBTOOL
  71
  72 ### Some checks on what the C++ compiler can(not) do
  73 LYX_CXX_MUTABLE
  74 LYX_CXX_PARTIAL
  75 LYX_CXX_EXPLICIT
  76 dnl we do not use stl stack, or at least not on gcc 2.7, which was the
  77 dnl cause for this test.
  78 dnl LYX_CXX_STL_STACK
  79 LYX_CXX_STL_STRING
  80 LYX_CXX_NAMESPACES
  81 LYX_CXX_CHEADERS
  82 LYX_STD_COUNT
  83 dnl we disable rtti for now
  84 dnl LYX_CXX_RTTI
  85 AC_CHECK_HEADERS(ostream istream sstream)
  86 LYX_CXX_STL_MODERN_STREAMS
  87
  88 ### We need a regex implementation, so we provide our own if none is found.
  89 LYX_REGEX
  90
  91 ### Library Files
  92 dnl by testing these we check if it is ok to have
  93 dnl -lc and -lm as args to the compiler
  94 AC_CHECK_LIB(m, sin)
  95 AC_CHECK_LIB(c, fopen)
  96
  97 ### Add extra directories to check for libraries.
  98 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  99 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 100 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 101
 102 ### Add extra directories to check for include files.
 103 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 104 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 105 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 106
 107 ### Add both includes and libraries
 108 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 109 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 110 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 111   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 112
 113 ### Check for the -liberty library
 114 test "x$GXX" = xyes && lyx_use_liberty=yes
 115 AC_ARG_WITH(liberty,
 116   [  --without-liberty       do not try to link against libiberty.a],
 117   [lyx_use_liberty=$withval])
 118 if test x$lyx_use_liberty = xyes; then
 119   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 120   AC_CHECK_LIB(iberty,main)
 121 fi
 122
 123 ### Check which libsigc++ we're using
 124 LYX_WITH_SIGC
 125
 126 ### Check for X libraries
 127 # Check for the pt library (for SCO, needed for X)
 128 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 129 # The real thing.
 130 AC_PATH_XTRA
 131 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 132 # Since solaris X headers use int as implicit return type and modern
 133 # gcc's do not like that, let's use -isystem instead of -I.
 134 # We should test for gcc version and see whether it supports -isystem,
 135 # but since at least gcc 2.6.x supports it and it is still too old for
 136 # us, it seems we are safe.
 137 if test -n "$GXX" ; then
 138   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 139 fi
 140 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 141
 142 ## Check whether X is new enough to handle the input method stuff
 143 AC_CHECK_FUNCS(XOpenIM)
 144
 145 ### check which frontend we want to use
 146 LYX_USE_FRONTEND
 147 dnl The code below is not in a macro, because this would cause big
 148 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 149 case "$lyx_use_frontend" in
 150   kde)
 151     KDE_DO_IT_ALL
 152     FRONTEND="kde"
 153     FRONTEND_GUILIB="\${top_builddir}/src/frontends/kde/libkde.la"
 154     FRONTEND_LDFLAGS="\$(QT_LDFLAGS) \$(KDE_LDFLAGS)"
 155     FRONTEND_INCLUDES="\$(QT_INCLUDES) \$(KDE_INCLUDES)"
 156     FRONTEND_LIBS="\$(KDE_LIBS)"
 157     AC_DEFINE(KDEGUI);;
 158   xforms)
 159     FRONTEND="xforms"
 160     FRONTEND_GUILIB="\${top_builddir}/src/frontends/xforms/libxforms.la";;
 161   *)
 162     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 163 esac
 164
 165 ### Check for xforms and xpm (only if X has been found).
 166 if test "$have_x" = yes ; then
 167 # We surely need these two libraries and want to check carefully the
 168 # version numbers...
 169 LYX_PATH_XPM
 170 LYX_PATH_XFORMS
 171 AC_SUBST(LYX_LIBS)
 172 else
 173 LYX_ERROR(dnl
 174 [Cannot find X window libraries and/or headers. Check your installation.
 175    If you use a Linux system, check that you have installed
 176    the development tools.])
 177 fi
 178
 179 ### Setup GNU gettext
 180 dnl GNU gettext is written in C
 181 AC_LANG_C
 182 # Some tests that may be useful for gettext
 183 AC_C_CONST
 184 AC_C_INLINE
 185 # Do the real setup now
 186 AM_GNU_GETTEXT
 187 # a hack for those who try to change LyX, but do not have gettext installed
 188 case  "${XGETTEXT}" in
 189  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 190 esac
 191
 192 AC_SUBST(LINGUAS)
 193
 194 AC_LANG_CPLUSPLUS
 195
 196 # some standard header files
 197 AC_HEADER_DIRENT
 198 AC_HEADER_MAJOR
 199 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 200
 201 # some annoying header files
 202 #LYX_PATH_HEADER(stl_string_fwd.h)
 203 LYX_STL_STRING_FWD
 204
 205 # some standard structures
 206 AC_HEADER_STAT
 207 AC_HEADER_TIME
 208 AC_STRUCT_ST_BLKSIZE
 209 AC_STRUCT_ST_BLOCKS
 210 AC_STRUCT_ST_RDEV
 211
 212 # some standard types
 213 AC_TYPE_MODE_T
 214 AC_TYPE_OFF_T
 215 AC_TYPE_PID_T
 216 AC_TYPE_SIGNAL
 217 AC_TYPE_SIZE_T
 218 AC_TYPE_UID_T
 219
 220 # some functions we'd like to have
 221 AC_ARG_WITH(broken-headers,
 222     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 223     [lyx_broken_headers=$withval])
 224 if test "x$lyx_broken_headers" = "xyes"; then
 225   lyx_flags="$lyx_flags broken-headers"
 226   AC_DEFINE(BROKEN_HEADERS, 1,
 227     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 228 fi
 229 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo)
 230
 231 dnl Until this is fixed in autoconf we provide our own version
 232 LYX_FUNC_SELECT_ARGTYPES
 233
 234 dnl check whether we have to work around solaris broken putenv()
 235 LYX_FUNC_PUTENV_ARGTYPE
 236
 237 # SunOS 4.1.3 does not have strerror and atexit
 238 AC_REPLACE_FUNCS(strerror atexit)
 239
 240 ### and now some special lyx flags.
 241 AC_ARG_WITH(two-colors,[  --with-two-colors       use two color pixmaps],
 242   [AC_DEFINE(TWO_COLOR_ICONS,1,
 243      [You might want to define TWO_COLOR_ICONS if you want to spare
 244  your colormap.  This will use monochrome icons instead of colored ones.])
 245    lyx_flags="$lyx_flags two-colors"])
 246 AC_ARG_ENABLE(assertions,
 247   [  --enable-assertions     add runtime sanity checks in the program],,
 248   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 249         enable_assertions=yes;
 250     else
 251         enable_assertions=no;
 252     fi;])
 253 if test "x$enable_assertions" = xyes ; then
 254    lyx_flags="$lyx_flags assertions"
 255    AC_DEFINE(ENABLE_ASSERTIONS,1,
 256     [Define if you want assertions to be enabled in the code])
 257 fi
 258
 259 ### Finish the work.
 260 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 261 AC_OUTPUT([Makefile \
 262        development/lyx.spec \
 263        lib/Makefile \
 264        intl/Makefile \
 265        po/Makefile.in \
 266        src/Makefile \
 267        src/mathed/Makefile \
 268        src/insets/Makefile \
 269        src/support/Makefile \
 270        src/xtl/Makefile \
 271        src/frontends/Makefile \
 272        src/frontends/xforms/Makefile \
 273        src/frontends/kde/Makefile \
 274 ],  [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 275
 276
 277 cat <<EOF
 278
 279 Configuration:
 280   Source code location:       ${srcdir}
 281   C++ Compiler:                   ${CXX}
 282   C++ Compiler flags:             ${CXXFLAGS}
 283   C   Compiler:                   ${CC}
 284   C   Compiler flags:             ${CFLAGS}
 285   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 286   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 287   Special flags:              ${lyx_flags}
 288
 289 EOF
 290
 291 # Display a final warning if there has been a LYX_ERROR
 292 LYX_CHECK_ERRORS