configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.2.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43
  44 # Work around a problem in automake 1.4: when invoking install-strip,
  45 # INSTALL_PROGRAM is changed to 'install -s', and since
  46 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  47 # which returns an error condition when stripping fails.
  48 INSTALL_SCRIPT='${INSTALL}'
  49
  50 ### we will also need a C compiler to compile GNU gettext
  51 AC_PROG_CC
  52
  53 ### check for special systems
  54 AC_ISC_POSIX
  55 AC_AIX
  56 LYX_HPUX
  57 LYX_SUNOS4
  58 LYX_SCO
  59
  60 ### Check for program extensions (.exe or nothing)
  61 AC_EXEEXT
  62
  63 ### check which frontend we want to use
  64 LYX_USE_FRONTEND
  65 dnl The code below is not in a macro, because this would cause big
  66 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  67 case "$lyx_use_frontend" in
  68   gnome)
  69     GNOME_INIT
  70     GNOME_COMPILE_WARNINGS
  71     GNOME_X_CHECKS
  72 esac
  73
  74 ### Check for a C++ compiler
  75 LYX_PROG_CXX
  76 ### Some checks on what the C++ compiler can(not) do
  77 AC_LANG_CPLUSPLUS
  78 dnl we do not need that currently (and probably all our supported
  79 dnl compiler allow that)
  80 dnl LYX_CXX_PARTIAL
  81 LYX_CXX_EXPLICIT
  82 LYX_CXX_STL_STRING
  83 LYX_CXX_GOOD_STD_STRING
  84 LYX_CXX_CHEADERS
  85 LYX_CXX_GLOBAL_CSTD
  86 LYX_STD_COUNT
  87 dnl we disable rtti for now
  88 dnl LYX_CXX_RTTI
  89 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  90 LYX_CXX_STL_MODERN_STREAMS
  91
  92 ### and now some special lyx flags.
  93 AC_ARG_ENABLE(assertions,
  94   [  --enable-assertions     add runtime sanity checks in the program],,
  95   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  96         enable_assertions=yes;
  97     else
  98         enable_assertions=no;
  99     fi;])
 100 if test "x$enable_assertions" = xyes ; then
 101    lyx_flags="$lyx_flags assertions"
 102    AC_DEFINE(ENABLE_ASSERTIONS,1,
 103     [Define if you want assertions to be enabled in the code])
 104 fi
 105
 106 ### We need a regex implementation, so we provide our own if none is found.
 107 LYX_REGEX
 108
 109 ### Library Files
 110 dnl by testing these we check if it is ok to have
 111 dnl -lc and -lm as args to the compiler
 112 AC_CHECK_LIB(m, sin)
 113 AC_CHECK_LIB(c, fopen)
 114 AC_ARG_WITH(aiksaurus,
 115   [  --without-aiksaurus     do not use the Aiksaurus library],
 116   [lyx_use_aiksaurus=$withval])
 117 if test x$lyx_use_aiksaurus != xno; then
 118 AC_CHECK_LIB(Aiksaurus, main,
 119         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 120          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 121         ],,"-lbz2")
 122 fi
 123 AC_SUBST(AIKSAURUS_LIBS)
 124
 125 ### Add extra directories to check for libraries.
 126 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 127 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 128 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 129
 130 ### Add extra directories to check for include files.
 131 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 132 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 133 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 134
 135 ### Add both includes and libraries
 136 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 137 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 138 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 139   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 140
 141 ### Check for the -liberty library
 142 test "x$GXX" = xyes && lyx_use_liberty=yes
 143 AC_ARG_WITH(liberty,
 144   [  --without-liberty       do not try to link against libiberty.a],
 145   [lyx_use_liberty=$withval])
 146 if test x$lyx_use_liberty = xyes; then
 147   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 148   AC_CHECK_LIB(iberty,main)
 149 fi
 150
 151 ### Setup libtool
 152 AC_DISABLE_SHARED
 153 AC_LIBTOOL_WIN32_DLL
 154 #AM_PROG_LIBTOOL
 155 LYX_PROG_LIBTOOL
 156
 157 ### Check which libsigc++ we're using
 158 LYX_WITH_SIGC
 159
 160 ### Check if we want pspell libraries
 161 CHECK_WITH_PSPELL
 162
 163 ### Check for X libraries
 164 # The real thing.
 165 AC_PATH_XTRA
 166 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 167 # Since solaris X headers use int as implicit return type and modern
 168 # gcc's do not like that, let's use -isystem instead of -I.
 169 # We should test for gcc version and see whether it supports -isystem,
 170 # but since at least gcc 2.6.x supports it and it is still too old for
 171 # us, it seems we are safe.
 172 if test -n "$GXX" ; then
 173   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 174 fi
 175 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 176
 177 ## Check whether X is new enough to handle the input method stuff
 178 AC_CHECK_FUNCS(XOpenIM)
 179
 180 ### check which frontend we want to use
 181 #LYX_USE_FRONTEND
 182 dnl The code below is not in a macro, because this would cause big
 183 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 184 case "$lyx_use_frontend" in
 185   xforms)
 186   # for now don't set it for xforms as this is always entered
 187         LYX_PATH_XPM
 188         LYX_PATH_XFORMS
 189         FRONTEND="xforms"
 190         FRONTEND_GUILIB="xforms/*.lo"
 191         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 192         FRONTEND_LIBS="@XFORMS_LIB@ @XPM_LIB@"
 193         FRONTEND_INFO=`cat <<EOF
 194     libXpm version:               ${XPM_VERSION}\n\
 195     libforms version:             ${XFORMS_VERSION}\n
 196 `
 197         ;;
 198   gnome)
 199     LYX_PATH_XPM
 200     LYX_PATH_XFORMS
 201     AM_PATH_GTKMM(1.2.1,,
 202         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 203     AM_PATH_GNOMEMM
 204
 205 dnl ******************************
 206 dnl LibGlade checking
 207 dnl ******************************
 208 dnl Ensure gnome-config is available...
 209         AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 210         AC_MSG_CHECKING(for Glade libraries)
 211         if $GNOME_CONFIG --libs libglade > /dev/null 2>&1; then
 212         AC_MSG_RESULT(found)
 213         else
 214             AC_MSG_ERROR(Did not find libGlade installed)
 215         fi
 216
 217     FRONTEND="xforms gnome"
 218     FRONTEND_GUILIB="gnome/*.lo"
 219     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 220     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS) `gnome-config --cflags libglade gnomeui`"
 221     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ \$(GNOMEMM_LIBS) \$(GTKMM_LIBS) `gnome-config --libs libglade gnomeui`";;
 222   qt2)
 223         LYX_PATH_XPM
 224         LYX_PATH_XFORMS
 225     QT2_DO_IT_ALL
 226     FRONTEND="qt2"
 227     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo"
 228     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 229     FRONTEND_INCLUDES="-I\${srcdir}/qt2 -I\${top_srcdir}/src/frontends/xforms \$(QT2_INCLUDES)"
 230     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ \$(QT2_LIBS)";;
 231   *)
 232     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 233 esac
 234
 235 ### Check for xforms and xpm (only if X has been found).
 236 if test "$have_x" = no ; then
 237 # We surely need these two libraries and want to check carefully the
 238 # version numbers...
 239 #LYX_PATH_XPM
 240 #LYX_PATH_XFORMS
 241 #FRONTEND_INFO=`cat <<EOF
 242 #    libXpm version:               ${XPM_VERSION}\n\
 243 #    libforms version:             ${XFORMS_VERSION}\n
 244 #`
 245 #
 246 #AC_SUBST(LYX_LIBS)
 247 #else
 248 LYX_ERROR(dnl
 249 [Cannot find X window libraries and/or headers. Check your installation.
 250    If you use a Linux system, check that you have installed
 251    the development tools.])
 252 fi
 253
 254 ### Check whether the xforms library has a viable image loader
 255 ### For now, run this test always so config.h is unchanged by a change in
 256 ### frontend
 257 LYX_USE_XFORMS_IMAGE_LOADER
 258
 259 ### Setup GNU gettext
 260 dnl GNU gettext is written in C
 261 AC_LANG_C
 262 # Some tests that may be useful for gettext
 263 AC_C_CONST
 264 AC_C_INLINE
 265 # Do the real setup now
 266 AM_GNU_GETTEXT
 267 # a hack for those who try to change LyX, but do not have gettext installed
 268 case  "${XGETTEXT}" in
 269  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 270 esac
 271
 272 AC_SUBST(LINGUAS)
 273
 274 AC_LANG_CPLUSPLUS
 275
 276 # some standard header files
 277 AC_HEADER_DIRENT
 278 AC_HEADER_MAJOR
 279 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 280
 281 # some annoying header files
 282 #LYX_PATH_HEADER(stl_string_fwd.h)
 283 LYX_STL_STRING_FWD
 284
 285 # some standard structures
 286 AC_HEADER_STAT
 287 AC_HEADER_TIME
 288 AC_STRUCT_ST_BLKSIZE
 289 AC_STRUCT_ST_BLOCKS
 290 AC_STRUCT_ST_RDEV
 291
 292 # some standard types
 293 AC_TYPE_MODE_T
 294 AC_TYPE_OFF_T
 295 AC_TYPE_PID_T
 296 AC_TYPE_SIGNAL
 297 AC_TYPE_SIZE_T
 298 AC_TYPE_UID_T
 299
 300 # some functions we'd like to have
 301 AC_ARG_WITH(broken-headers,
 302     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 303     [lyx_broken_headers=$withval])
 304 if test "x$lyx_broken_headers" = "xyes"; then
 305   lyx_flags="$lyx_flags broken-headers"
 306   AC_DEFINE(BROKEN_HEADERS, 1,
 307     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 308 fi
 309 AC_CHECK_FUNCS(snprintf vsnprintf)
 310 LYX_CHECK_DECL(snprintf, stdio.h)
 311 LYX_CHECK_DECL(vsnprintf, stdio.h)
 312 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 313
 314 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo \
 315   mkstemp mktemp)
 316
 317 dnl Until this is fixed in autoconf we provide our own version
 318 LYX_FUNC_SELECT_ARGTYPES
 319
 320 dnl check whether we have to work around solaris broken putenv()
 321 LYX_FUNC_PUTENV_ARGTYPE
 322
 323 # SunOS 4.1.3 does not have strerror and atexit
 324 AC_REPLACE_FUNCS(strerror atexit)
 325
 326 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 327
 328 ### Some information on what just happened
 329 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 330 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 331 VERSION_INFO=`cat <<EOF
 332 Configuration\n\
 333   Host type:                      ${host_alias}\n\
 334   Special build flags:           ${lyx_flags}\n\
 335   C   Compiler:                   ${CC}\n\
 336   C   Compiler flags:             ${CFLAGS}\n\
 337   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 338   C++ Compiler flags:             ${CXXFLAGS}\n\
 339   Linker flags:                   ${LDFLAGS}\n\
 340   Frontend:                       ${lyx_use_frontend}\n\
 341 ${FRONTEND_INFO}\
 342   LyX binary dir:                 ${real_bindir}\n\
 343   LyX files dir:                  ${real_datadir}\n
 344 `
 345
 346 AC_SUBST(VERSION_INFO)
 347
 348 ### Finish the work.
 349 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 350 AC_OUTPUT([Makefile \
 351        boost/Makefile \
 352        development/lyx.spec \
 353        lib/Makefile \
 354        intl/Makefile \
 355        po/Makefile.in \
 356        sourcedoc/Doxyfile \
 357        src/Makefile \
 358        src/version.C \
 359        src/mathed/Makefile \
 360        src/graphics/Makefile \
 361        src/insets/Makefile \
 362        src/support/Makefile \
 363        src/frontends/Makefile \
 364        src/frontends/controllers/Makefile \
 365        src/frontends/xforms/Makefile \
 366        src/frontends/qt2/Makefile \
 367        src/frontends/qt2/xforms/Makefile \
 368        src/frontends/qt2/moc/Makefile \
 369        src/frontends/qt2/ui/Makefile \
 370        src/frontends/qt2/ui/moc/Makefile \
 371        src/frontends/gnome/Makefile \
 372 ])
 373
 374 # show version information
 375 echo
 376 printf "$VERSION_INFO"
 377 echo
 378
 379 # Display a final warning if there has been a LYX_ERROR
 380 LYX_CHECK_ERRORS