configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/lyx.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 LYX_VERSION_SUFFIX
  15
  16 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  17
  18 # The list of languages known to LyX
  19 # This is needed by GNU gettext
  20 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  21
  22 AC_PREFIX_PROGRAM(lyx)
  23
  24 # fix the value of the prefixes.
  25 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  26 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  27
  28 ### Set the execute permissions of the various scripts correctly
  29 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  30   chmod 755 ${srcdir}/${file}
  31 done
  32
  33 ### Check for programs
  34 AC_PROG_MAKE_SET
  35 AC_PROG_INSTALL
  36 #AC_PROG_RANLIB
  37 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  38 if test "x$KPSEWHICH" = xkpsewhich ; then
  39     AC_DEFINE(HAVE_KPSEWHICH, 1,
  40     [Define this if you have the kpsewhich program working on your system.])
  41 fi
  42
  43 # Work around a problem in automake 1.4: when invoking install-strip,
  44 # INSTALL_PROGRAM is changed to 'install -s', and since
  45 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  46 # which returns an error condition when stripping fails.
  47 INSTALL_SCRIPT='${INSTALL}'
  48
  49 ### we will also need a C compiler to compile GNU gettext
  50 AC_PROG_CC
  51
  52 ### check for special systems
  53 AC_ISC_POSIX
  54 AC_AIX
  55 LYX_HPUX
  56 LYX_SUNOS4
  57 LYX_SCO
  58
  59 ### Check for program extensions (.exe or nothing)
  60 AC_EXEEXT
  61
  62 ### check which frontend we want to use
  63 LYX_USE_FRONTEND
  64 dnl The code below is not in a macro, because this would cause big
  65 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  66 case "$lyx_use_frontend" in
  67   gnome)
  68     GNOME_INIT
  69     GNOME_COMPILE_WARNINGS
  70     GNOME_X_CHECKS
  71 esac
  72
  73 ### Check for a C++ compiler
  74 AC_LANG_CPLUSPLUS
  75 LYX_PROG_CXX
  76 AC_PROG_CXXCPP
  77 AC_DISABLE_SHARED
  78 AC_LIBTOOL_WIN32_DLL
  79 AM_PROG_LIBTOOL
  80
  81 ### Some checks on what the C++ compiler can(not) do
  82 LYX_CXX_MUTABLE
  83 LYX_CXX_PARTIAL
  84 LYX_CXX_EXPLICIT
  85 dnl we do not use stl stack, or at least not on gcc 2.7, which was the
  86 dnl cause for this test.
  87 dnl LYX_CXX_STL_STACK
  88 LYX_CXX_STL_STRING
  89 LYX_CXX_GOOD_STD_STRING
  90 LYX_CXX_NAMESPACES
  91 LYX_CXX_CHEADERS
  92 LYX_CXX_GLOBAL_CSTD
  93 LYX_STD_COUNT
  94 dnl we disable rtti for now
  95 dnl LYX_CXX_RTTI
  96 AC_CHECK_HEADERS(ostream istream sstream locale)
  97 LYX_CXX_STL_MODERN_STREAMS
  98
  99 ### We need a regex implementation, so we provide our own if none is found.
 100 LYX_REGEX
 101
 102 ### Library Files
 103 dnl by testing these we check if it is ok to have
 104 dnl -lc and -lm as args to the compiler
 105 AC_CHECK_LIB(m, sin)
 106 AC_CHECK_LIB(c, fopen)
 107
 108 ### Add extra directories to check for libraries.
 109 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 110 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 111 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 112
 113 ### Add extra directories to check for include files.
 114 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 115 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 116 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 117
 118 ### Add both includes and libraries
 119 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 120 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 121 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 122   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 123
 124 ### Check for the -liberty library
 125 test "x$GXX" = xyes && lyx_use_liberty=yes
 126 AC_ARG_WITH(liberty,
 127   [  --without-liberty       do not try to link against libiberty.a],
 128   [lyx_use_liberty=$withval])
 129 if test x$lyx_use_liberty = xyes; then
 130   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 131   AC_CHECK_LIB(iberty,main)
 132 fi
 133
 134 ### Check which libsigc++ we're using
 135 LYX_WITH_SIGC
 136
 137 ### Check if we want pspell libraries
 138 CHECK_WITH_PSPELL
 139
 140 ### Check for X libraries
 141 # Check for the pt library (for SCO, needed for X)
 142 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 143 # The real thing.
 144 AC_PATH_XTRA
 145 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 146 # Since solaris X headers use int as implicit return type and modern
 147 # gcc's do not like that, let's use -isystem instead of -I.
 148 # We should test for gcc version and see whether it supports -isystem,
 149 # but since at least gcc 2.6.x supports it and it is still too old for
 150 # us, it seems we are safe.
 151 if test -n "$GXX" ; then
 152   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 153 fi
 154 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 155
 156 ## Check whether X is new enough to handle the input method stuff
 157 AC_CHECK_FUNCS(XOpenIM)
 158
 159 ### check which frontend we want to use
 160 #LYX_USE_FRONTEND
 161 dnl The code below is not in a macro, because this would cause big
 162 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 163 case "$lyx_use_frontend" in
 164   kde)
 165     KDE_DO_IT_ALL
 166     FRONTEND="kde"
 167     FRONTEND_GUILIB="\${top_builddir}/src/frontends/kde/libkde.la"
 168     FRONTEND_LDFLAGS="\$(QT_LDFLAGS) \$(KDE_LDFLAGS)"
 169     FRONTEND_INCLUDES="-I\${srcdir}/kde \$(QT_INCLUDES) \$(KDE_INCLUDES)"
 170     FRONTEND_LIBS="\$(KDE_LIBS)";;
 171   xforms)
 172   # for now don't set it for xforms as this is always entered
 173     FRONTEND=""
 174     FRONTEND_GUILIB="\${top_builddir}/src/frontends/xforms/libxforms.la";;
 175   gnome)
 176     AM_PATH_GTKMM(1.2.1,,
 177         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 178     AM_PATH_GNOMEMM
 179
 180 dnl ******************************
 181 dnl LibGlade checking
 182 dnl ******************************
 183 dnl Ensure gnome-config is available...
 184         AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 185         AC_MSG_CHECKING(for Glade libraries)
 186         if $GNOME_CONFIG --libs libglade > /dev/null 2>&1; then
 187         AC_MSG_RESULT(found)
 188         else
 189             AC_MSG_ERROR(Did not find libGlade installed)
 190         fi
 191
 192     FRONTEND="gnome"
 193     FRONTEND_GUILIB="\${top_builddir}/src/frontends/gnome/libgnome.la"
 194     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 195     FRONTEND_INCLUDES="-I\${srcdir}/gnome \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 196     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS) `gnome-config --libs libglade`";;
 197   qt2)
 198     QT2_DO_IT_ALL
 199     FRONTEND="qt2"
 200     FRONTEND_GUILIB="\${top_builddir}/src/frontends/qt2/libqt2.la"
 201     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 202     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT2_INCLUDES)"
 203     FRONTEND_LIBS="\$(QT2_LIBS)";;
 204   *)
 205     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 206 esac
 207
 208 ### Check for xforms and xpm (only if X has been found).
 209 if test "$have_x" = yes ; then
 210 # We surely need these two libraries and want to check carefully the
 211 # version numbers...
 212 LYX_PATH_XPM
 213 LYX_PATH_XFORMS
 214 AC_SUBST(LYX_LIBS)
 215 else
 216 LYX_ERROR(dnl
 217 [Cannot find X window libraries and/or headers. Check your installation.
 218    If you use a Linux system, check that you have installed
 219    the development tools.])
 220 fi
 221
 222 ### Setup GNU gettext
 223 dnl GNU gettext is written in C
 224 AC_LANG_C
 225 # Some tests that may be useful for gettext
 226 AC_C_CONST
 227 AC_C_INLINE
 228 # Do the real setup now
 229 AM_GNU_GETTEXT
 230 # a hack for those who try to change LyX, but do not have gettext installed
 231 case  "${XGETTEXT}" in
 232  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 233 esac
 234
 235 AC_SUBST(LINGUAS)
 236
 237 AC_LANG_CPLUSPLUS
 238
 239 # some standard header files
 240 AC_HEADER_DIRENT
 241 AC_HEADER_MAJOR
 242 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 243
 244 # some annoying header files
 245 #LYX_PATH_HEADER(stl_string_fwd.h)
 246 LYX_STL_STRING_FWD
 247
 248 # some standard structures
 249 AC_HEADER_STAT
 250 AC_HEADER_TIME
 251 AC_STRUCT_ST_BLKSIZE
 252 AC_STRUCT_ST_BLOCKS
 253 AC_STRUCT_ST_RDEV
 254
 255 # some standard types
 256 AC_TYPE_MODE_T
 257 AC_TYPE_OFF_T
 258 AC_TYPE_PID_T
 259 AC_TYPE_SIGNAL
 260 AC_TYPE_SIZE_T
 261 AC_TYPE_UID_T
 262
 263 # some functions we'd like to have
 264 AC_ARG_WITH(broken-headers,
 265     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 266     [lyx_broken_headers=$withval])
 267 if test "x$lyx_broken_headers" = "xyes"; then
 268   lyx_flags="$lyx_flags broken-headers"
 269   AC_DEFINE(BROKEN_HEADERS, 1,
 270     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 271 fi
 272 AC_CHECK_FUNCS(snprintf vsnprintf)
 273 LYX_CHECK_DECL(snprintf, stdio.h)
 274 LYX_CHECK_DECL(vsnprintf, stdio.h)
 275
 276 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo \
 277   mkstemp mktemp)
 278
 279 dnl Until this is fixed in autoconf we provide our own version
 280 LYX_FUNC_SELECT_ARGTYPES
 281
 282 dnl check whether we have to work around solaris broken putenv()
 283 LYX_FUNC_PUTENV_ARGTYPE
 284
 285 # SunOS 4.1.3 does not have strerror and atexit
 286 AC_REPLACE_FUNCS(strerror atexit)
 287
 288 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 289
 290 ### and now some special lyx flags.
 291 AC_ARG_ENABLE(assertions,
 292   [  --enable-assertions     add runtime sanity checks in the program],,
 293   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 294         enable_assertions=yes;
 295     else
 296         enable_assertions=no;
 297     fi;])
 298 if test "x$enable_assertions" = xyes ; then
 299    lyx_flags="$lyx_flags assertions"
 300    AC_DEFINE(ENABLE_ASSERTIONS,1,
 301     [Define if you want assertions to be enabled in the code])
 302 fi
 303
 304 ### Finish the work.
 305 AC_CONFIG_SUBDIRS(boost sigc++ lib lib/reLyX)
 306 AC_OUTPUT([Makefile \
 307        development/lyx.spec \
 308        lib/Makefile \
 309        intl/Makefile \
 310        po/Makefile.in \
 311        sourcedoc/Doxyfile \
 312        src/Makefile \
 313        src/mathed/Makefile \
 314        src/graphics/Makefile \
 315        src/insets/Makefile \
 316        src/support/Makefile \
 317        src/frontends/Makefile \
 318        src/frontends/support/Makefile \
 319        src/frontends/controllers/Makefile \
 320        src/frontends/xforms/Makefile \
 321        src/frontends/qt2/Makefile \
 322        src/frontends/kde/Makefile \
 323        src/frontends/kde/moc/Makefile \
 324        src/frontends/kde/dlg/Makefile \
 325        src/frontends/kde/dlg/moc/Makefile \
 326        src/frontends/gnome/Makefile \
 327 ],  [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 328
 329
 330 cat <<EOF
 331
 332 Configuration:
 333   Source code location:       ${srcdir}
 334   C++ Compiler:                   ${CXX}
 335   C++ Compiler flags:             ${CXXFLAGS}
 336   C   Compiler:                   ${CC}
 337   C   Compiler flags:             ${CFLAGS}
 338   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 339   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 340   Special flags:              ${lyx_flags}
 341
 342 EOF
 343
 344 # Display a final warning if there has been a LYX_ERROR
 345 LYX_CHECK_ERRORS