configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.3.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### check which frontend we want to use
  65 LYX_USE_FRONTEND
  66
  67 #old gnome stuff removed by Michael Koziarski 25-05-2002
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71 ### Some checks on what the C++ compiler can(not) do
  72 AC_LANG_CPLUSPLUS
  73 dnl we do not need that currently (and probably all our supported
  74 dnl compiler allow that)
  75 dnl LYX_CXX_PARTIAL
  76 LYX_CXX_EXPLICIT
  77 LYX_CXX_STL_STRING
  78 LYX_CXX_GOOD_STD_STRING
  79 LYX_CXX_CHEADERS
  80 LYX_CXX_GLOBAL_CSTD
  81 LYX_STD_COUNT
  82 dnl we disable rtti for now
  83 dnl LYX_CXX_RTTI
  84 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  85 LYX_CXX_STL_MODERN_STREAMS
  86
  87 ### and now some special lyx flags.
  88 AC_ARG_ENABLE(assertions,
  89   [  --enable-assertions     add runtime sanity checks in the program],,
  90   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  91         enable_assertions=yes;
  92     else
  93         enable_assertions=no;
  94     fi;])
  95 if test "x$enable_assertions" = xyes ; then
  96    lyx_flags="$lyx_flags assertions"
  97    AC_DEFINE(ENABLE_ASSERTIONS,1,
  98     [Define if you want assertions to be enabled in the code])
  99 fi
 100
 101 ### We need a regex implementation, so we provide our own if none is found.
 102 LYX_REGEX
 103
 104 ### Library Files
 105 dnl by testing these we check if it is ok to have
 106 dnl -lc and -lm as args to the compiler
 107 AC_CHECK_LIB(m, sin)
 108 AC_CHECK_LIB(c, fopen)
 109 AC_ARG_WITH(aiksaurus,
 110   [  --without-aiksaurus     do not use the Aiksaurus library],
 111   [lyx_use_aiksaurus=$withval])
 112 if test x$lyx_use_aiksaurus != xno; then
 113 AC_CHECK_LIB(Aiksaurus, main,
 114         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 115          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 116         ],,"-lbz2")
 117 fi
 118 AC_SUBST(AIKSAURUS_LIBS)
 119
 120 ### Add extra directories to check for libraries.
 121 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 122 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 123 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 124
 125 ### Add extra directories to check for include files.
 126 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 127 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 128 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 129
 130 ### Add both includes and libraries
 131 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 132 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 133 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 134   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 135
 136 ### Check for the -liberty library
 137 test "x$GXX" = xyes && lyx_use_liberty=yes
 138 AC_ARG_WITH(liberty,
 139   [  --without-liberty       do not try to link against libiberty.a],
 140   [lyx_use_liberty=$withval])
 141 if test x$lyx_use_liberty = xyes; then
 142   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 143   AC_CHECK_LIB(iberty,main)
 144 fi
 145
 146 ### Setup libtool
 147 AC_DISABLE_SHARED
 148 AC_LIBTOOL_WIN32_DLL
 149 #AM_PROG_LIBTOOL
 150 LYX_PROG_LIBTOOL
 151
 152 ### Check which libsigc++ we're using
 153 LYX_WITH_SIGC
 154
 155 ### Check if we want pspell libraries
 156 CHECK_WITH_PSPELL
 157
 158 ### Check for X libraries
 159 # The real thing.
 160 AC_PATH_XTRA
 161 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 162 # Since solaris X headers use int as implicit return type and modern
 163 # gcc's do not like that, let's use -isystem instead of -I.
 164 # We should test for gcc version and see whether it supports -isystem,
 165 # but since at least gcc 2.6.x supports it and it is still too old for
 166 # us, it seems we are safe.
 167 if test -n "$GXX" ; then
 168   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 169 fi
 170 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 171
 172 ## Check whether X is new enough to handle the input method stuff
 173 AC_CHECK_FUNCS(XOpenIM)
 174
 175 ### check which frontend we want to use
 176 #LYX_USE_FRONTEND
 177 dnl The code below is not in a macro, because this would cause big
 178 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 179 case "$lyx_use_frontend" in
 180   xforms)
 181   # for now don't set it for xforms as this is always entered
 182         LYX_PATH_XPM
 183         LYX_PATH_XFORMS
 184         FRONTEND="xforms"
 185         FRONTEND_GUILIB="xforms/*.lo"
 186         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 187         FRONTEND_LIBS="@XFORMS_LIB@ @XPM_LIB@"
 188         FRONTEND_INFO=`cat <<EOF
 189     libXpm version:               ${XPM_VERSION}\n\
 190     libforms version:             ${XFORMS_VERSION}\n
 191 `
 192         ;;
 193   gnome)
 194     LYX_PATH_XPM
 195     LYX_PATH_XFORMS
 196
 197     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 198     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 199     AC_SUBST(GNOME_FRONTEND_LIBS)
 200
 201     FRONTEND="xforms gnome"
 202     FRONTEND_GUILIB="gnome/*.lo"
 203     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 204     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 205     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}";;
 206   qt2)
 207         LYX_PATH_XPM
 208         LYX_PATH_XFORMS
 209     QT2_DO_IT_ALL
 210     FRONTEND="qt2"
 211     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo qt2/xforms/*.lo"
 212     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 213     FRONTEND_INCLUDES="-I\${srcdir}/qt2 -I\${top_srcdir}/src/frontends/xforms \$(QT2_INCLUDES)"
 214     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ \$(QT2_LIBS)";;
 215   *)
 216     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 217 esac
 218
 219 ### Check for xforms and xpm (only if X has been found).
 220 if test "$have_x" = no ; then
 221 # We surely need these two libraries and want to check carefully the
 222 # version numbers...
 223 #LYX_PATH_XPM
 224 #LYX_PATH_XFORMS
 225 #FRONTEND_INFO=`cat <<EOF
 226 #    libXpm version:               ${XPM_VERSION}\n\
 227 #    libforms version:             ${XFORMS_VERSION}\n
 228 #`
 229 #
 230 #AC_SUBST(LYX_LIBS)
 231 #else
 232 LYX_ERROR(dnl
 233 [Cannot find X window libraries and/or headers. Check your installation.
 234    If you use a Linux system, check that you have installed
 235    the development tools.])
 236 fi
 237
 238 ### Check whether the xforms library has a viable image loader
 239 ### For now, run this test always so config.h is unchanged by a change in
 240 ### frontend
 241 LYX_USE_XFORMS_IMAGE_LOADER
 242 LYX_XFORMS_IMAGE_LOADER_NEEDS_JPEG
 243
 244 ### Setup GNU gettext
 245 dnl GNU gettext is written in C
 246 AC_LANG_C
 247 # Some tests that may be useful for gettext
 248 AC_C_CONST
 249 AC_C_INLINE
 250 # Do the real setup now
 251 AM_GNU_GETTEXT
 252 # a hack for those who try to change LyX, but do not have gettext installed
 253 case  "${XGETTEXT}" in
 254  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 255 esac
 256
 257 AC_SUBST(LINGUAS)
 258
 259 AC_LANG_CPLUSPLUS
 260
 261 # some standard header files
 262 AC_HEADER_DIRENT
 263 AC_HEADER_MAJOR
 264 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 265
 266 # some annoying header files
 267 #LYX_PATH_HEADER(stl_string_fwd.h)
 268 LYX_STL_STRING_FWD
 269
 270 # some standard structures
 271 AC_HEADER_STAT
 272 AC_HEADER_TIME
 273 AC_STRUCT_ST_BLKSIZE
 274 AC_STRUCT_ST_BLOCKS
 275 AC_STRUCT_ST_RDEV
 276
 277 # some standard types
 278 AC_TYPE_MODE_T
 279 AC_TYPE_OFF_T
 280 AC_TYPE_PID_T
 281 AC_TYPE_SIGNAL
 282 AC_TYPE_SIZE_T
 283 AC_TYPE_UID_T
 284
 285 # some functions we'd like to have
 286 AC_ARG_WITH(broken-headers,
 287     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 288     [lyx_broken_headers=$withval])
 289 if test "x$lyx_broken_headers" = "xyes"; then
 290   lyx_flags="$lyx_flags broken-headers"
 291   AC_DEFINE(BROKEN_HEADERS, 1,
 292     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 293 fi
 294 AC_CHECK_FUNCS(snprintf vsnprintf)
 295 LYX_CHECK_DECL(snprintf, stdio.h)
 296 LYX_CHECK_DECL(vsnprintf, stdio.h)
 297 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 298
 299 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 300 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 301 dnl We aim to remove this eventually, since we should test as much as
 302 dnl possible with the compiler which will use the functions (JMarc)
 303 AC_LANG_C
 304 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo mkstemp mktemp)
 305 # SunOS 4.1.3 does not have strerror and atexit
 306 AC_REPLACE_FUNCS(strerror atexit)
 307 AC_LANG_CPLUSPLUS
 308
 309 dnl Until this is fixed in autoconf we provide our own version
 310 LYX_FUNC_SELECT_ARGTYPES
 311
 312 dnl check whether we have to work around solaris broken putenv()
 313 LYX_FUNC_PUTENV_ARGTYPE
 314
 315
 316 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 317
 318 ### Some information on what just happened
 319 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 320 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 321 VERSION_INFO=`cat <<EOF
 322 Configuration\n\
 323   Host type:                      ${host_alias}\n\
 324   Special build flags:           ${lyx_flags}\n\
 325   C   Compiler:                   ${CC}\n\
 326   C   Compiler flags:             ${CFLAGS}\n\
 327   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 328   C++ Compiler flags:             ${CXXFLAGS}\n\
 329   Linker flags:                   ${LDFLAGS}\n\
 330   Frontend:                       ${lyx_use_frontend}\n\
 331 ${FRONTEND_INFO}\
 332   LyX binary dir:                 ${real_bindir}\n\
 333   LyX files dir:                  ${real_datadir}\n
 334 `
 335
 336 AC_SUBST(VERSION_INFO)
 337
 338 ### Finish the work.
 339 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 340 AC_OUTPUT([Makefile \
 341        boost/Makefile \
 342        boost/libs/Makefile \
 343        boost/libs/regex/Makefile \
 344        boost/libs/regex/src/Makefile \
 345        boost/libs/signals/Makefile \
 346        boost/libs/signals/src/Makefile \
 347        config/Makefile \
 348        development/lyx.spec \
 349        lib/Makefile \
 350        intl/Makefile \
 351        po/Makefile.in \
 352        sourcedoc/Doxyfile \
 353        src/Makefile \
 354        src/version.C \
 355        src/mathed/Makefile \
 356        src/graphics/Makefile \
 357        src/insets/Makefile \
 358        src/support/Makefile \
 359        src/frontends/Makefile \
 360        src/frontends/controllers/Makefile \
 361        src/frontends/xforms/Makefile \
 362        src/frontends/xforms/forms/Makefile \
 363        src/frontends/qt2/Makefile \
 364        src/frontends/qt2/xforms/Makefile \
 365        src/frontends/qt2/moc/Makefile \
 366        src/frontends/qt2/ui/Makefile \
 367        src/frontends/qt2/ui/moc/Makefile \
 368        src/frontends/gnome/Makefile \
 369 ])
 370
 371 # show version information
 372 echo
 373 printf "$VERSION_INFO"
 374 echo
 375
 376 # Display a final warning if there has been a LYX_ERROR
 377 LYX_CHECK_ERRORS