configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.3.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### check which frontend we want to use
  65 LYX_USE_FRONTEND
  66
  67 #old gnome stuff removed by Michael Koziarski 25-05-2002
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71 ### Some checks on what the C++ compiler can(not) do
  72 AC_LANG_CPLUSPLUS
  73 dnl we do not need that currently (and probably all our supported
  74 dnl compiler allow that)
  75 dnl LYX_CXX_PARTIAL
  76 LYX_CXX_EXPLICIT
  77 LYX_CXX_STL_STRING
  78 LYX_CXX_GOOD_STD_STRING
  79 LYX_CXX_CHEADERS
  80 LYX_CXX_GLOBAL_CSTD
  81 LYX_STD_COUNT
  82 dnl we disable rtti for now
  83 dnl LYX_CXX_RTTI
  84 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  85 LYX_CXX_STL_MODERN_STREAMS
  86
  87 ### and now some special lyx flags.
  88 AC_ARG_ENABLE(assertions,
  89   [  --enable-assertions     add runtime sanity checks in the program],,
  90   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  91         enable_assertions=yes;
  92     else
  93         enable_assertions=no;
  94     fi;])
  95 if test "x$enable_assertions" = xyes ; then
  96    lyx_flags="$lyx_flags assertions"
  97    AC_DEFINE(ENABLE_ASSERTIONS,1,
  98     [Define if you want assertions to be enabled in the code])
  99 fi
 100
 101 ### Library Files
 102 dnl by testing these we check if it is ok to have
 103 dnl -lc and -lm as args to the compiler
 104 AC_CHECK_LIB(m, sin)
 105 AC_CHECK_LIB(c, fopen)
 106
 107 ### Add extra directories to check for libraries.
 108 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 109 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 110 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 111
 112 ### Add extra directories to check for include files.
 113 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 114 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 115 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 116
 117 ### Add both includes and libraries
 118 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 119 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 120 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 121   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 122
 123 AC_ARG_WITH(aiksaurus,
 124   [  --without-aiksaurus     do not use the Aiksaurus library],
 125   [lyx_use_aiksaurus=$withval])
 126 if test x$lyx_use_aiksaurus != xno; then
 127 AC_CHECK_LIB(Aiksaurus, main,
 128         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 129          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 130         ],,"-lbz2")
 131 fi
 132 AC_SUBST(AIKSAURUS_LIBS)
 133
 134 ### Setup libtool
 135 AC_DISABLE_SHARED
 136 AC_LIBTOOL_WIN32_DLL
 137 #AM_PROG_LIBTOOL
 138 LYX_PROG_LIBTOOL
 139
 140 ### Check if we want pspell libraries
 141 CHECK_WITH_PSPELL
 142
 143 ### Check for X libraries
 144 # The real thing.
 145 AC_PATH_XTRA
 146 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 147 # Since solaris X headers use int as implicit return type and modern
 148 # gcc's do not like that, let's use -isystem instead of -I.
 149 # We should test for gcc version and see whether it supports -isystem,
 150 # but since at least gcc 2.6.x supports it and it is still too old for
 151 # us, it seems we are safe.
 152 if test -n "$GXX" ; then
 153   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 154 fi
 155 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 156
 157 ## Check whether X is new enough to handle the input method stuff
 158 AC_CHECK_FUNCS(XOpenIM)
 159
 160 ### check which frontend we want to use
 161 # We have to check for xforms anyway
 162 LYX_PATH_XPM
 163 LYX_PATH_XFORMS
 164
 165 #LYX_USE_FRONTEND
 166 dnl The code below is not in a macro, because this would cause big
 167 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 168 case "$lyx_use_frontend" in
 169   xforms)
 170   # for now don't set it for xforms as this is always entered
 171         FRONTEND="xforms"
 172         FRONTEND_GUILIB="xforms/*.lo xforms/forms/*.lo"
 173         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 174         case "$host" in
 175           *cygwin)
 176             FRONTEND_LIBS="@XFORMS_LIB@ @XFORMS_IMAGE_LIB@ @XPM_LIB@"
 177             ;;
 178           *)
 179             FRONTEND_LIBS="@XFORMS_IMAGE_LIB@ @XFORMS_LIB@ @XPM_LIB@"
 180             ;;
 181         esac
 182         FRONTEND_INFO=`cat <<EOF
 183     libXpm version:               ${XPM_VERSION}\n\
 184     libforms version:             ${XFORMS_VERSION}\n
 185 `
 186         ;;
 187   gnome)
 188     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 189     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 190     AC_SUBST(GNOME_FRONTEND_LIBS)
 191
 192     FRONTEND="xforms gnome"
 193     FRONTEND_GUILIB="gnome/*.lo"
 194     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 195     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 196     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}";;
 197   qt2)
 198     QT2_DO_IT_ALL
 199     FRONTEND="qt2"
 200     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo"
 201     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 202     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT2_INCLUDES)"
 203     FRONTEND_LIBS="\$(QT2_LIBS)";;
 204   *)
 205     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 206 esac
 207
 208 ### Check for xforms and xpm (only if X has been found).
 209 if test "$have_x" = no ; then
 210 # We surely need these two libraries and want to check carefully the
 211 # version numbers...
 212 #LYX_PATH_XPM
 213 #LYX_PATH_XFORMS
 214 #FRONTEND_INFO=`cat <<EOF
 215 #    libXpm version:               ${XPM_VERSION}\n\
 216 #    libforms version:             ${XFORMS_VERSION}\n
 217 #`
 218 #
 219 #AC_SUBST(LYX_LIBS)
 220 #else
 221 LYX_ERROR(dnl
 222 [Cannot find X window libraries and/or headers. Check your installation.
 223    If you use a Linux system, check that you have installed
 224    the development tools.])
 225 fi
 226
 227 ### Check whether the xforms library has a viable image loader
 228 ### For now, run this test always so config.h is unchanged by a change in
 229 ### frontend
 230 LYX_USE_XFORMS_IMAGE_LOADER
 231
 232 ### Setup GNU gettext
 233 dnl GNU gettext is written in C
 234 AC_LANG_C
 235 # Some tests that may be useful for gettext
 236 AC_C_CONST
 237 AC_C_INLINE
 238 # Do the real setup now
 239 AM_GNU_GETTEXT
 240 # a hack for those who try to change LyX, but do not have gettext installed
 241 case  "${XGETTEXT}" in
 242  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 243 esac
 244
 245 AC_SUBST(LINGUAS)
 246
 247 AC_LANG_CPLUSPLUS
 248
 249 # some standard header files
 250 AC_HEADER_DIRENT
 251 AC_HEADER_MAJOR
 252 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 253
 254 # some standard structures
 255 AC_HEADER_STAT
 256 AC_HEADER_TIME
 257 AC_STRUCT_ST_BLKSIZE
 258 AC_STRUCT_ST_BLOCKS
 259 AC_STRUCT_ST_RDEV
 260
 261 # some standard types
 262 AC_TYPE_MODE_T
 263 AC_TYPE_OFF_T
 264 AC_TYPE_PID_T
 265 AC_TYPE_SIGNAL
 266 AC_TYPE_SIZE_T
 267 AC_TYPE_UID_T
 268
 269 # some functions we'd like to have
 270 AC_ARG_WITH(broken-headers,
 271     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 272     [lyx_broken_headers=$withval])
 273 if test "x$lyx_broken_headers" = "xyes"; then
 274   lyx_flags="$lyx_flags broken-headers"
 275   AC_DEFINE(BROKEN_HEADERS, 1,
 276     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 277 fi
 278 AC_CHECK_FUNCS(snprintf vsnprintf)
 279 LYX_CHECK_DECL(snprintf, stdio.h)
 280 LYX_CHECK_DECL(vsnprintf, stdio.h)
 281 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 282
 283 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 284 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 285 dnl We aim to remove this eventually, since we should test as much as
 286 dnl possible with the compiler which will use the functions (JMarc)
 287 AC_LANG_C
 288 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo mkstemp mktemp)
 289 # SunOS 4.1.3 does not have strerror and atexit
 290 AC_REPLACE_FUNCS(strerror atexit)
 291 AC_LANG_CPLUSPLUS
 292
 293 dnl Until this is fixed in autoconf we provide our own version
 294 LYX_FUNC_SELECT_ARGTYPES
 295
 296 dnl check whether we have to work around solaris broken putenv()
 297 LYX_FUNC_PUTENV_ARGTYPE
 298
 299
 300 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 301
 302 ### Some information on what just happened
 303 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 304 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 305 VERSION_INFO=`cat <<EOF
 306 Configuration\n\
 307   Host type:                      ${host}\n\
 308   Special build flags:           ${lyx_flags}\n\
 309   C   Compiler:                   ${CC}\n\
 310   C   Compiler flags:             ${CFLAGS}\n\
 311   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 312   C++ Compiler flags:             ${CXXFLAGS}\n\
 313   Linker flags:                   ${LDFLAGS}\n\
 314   Frontend:                       ${lyx_use_frontend}\n\
 315 ${FRONTEND_INFO}\
 316   LyX binary dir:                 ${real_bindir}\n\
 317   LyX files dir:                  ${real_datadir}\n
 318 `
 319
 320 AC_SUBST(VERSION_INFO)
 321
 322 ### Finish the work.
 323 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 324 AC_OUTPUT([Makefile \
 325        boost/Makefile \
 326        boost/libs/Makefile \
 327        boost/libs/regex/Makefile \
 328        boost/libs/regex/src/Makefile \
 329        boost/libs/signals/Makefile \
 330        boost/libs/signals/src/Makefile \
 331        config/Makefile \
 332        development/lyx.spec \
 333        lib/Makefile \
 334        intl/Makefile \
 335        po/Makefile.in \
 336        sourcedoc/Doxyfile \
 337        src/Makefile \
 338        src/version.C \
 339        src/mathed/Makefile \
 340        src/graphics/Makefile \
 341        src/insets/Makefile \
 342        src/support/Makefile \
 343        src/frontends/Makefile \
 344        src/frontends/controllers/Makefile \
 345        src/frontends/xforms/Makefile \
 346        src/frontends/xforms/forms/Makefile \
 347        src/frontends/qt2/Makefile \
 348        src/frontends/qt2/moc/Makefile \
 349        src/frontends/qt2/ui/Makefile \
 350        src/frontends/qt2/ui/moc/Makefile \
 351        src/frontends/gnome/Makefile \
 352 ])
 353
 354 # show version information
 355 echo
 356 printf "$VERSION_INFO"
 357 echo
 358
 359 # Display a final warning if there has been a LYX_ERROR
 360 LYX_CHECK_ERRORS