configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.3.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### check which frontend we want to use
  65 LYX_USE_FRONTEND
  66
  67 #old gnome stuff removed by Michael Koziarski 25-05-2002
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71 ### Some checks on what the C++ compiler can(not) do
  72 AC_LANG_CPLUSPLUS
  73 dnl we do not need that currently (and probably all our supported
  74 dnl compiler allow that)
  75 dnl LYX_CXX_PARTIAL
  76 LYX_CXX_EXPLICIT
  77 LYX_CXX_STL_STRING
  78 LYX_CXX_GOOD_STD_STRING
  79 LYX_CXX_CHEADERS
  80 LYX_CXX_GLOBAL_CSTD
  81 LYX_STD_COUNT
  82 dnl we disable rtti for now
  83 dnl LYX_CXX_RTTI
  84 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  85 LYX_CXX_STL_MODERN_STREAMS
  86
  87 ### and now some special lyx flags.
  88 AC_ARG_ENABLE(assertions,
  89   [  --enable-assertions     add runtime sanity checks in the program],,
  90   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  91         enable_assertions=yes;
  92     else
  93         enable_assertions=no;
  94     fi;])
  95 if test "x$enable_assertions" = xyes ; then
  96    lyx_flags="$lyx_flags assertions"
  97    AC_DEFINE(ENABLE_ASSERTIONS,1,
  98     [Define if you want assertions to be enabled in the code])
  99 fi
 100
 101 ### We need a regex implementation, so we provide our own if none is found.
 102 LYX_REGEX
 103
 104 ### Library Files
 105 dnl by testing these we check if it is ok to have
 106 dnl -lc and -lm as args to the compiler
 107 AC_CHECK_LIB(m, sin)
 108 AC_CHECK_LIB(c, fopen)
 109
 110 ### Add extra directories to check for libraries.
 111 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 112 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 113 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 114
 115 ### Add extra directories to check for include files.
 116 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 117 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 118 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 119
 120 ### Add both includes and libraries
 121 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 122 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 123 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 124   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 125
 126 ### Check for the -liberty library
 127 test "x$GXX" = xyes && lyx_use_liberty=yes
 128 AC_ARG_WITH(liberty,
 129   [  --without-liberty       do not try to link against libiberty.a],
 130   [lyx_use_liberty=$withval])
 131 if test x$lyx_use_liberty = xyes; then
 132   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 133   AC_CHECK_LIB(iberty,main)
 134 fi
 135
 136 AC_ARG_WITH(aiksaurus,
 137   [  --without-aiksaurus     do not use the Aiksaurus library],
 138   [lyx_use_aiksaurus=$withval])
 139 if test x$lyx_use_aiksaurus != xno; then
 140 AC_CHECK_LIB(Aiksaurus, main,
 141         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 142          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 143         ],,"-lbz2")
 144 fi
 145 AC_SUBST(AIKSAURUS_LIBS)
 146
 147 ### Setup libtool
 148 AC_DISABLE_SHARED
 149 AC_LIBTOOL_WIN32_DLL
 150 #AM_PROG_LIBTOOL
 151 LYX_PROG_LIBTOOL
 152
 153 ### Check which libsigc++ we're using
 154 LYX_WITH_SIGC
 155
 156 ### Check if we want pspell libraries
 157 CHECK_WITH_PSPELL
 158
 159 ### Check for X libraries
 160 # The real thing.
 161 AC_PATH_XTRA
 162 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 163 # Since solaris X headers use int as implicit return type and modern
 164 # gcc's do not like that, let's use -isystem instead of -I.
 165 # We should test for gcc version and see whether it supports -isystem,
 166 # but since at least gcc 2.6.x supports it and it is still too old for
 167 # us, it seems we are safe.
 168 if test -n "$GXX" ; then
 169   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 170 fi
 171 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 172
 173 ## Check whether X is new enough to handle the input method stuff
 174 AC_CHECK_FUNCS(XOpenIM)
 175
 176 ### check which frontend we want to use
 177 #LYX_USE_FRONTEND
 178 dnl The code below is not in a macro, because this would cause big
 179 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 180 case "$lyx_use_frontend" in
 181   xforms)
 182   # for now don't set it for xforms as this is always entered
 183         LYX_PATH_XPM
 184         LYX_PATH_XFORMS
 185         FRONTEND="xforms"
 186         FRONTEND_GUILIB="xforms/*.lo"
 187         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 188         FRONTEND_LIBS="@XFORMS_LIB@ @XPM_LIB@"
 189         FRONTEND_INFO=`cat <<EOF
 190     libXpm version:               ${XPM_VERSION}\n\
 191     libforms version:             ${XFORMS_VERSION}\n
 192 `
 193         ;;
 194   gnome)
 195     LYX_PATH_XPM
 196     LYX_PATH_XFORMS
 197
 198     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 199     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 200     AC_SUBST(GNOME_FRONTEND_LIBS)
 201
 202     FRONTEND="xforms gnome"
 203     FRONTEND_GUILIB="gnome/*.lo"
 204     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 205     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 206     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}";;
 207   qt2)
 208         LYX_PATH_XPM
 209         LYX_PATH_XFORMS
 210     QT2_DO_IT_ALL
 211     FRONTEND="qt2"
 212     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo qt2/xforms/*.lo"
 213     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 214     FRONTEND_INCLUDES="-I\${srcdir}/qt2 -I\${top_srcdir}/src/frontends/xforms \$(QT2_INCLUDES)"
 215     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ \$(QT2_LIBS)";;
 216   *)
 217     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 218 esac
 219
 220 ### Check for xforms and xpm (only if X has been found).
 221 if test "$have_x" = no ; then
 222 # We surely need these two libraries and want to check carefully the
 223 # version numbers...
 224 #LYX_PATH_XPM
 225 #LYX_PATH_XFORMS
 226 #FRONTEND_INFO=`cat <<EOF
 227 #    libXpm version:               ${XPM_VERSION}\n\
 228 #    libforms version:             ${XFORMS_VERSION}\n
 229 #`
 230 #
 231 #AC_SUBST(LYX_LIBS)
 232 #else
 233 LYX_ERROR(dnl
 234 [Cannot find X window libraries and/or headers. Check your installation.
 235    If you use a Linux system, check that you have installed
 236    the development tools.])
 237 fi
 238
 239 ### Check whether the xforms library has a viable image loader
 240 ### For now, run this test always so config.h is unchanged by a change in
 241 ### frontend
 242 LYX_USE_XFORMS_IMAGE_LOADER
 243 LYX_XFORMS_IMAGE_LOADER_NEEDS_JPEG
 244
 245 ### Setup GNU gettext
 246 dnl GNU gettext is written in C
 247 AC_LANG_C
 248 # Some tests that may be useful for gettext
 249 AC_C_CONST
 250 AC_C_INLINE
 251 # Do the real setup now
 252 AM_GNU_GETTEXT
 253 # a hack for those who try to change LyX, but do not have gettext installed
 254 case  "${XGETTEXT}" in
 255  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 256 esac
 257
 258 AC_SUBST(LINGUAS)
 259
 260 AC_LANG_CPLUSPLUS
 261
 262 # some standard header files
 263 AC_HEADER_DIRENT
 264 AC_HEADER_MAJOR
 265 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 266
 267 # some annoying header files
 268 #LYX_PATH_HEADER(stl_string_fwd.h)
 269 LYX_STL_STRING_FWD
 270
 271 # some standard structures
 272 AC_HEADER_STAT
 273 AC_HEADER_TIME
 274 AC_STRUCT_ST_BLKSIZE
 275 AC_STRUCT_ST_BLOCKS
 276 AC_STRUCT_ST_RDEV
 277
 278 # some standard types
 279 AC_TYPE_MODE_T
 280 AC_TYPE_OFF_T
 281 AC_TYPE_PID_T
 282 AC_TYPE_SIGNAL
 283 AC_TYPE_SIZE_T
 284 AC_TYPE_UID_T
 285
 286 # some functions we'd like to have
 287 AC_ARG_WITH(broken-headers,
 288     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 289     [lyx_broken_headers=$withval])
 290 if test "x$lyx_broken_headers" = "xyes"; then
 291   lyx_flags="$lyx_flags broken-headers"
 292   AC_DEFINE(BROKEN_HEADERS, 1,
 293     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 294 fi
 295 AC_CHECK_FUNCS(snprintf vsnprintf)
 296 LYX_CHECK_DECL(snprintf, stdio.h)
 297 LYX_CHECK_DECL(vsnprintf, stdio.h)
 298 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 299
 300 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 301 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 302 dnl We aim to remove this eventually, since we should test as much as
 303 dnl possible with the compiler which will use the functions (JMarc)
 304 AC_LANG_C
 305 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo mkstemp mktemp)
 306 # SunOS 4.1.3 does not have strerror and atexit
 307 AC_REPLACE_FUNCS(strerror atexit)
 308 AC_LANG_CPLUSPLUS
 309
 310 dnl Until this is fixed in autoconf we provide our own version
 311 LYX_FUNC_SELECT_ARGTYPES
 312
 313 dnl check whether we have to work around solaris broken putenv()
 314 LYX_FUNC_PUTENV_ARGTYPE
 315
 316
 317 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 318
 319 ### Some information on what just happened
 320 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 321 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 322 VERSION_INFO=`cat <<EOF
 323 Configuration\n\
 324   Host type:                      ${host_alias}\n\
 325   Special build flags:           ${lyx_flags}\n\
 326   C   Compiler:                   ${CC}\n\
 327   C   Compiler flags:             ${CFLAGS}\n\
 328   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 329   C++ Compiler flags:             ${CXXFLAGS}\n\
 330   Linker flags:                   ${LDFLAGS}\n\
 331   Frontend:                       ${lyx_use_frontend}\n\
 332 ${FRONTEND_INFO}\
 333   LyX binary dir:                 ${real_bindir}\n\
 334   LyX files dir:                  ${real_datadir}\n
 335 `
 336
 337 AC_SUBST(VERSION_INFO)
 338
 339 ### Finish the work.
 340 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 341 AC_OUTPUT([Makefile \
 342        boost/Makefile \
 343        boost/libs/Makefile \
 344        boost/libs/regex/Makefile \
 345        boost/libs/regex/src/Makefile \
 346        boost/libs/signals/Makefile \
 347        boost/libs/signals/src/Makefile \
 348        config/Makefile \
 349        development/lyx.spec \
 350        lib/Makefile \
 351        intl/Makefile \
 352        po/Makefile.in \
 353        sourcedoc/Doxyfile \
 354        src/Makefile \
 355        src/version.C \
 356        src/mathed/Makefile \
 357        src/graphics/Makefile \
 358        src/insets/Makefile \
 359        src/support/Makefile \
 360        src/frontends/Makefile \
 361        src/frontends/controllers/Makefile \
 362        src/frontends/xforms/Makefile \
 363        src/frontends/xforms/forms/Makefile \
 364        src/frontends/qt2/Makefile \
 365        src/frontends/qt2/xforms/Makefile \
 366        src/frontends/qt2/moc/Makefile \
 367        src/frontends/qt2/ui/Makefile \
 368        src/frontends/qt2/ui/moc/Makefile \
 369        src/frontends/gnome/Makefile \
 370 ])
 371
 372 # show version information
 373 echo
 374 printf "$VERSION_INFO"
 375 echo
 376
 377 # Display a final warning if there has been a LYX_ERROR
 378 LYX_CHECK_ERRORS