configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/lyx.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 AC_ARG_WITH(lyx-suffix,
  15   [  --with-lyx-suffix       install lyx files as lyx-<suffix>],
  16   [lyxname="lyx-$withval"
  17    program_suffix=-$withval],
  18   [lyxname=lyx])
  19
  20 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  21
  22 # The list of languages known to LyX
  23 # This is needed by GNU gettext
  24 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  25
  26 AC_PREFIX_PROGRAM(lyx)
  27
  28 # fix the value of the prefixes.
  29 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  30 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  31
  32 ### Set the execute permissions of the various scripts correctly
  33 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  34   chmod 755 ${srcdir}/${file}
  35 done
  36
  37 ### Check for programs
  38 AC_PROG_MAKE_SET
  39 AC_PROG_INSTALL
  40 #AC_PROG_RANLIB
  41 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  42 if test "x$KPSEWHICH" = xkpsewhich ; then
  43     AC_DEFINE(HAVE_KPSEWHICH, 1,
  44     [Define this if you have the kpsewhich program working on your system.])
  45 fi
  46
  47 # Work around a problem in automake 1.4: when invoking install-strip,
  48 # INSTALL_PROGRAM is changed to 'install -s', and since
  49 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  50 # which returns an error condition when stripping fails.
  51 INSTALL_SCRIPT='${INSTALL}'
  52
  53 ### we will also need a C compiler to compile GNU gettext
  54 AC_PROG_CC
  55
  56 ### check for special systems
  57 AC_ISC_POSIX
  58 AC_AIX
  59 LYX_HPUX
  60 LYX_SUNOS4
  61 LYX_SCO
  62
  63 ### Check for program extensions (.exe or nothing)
  64 AC_EXEEXT
  65
  66 ### check which frontend we want to use
  67 LYX_USE_FRONTEND
  68 dnl The code below is not in a macro, because this would cause big
  69 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  70 case "$lyx_use_frontend" in
  71   gnome)
  72     GNOME_INIT
  73     GNOME_COMPILE_WARNINGS
  74     GNOME_X_CHECKS
  75 esac
  76
  77 ### Check for a C++ compiler
  78 AC_LANG_CPLUSPLUS
  79 LYX_PROG_CXX
  80 AC_PROG_CXXCPP
  81 AC_DISABLE_SHARED
  82 AC_LIBTOOL_WIN32_DLL
  83 AM_PROG_LIBTOOL
  84
  85 ### Some checks on what the C++ compiler can(not) do
  86 LYX_CXX_MUTABLE
  87 LYX_CXX_PARTIAL
  88 LYX_CXX_EXPLICIT
  89 dnl we do not use stl stack, or at least not on gcc 2.7, which was the
  90 dnl cause for this test.
  91 dnl LYX_CXX_STL_STACK
  92 LYX_CXX_STL_STRING
  93 LYX_CXX_GOOD_STD_STRING
  94 LYX_CXX_NAMESPACES
  95 LYX_CXX_CHEADERS
  96 LYX_CXX_GLOBAL_CSTD
  97 LYX_STD_COUNT
  98 dnl we disable rtti for now
  99 dnl LYX_CXX_RTTI
 100 AC_CHECK_HEADERS(ostream istream sstream locale)
 101 LYX_CXX_STL_MODERN_STREAMS
 102
 103 ### We need a regex implementation, so we provide our own if none is found.
 104 LYX_REGEX
 105
 106 ### Library Files
 107 dnl by testing these we check if it is ok to have
 108 dnl -lc and -lm as args to the compiler
 109 AC_CHECK_LIB(m, sin)
 110 AC_CHECK_LIB(c, fopen)
 111
 112 ### Add extra directories to check for libraries.
 113 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 114 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 115 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 116
 117 ### Add extra directories to check for include files.
 118 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 119 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 120 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 121
 122 ### Add both includes and libraries
 123 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 124 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 125 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 126   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 127
 128 ### Check for the -liberty library
 129 test "x$GXX" = xyes && lyx_use_liberty=yes
 130 AC_ARG_WITH(liberty,
 131   [  --without-liberty       do not try to link against libiberty.a],
 132   [lyx_use_liberty=$withval])
 133 if test x$lyx_use_liberty = xyes; then
 134   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 135   AC_CHECK_LIB(iberty,main)
 136 fi
 137
 138 ### Check which libsigc++ we're using
 139 LYX_WITH_SIGC
 140
 141 ### Check if we want pspell libraries
 142 CHECK_WITH_PSPELL
 143
 144 ### Check for X libraries
 145 # Check for the pt library (for SCO, needed for X)
 146 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 147 # The real thing.
 148 AC_PATH_XTRA
 149 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 150 # Since solaris X headers use int as implicit return type and modern
 151 # gcc's do not like that, let's use -isystem instead of -I.
 152 # We should test for gcc version and see whether it supports -isystem,
 153 # but since at least gcc 2.6.x supports it and it is still too old for
 154 # us, it seems we are safe.
 155 if test -n "$GXX" ; then
 156   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 157 fi
 158 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 159
 160 ## Check whether X is new enough to handle the input method stuff
 161 AC_CHECK_FUNCS(XOpenIM)
 162
 163 ### check which frontend we want to use
 164 #LYX_USE_FRONTEND
 165 dnl The code below is not in a macro, because this would cause big
 166 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 167 case "$lyx_use_frontend" in
 168   kde)
 169     KDE_DO_IT_ALL
 170     FRONTEND="kde"
 171     FRONTEND_GUILIB="\${top_builddir}/src/frontends/kde/libkde.la"
 172     FRONTEND_LDFLAGS="\$(QT_LDFLAGS) \$(KDE_LDFLAGS)"
 173     FRONTEND_INCLUDES="-I\${srcdir}/kde \$(QT_INCLUDES) \$(KDE_INCLUDES)"
 174     FRONTEND_LIBS="\$(KDE_LIBS)";;
 175   xforms)
 176   # for now don't set it for xforms as this is always entered
 177     FRONTEND=""
 178     FRONTEND_GUILIB="\${top_builddir}/src/frontends/xforms/libxforms.la";;
 179   gnome)
 180     AM_PATH_GTKMM(1.2.1,,
 181         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 182     AM_PATH_GNOMEMM
 183
 184     FRONTEND="gnome"
 185     FRONTEND_GUILIB="\${top_builddir}/src/frontends/gnome/libgnome.la"
 186     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 187     FRONTEND_INCLUDES="-I\${srcdir}/gnome \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 188     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS)";;
 189   qt2)
 190     QT2_DO_IT_ALL
 191     FRONTEND="qt2"
 192     FRONTEND_GUILIB="\${top_builddir}/src/frontends/qt2/libqt2.la"
 193     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 194     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT2_INCLUDES)"
 195     FRONTEND_LIBS="\$(QT2_LIBS)";;
 196   *)
 197     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 198 esac
 199
 200 ### Check for xforms and xpm (only if X has been found).
 201 if test "$have_x" = yes ; then
 202 # We surely need these two libraries and want to check carefully the
 203 # version numbers...
 204 LYX_PATH_XPM
 205 LYX_PATH_XFORMS
 206 AC_SUBST(LYX_LIBS)
 207 else
 208 LYX_ERROR(dnl
 209 [Cannot find X window libraries and/or headers. Check your installation.
 210    If you use a Linux system, check that you have installed
 211    the development tools.])
 212 fi
 213
 214 ### Setup GNU gettext
 215 dnl GNU gettext is written in C
 216 AC_LANG_C
 217 # Some tests that may be useful for gettext
 218 AC_C_CONST
 219 AC_C_INLINE
 220 # Do the real setup now
 221 AM_GNU_GETTEXT
 222 # a hack for those who try to change LyX, but do not have gettext installed
 223 case  "${XGETTEXT}" in
 224  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 225 esac
 226
 227 AC_SUBST(LINGUAS)
 228
 229 AC_LANG_CPLUSPLUS
 230
 231 # some standard header files
 232 AC_HEADER_DIRENT
 233 AC_HEADER_MAJOR
 234 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 235
 236 # some annoying header files
 237 #LYX_PATH_HEADER(stl_string_fwd.h)
 238 LYX_STL_STRING_FWD
 239
 240 # some standard structures
 241 AC_HEADER_STAT
 242 AC_HEADER_TIME
 243 AC_STRUCT_ST_BLKSIZE
 244 AC_STRUCT_ST_BLOCKS
 245 AC_STRUCT_ST_RDEV
 246
 247 # some standard types
 248 AC_TYPE_MODE_T
 249 AC_TYPE_OFF_T
 250 AC_TYPE_PID_T
 251 AC_TYPE_SIGNAL
 252 AC_TYPE_SIZE_T
 253 AC_TYPE_UID_T
 254
 255 # some functions we'd like to have
 256 AC_ARG_WITH(broken-headers,
 257     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 258     [lyx_broken_headers=$withval])
 259 if test "x$lyx_broken_headers" = "xyes"; then
 260   lyx_flags="$lyx_flags broken-headers"
 261   AC_DEFINE(BROKEN_HEADERS, 1,
 262     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 263 fi
 264 AC_CHECK_FUNCS(snprintf vsnprintf)
 265 LYX_CHECK_DECL(snprintf, stdio.h)
 266 LYX_CHECK_DECL(vsnprintf, stdio.h)
 267
 268 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo \
 269   mkstemp mktemp)
 270
 271 dnl Until this is fixed in autoconf we provide our own version
 272 LYX_FUNC_SELECT_ARGTYPES
 273
 274 dnl check whether we have to work around solaris broken putenv()
 275 LYX_FUNC_PUTENV_ARGTYPE
 276
 277 # SunOS 4.1.3 does not have strerror and atexit
 278 AC_REPLACE_FUNCS(strerror atexit)
 279
 280 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 281
 282 ### and now some special lyx flags.
 283 AC_ARG_ENABLE(assertions,
 284   [  --enable-assertions     add runtime sanity checks in the program],,
 285   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 286         enable_assertions=yes;
 287     else
 288         enable_assertions=no;
 289     fi;])
 290 if test "x$enable_assertions" = xyes ; then
 291    lyx_flags="$lyx_flags assertions"
 292    AC_DEFINE(ENABLE_ASSERTIONS,1,
 293     [Define if you want assertions to be enabled in the code])
 294 fi
 295
 296 ### Finish the work.
 297 AC_CONFIG_SUBDIRS(boost sigc++ lib lib/reLyX)
 298 AC_OUTPUT([Makefile \
 299        development/lyx.spec \
 300        lib/Makefile \
 301        intl/Makefile \
 302        po/Makefile.in \
 303        sourcedoc/Doxyfile \
 304        src/Makefile \
 305        src/mathed/Makefile \
 306        src/graphics/Makefile \
 307        src/insets/Makefile \
 308        src/support/Makefile \
 309        src/frontends/Makefile \
 310        src/frontends/support/Makefile \
 311        src/frontends/xforms/Makefile \
 312        src/frontends/qt2/Makefile \
 313        src/frontends/kde/Makefile \
 314        src/frontends/kde/moc/Makefile \
 315        src/frontends/kde/dlg/Makefile \
 316        src/frontends/kde/dlg/moc/Makefile \
 317        src/frontends/gnome/Makefile \
 318 ],  [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 319
 320
 321 cat <<EOF
 322
 323 Configuration:
 324   Source code location:       ${srcdir}
 325   C++ Compiler:                   ${CXX}
 326   C++ Compiler flags:             ${CXXFLAGS}
 327   C   Compiler:                   ${CC}
 328   C   Compiler flags:             ${CFLAGS}
 329   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 330   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 331   Special flags:              ${lyx_flags}
 332
 333 EOF
 334
 335 # Display a final warning if there has been a LYX_ERROR
 336 LYX_CHECK_ERRORS