configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.3.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### check which frontend we want to use
  65 LYX_USE_FRONTEND
  66 dnl The code below is not in a macro, because this would cause big
  67 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  68 case "$lyx_use_frontend" in
  69   gnome)
  70     GNOME_INIT
  71     GNOME_COMPILE_WARNINGS
  72     GNOME_X_CHECKS
  73 esac
  74
  75 ### Check for a C++ compiler
  76 LYX_PROG_CXX
  77 ### Some checks on what the C++ compiler can(not) do
  78 AC_LANG_CPLUSPLUS
  79 dnl we do not need that currently (and probably all our supported
  80 dnl compiler allow that)
  81 dnl LYX_CXX_PARTIAL
  82 LYX_CXX_EXPLICIT
  83 LYX_CXX_STL_STRING
  84 LYX_CXX_GOOD_STD_STRING
  85 LYX_CXX_CHEADERS
  86 LYX_CXX_GLOBAL_CSTD
  87 LYX_STD_COUNT
  88 dnl we disable rtti for now
  89 dnl LYX_CXX_RTTI
  90 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  91 LYX_CXX_STL_MODERN_STREAMS
  92
  93 ### and now some special lyx flags.
  94 AC_ARG_ENABLE(assertions,
  95   [  --enable-assertions     add runtime sanity checks in the program],,
  96   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  97         enable_assertions=yes;
  98     else
  99         enable_assertions=no;
 100     fi;])
 101 if test "x$enable_assertions" = xyes ; then
 102    lyx_flags="$lyx_flags assertions"
 103    AC_DEFINE(ENABLE_ASSERTIONS,1,
 104     [Define if you want assertions to be enabled in the code])
 105 fi
 106
 107 ### We need a regex implementation, so we provide our own if none is found.
 108 LYX_REGEX
 109
 110 ### Library Files
 111 dnl by testing these we check if it is ok to have
 112 dnl -lc and -lm as args to the compiler
 113 AC_CHECK_LIB(m, sin)
 114 AC_CHECK_LIB(c, fopen)
 115 AC_ARG_WITH(aiksaurus,
 116   [  --without-aiksaurus     do not use the Aiksaurus library],
 117   [lyx_use_aiksaurus=$withval])
 118 if test x$lyx_use_aiksaurus != xno; then
 119 AC_CHECK_LIB(Aiksaurus, main,
 120         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 121          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 122         ],,"-lbz2")
 123 fi
 124 AC_SUBST(AIKSAURUS_LIBS)
 125
 126 ### Add extra directories to check for libraries.
 127 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 128 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 129 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 130
 131 ### Add extra directories to check for include files.
 132 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 133 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 134 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 135
 136 ### Add both includes and libraries
 137 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 138 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 139 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 140   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 141
 142 ### Check for the -liberty library
 143 test "x$GXX" = xyes && lyx_use_liberty=yes
 144 AC_ARG_WITH(liberty,
 145   [  --without-liberty       do not try to link against libiberty.a],
 146   [lyx_use_liberty=$withval])
 147 if test x$lyx_use_liberty = xyes; then
 148   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 149   AC_CHECK_LIB(iberty,main)
 150 fi
 151
 152 ### Setup libtool
 153 AC_DISABLE_SHARED
 154 AC_LIBTOOL_WIN32_DLL
 155 #AM_PROG_LIBTOOL
 156 LYX_PROG_LIBTOOL
 157
 158 ### Check which libsigc++ we're using
 159 LYX_WITH_SIGC
 160
 161 ### Check if we want pspell libraries
 162 CHECK_WITH_PSPELL
 163
 164 ### Check for X libraries
 165 # The real thing.
 166 AC_PATH_XTRA
 167 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 168 # Since solaris X headers use int as implicit return type and modern
 169 # gcc's do not like that, let's use -isystem instead of -I.
 170 # We should test for gcc version and see whether it supports -isystem,
 171 # but since at least gcc 2.6.x supports it and it is still too old for
 172 # us, it seems we are safe.
 173 if test -n "$GXX" ; then
 174   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 175 fi
 176 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 177
 178 ## Check whether X is new enough to handle the input method stuff
 179 AC_CHECK_FUNCS(XOpenIM)
 180
 181 ### check which frontend we want to use
 182 #LYX_USE_FRONTEND
 183 dnl The code below is not in a macro, because this would cause big
 184 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 185 case "$lyx_use_frontend" in
 186   xforms)
 187   # for now don't set it for xforms as this is always entered
 188         LYX_PATH_XPM
 189         LYX_PATH_XFORMS
 190         FRONTEND="xforms"
 191         FRONTEND_GUILIB="xforms/*.lo"
 192         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 193         FRONTEND_LIBS="@XFORMS_LIB@ @XPM_LIB@"
 194         FRONTEND_INFO=`cat <<EOF
 195     libXpm version:               ${XPM_VERSION}\n\
 196     libforms version:             ${XFORMS_VERSION}\n
 197 `
 198         ;;
 199   gnome)
 200     LYX_PATH_XPM
 201     LYX_PATH_XFORMS
 202     AM_PATH_GTKMM(1.2.1,,
 203         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 204     AM_PATH_GNOMEMM
 205
 206 dnl ******************************
 207 dnl LibGlade checking
 208 dnl ******************************
 209 dnl Ensure gnome-config is available...
 210         AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 211         AC_MSG_CHECKING(for Glade libraries)
 212         if $GNOME_CONFIG --libs libglade > /dev/null 2>&1; then
 213         AC_MSG_RESULT(found)
 214         else
 215             AC_MSG_ERROR(Did not find libGlade installed)
 216         fi
 217
 218     FRONTEND="xforms gnome"
 219     FRONTEND_GUILIB="gnome/*.lo"
 220     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 221     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS) `gnome-config --cflags libglade gnomeui`"
 222     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ \$(GNOMEMM_LIBS) \$(GTKMM_LIBS) `gnome-config --libs libglade gnomeui`";;
 223   qt2)
 224         LYX_PATH_XPM
 225         LYX_PATH_XFORMS
 226     QT2_DO_IT_ALL
 227     FRONTEND="qt2"
 228     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo qt2/xforms/*.lo"
 229     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 230     FRONTEND_INCLUDES="-I\${srcdir}/qt2 -I\${top_srcdir}/src/frontends/xforms \$(QT2_INCLUDES)"
 231     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ \$(QT2_LIBS)";;
 232   *)
 233     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 234 esac
 235
 236 ### Check for xforms and xpm (only if X has been found).
 237 if test "$have_x" = no ; then
 238 # We surely need these two libraries and want to check carefully the
 239 # version numbers...
 240 #LYX_PATH_XPM
 241 #LYX_PATH_XFORMS
 242 #FRONTEND_INFO=`cat <<EOF
 243 #    libXpm version:               ${XPM_VERSION}\n\
 244 #    libforms version:             ${XFORMS_VERSION}\n
 245 #`
 246 #
 247 #AC_SUBST(LYX_LIBS)
 248 #else
 249 LYX_ERROR(dnl
 250 [Cannot find X window libraries and/or headers. Check your installation.
 251    If you use a Linux system, check that you have installed
 252    the development tools.])
 253 fi
 254
 255 ### Check whether the xforms library has a viable image loader
 256 ### For now, run this test always so config.h is unchanged by a change in
 257 ### frontend
 258 LYX_USE_XFORMS_IMAGE_LOADER
 259 LYX_XFORMS_IMAGE_LOADER_NEEDS_JPEG
 260
 261 ### Setup GNU gettext
 262 dnl GNU gettext is written in C
 263 AC_LANG_C
 264 # Some tests that may be useful for gettext
 265 AC_C_CONST
 266 AC_C_INLINE
 267 # Do the real setup now
 268 AM_GNU_GETTEXT
 269 # a hack for those who try to change LyX, but do not have gettext installed
 270 case  "${XGETTEXT}" in
 271  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 272 esac
 273
 274 AC_SUBST(LINGUAS)
 275
 276 AC_LANG_CPLUSPLUS
 277
 278 # some standard header files
 279 AC_HEADER_DIRENT
 280 AC_HEADER_MAJOR
 281 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 282
 283 # some annoying header files
 284 #LYX_PATH_HEADER(stl_string_fwd.h)
 285 LYX_STL_STRING_FWD
 286
 287 # some standard structures
 288 AC_HEADER_STAT
 289 AC_HEADER_TIME
 290 AC_STRUCT_ST_BLKSIZE
 291 AC_STRUCT_ST_BLOCKS
 292 AC_STRUCT_ST_RDEV
 293
 294 # some standard types
 295 AC_TYPE_MODE_T
 296 AC_TYPE_OFF_T
 297 AC_TYPE_PID_T
 298 AC_TYPE_SIGNAL
 299 AC_TYPE_SIZE_T
 300 AC_TYPE_UID_T
 301
 302 # some functions we'd like to have
 303 AC_ARG_WITH(broken-headers,
 304     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 305     [lyx_broken_headers=$withval])
 306 if test "x$lyx_broken_headers" = "xyes"; then
 307   lyx_flags="$lyx_flags broken-headers"
 308   AC_DEFINE(BROKEN_HEADERS, 1,
 309     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 310 fi
 311 AC_CHECK_FUNCS(snprintf vsnprintf)
 312 LYX_CHECK_DECL(snprintf, stdio.h)
 313 LYX_CHECK_DECL(vsnprintf, stdio.h)
 314 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 315
 316 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 317 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 318 dnl We aim to remove this eventually, since we should test as much as
 319 dnl possible with the compiler which will use the functions (JMarc)
 320 AC_LANG_C
 321 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo mkstemp mktemp)
 322 # SunOS 4.1.3 does not have strerror and atexit
 323 AC_REPLACE_FUNCS(strerror atexit)
 324 AC_LANG_CPLUSPLUS
 325
 326 dnl Until this is fixed in autoconf we provide our own version
 327 LYX_FUNC_SELECT_ARGTYPES
 328
 329 dnl check whether we have to work around solaris broken putenv()
 330 LYX_FUNC_PUTENV_ARGTYPE
 331
 332
 333 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 334
 335 ### Some information on what just happened
 336 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 337 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 338 VERSION_INFO=`cat <<EOF
 339 Configuration\n\
 340   Host type:                      ${host_alias}\n\
 341   Special build flags:           ${lyx_flags}\n\
 342   C   Compiler:                   ${CC}\n\
 343   C   Compiler flags:             ${CFLAGS}\n\
 344   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 345   C++ Compiler flags:             ${CXXFLAGS}\n\
 346   Linker flags:                   ${LDFLAGS}\n\
 347   Frontend:                       ${lyx_use_frontend}\n\
 348 ${FRONTEND_INFO}\
 349   LyX binary dir:                 ${real_bindir}\n\
 350   LyX files dir:                  ${real_datadir}\n
 351 `
 352
 353 AC_SUBST(VERSION_INFO)
 354
 355 ### Finish the work.
 356 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 357 AC_OUTPUT([Makefile \
 358        boost/Makefile \
 359        boost/libs/Makefile \
 360        boost/libs/regex/Makefile \
 361        boost/libs/regex/src/Makefile \
 362        config/Makefile \
 363        development/lyx.spec \
 364        lib/Makefile \
 365        intl/Makefile \
 366        po/Makefile.in \
 367        sourcedoc/Doxyfile \
 368        src/Makefile \
 369        src/version.C \
 370        src/mathed/Makefile \
 371        src/graphics/Makefile \
 372        src/insets/Makefile \
 373        src/support/Makefile \
 374        src/frontends/Makefile \
 375        src/frontends/controllers/Makefile \
 376        src/frontends/xforms/Makefile \
 377        src/frontends/xforms/forms/Makefile \
 378        src/frontends/qt2/Makefile \
 379        src/frontends/qt2/xforms/Makefile \
 380        src/frontends/qt2/moc/Makefile \
 381        src/frontends/qt2/ui/Makefile \
 382        src/frontends/qt2/ui/moc/Makefile \
 383        src/frontends/gnome/Makefile \
 384 ])
 385
 386 # show version information
 387 echo
 388 printf "$VERSION_INFO"
 389 echo
 390
 391 # Display a final warning if there has been a LYX_ERROR
 392 LYX_CHECK_ERRORS