configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/lyx.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 AC_ARG_WITH(lyxname,
  15   [  --with-lyxname          the name under which lyx will be installed],
  16   [lyxname=$withval],[lyxname=lyx])
  17
  18 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  19
  20 # The list of languages known to LyX
  21 # This is needed by GNU gettext
  22 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  23
  24 AC_PREFIX_PROGRAM(lyx)
  25
  26 # fix the value of the prefixes.
  27 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  28 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  29
  30 ### Set the execute permissions of the various scripts correctly
  31 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  32   chmod 755 ${srcdir}/${file}
  33 done
  34
  35 ### Check for programs
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 #AC_PROG_RANLIB
  39 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  40 if test "x$KPSEWHICH" = xkpsewhich ; then
  41     AC_DEFINE(HAVE_KPSEWHICH, 1,
  42     [Define this if you have the kpsewhich program working on your system.])
  43 fi
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### Check for a C++ compiler
  65 AC_LANG_CPLUSPLUS
  66 LYX_PROG_CXX
  67 AC_PROG_CXXCPP
  68 AC_DISABLE_SHARED
  69 AC_LIBTOOL_WIN32_DLL
  70 AM_PROG_LIBTOOL
  71
  72 ### Some checks on what the C++ compiler can(not) do
  73 LYX_CXX_MUTABLE
  74 LYX_CXX_PARTIAL
  75 LYX_CXX_EXPLICIT
  76 dnl we do not use stl stack, or at least not on gcc 2.7, which was the
  77 dnl cause for this test.
  78 dnl LYX_CXX_STL_STACK
  79 LYX_CXX_STL_STRING
  80 LYX_CXX_GOOD_STD_STRING
  81 LYX_CXX_NAMESPACES
  82 LYX_CXX_CHEADERS
  83 LYX_STD_COUNT
  84 dnl we disable rtti for now
  85 dnl LYX_CXX_RTTI
  86 AC_CHECK_HEADERS(ostream istream sstream)
  87 LYX_CXX_STL_MODERN_STREAMS
  88
  89 ### We need a regex implementation, so we provide our own if none is found.
  90 LYX_REGEX
  91
  92 ### Library Files
  93 dnl by testing these we check if it is ok to have
  94 dnl -lc and -lm as args to the compiler
  95 AC_CHECK_LIB(m, sin)
  96 AC_CHECK_LIB(c, fopen)
  97
  98 ### Add extra directories to check for libraries.
  99 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 100 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 101 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 102
 103 ### Add extra directories to check for include files.
 104 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 105 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 106 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 107
 108 ### Add both includes and libraries
 109 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 110 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 111 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 112   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 113
 114 ### Check for the -liberty library
 115 test "x$GXX" = xyes && lyx_use_liberty=yes
 116 AC_ARG_WITH(liberty,
 117   [  --without-liberty       do not try to link against libiberty.a],
 118   [lyx_use_liberty=$withval])
 119 if test x$lyx_use_liberty = xyes; then
 120   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 121   AC_CHECK_LIB(iberty,main)
 122 fi
 123
 124 ### Check which libsigc++ we're using
 125 LYX_WITH_SIGC
 126
 127 ### Check for X libraries
 128 # Check for the pt library (for SCO, needed for X)
 129 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 130 # The real thing.
 131 AC_PATH_XTRA
 132 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 133 # Since solaris X headers use int as implicit return type and modern
 134 # gcc's do not like that, let's use -isystem instead of -I.
 135 # We should test for gcc version and see whether it supports -isystem,
 136 # but since at least gcc 2.6.x supports it and it is still too old for
 137 # us, it seems we are safe.
 138 if test -n "$GXX" ; then
 139   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 140 fi
 141 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 142
 143 ## Check whether X is new enough to handle the input method stuff
 144 AC_CHECK_FUNCS(XOpenIM)
 145
 146 ### check which frontend we want to use
 147 LYX_USE_FRONTEND
 148 dnl The code below is not in a macro, because this would cause big
 149 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 150 case "$lyx_use_frontend" in
 151   kde)
 152     KDE_DO_IT_ALL
 153     FRONTEND="kde"
 154     FRONTEND_GUILIB="\${top_builddir}/src/frontends/kde/libkde.la"
 155     FRONTEND_LDFLAGS="\$(QT_LDFLAGS) \$(KDE_LDFLAGS)"
 156     FRONTEND_INCLUDES="\$(QT_INCLUDES) \$(KDE_INCLUDES)"
 157     FRONTEND_LIBS="\$(KDE_LIBS)"
 158     AC_DEFINE(KDEGUI);;
 159   xforms)
 160     FRONTEND="xforms"
 161     FRONTEND_GUILIB="\${top_builddir}/src/frontends/xforms/libxforms.la";;
 162   gnome)
 163     AM_PATH_GTKMM(1.2.1,,
 164         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 165     AM_PATH_GNOMEMM
 166
 167     FRONTEND="gnome"
 168     FRONTEND_GUILIB="\${top_builddir}/src/frontends/gnome/libgnome.la"
 169     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 170     FRONTEND_INCLUDES="\$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 171     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS)"
 172     AC_DEFINE(GTKGUI);;
 173   *)
 174     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 175 esac
 176
 177 ### Check for xforms and xpm (only if X has been found).
 178 if test "$have_x" = yes ; then
 179 # We surely need these two libraries and want to check carefully the
 180 # version numbers...
 181 LYX_PATH_XPM
 182 LYX_PATH_XFORMS
 183 AC_SUBST(LYX_LIBS)
 184 else
 185 LYX_ERROR(dnl
 186 [Cannot find X window libraries and/or headers. Check your installation.
 187    If you use a Linux system, check that you have installed
 188    the development tools.])
 189 fi
 190
 191 ### Setup GNU gettext
 192 dnl GNU gettext is written in C
 193 AC_LANG_C
 194 # Some tests that may be useful for gettext
 195 AC_C_CONST
 196 AC_C_INLINE
 197 # Do the real setup now
 198 AM_GNU_GETTEXT
 199 # a hack for those who try to change LyX, but do not have gettext installed
 200 case  "${XGETTEXT}" in
 201  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 202 esac
 203
 204 AC_SUBST(LINGUAS)
 205
 206 AC_LANG_CPLUSPLUS
 207
 208 # some standard header files
 209 AC_HEADER_DIRENT
 210 AC_HEADER_MAJOR
 211 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 212
 213 # some annoying header files
 214 #LYX_PATH_HEADER(stl_string_fwd.h)
 215 LYX_STL_STRING_FWD
 216
 217 # some standard structures
 218 AC_HEADER_STAT
 219 AC_HEADER_TIME
 220 AC_STRUCT_ST_BLKSIZE
 221 AC_STRUCT_ST_BLOCKS
 222 AC_STRUCT_ST_RDEV
 223
 224 # some standard types
 225 AC_TYPE_MODE_T
 226 AC_TYPE_OFF_T
 227 AC_TYPE_PID_T
 228 AC_TYPE_SIGNAL
 229 AC_TYPE_SIZE_T
 230 AC_TYPE_UID_T
 231
 232 # some functions we'd like to have
 233 AC_ARG_WITH(broken-headers,
 234     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 235     [lyx_broken_headers=$withval])
 236 if test "x$lyx_broken_headers" = "xyes"; then
 237   lyx_flags="$lyx_flags broken-headers"
 238   AC_DEFINE(BROKEN_HEADERS, 1,
 239     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 240 fi
 241 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo)
 242
 243 dnl Until this is fixed in autoconf we provide our own version
 244 LYX_FUNC_SELECT_ARGTYPES
 245
 246 dnl check whether we have to work around solaris broken putenv()
 247 LYX_FUNC_PUTENV_ARGTYPE
 248
 249 # SunOS 4.1.3 does not have strerror and atexit
 250 AC_REPLACE_FUNCS(strerror atexit)
 251
 252 ### and now some special lyx flags.
 253 AC_ARG_ENABLE(assertions,
 254   [  --enable-assertions     add runtime sanity checks in the program],,
 255   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 256         enable_assertions=yes;
 257     else
 258         enable_assertions=no;
 259     fi;])
 260 if test "x$enable_assertions" = xyes ; then
 261    lyx_flags="$lyx_flags assertions"
 262    AC_DEFINE(ENABLE_ASSERTIONS,1,
 263     [Define if you want assertions to be enabled in the code])
 264 fi
 265
 266 ### Finish the work.
 267 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 268 AC_OUTPUT([Makefile \
 269        development/lyx.spec \
 270        lib/Makefile \
 271        intl/Makefile \
 272        po/Makefile.in \
 273        src/Makefile \
 274        src/mathed/Makefile \
 275        src/graphics/Makefile \
 276        src/insets/Makefile \
 277        src/support/Makefile \
 278        src/xtl/Makefile \
 279        src/frontends/Makefile \
 280        src/frontends/xforms/Makefile \
 281        src/frontends/kde/Makefile \
 282        src/frontends/gnome/Makefile \
 283 ],  [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 284
 285
 286 cat <<EOF
 287
 288 Configuration:
 289   Source code location:       ${srcdir}
 290   C++ Compiler:                   ${CXX}
 291   C++ Compiler flags:             ${CXXFLAGS}
 292   C   Compiler:                   ${CC}
 293   C   Compiler flags:             ${CFLAGS}
 294   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 295   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 296   Special flags:              ${lyx_flags}
 297
 298 EOF
 299
 300 # Display a final warning if there has been a LYX_ERROR
 301 LYX_CHECK_ERRORS