configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 LYX_VERSION_SUFFIX
  15
  16 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  17
  18 # The list of languages known to LyX
  19 # This is needed by GNU gettext
  20 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  21
  22 AC_PREFIX_PROGRAM(lyx)
  23
  24 # fix the value of the prefixes.
  25 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  26 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  27
  28 ### Set the execute permissions of the various scripts correctly
  29 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  30   chmod 755 ${srcdir}/${file}
  31 done
  32
  33 ### Check for programs
  34 AC_PROG_MAKE_SET
  35 AC_PROG_INSTALL
  36 #AC_PROG_RANLIB
  37 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  38 if test "x$KPSEWHICH" = xkpsewhich ; then
  39     AC_DEFINE(HAVE_KPSEWHICH, 1,
  40     [Define this if you have the kpsewhich program working on your system.])
  41 fi
  42
  43 # Work around a problem in automake 1.4: when invoking install-strip,
  44 # INSTALL_PROGRAM is changed to 'install -s', and since
  45 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  46 # which returns an error condition when stripping fails.
  47 INSTALL_SCRIPT='${INSTALL}'
  48
  49 ### we will also need a C compiler to compile GNU gettext
  50 AC_PROG_CC
  51
  52 ### check for special systems
  53 AC_ISC_POSIX
  54 AC_AIX
  55 LYX_HPUX
  56 LYX_SUNOS4
  57 LYX_SCO
  58
  59 ### Check for program extensions (.exe or nothing)
  60 AC_EXEEXT
  61
  62 ### check which frontend we want to use
  63 LYX_USE_FRONTEND
  64 dnl The code below is not in a macro, because this would cause big
  65 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  66 case "$lyx_use_frontend" in
  67   gnome)
  68     GNOME_INIT
  69     GNOME_COMPILE_WARNINGS
  70     GNOME_X_CHECKS
  71 esac
  72
  73 ### Check for a C++ compiler
  74 AC_LANG_CPLUSPLUS
  75 LYX_PROG_CXX
  76 AC_PROG_CXXCPP
  77 ### Some checks on what the C++ compiler can(not) do
  78 dnl we do not need that currently (and probably all our supported
  79 dnl compiler allow that)
  80 dnl LYX_CXX_PARTIAL
  81 LYX_CXX_EXPLICIT
  82 LYX_CXX_STL_STRING
  83 LYX_CXX_GOOD_STD_STRING
  84 LYX_CXX_CHEADERS
  85 LYX_CXX_GLOBAL_CSTD
  86 LYX_STD_COUNT
  87 dnl we disable rtti for now
  88 dnl LYX_CXX_RTTI
  89 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  90 LYX_CXX_STL_MODERN_STREAMS
  91
  92 ### and now some special lyx flags.
  93 AC_ARG_ENABLE(assertions,
  94   [  --enable-assertions     add runtime sanity checks in the program],,
  95   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  96         enable_assertions=yes;
  97     else
  98         enable_assertions=no;
  99     fi;])
 100 if test "x$enable_assertions" = xyes ; then
 101    lyx_flags="$lyx_flags assertions"
 102    AC_DEFINE(ENABLE_ASSERTIONS,1,
 103     [Define if you want assertions to be enabled in the code])
 104 fi
 105
 106 ### We need a regex implementation, so we provide our own if none is found.
 107 LYX_REGEX
 108
 109 ### Library Files
 110 dnl by testing these we check if it is ok to have
 111 dnl -lc and -lm as args to the compiler
 112 AC_CHECK_LIB(m, sin)
 113 AC_CHECK_LIB(c, fopen)
 114 AC_CHECK_LIB(bz2, main)
 115 AC_CHECK_LIB(AikSaurus, main,
 116         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 117          AIKSAURUS_LIBS="-lAikSaurus"
 118          AC_SUBST(AIKSAURUS_LIBS)
 119         ])
 120
 121 ### Add extra directories to check for libraries.
 122 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 123 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 124 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 125
 126 ### Add extra directories to check for include files.
 127 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 128 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 129 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 130
 131 ### Add both includes and libraries
 132 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 133 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 134 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 135   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 136
 137 ### Check for the -liberty library
 138 test "x$GXX" = xyes && lyx_use_liberty=yes
 139 AC_ARG_WITH(liberty,
 140   [  --without-liberty       do not try to link against libiberty.a],
 141   [lyx_use_liberty=$withval])
 142 if test x$lyx_use_liberty = xyes; then
 143   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 144   AC_CHECK_LIB(iberty,main)
 145 fi
 146
 147 ### Setup libtool
 148 AC_DISABLE_SHARED
 149 AC_LIBTOOL_WIN32_DLL
 150 #AM_PROG_LIBTOOL
 151 LYX_PROG_LIBTOOL
 152
 153 ### Check which libsigc++ we're using
 154 LYX_WITH_SIGC
 155
 156 ### Check if we want pspell libraries
 157 CHECK_WITH_PSPELL
 158
 159 ### Check for X libraries
 160 # Check for the pt library (for SCO, needed for X)
 161 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 162 # The real thing.
 163 AC_PATH_XTRA
 164 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 165 # Since solaris X headers use int as implicit return type and modern
 166 # gcc's do not like that, let's use -isystem instead of -I.
 167 # We should test for gcc version and see whether it supports -isystem,
 168 # but since at least gcc 2.6.x supports it and it is still too old for
 169 # us, it seems we are safe.
 170 if test -n "$GXX" ; then
 171   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 172 fi
 173 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 174
 175 ## Check whether X is new enough to handle the input method stuff
 176 AC_CHECK_FUNCS(XOpenIM)
 177
 178 ### check which frontend we want to use
 179 #LYX_USE_FRONTEND
 180 dnl The code below is not in a macro, because this would cause big
 181 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 182 case "$lyx_use_frontend" in
 183   xforms)
 184   # for now don't set it for xforms as this is always entered
 185     FRONTEND=""
 186     FRONTEND_GUILIB="xforms/libxforms.la";;
 187   gnome)
 188     AM_PATH_GTKMM(1.2.1,,
 189         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 190     AM_PATH_GNOMEMM
 191
 192 dnl ******************************
 193 dnl LibGlade checking
 194 dnl ******************************
 195 dnl Ensure gnome-config is available...
 196         AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 197         AC_MSG_CHECKING(for Glade libraries)
 198         if $GNOME_CONFIG --libs libglade > /dev/null 2>&1; then
 199         AC_MSG_RESULT(found)
 200         else
 201             AC_MSG_ERROR(Did not find libGlade installed)
 202         fi
 203
 204     FRONTEND="gnome"
 205     FRONTEND_GUILIB="gnome/libgnome.la"
 206     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 207     FRONTEND_INCLUDES="-I\${srcdir}/gnome \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 208     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS) `gnome-config --libs libglade`";;
 209   qt2)
 210     QT2_DO_IT_ALL
 211     FRONTEND="qt2"
 212     FRONTEND_GUILIB="qt2/libqt2.la"
 213     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 214     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT2_INCLUDES)"
 215     FRONTEND_LIBS="\$(QT2_LIBS)";;
 216   *)
 217     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 218 esac
 219
 220 ### Check for xforms and xpm (only if X has been found).
 221 if test "$have_x" = yes ; then
 222 # We surely need these two libraries and want to check carefully the
 223 # version numbers...
 224 LYX_PATH_XPM
 225 LYX_PATH_XFORMS
 226 AC_SUBST(LYX_LIBS)
 227 else
 228 LYX_ERROR(dnl
 229 [Cannot find X window libraries and/or headers. Check your installation.
 230    If you use a Linux system, check that you have installed
 231    the development tools.])
 232 fi
 233
 234 ### Setup GNU gettext
 235 dnl GNU gettext is written in C
 236 AC_LANG_C
 237 # Some tests that may be useful for gettext
 238 AC_C_CONST
 239 AC_C_INLINE
 240 # Do the real setup now
 241 AM_GNU_GETTEXT
 242 # a hack for those who try to change LyX, but do not have gettext installed
 243 case  "${XGETTEXT}" in
 244  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 245 esac
 246
 247 AC_SUBST(LINGUAS)
 248
 249 AC_LANG_CPLUSPLUS
 250
 251 # some standard header files
 252 AC_HEADER_DIRENT
 253 AC_HEADER_MAJOR
 254 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 255
 256 # some annoying header files
 257 #LYX_PATH_HEADER(stl_string_fwd.h)
 258 LYX_STL_STRING_FWD
 259
 260 # some standard structures
 261 AC_HEADER_STAT
 262 AC_HEADER_TIME
 263 AC_STRUCT_ST_BLKSIZE
 264 AC_STRUCT_ST_BLOCKS
 265 AC_STRUCT_ST_RDEV
 266
 267 # some standard types
 268 AC_TYPE_MODE_T
 269 AC_TYPE_OFF_T
 270 AC_TYPE_PID_T
 271 AC_TYPE_SIGNAL
 272 AC_TYPE_SIZE_T
 273 AC_TYPE_UID_T
 274
 275 # some functions we'd like to have
 276 AC_ARG_WITH(broken-headers,
 277     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 278     [lyx_broken_headers=$withval])
 279 if test "x$lyx_broken_headers" = "xyes"; then
 280   lyx_flags="$lyx_flags broken-headers"
 281   AC_DEFINE(BROKEN_HEADERS, 1,
 282     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 283 fi
 284 AC_CHECK_FUNCS(snprintf vsnprintf)
 285 LYX_CHECK_DECL(snprintf, stdio.h)
 286 LYX_CHECK_DECL(vsnprintf, stdio.h)
 287 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 288
 289 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo \
 290   mkstemp mktemp)
 291
 292 dnl Until this is fixed in autoconf we provide our own version
 293 LYX_FUNC_SELECT_ARGTYPES
 294
 295 dnl check whether we have to work around solaris broken putenv()
 296 LYX_FUNC_PUTENV_ARGTYPE
 297
 298 # SunOS 4.1.3 does not have strerror and atexit
 299 AC_REPLACE_FUNCS(strerror atexit)
 300
 301 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 302
 303 ### Finish the work.
 304 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 305 AC_OUTPUT([Makefile \
 306        boost/Makefile \
 307        development/lyx.spec \
 308        lib/Makefile \
 309        intl/Makefile \
 310        po/Makefile.in \
 311        sourcedoc/Doxyfile \
 312        src/Makefile \
 313        src/mathed/Makefile \
 314        src/graphics/Makefile \
 315        src/insets/Makefile \
 316        src/support/Makefile \
 317        src/frontends/Makefile \
 318        src/frontends/support/Makefile \
 319        src/frontends/controllers/Makefile \
 320        src/frontends/xforms/Makefile \
 321        src/frontends/qt2/Makefile \
 322        src/frontends/gnome/Makefile \
 323 ])
 324
 325
 326 cat <<EOF
 327
 328 Configuration:
 329   Source code location:       ${srcdir}
 330   C++ Compiler:                   ${CXX}
 331   C++ Compiler flags:             ${CXXFLAGS}
 332   C   Compiler:                   ${CC}
 333   C   Compiler flags:             ${CFLAGS}
 334   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 335   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 336   Special flags:              ${lyx_flags}
 337
 338 EOF
 339
 340 # Display a final warning if there has been a LYX_ERROR
 341 LYX_CHECK_ERRORS