configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/lyx.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 AC_ARG_WITH(lyxname,
  15   [  --with-lyxname          the name under which lyx will be installed],
  16   [lyxname=$withval],[lyxname=lyx])
  17
  18 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  19
  20 # The list of languages known to LyX
  21 # This is needed by GNU gettext
  22 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  23
  24 AC_PREFIX_PROGRAM(lyx)
  25
  26 # fix the value of the prefixes.
  27 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  28 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  29
  30 ### Set the execute permissions of the various scripts correctly
  31 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  32   chmod 755 ${srcdir}/${file}
  33 done
  34
  35 ### Check for programs
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 #AC_PROG_RANLIB
  39 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  40 if test "x$KPSEWHICH" = xkpsewhich ; then
  41     AC_DEFINE(HAVE_KPSEWHICH, 1,
  42     [Define this if you have the kpsewhich program working on your system.])
  43 fi
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### check which frontend we want to use
  65 LYX_USE_FRONTEND
  66 dnl The code below is not in a macro, because this would cause big
  67 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  68 case "$lyx_use_frontend" in
  69   gnome)
  70     GNOME_INIT
  71     GNOME_COMPILE_WARNINGS
  72     GNOME_X_CHECKS
  73 esac
  74
  75 ### Check for a C++ compiler
  76 AC_LANG_CPLUSPLUS
  77 LYX_PROG_CXX
  78 AC_PROG_CXXCPP
  79 AC_DISABLE_SHARED
  80 AC_LIBTOOL_WIN32_DLL
  81 AM_PROG_LIBTOOL
  82
  83 ### Some checks on what the C++ compiler can(not) do
  84 LYX_CXX_MUTABLE
  85 LYX_CXX_PARTIAL
  86 LYX_CXX_EXPLICIT
  87 dnl we do not use stl stack, or at least not on gcc 2.7, which was the
  88 dnl cause for this test.
  89 dnl LYX_CXX_STL_STACK
  90 LYX_CXX_STL_STRING
  91 LYX_CXX_GOOD_STD_STRING
  92 LYX_CXX_NAMESPACES
  93 LYX_CXX_CHEADERS
  94 LYX_CXX_GLOBAL_CSTD
  95 LYX_STD_COUNT
  96 dnl we disable rtti for now
  97 dnl LYX_CXX_RTTI
  98 AC_CHECK_HEADERS(ostream istream sstream locale)
  99 LYX_CXX_STL_MODERN_STREAMS
 100
 101 ### We need a regex implementation, so we provide our own if none is found.
 102 LYX_REGEX
 103
 104 ### Library Files
 105 dnl by testing these we check if it is ok to have
 106 dnl -lc and -lm as args to the compiler
 107 AC_CHECK_LIB(m, sin)
 108 AC_CHECK_LIB(c, fopen)
 109
 110 ### Add extra directories to check for libraries.
 111 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 112 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 113 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 114
 115 ### Add extra directories to check for include files.
 116 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 117 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 118 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 119
 120 ### Add both includes and libraries
 121 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 122 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 123 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 124   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 125
 126 ### Check for the -liberty library
 127 test "x$GXX" = xyes && lyx_use_liberty=yes
 128 AC_ARG_WITH(liberty,
 129   [  --without-liberty       do not try to link against libiberty.a],
 130   [lyx_use_liberty=$withval])
 131 if test x$lyx_use_liberty = xyes; then
 132   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 133   AC_CHECK_LIB(iberty,main)
 134 fi
 135
 136 ### Check which libsigc++ we're using
 137 LYX_WITH_SIGC
 138
 139 ### Check if we want pspell libraries
 140 CHECK_WITH_PSPELL
 141
 142 ### Check for X libraries
 143 # Check for the pt library (for SCO, needed for X)
 144 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 145 # The real thing.
 146 AC_PATH_XTRA
 147 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 148 # Since solaris X headers use int as implicit return type and modern
 149 # gcc's do not like that, let's use -isystem instead of -I.
 150 # We should test for gcc version and see whether it supports -isystem,
 151 # but since at least gcc 2.6.x supports it and it is still too old for
 152 # us, it seems we are safe.
 153 if test -n "$GXX" ; then
 154   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 155 fi
 156 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 157
 158 ## Check whether X is new enough to handle the input method stuff
 159 AC_CHECK_FUNCS(XOpenIM)
 160
 161 ### check which frontend we want to use
 162 #LYX_USE_FRONTEND
 163 dnl The code below is not in a macro, because this would cause big
 164 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 165 case "$lyx_use_frontend" in
 166   kde)
 167     KDE_DO_IT_ALL
 168     FRONTEND="kde"
 169     FRONTEND_GUILIB="\${top_builddir}/src/frontends/kde/libkde.la"
 170     FRONTEND_LDFLAGS="\$(QT_LDFLAGS) \$(KDE_LDFLAGS)"
 171     FRONTEND_INCLUDES="-I\${srcdir}/kde \$(QT_INCLUDES) \$(KDE_INCLUDES)"
 172     FRONTEND_LIBS="\$(KDE_LIBS)";;
 173   xforms)
 174   # for now don't set it for xforms as this is always entered
 175     FRONTEND=""
 176     FRONTEND_GUILIB="\${top_builddir}/src/frontends/xforms/libxforms.la";;
 177   gnome)
 178     AM_PATH_GTKMM(1.2.1,,
 179         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 180     AM_PATH_GNOMEMM
 181
 182     FRONTEND="gnome"
 183     FRONTEND_GUILIB="\${top_builddir}/src/frontends/gnome/libgnome.la"
 184     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 185     FRONTEND_INCLUDES="-I\${srcdir}/gnome \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 186     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS)";;
 187   *)
 188     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 189 esac
 190
 191 ### Check for xforms and xpm (only if X has been found).
 192 if test "$have_x" = yes ; then
 193 # We surely need these two libraries and want to check carefully the
 194 # version numbers...
 195 LYX_PATH_XPM
 196 LYX_PATH_XFORMS
 197 AC_SUBST(LYX_LIBS)
 198 else
 199 LYX_ERROR(dnl
 200 [Cannot find X window libraries and/or headers. Check your installation.
 201    If you use a Linux system, check that you have installed
 202    the development tools.])
 203 fi
 204
 205 ### Setup GNU gettext
 206 dnl GNU gettext is written in C
 207 AC_LANG_C
 208 # Some tests that may be useful for gettext
 209 AC_C_CONST
 210 AC_C_INLINE
 211 # Do the real setup now
 212 AM_GNU_GETTEXT
 213 # a hack for those who try to change LyX, but do not have gettext installed
 214 case  "${XGETTEXT}" in
 215  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 216 esac
 217
 218 AC_SUBST(LINGUAS)
 219
 220 AC_LANG_CPLUSPLUS
 221
 222 # some standard header files
 223 AC_HEADER_DIRENT
 224 AC_HEADER_MAJOR
 225 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 226
 227 # some annoying header files
 228 #LYX_PATH_HEADER(stl_string_fwd.h)
 229 LYX_STL_STRING_FWD
 230
 231 # some standard structures
 232 AC_HEADER_STAT
 233 AC_HEADER_TIME
 234 AC_STRUCT_ST_BLKSIZE
 235 AC_STRUCT_ST_BLOCKS
 236 AC_STRUCT_ST_RDEV
 237
 238 # some standard types
 239 AC_TYPE_MODE_T
 240 AC_TYPE_OFF_T
 241 AC_TYPE_PID_T
 242 AC_TYPE_SIGNAL
 243 AC_TYPE_SIZE_T
 244 AC_TYPE_UID_T
 245
 246 # some functions we'd like to have
 247 AC_ARG_WITH(broken-headers,
 248     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 249     [lyx_broken_headers=$withval])
 250 if test "x$lyx_broken_headers" = "xyes"; then
 251   lyx_flags="$lyx_flags broken-headers"
 252   AC_DEFINE(BROKEN_HEADERS, 1,
 253     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 254 fi
 255 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo snprintf vsnprintf)
 256 AC_CHECK_FUNCS(mkstemp mktemp)
 257
 258 dnl Until this is fixed in autoconf we provide our own version
 259 LYX_FUNC_SELECT_ARGTYPES
 260
 261 dnl check whether we have to work around solaris broken putenv()
 262 LYX_FUNC_PUTENV_ARGTYPE
 263
 264 # SunOS 4.1.3 does not have strerror and atexit
 265 AC_REPLACE_FUNCS(strerror atexit)
 266
 267 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 268
 269 ### and now some special lyx flags.
 270 AC_ARG_ENABLE(assertions,
 271   [  --enable-assertions     add runtime sanity checks in the program],,
 272   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 273         enable_assertions=yes;
 274     else
 275         enable_assertions=no;
 276     fi;])
 277 if test "x$enable_assertions" = xyes ; then
 278    lyx_flags="$lyx_flags assertions"
 279    AC_DEFINE(ENABLE_ASSERTIONS,1,
 280     [Define if you want assertions to be enabled in the code])
 281 fi
 282
 283 ### Finish the work.
 284 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 285 AC_OUTPUT([Makefile \
 286        development/lyx.spec \
 287        lib/Makefile \
 288        intl/Makefile \
 289        po/Makefile.in \
 290        boost/Makefile \
 291        src/Makefile \
 292        src/mathed/Makefile \
 293        src/graphics/Makefile \
 294        src/insets/Makefile \
 295        src/support/Makefile \
 296        src/frontends/Makefile \
 297        src/frontends/support/Makefile \
 298        src/frontends/xforms/Makefile \
 299        src/frontends/kde/Makefile \
 300        src/frontends/gnome/Makefile \
 301 ],  [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 302
 303
 304 cat <<EOF
 305
 306 Configuration:
 307   Source code location:       ${srcdir}
 308   C++ Compiler:                   ${CXX}
 309   C++ Compiler flags:             ${CXXFLAGS}
 310   C   Compiler:                   ${CC}
 311   C   Compiler flags:             ${CFLAGS}
 312   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 313   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 314   Special flags:              ${lyx_flags}
 315
 316 EOF
 317
 318 # Display a final warning if there has been a LYX_ERROR
 319 LYX_CHECK_ERRORS