configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.3.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57
  58 ### Check for program extensions (.exe or nothing)
  59 AC_EXEEXT
  60
  61 ### check which frontend we want to use
  62 LYX_USE_FRONTEND
  63
  64 #old gnome stuff removed by Michael Koziarski 25-05-2002
  65
  66 ### Check for a C++ compiler
  67 LYX_PROG_CXX
  68 ### Some checks on what the C++ compiler can(not) do
  69 AC_LANG_CPLUSPLUS
  70 dnl we do not need that currently (and probably all our supported
  71 dnl compiler allow that)
  72 dnl LYX_CXX_PARTIAL
  73 LYX_CXX_EXPLICIT
  74 LYX_CXX_STL_STRING
  75 LYX_CXX_GOOD_STD_STRING
  76 LYX_CXX_CHEADERS
  77 LYX_CXX_GLOBAL_CSTD
  78 LYX_STD_COUNT
  79 dnl we disable rtti for now
  80 dnl LYX_CXX_RTTI
  81 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  82 LYX_CXX_STL_MODERN_STREAMS
  83
  84 ### and now some special lyx flags.
  85 AC_ARG_ENABLE(assertions,
  86   [  --enable-assertions     add runtime sanity checks in the program],,
  87   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  88         enable_assertions=yes;
  89     else
  90         enable_assertions=no;
  91     fi;])
  92 if test "x$enable_assertions" = xyes ; then
  93    lyx_flags="$lyx_flags assertions"
  94    AC_DEFINE(ENABLE_ASSERTIONS,1,
  95     [Define if you want assertions to be enabled in the code])
  96 fi
  97
  98 ### Library Files
  99 dnl by testing these we check if it is ok to have
 100 dnl -lc and -lm as args to the compiler
 101 AC_CHECK_LIB(m, sin)
 102 AC_CHECK_LIB(c, fopen)
 103
 104 ### Add extra directories to check for libraries.
 105 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 106 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 107 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 108
 109 ### Add extra directories to check for include files.
 110 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 111 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 112 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 113
 114 ### Add both includes and libraries
 115 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 116 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 117 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 118   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 119
 120 AC_ARG_WITH(aiksaurus,
 121   [  --without-aiksaurus     do not use the Aiksaurus library],
 122   [lyx_use_aiksaurus=$withval])
 123 if test x$lyx_use_aiksaurus != xno; then
 124 AC_CHECK_LIB(Aiksaurus, main,
 125         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 126          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 127         ],,"-lbz2")
 128 fi
 129 AC_SUBST(AIKSAURUS_LIBS)
 130
 131 ### Setup libtool
 132 AC_DISABLE_SHARED
 133 AC_LIBTOOL_WIN32_DLL
 134 #AM_PROG_LIBTOOL
 135 LYX_PROG_LIBTOOL
 136
 137 ### Check if we want pspell libraries
 138 CHECK_WITH_PSPELL
 139
 140 ### Check for X libraries
 141 # The real thing.
 142 AC_PATH_XTRA
 143 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 144 # Since solaris X headers use int as implicit return type and modern
 145 # gcc's do not like that, let's use -isystem instead of -I.
 146 # We should test for gcc version and see whether it supports -isystem,
 147 # but since at least gcc 2.6.x supports it and it is still too old for
 148 # us, it seems we are safe.
 149 if test -n "$GXX" ; then
 150   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 151 fi
 152 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 153
 154 ## Check whether X is new enough to handle the input method stuff
 155 AC_CHECK_FUNCS(XOpenIM)
 156
 157 ### check which frontend we want to use
 158 # We have to check for xforms anyway
 159 LYX_PATH_XPM
 160 LYX_PATH_XFORMS
 161
 162 #LYX_USE_FRONTEND
 163 dnl The code below is not in a macro, because this would cause big
 164 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 165 case "$lyx_use_frontend" in
 166   xforms)
 167   # for now don't set it for xforms as this is always entered
 168         FRONTEND="xforms"
 169         FRONTEND_GUILIB="xforms/*.lo xforms/forms/*.lo"
 170         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 171         case "$host" in
 172           *cygwin)
 173             FRONTEND_LIBS="@XFORMS_LIB@ @XFORMS_IMAGE_LIB@ @XPM_LIB@"
 174             ;;
 175           *)
 176             FRONTEND_LIBS="@XFORMS_IMAGE_LIB@ @XFORMS_LIB@ @XPM_LIB@"
 177             ;;
 178         esac
 179         FRONTEND_INFO="    libXpm version:               ${XPM_VERSION}\n\
 180     libforms version:             ${XFORMS_VERSION}\n"
 181         ;;
 182   gnome)
 183     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 184     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 185     AC_SUBST(GNOME_FRONTEND_LIBS)
 186
 187     FRONTEND="xforms gnome"
 188     FRONTEND_GUILIB="gnome/*.lo"
 189     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 190     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 191     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}";;
 192   qt2)
 193     QT2_DO_IT_ALL
 194     FRONTEND="qt2"
 195     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo"
 196     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 197     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT2_INCLUDES)"
 198     FRONTEND_LIBS="\$(QT2_LIBS)";;
 199   *)
 200     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 201 esac
 202
 203 ### Check for xforms and xpm (only if X has been found).
 204 if test "$have_x" = no ; then
 205 LYX_ERROR(dnl
 206 [Cannot find X window libraries and/or headers. Check your installation.
 207    If you use a Linux system, check that you have installed
 208    the development tools.])
 209 fi
 210
 211 ### Check whether the xforms library has a viable image loader
 212 ### For now, run this test always so config.h is unchanged by a change in
 213 ### frontend
 214 LYX_USE_XFORMS_IMAGE_LOADER
 215
 216 ### Setup GNU gettext
 217 dnl GNU gettext is written in C
 218 AC_LANG_C
 219 # Some tests that may be useful for gettext
 220 AC_C_CONST
 221 AC_C_INLINE
 222 # Do the real setup now
 223 AM_GNU_GETTEXT
 224 # a hack for those who try to change LyX, but do not have gettext installed
 225 case  "${XGETTEXT}" in
 226  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 227 esac
 228
 229 AC_SUBST(LINGUAS)
 230
 231 AC_LANG_CPLUSPLUS
 232
 233 # some standard header files
 234 AC_HEADER_DIRENT
 235 AC_HEADER_MAJOR
 236 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 237
 238 # some standard structures
 239 AC_HEADER_STAT
 240 AC_HEADER_TIME
 241
 242 # some standard types
 243 AC_TYPE_MODE_T
 244 AC_TYPE_OFF_T
 245 AC_TYPE_PID_T
 246 AC_TYPE_SIGNAL
 247 AC_TYPE_SIZE_T
 248 AC_TYPE_UID_T
 249
 250 AC_CHECK_FUNCS(snprintf vsnprintf)
 251 LYX_CHECK_DECL(snprintf, stdio.h)
 252 LYX_CHECK_DECL(vsnprintf, stdio.h)
 253 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 254
 255 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 256 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 257 dnl We aim to remove this eventually, since we should test as much as
 258 dnl possible with the compiler which will use the functions (JMarc)
 259 AC_LANG_C
 260 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo mkstemp mktemp)
 261 AC_LANG_CPLUSPLUS
 262
 263 dnl Until this is fixed in autoconf we provide our own version
 264 LYX_FUNC_SELECT_ARGTYPES
 265
 266 dnl check whether we have to work around solaris broken putenv()
 267 LYX_FUNC_PUTENV_ARGTYPE
 268
 269
 270 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 271
 272 ### Some information on what just happened
 273 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 274 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 275 VERSION_INFO="Configuration\n\
 276   Host type:                      ${host}\n\
 277   Special build flags:           ${lyx_flags}\n\
 278   C   Compiler:                   ${CC}\n\
 279   C   Compiler flags:             ${CFLAGS}\n\
 280   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 281   C++ Compiler flags:             ${CXXFLAGS}\n\
 282   Linker flags:                   ${LDFLAGS}\n\
 283   Frontend:                       ${lyx_use_frontend}\n\
 284 ${FRONTEND_INFO}\
 285   LyX binary dir:                 ${real_bindir}\n\
 286   LyX files dir:                  ${real_datadir}\n"
 287
 288
 289 AC_SUBST(VERSION_INFO)
 290
 291 ### Finish the work.
 292 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 293 AC_OUTPUT([Makefile \
 294        boost/Makefile \
 295        boost/libs/Makefile \
 296        boost/libs/regex/Makefile \
 297        boost/libs/regex/src/Makefile \
 298        boost/libs/signals/Makefile \
 299        boost/libs/signals/src/Makefile \
 300        config/Makefile \
 301        development/lyx.spec \
 302        lib/Makefile \
 303        intl/Makefile \
 304        po/Makefile.in \
 305        sourcedoc/Doxyfile \
 306        src/Makefile \
 307        src/version.C \
 308        src/mathed/Makefile \
 309        src/graphics/Makefile \
 310        src/insets/Makefile \
 311        src/support/Makefile \
 312        src/frontends/Makefile \
 313        src/frontends/controllers/Makefile \
 314        src/frontends/xforms/Makefile \
 315        src/frontends/xforms/forms/Makefile \
 316        src/frontends/qt2/Makefile \
 317        src/frontends/qt2/moc/Makefile \
 318        src/frontends/qt2/ui/Makefile \
 319        src/frontends/qt2/ui/moc/Makefile \
 320        src/frontends/gnome/Makefile \
 321 ])
 322
 323 # show version information
 324 echo
 325 printf "$VERSION_INFO"
 326 echo
 327
 328 # Display a final warning if there has been a LYX_ERROR
 329 LYX_CHECK_ERRORS