configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 LYX_VERSION_SUFFIX
  15
  16 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  17
  18 # The list of languages known to LyX
  19 # This is needed by GNU gettext
  20 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  21
  22 AC_PREFIX_PROGRAM(lyx)
  23
  24 # fix the value of the prefixes.
  25 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  26 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  27
  28 ### Set the execute permissions of the various scripts correctly
  29 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  30   chmod 755 ${srcdir}/${file}
  31 done
  32
  33 ### Check for programs
  34 AC_PROG_MAKE_SET
  35 AC_PROG_INSTALL
  36 #AC_PROG_RANLIB
  37 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  38 if test "x$KPSEWHICH" = xkpsewhich ; then
  39     AC_DEFINE(HAVE_KPSEWHICH, 1,
  40     [Define this if you have the kpsewhich program working on your system.])
  41 fi
  42
  43 # Work around a problem in automake 1.4: when invoking install-strip,
  44 # INSTALL_PROGRAM is changed to 'install -s', and since
  45 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  46 # which returns an error condition when stripping fails.
  47 INSTALL_SCRIPT='${INSTALL}'
  48
  49 ### we will also need a C compiler to compile GNU gettext
  50 AC_PROG_CC
  51
  52 ### check for special systems
  53 AC_ISC_POSIX
  54 AC_AIX
  55 LYX_HPUX
  56 LYX_SUNOS4
  57 LYX_SCO
  58
  59 ### Check for program extensions (.exe or nothing)
  60 AC_EXEEXT
  61
  62 ### check which frontend we want to use
  63 LYX_USE_FRONTEND
  64 dnl The code below is not in a macro, because this would cause big
  65 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  66 case "$lyx_use_frontend" in
  67   gnome)
  68     GNOME_INIT
  69     GNOME_COMPILE_WARNINGS
  70     GNOME_X_CHECKS
  71 esac
  72
  73 ### Check for a C++ compiler
  74 AC_LANG_CPLUSPLUS
  75 LYX_PROG_CXX
  76 AC_PROG_CXXCPP
  77 AC_DISABLE_SHARED
  78 AC_LIBTOOL_WIN32_DLL
  79 #AM_PROG_LIBTOOL
  80 LYX_PROG_LIBTOOL
  81
  82 ### Some checks on what the C++ compiler can(not) do
  83 LYX_CXX_MUTABLE
  84 LYX_CXX_PARTIAL
  85 LYX_CXX_EXPLICIT
  86 dnl we do not use stl stack, or at least not on gcc 2.7, which was the
  87 dnl cause for this test.
  88 dnl LYX_CXX_STL_STACK
  89 LYX_CXX_STL_STRING
  90 LYX_CXX_GOOD_STD_STRING
  91 LYX_CXX_NAMESPACES
  92 LYX_CXX_CHEADERS
  93 LYX_CXX_GLOBAL_CSTD
  94 LYX_STD_COUNT
  95 dnl we disable rtti for now
  96 dnl LYX_CXX_RTTI
  97 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  98 LYX_CXX_STL_MODERN_STREAMS
  99
 100 ### We need a regex implementation, so we provide our own if none is found.
 101 LYX_REGEX
 102
 103 ### Library Files
 104 dnl by testing these we check if it is ok to have
 105 dnl -lc and -lm as args to the compiler
 106 AC_CHECK_LIB(m, sin)
 107 AC_CHECK_LIB(c, fopen)
 108
 109 ### Add extra directories to check for libraries.
 110 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 111 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 112 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 113
 114 ### Add extra directories to check for include files.
 115 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 116 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 117 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 118
 119 ### Add both includes and libraries
 120 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 121 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 122 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 123   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 124
 125 ### Check for the -liberty library
 126 test "x$GXX" = xyes && lyx_use_liberty=yes
 127 AC_ARG_WITH(liberty,
 128   [  --without-liberty       do not try to link against libiberty.a],
 129   [lyx_use_liberty=$withval])
 130 if test x$lyx_use_liberty = xyes; then
 131   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 132   AC_CHECK_LIB(iberty,main)
 133 fi
 134
 135 ### Check which libsigc++ we're using
 136 LYX_WITH_SIGC
 137
 138 ### Check if we want pspell libraries
 139 CHECK_WITH_PSPELL
 140
 141 ### Check for X libraries
 142 # Check for the pt library (for SCO, needed for X)
 143 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 144 # The real thing.
 145 AC_PATH_XTRA
 146 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 147 # Since solaris X headers use int as implicit return type and modern
 148 # gcc's do not like that, let's use -isystem instead of -I.
 149 # We should test for gcc version and see whether it supports -isystem,
 150 # but since at least gcc 2.6.x supports it and it is still too old for
 151 # us, it seems we are safe.
 152 if test -n "$GXX" ; then
 153   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 154 fi
 155 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 156
 157 ## Check whether X is new enough to handle the input method stuff
 158 AC_CHECK_FUNCS(XOpenIM)
 159
 160 ### check which frontend we want to use
 161 #LYX_USE_FRONTEND
 162 dnl The code below is not in a macro, because this would cause big
 163 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 164 case "$lyx_use_frontend" in
 165   xforms)
 166   # for now don't set it for xforms as this is always entered
 167     FRONTEND=""
 168     FRONTEND_GUILIB="xforms/libxforms.la";;
 169   gnome)
 170     AM_PATH_GTKMM(1.2.1,,
 171         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 172     AM_PATH_GNOMEMM
 173
 174 dnl ******************************
 175 dnl LibGlade checking
 176 dnl ******************************
 177 dnl Ensure gnome-config is available...
 178         AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 179         AC_MSG_CHECKING(for Glade libraries)
 180         if $GNOME_CONFIG --libs libglade > /dev/null 2>&1; then
 181         AC_MSG_RESULT(found)
 182         else
 183             AC_MSG_ERROR(Did not find libGlade installed)
 184         fi
 185
 186     FRONTEND="gnome"
 187     FRONTEND_GUILIB="gnome/libgnome.la"
 188     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 189     FRONTEND_INCLUDES="-I\${srcdir}/gnome \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 190     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS) `gnome-config --libs libglade`";;
 191   qt2)
 192     QT2_DO_IT_ALL
 193     FRONTEND="qt2"
 194     FRONTEND_GUILIB="qt2/libqt2.la"
 195     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 196     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT2_INCLUDES)"
 197     FRONTEND_LIBS="\$(QT2_LIBS)";;
 198   *)
 199     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 200 esac
 201
 202 ### Check for xforms and xpm (only if X has been found).
 203 if test "$have_x" = yes ; then
 204 # We surely need these two libraries and want to check carefully the
 205 # version numbers...
 206 LYX_PATH_XPM
 207 LYX_PATH_XFORMS
 208 AC_SUBST(LYX_LIBS)
 209 else
 210 LYX_ERROR(dnl
 211 [Cannot find X window libraries and/or headers. Check your installation.
 212    If you use a Linux system, check that you have installed
 213    the development tools.])
 214 fi
 215
 216 ### Setup GNU gettext
 217 dnl GNU gettext is written in C
 218 AC_LANG_C
 219 # Some tests that may be useful for gettext
 220 AC_C_CONST
 221 AC_C_INLINE
 222 # Do the real setup now
 223 AM_GNU_GETTEXT
 224 # a hack for those who try to change LyX, but do not have gettext installed
 225 case  "${XGETTEXT}" in
 226  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 227 esac
 228
 229 AC_SUBST(LINGUAS)
 230
 231 AC_LANG_CPLUSPLUS
 232
 233 # some standard header files
 234 AC_HEADER_DIRENT
 235 AC_HEADER_MAJOR
 236 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 237
 238 # some annoying header files
 239 #LYX_PATH_HEADER(stl_string_fwd.h)
 240 LYX_STL_STRING_FWD
 241
 242 # some standard structures
 243 AC_HEADER_STAT
 244 AC_HEADER_TIME
 245 AC_STRUCT_ST_BLKSIZE
 246 AC_STRUCT_ST_BLOCKS
 247 AC_STRUCT_ST_RDEV
 248
 249 # some standard types
 250 AC_TYPE_MODE_T
 251 AC_TYPE_OFF_T
 252 AC_TYPE_PID_T
 253 AC_TYPE_SIGNAL
 254 AC_TYPE_SIZE_T
 255 AC_TYPE_UID_T
 256
 257 # some functions we'd like to have
 258 AC_ARG_WITH(broken-headers,
 259     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 260     [lyx_broken_headers=$withval])
 261 if test "x$lyx_broken_headers" = "xyes"; then
 262   lyx_flags="$lyx_flags broken-headers"
 263   AC_DEFINE(BROKEN_HEADERS, 1,
 264     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 265 fi
 266 AC_CHECK_FUNCS(snprintf vsnprintf)
 267 LYX_CHECK_DECL(snprintf, stdio.h)
 268 LYX_CHECK_DECL(vsnprintf, stdio.h)
 269 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 270
 271 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo \
 272   mkstemp mktemp)
 273
 274 dnl Until this is fixed in autoconf we provide our own version
 275 LYX_FUNC_SELECT_ARGTYPES
 276
 277 dnl check whether we have to work around solaris broken putenv()
 278 LYX_FUNC_PUTENV_ARGTYPE
 279
 280 # SunOS 4.1.3 does not have strerror and atexit
 281 AC_REPLACE_FUNCS(strerror atexit)
 282
 283 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 284
 285 ### and now some special lyx flags.
 286 AC_ARG_ENABLE(assertions,
 287   [  --enable-assertions     add runtime sanity checks in the program],,
 288   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 289         enable_assertions=yes;
 290     else
 291         enable_assertions=no;
 292     fi;])
 293 if test "x$enable_assertions" = xyes ; then
 294    lyx_flags="$lyx_flags assertions"
 295    AC_DEFINE(ENABLE_ASSERTIONS,1,
 296     [Define if you want assertions to be enabled in the code])
 297 fi
 298
 299 ### Finish the work.
 300 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 301 AC_OUTPUT([Makefile \
 302        boost/Makefile \
 303        development/lyx.spec \
 304        lib/Makefile \
 305        intl/Makefile \
 306        po/Makefile.in \
 307        sourcedoc/Doxyfile \
 308        src/Makefile \
 309        src/mathed/Makefile \
 310        src/graphics/Makefile \
 311        src/insets/Makefile \
 312        src/support/Makefile \
 313        src/frontends/Makefile \
 314        src/frontends/support/Makefile \
 315        src/frontends/controllers/Makefile \
 316        src/frontends/xforms/Makefile \
 317        src/frontends/qt2/Makefile \
 318        src/frontends/gnome/Makefile \
 319 ],  [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 320
 321
 322 cat <<EOF
 323
 324 Configuration:
 325   Source code location:       ${srcdir}
 326   C++ Compiler:                   ${CXX}
 327   C++ Compiler flags:             ${CXXFLAGS}
 328   C   Compiler:                   ${CC}
 329   C   Compiler flags:             ${CFLAGS}
 330   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 331   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 332   Special flags:              ${lyx_flags}
 333
 334 EOF
 335
 336 # Display a final warning if there has been a LYX_ERROR
 337 LYX_CHECK_ERRORS