configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/lyx.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 AM_INIT_AUTOMAKE(lyx, $VERSION)
  15
  16 # The list of languages known to LyX
  17 # This is needed by GNU gettext
  18 ALL_LINGUAS="ca cs da de es fi fr hu it nl no pl pt ru sl sv tr wa"
  19
  20 AC_PREFIX_PROGRAM(lyx)
  21
  22 # fix the value of the prefixes.
  23 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  24 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  25
  26 ### Set the execute permissions of the various scripts correctly
  27 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  28   chmod 755 ${srcdir}/${file}
  29 done
  30
  31 ### Check for programs
  32 AC_PROG_MAKE_SET
  33 AC_PROG_INSTALL
  34 #AC_PROG_RANLIB
  35 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  36 if test "x$KPSEWHICH" = xkpsewhich ; then
  37     AC_DEFINE(HAVE_KPSEWHICH, 1,
  38     [Define this if you have the kpsewhich program working on your system.])
  39 fi
  40
  41 ### we will also need a C compiler to compile GNU gettext
  42 AC_PROG_CC
  43
  44 ### check for special systems
  45 AC_ISC_POSIX
  46 AC_AIX
  47 LYX_HPUX
  48 LYX_SUNOS4
  49 LYX_SCO
  50
  51 ### Check for program extensions (.exe or nothing)
  52 AC_EXEEXT
  53
  54 ### Check for a C++ compiler
  55 AC_LANG_CPLUSPLUS
  56 LYX_PROG_CXX
  57 AC_PROG_CXXCPP
  58 AC_DISABLE_SHARED
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 ### check the size of pointers and ints
  63 # the defaults are given for cross compilation.
  64 LYX_CXX_MUTABLE
  65 LYX_CXX_PARTIAL
  66 LYX_CXX_EXPLICIT
  67 dnl we do not use stl stack, or at least not on gcc 2.7, which was the
  68 dnl cause for this test.
  69 dnl LYX_CXX_STL_STACK
  70 LYX_CXX_STL_STRING
  71 LYX_CXX_NAMESPACES
  72 LYX_CXX_CHEADERS
  73 LYX_STD_COUNT
  74 dnl we disable rtti for now
  75 dnl LYX_CXX_RTTI
  76 AC_CHECK_HEADERS(ostream istream)
  77 LYX_CXX_STL_MODERN_STREAMS
  78 LYX_REGEX
  79
  80 ### Library Files
  81 dnl by testing these we check if it is ok to have
  82 dnl -lc and -lm as args to the compiler
  83 AC_CHECK_LIB(m, sin)
  84 AC_CHECK_LIB(c, fopen)
  85
  86 ### Add extra directories to check for libraries.
  87 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  88 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  89 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  90
  91 ### Add extra directories to check for include files.
  92 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
  93 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
  94 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
  95
  96 ### Add both includes and libraries
  97 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
  98 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
  99 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 100   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 101
 102 ### Check for the -liberty library
 103 test "x$GXX" = xyes && lyx_use_liberty=yes
 104 AC_ARG_WITH(liberty,
 105   [  --without-liberty       do not try to link against libiberty.a],
 106   [lyx_use_liberty=$withval])
 107 if test x$lyx_use_liberty = xyes; then
 108   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 109   AC_CHECK_LIB(iberty,main)
 110 fi
 111
 112 ### Check for X libraries
 113 # Check for the pt library (for SCO, needed for X)
 114 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 115 # The real thing.
 116 AC_PATH_XTRA
 117 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 118 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 119
 120 ## Check whether X is new enough to handle the input method stuff
 121 AC_CHECK_FUNCS(XOpenIM)
 122
 123 ### Check for xforms and xpm (only if X has been found).
 124 if test "$have_x" = yes ; then
 125 # We surely need these two libraries and want to check carefully the
 126 # version numbers...
 127 LYX_PATH_XPM
 128 LYX_PATH_XFORMS
 129 AC_SUBST(LYX_LIBS)
 130 else
 131 LYX_ERROR(dnl
 132 [Cannot find X window libraries and/or headers. Check your installation.
 133    If you use a Linux system, check that you have installed
 134    the development tools.])
 135 fi
 136
 137 ### Setup GNU gettext
 138 dnl GNU gettext is written in C
 139 AC_LANG_C
 140 # Some tests that may be useful for gettext
 141 AC_C_CONST
 142 AC_C_INLINE
 143 # Do the real setup now
 144 AM_GNU_GETTEXT
 145 # a hack for those who try to change LyX, but do not have gettext installed
 146 case  "${XGETTEXT}" in
 147  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 148 esac
 149
 150 AC_SUBST(LINGUAS)
 151
 152 AC_LANG_CPLUSPLUS
 153
 154 # some standard header files
 155 AC_HEADER_DIRENT
 156 AC_HEADER_MAJOR
 157 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h)
 158
 159 # some annoying header files
 160 #LYX_PATH_HEADER(stl_string_fwd.h)
 161 LYX_STL_STRING_FWD
 162
 163 # some standard structures
 164 AC_HEADER_STAT
 165 AC_HEADER_TIME
 166 AC_STRUCT_ST_BLKSIZE
 167 AC_STRUCT_ST_BLOCKS
 168 AC_STRUCT_ST_RDEV
 169
 170 # some standard types
 171 AC_TYPE_MODE_T
 172 AC_TYPE_OFF_T
 173 AC_TYPE_PID_T
 174 AC_TYPE_SIGNAL
 175 AC_TYPE_SIZE_T
 176 AC_TYPE_UID_T
 177
 178 # some functions we'd like to have
 179 AC_ARG_WITH(broken-headers,
 180     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 181     [lyx_broken_headers=$withval])
 182 if test "x$lyx_broken_headers" = "xyes"; then
 183   lyx_flags="$lyx_flags broken-headers"
 184   AC_DEFINE(BROKEN_HEADERS, 1,
 185     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 186 fi
 187 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo)
 188
 189 dnl Until this is fixed in autoconf we provide our own version
 190 LYX_FUNC_SELECT_ARGTYPES
 191
 192 dnl check whether we have to work around solaris broken putenv()
 193 LYX_FUNC_PUTENV_ARGTYPE
 194
 195 # SunOS 4.1.3 does not have strerror and atexit
 196 AC_REPLACE_FUNCS(strerror atexit)
 197
 198 ### and now some special lyx flags.
 199 AC_ARG_WITH(two-colors,[  --with-two-colors       use two color pixmaps],
 200   [AC_DEFINE(TWO_COLOR_ICONS,1,
 201      [You might want to define TWO_COLOR_ICONS if you want to spare
 202  your colormap.  This will use monochrome icons instead of colored ones.])
 203    lyx_flags="$lyx_flags two-colors"])
 204 AC_ARG_ENABLE(assertions,
 205   [  --enable-assertions     add runtime sanity checks in the program],,
 206   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 207         enable_assertions=yes;
 208     else
 209         enable_assertions=no;
 210     fi;])
 211 if test "x$enable_assertions" = xyes ; then
 212    lyx_flags="$lyx_flags assertions"
 213    AC_DEFINE(ENABLE_ASSERTIONS,1,
 214     [Define if you want assertions to be enabled in the code])
 215 fi
 216
 217 ### Finish the work.
 218 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 219 AC_OUTPUT([Makefile \
 220        development/lyx.spec \
 221        lib/Makefile \
 222        intl/Makefile \
 223        po/Makefile.in \
 224        src/Makefile \
 225        src/mathed/Makefile \
 226        src/insets/Makefile \
 227        src/support/Makefile \
 228 ],  [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 229
 230
 231 cat <<EOF
 232
 233 Configuration:
 234   Source code location:       ${srcdir}
 235   C++ Compiler:                   ${CXX}
 236   C++ Compiler flags:             ${CXXFLAGS}
 237   C   Compiler:                   ${CC}
 238   C   Compiler flags:             ${CFLAGS}
 239   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 240   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 241   Special flags:              ${lyx_flags}
 242
 243 EOF
 244
 245 # Display a final warning if there has been a LYX_ERROR
 246 LYX_CHECK_ERRORS
 247