configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.2.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43
  44 # Work around a problem in automake 1.4: when invoking install-strip,
  45 # INSTALL_PROGRAM is changed to 'install -s', and since
  46 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  47 # which returns an error condition when stripping fails.
  48 INSTALL_SCRIPT='${INSTALL}'
  49
  50 ### we will also need a C compiler to compile GNU gettext
  51 AC_PROG_CC
  52
  53 ### check for special systems
  54 AC_ISC_POSIX
  55 AC_AIX
  56 LYX_HPUX
  57 LYX_SUNOS4
  58 LYX_SCO
  59
  60 ### Check for program extensions (.exe or nothing)
  61 AC_EXEEXT
  62
  63 ### check which frontend we want to use
  64 LYX_USE_FRONTEND
  65 dnl The code below is not in a macro, because this would cause big
  66 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  67 case "$lyx_use_frontend" in
  68   gnome)
  69     GNOME_INIT
  70     GNOME_COMPILE_WARNINGS
  71     GNOME_X_CHECKS
  72 esac
  73
  74 ### Check for a C++ compiler
  75 LYX_PROG_CXX
  76 ### Some checks on what the C++ compiler can(not) do
  77 AC_LANG_CPLUSPLUS
  78 dnl we do not need that currently (and probably all our supported
  79 dnl compiler allow that)
  80 dnl LYX_CXX_PARTIAL
  81 LYX_CXX_EXPLICIT
  82 LYX_CXX_STL_STRING
  83 LYX_CXX_GOOD_STD_STRING
  84 LYX_CXX_CHEADERS
  85 LYX_CXX_GLOBAL_CSTD
  86 LYX_STD_COUNT
  87 dnl we disable rtti for now
  88 dnl LYX_CXX_RTTI
  89 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  90 LYX_CXX_STL_MODERN_STREAMS
  91
  92 ### and now some special lyx flags.
  93 AC_ARG_ENABLE(assertions,
  94   [  --enable-assertions     add runtime sanity checks in the program],,
  95   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  96         enable_assertions=yes;
  97     else
  98         enable_assertions=no;
  99     fi;])
 100 if test "x$enable_assertions" = xyes ; then
 101    lyx_flags="$lyx_flags assertions"
 102    AC_DEFINE(ENABLE_ASSERTIONS,1,
 103     [Define if you want assertions to be enabled in the code])
 104 fi
 105
 106 ### We need a regex implementation, so we provide our own if none is found.
 107 LYX_REGEX
 108
 109 ### Library Files
 110 dnl by testing these we check if it is ok to have
 111 dnl -lc and -lm as args to the compiler
 112 AC_CHECK_LIB(m, sin)
 113 AC_CHECK_LIB(c, fopen)
 114 AC_ARG_WITH(aiksaurus,
 115   [  --without-aiksaurus     do not use the Aiksaurus library],
 116   [lyx_use_aiksaurus=$withval])
 117 if test x$lyx_use_aiksaurus != xno; then
 118 AC_CHECK_LIB(Aiksaurus, main,
 119         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 120          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 121         ],,"-lbz2")
 122 fi
 123 AC_SUBST(AIKSAURUS_LIBS)
 124
 125 ### Add extra directories to check for libraries.
 126 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 127 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 128 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 129
 130 ### Add extra directories to check for include files.
 131 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 132 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 133 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 134
 135 ### Add both includes and libraries
 136 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 137 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 138 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 139   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 140
 141 ### Check for the -liberty library
 142 test "x$GXX" = xyes && lyx_use_liberty=yes
 143 AC_ARG_WITH(liberty,
 144   [  --without-liberty       do not try to link against libiberty.a],
 145   [lyx_use_liberty=$withval])
 146 if test x$lyx_use_liberty = xyes; then
 147   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 148   AC_CHECK_LIB(iberty,main)
 149 fi
 150
 151 ### Setup libtool
 152 AC_DISABLE_SHARED
 153 AC_LIBTOOL_WIN32_DLL
 154 #AM_PROG_LIBTOOL
 155 LYX_PROG_LIBTOOL
 156
 157 ### Check which libsigc++ we're using
 158 LYX_WITH_SIGC
 159
 160 ### Check if we want pspell libraries
 161 CHECK_WITH_PSPELL
 162
 163 ### Check for X libraries
 164 dnl # Check for the pt library (for SCO, needed for X)
 165 dnl AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 166 # The real thing.
 167 AC_PATH_XTRA
 168 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 169 # Since solaris X headers use int as implicit return type and modern
 170 # gcc's do not like that, let's use -isystem instead of -I.
 171 # We should test for gcc version and see whether it supports -isystem,
 172 # but since at least gcc 2.6.x supports it and it is still too old for
 173 # us, it seems we are safe.
 174 if test -n "$GXX" ; then
 175   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 176 fi
 177 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 178
 179 ## Check whether X is new enough to handle the input method stuff
 180 AC_CHECK_FUNCS(XOpenIM)
 181
 182 ### check which frontend we want to use
 183 #LYX_USE_FRONTEND
 184 dnl The code below is not in a macro, because this would cause big
 185 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 186 case "$lyx_use_frontend" in
 187   xforms)
 188   # for now don't set it for xforms as this is always entered
 189         LYX_PATH_XPM
 190         LYX_PATH_XFORMS
 191         FRONTEND="xforms"
 192         FRONTEND_GUILIB="xforms/*.lo"
 193         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 194         FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@"
 195         FRONTEND_INFO=`cat <<EOF
 196     libXpm version:               ${XPM_VERSION}\n\
 197     libforms version:             ${XFORMS_VERSION}\n
 198 `
 199         ;;
 200   gnome)
 201     LYX_PATH_XPM
 202     LYX_PATH_XFORMS
 203     AM_PATH_GTKMM(1.2.1,,
 204         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 205     AM_PATH_GNOMEMM
 206
 207 dnl ******************************
 208 dnl LibGlade checking
 209 dnl ******************************
 210 dnl Ensure gnome-config is available...
 211         AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 212         AC_MSG_CHECKING(for Glade libraries)
 213         if $GNOME_CONFIG --libs libglade > /dev/null 2>&1; then
 214         AC_MSG_RESULT(found)
 215         else
 216             AC_MSG_ERROR(Did not find libGlade installed)
 217         fi
 218
 219     FRONTEND="xforms gnome"
 220     FRONTEND_GUILIB="gnome/*.lo"
 221     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 222     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS) `gnome-config --cflags libglade gnomeui`"
 223     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ \$(GNOMEMM_LIBS) \$(GTKMM_LIBS) `gnome-config --libs libglade gnomeui`";;
 224   qt2)
 225         LYX_PATH_XPM
 226         LYX_PATH_XFORMS
 227     QT2_DO_IT_ALL
 228     FRONTEND="qt2"
 229     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo"
 230     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 231     FRONTEND_INCLUDES="-I\${srcdir}/qt2 -I\${top_srcdir}/src/frontends/xforms \$(QT2_INCLUDES)"
 232     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ \$(QT2_LIBS)";;
 233   *)
 234     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 235 esac
 236
 237 ### Check for xforms and xpm (only if X has been found).
 238 if test "$have_x" = no ; then
 239 # We surely need these two libraries and want to check carefully the
 240 # version numbers...
 241 #LYX_PATH_XPM
 242 #LYX_PATH_XFORMS
 243 #FRONTEND_INFO=`cat <<EOF
 244 #    libXpm version:               ${XPM_VERSION}\n\
 245 #    libforms version:             ${XFORMS_VERSION}\n
 246 #`
 247 #
 248 #AC_SUBST(LYX_LIBS)
 249 #else
 250 LYX_ERROR(dnl
 251 [Cannot find X window libraries and/or headers. Check your installation.
 252    If you use a Linux system, check that you have installed
 253    the development tools.])
 254 fi
 255
 256 ### Check whether the xforms library has a viable image loader
 257 ### For now, run this test always so config.h is unchanged by a change in
 258 ### frontend
 259 LYX_USE_XFORMS_IMAGE_LOADER
 260
 261 ### If the gui cannot load images itself, then we default to the
 262 ### very simple one in graphics/GraphicsImageXPM.[Ch]
 263 AM_CONDITIONAL(USE_BASIC_IMAGE_LOADER,
 264                test x$lyx_use_xforms_image_loader = xno)
 265
 266 ### Setup GNU gettext
 267 dnl GNU gettext is written in C
 268 AC_LANG_C
 269 # Some tests that may be useful for gettext
 270 AC_C_CONST
 271 AC_C_INLINE
 272 # Do the real setup now
 273 AM_GNU_GETTEXT
 274 # a hack for those who try to change LyX, but do not have gettext installed
 275 case  "${XGETTEXT}" in
 276  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 277 esac
 278
 279 AC_SUBST(LINGUAS)
 280
 281 AC_LANG_CPLUSPLUS
 282
 283 # some standard header files
 284 AC_HEADER_DIRENT
 285 AC_HEADER_MAJOR
 286 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 287
 288 # some annoying header files
 289 #LYX_PATH_HEADER(stl_string_fwd.h)
 290 LYX_STL_STRING_FWD
 291
 292 # some standard structures
 293 AC_HEADER_STAT
 294 AC_HEADER_TIME
 295 AC_STRUCT_ST_BLKSIZE
 296 AC_STRUCT_ST_BLOCKS
 297 AC_STRUCT_ST_RDEV
 298
 299 # some standard types
 300 AC_TYPE_MODE_T
 301 AC_TYPE_OFF_T
 302 AC_TYPE_PID_T
 303 AC_TYPE_SIGNAL
 304 AC_TYPE_SIZE_T
 305 AC_TYPE_UID_T
 306
 307 # some functions we'd like to have
 308 AC_ARG_WITH(broken-headers,
 309     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 310     [lyx_broken_headers=$withval])
 311 if test "x$lyx_broken_headers" = "xyes"; then
 312   lyx_flags="$lyx_flags broken-headers"
 313   AC_DEFINE(BROKEN_HEADERS, 1,
 314     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 315 fi
 316 AC_CHECK_FUNCS(snprintf vsnprintf)
 317 LYX_CHECK_DECL(snprintf, stdio.h)
 318 LYX_CHECK_DECL(vsnprintf, stdio.h)
 319 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 320
 321 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo \
 322   mkstemp mktemp)
 323
 324 dnl Until this is fixed in autoconf we provide our own version
 325 LYX_FUNC_SELECT_ARGTYPES
 326
 327 dnl check whether we have to work around solaris broken putenv()
 328 LYX_FUNC_PUTENV_ARGTYPE
 329
 330 # SunOS 4.1.3 does not have strerror and atexit
 331 AC_REPLACE_FUNCS(strerror atexit)
 332
 333 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 334
 335 ### Some information on what just happened
 336 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 337 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 338 VERSION_INFO=`cat <<EOF
 339 Configuration\n\
 340   Host type:                      ${host_alias}\n\
 341   Special build flags:           ${lyx_flags}\n\
 342   C   Compiler:                   ${CC}\n\
 343   C   Compiler flags:             ${CFLAGS}\n\
 344   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 345   C++ Compiler flags:             ${CXXFLAGS}\n\
 346   Linker flags:                   ${LDFLAGS}\n\
 347   Frontend:                       ${lyx_use_frontend}\n\
 348 ${FRONTEND_INFO}\
 349   LyX binary dir:                 ${real_bindir}\n\
 350   LyX files dir:                  ${real_datadir}\n
 351 `
 352
 353 AC_SUBST(VERSION_INFO)
 354
 355 ### Finish the work.
 356 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 357 AC_OUTPUT([Makefile \
 358        boost/Makefile \
 359        development/lyx.spec \
 360        lib/Makefile \
 361        intl/Makefile \
 362        po/Makefile.in \
 363        sourcedoc/Doxyfile \
 364        src/Makefile \
 365        src/version.C \
 366        src/mathed/Makefile \
 367        src/graphics/Makefile \
 368        src/insets/Makefile \
 369        src/support/Makefile \
 370        src/frontends/Makefile \
 371        src/frontends/controllers/Makefile \
 372        src/frontends/xforms/Makefile \
 373        src/frontends/qt2/Makefile \
 374        src/frontends/qt2/xforms/Makefile \
 375        src/frontends/qt2/moc/Makefile \
 376        src/frontends/qt2/ui/Makefile \
 377        src/frontends/qt2/ui/moc/Makefile \
 378        src/frontends/gnome/Makefile \
 379 ])
 380
 381 # show version information
 382 echo
 383 printf "$VERSION_INFO"
 384 echo
 385
 386 # Display a final warning if there has been a LYX_ERROR
 387 LYX_CHECK_ERRORS