configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.2.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  24
  25 AC_PREFIX_PROGRAM(lyx)
  26
  27 # fix the value of the prefixes.
  28 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  29 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  30
  31 ### Set the execute permissions of the various scripts correctly
  32 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  33   chmod 755 ${srcdir}/${file}
  34 done
  35
  36 ### Check for programs
  37 AC_PROG_MAKE_SET
  38 AC_PROG_INSTALL
  39 #AC_PROG_RANLIB
  40 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  41 if test "x$KPSEWHICH" = xkpsewhich ; then
  42     AC_DEFINE(HAVE_KPSEWHICH, 1,
  43     [Define this if you have the kpsewhich program working on your system.])
  44 fi
  45
  46 # Work around a problem in automake 1.4: when invoking install-strip,
  47 # INSTALL_PROGRAM is changed to 'install -s', and since
  48 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  49 # which returns an error condition when stripping fails.
  50 INSTALL_SCRIPT='${INSTALL}'
  51
  52 ### we will also need a C compiler to compile GNU gettext
  53 AC_PROG_CC
  54
  55 ### check for special systems
  56 AC_ISC_POSIX
  57 AC_AIX
  58 LYX_HPUX
  59 LYX_SUNOS4
  60 LYX_SCO
  61
  62 ### Check for program extensions (.exe or nothing)
  63 AC_EXEEXT
  64
  65 ### check which frontend we want to use
  66 LYX_USE_FRONTEND
  67 dnl The code below is not in a macro, because this would cause big
  68 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  69 case "$lyx_use_frontend" in
  70   gnome)
  71     GNOME_INIT
  72     GNOME_COMPILE_WARNINGS
  73     GNOME_X_CHECKS
  74 esac
  75
  76 ### Check for a C++ compiler
  77 LYX_PROG_CXX
  78 ### Some checks on what the C++ compiler can(not) do
  79 AC_LANG_CPLUSPLUS
  80 dnl we do not need that currently (and probably all our supported
  81 dnl compiler allow that)
  82 dnl LYX_CXX_PARTIAL
  83 LYX_CXX_EXPLICIT
  84 LYX_CXX_STL_STRING
  85 LYX_CXX_GOOD_STD_STRING
  86 LYX_CXX_CHEADERS
  87 LYX_CXX_GLOBAL_CSTD
  88 LYX_STD_COUNT
  89 dnl we disable rtti for now
  90 dnl LYX_CXX_RTTI
  91 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  92 LYX_CXX_STL_MODERN_STREAMS
  93
  94 ### and now some special lyx flags.
  95 AC_ARG_ENABLE(assertions,
  96   [  --enable-assertions     add runtime sanity checks in the program],,
  97   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  98         enable_assertions=yes;
  99     else
 100         enable_assertions=no;
 101     fi;])
 102 if test "x$enable_assertions" = xyes ; then
 103    lyx_flags="$lyx_flags assertions"
 104    AC_DEFINE(ENABLE_ASSERTIONS,1,
 105     [Define if you want assertions to be enabled in the code])
 106 fi
 107
 108 ### We need a regex implementation, so we provide our own if none is found.
 109 LYX_REGEX
 110
 111 ### Library Files
 112 dnl by testing these we check if it is ok to have
 113 dnl -lc and -lm as args to the compiler
 114 AC_CHECK_LIB(m, sin)
 115 AC_CHECK_LIB(c, fopen)
 116 AC_ARG_WITH(aiksaurus,
 117   [  --without-aiksaurus     do not use the AikSaurus library],
 118   [lyx_use_aiksaurus=$withval])
 119 if test x$lyx_use_aiksaurus != xno; then
 120 AC_CHECK_LIB(AikSaurus, main,
 121         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 122          AIKSAURUS_LIBS="-lAikSaurus -lbz2"
 123         ],,"-lbz2")
 124 fi
 125 AC_SUBST(AIKSAURUS_LIBS)
 126
 127 ### Add extra directories to check for libraries.
 128 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 129 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 130 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 131
 132 ### Add extra directories to check for include files.
 133 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 134 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 135 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 136
 137 ### Add both includes and libraries
 138 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 139 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 140 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 141   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 142
 143 ### Check for the -liberty library
 144 test "x$GXX" = xyes && lyx_use_liberty=yes
 145 AC_ARG_WITH(liberty,
 146   [  --without-liberty       do not try to link against libiberty.a],
 147   [lyx_use_liberty=$withval])
 148 if test x$lyx_use_liberty = xyes; then
 149   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 150   AC_CHECK_LIB(iberty,main)
 151 fi
 152
 153 ### Setup libtool
 154 AC_DISABLE_SHARED
 155 AC_LIBTOOL_WIN32_DLL
 156 #AM_PROG_LIBTOOL
 157 LYX_PROG_LIBTOOL
 158
 159 ### Check which libsigc++ we're using
 160 LYX_WITH_SIGC
 161
 162 ### Check if we want pspell libraries
 163 CHECK_WITH_PSPELL
 164
 165 ### Check for X libraries
 166 # Check for the pt library (for SCO, needed for X)
 167 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 168 # The real thing.
 169 AC_PATH_XTRA
 170 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 171 # Since solaris X headers use int as implicit return type and modern
 172 # gcc's do not like that, let's use -isystem instead of -I.
 173 # We should test for gcc version and see whether it supports -isystem,
 174 # but since at least gcc 2.6.x supports it and it is still too old for
 175 # us, it seems we are safe.
 176 if test -n "$GXX" ; then
 177   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 178 fi
 179 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 180
 181 ## Check whether X is new enough to handle the input method stuff
 182 AC_CHECK_FUNCS(XOpenIM)
 183
 184 ### check which frontend we want to use
 185 #LYX_USE_FRONTEND
 186 dnl The code below is not in a macro, because this would cause big
 187 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 188 case "$lyx_use_frontend" in
 189   xforms)
 190   # for now don't set it for xforms as this is always entered
 191     FRONTEND=""
 192     FRONTEND_GUILIB="xforms/libxforms.la";;
 193   gnome)
 194     AM_PATH_GTKMM(1.2.1,,
 195         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 196     AM_PATH_GNOMEMM
 197
 198 dnl ******************************
 199 dnl LibGlade checking
 200 dnl ******************************
 201 dnl Ensure gnome-config is available...
 202         AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 203         AC_MSG_CHECKING(for Glade libraries)
 204         if $GNOME_CONFIG --libs libglade > /dev/null 2>&1; then
 205         AC_MSG_RESULT(found)
 206         else
 207             AC_MSG_ERROR(Did not find libGlade installed)
 208         fi
 209
 210     FRONTEND="gnome"
 211     FRONTEND_GUILIB="gnome/libgnome.la"
 212     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 213     FRONTEND_INCLUDES="-I\${srcdir}/gnome \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 214     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS) `gnome-config --libs libglade`";;
 215   qt2)
 216     QT2_DO_IT_ALL
 217     FRONTEND="qt2"
 218     FRONTEND_GUILIB="qt2/libqt2.la"
 219     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 220     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT2_INCLUDES)"
 221     FRONTEND_LIBS="\$(QT2_LIBS)";;
 222   *)
 223     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 224 esac
 225
 226 ### Check for xforms and xpm (only if X has been found).
 227 if test "$have_x" = yes ; then
 228 # We surely need these two libraries and want to check carefully the
 229 # version numbers...
 230 LYX_PATH_XPM
 231 LYX_PATH_XFORMS
 232 FRONTEND_INFO=`cat <<EOF
 233     libXpm version:               ${XPM_VERSION}\n\
 234     libforms version:             ${XFORMS_VERSION}\n
 235 `
 236
 237 AC_SUBST(LYX_LIBS)
 238 else
 239 LYX_ERROR(dnl
 240 [Cannot find X window libraries and/or headers. Check your installation.
 241    If you use a Linux system, check that you have installed
 242    the development tools.])
 243 fi
 244
 245 ### Setup GNU gettext
 246 dnl GNU gettext is written in C
 247 AC_LANG_C
 248 # Some tests that may be useful for gettext
 249 AC_C_CONST
 250 AC_C_INLINE
 251 # Do the real setup now
 252 AM_GNU_GETTEXT
 253 # a hack for those who try to change LyX, but do not have gettext installed
 254 case  "${XGETTEXT}" in
 255  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 256 esac
 257
 258 AC_SUBST(LINGUAS)
 259
 260 AC_LANG_CPLUSPLUS
 261
 262 # some standard header files
 263 AC_HEADER_DIRENT
 264 AC_HEADER_MAJOR
 265 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 266
 267 # some annoying header files
 268 #LYX_PATH_HEADER(stl_string_fwd.h)
 269 LYX_STL_STRING_FWD
 270
 271 # some standard structures
 272 AC_HEADER_STAT
 273 AC_HEADER_TIME
 274 AC_STRUCT_ST_BLKSIZE
 275 AC_STRUCT_ST_BLOCKS
 276 AC_STRUCT_ST_RDEV
 277
 278 # some standard types
 279 AC_TYPE_MODE_T
 280 AC_TYPE_OFF_T
 281 AC_TYPE_PID_T
 282 AC_TYPE_SIGNAL
 283 AC_TYPE_SIZE_T
 284 AC_TYPE_UID_T
 285
 286 # some functions we'd like to have
 287 AC_ARG_WITH(broken-headers,
 288     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 289     [lyx_broken_headers=$withval])
 290 if test "x$lyx_broken_headers" = "xyes"; then
 291   lyx_flags="$lyx_flags broken-headers"
 292   AC_DEFINE(BROKEN_HEADERS, 1,
 293     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 294 fi
 295 AC_CHECK_FUNCS(snprintf vsnprintf)
 296 LYX_CHECK_DECL(snprintf, stdio.h)
 297 LYX_CHECK_DECL(vsnprintf, stdio.h)
 298 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 299
 300 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo \
 301   mkstemp mktemp)
 302
 303 dnl Until this is fixed in autoconf we provide our own version
 304 LYX_FUNC_SELECT_ARGTYPES
 305
 306 dnl check whether we have to work around solaris broken putenv()
 307 LYX_FUNC_PUTENV_ARGTYPE
 308
 309 # SunOS 4.1.3 does not have strerror and atexit
 310 AC_REPLACE_FUNCS(strerror atexit)
 311
 312 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 313
 314 ### Some information on what just happened
 315 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 316 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 317 VERSION_INFO=`cat <<EOF
 318 Configuration\n\
 319   Host type:                      ${host_alias}\n\
 320   Special build flags:           ${lyx_flags}\n\
 321   C   Compiler:                   ${CC}\n\
 322   C   Compiler flags:             ${CFLAGS}\n\
 323   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 324   C++ Compiler flags:             ${CXXFLAGS}\n\
 325   Linker flags:                   ${LDFLAGS}\n\
 326   Frontend:                       ${lyx_use_frontend}\n\
 327 ${FRONTEND_INFO}\
 328   LyX binary dir:                 ${real_bindir}\n\
 329   LyX files dir:                  ${real_datadir}\n
 330 `
 331
 332 AC_SUBST(VERSION_INFO)
 333
 334 ### Finish the work.
 335 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 336 AC_OUTPUT([Makefile \
 337        boost/Makefile \
 338        development/lyx.spec \
 339        lib/Makefile \
 340        intl/Makefile \
 341        po/Makefile.in \
 342        sourcedoc/Doxyfile \
 343        src/Makefile \
 344        src/version.C \
 345        src/mathed/Makefile \
 346        src/graphics/Makefile \
 347        src/insets/Makefile \
 348        src/support/Makefile \
 349        src/frontends/Makefile \
 350        src/frontends/support/Makefile \
 351        src/frontends/controllers/Makefile \
 352        src/frontends/xforms/Makefile \
 353        src/frontends/qt2/Makefile \
 354        src/frontends/qt2/moc/Makefile \
 355        src/frontends/qt2/ui/Makefile \
 356        src/frontends/qt2/ui/moc/Makefile \
 357        src/frontends/gnome/Makefile \
 358 ])
 359
 360 # show version information
 361 echo
 362 printf "$VERSION_INFO"
 363 echo
 364
 365 # Display a final warning if there has been a LYX_ERROR
 366 LYX_CHECK_ERRORS