configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.3.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### check which frontend we want to use
  65 LYX_USE_FRONTEND
  66
  67 #old gnome stuff removed by Michael Koziarski 25-05-2002
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71 ### Some checks on what the C++ compiler can(not) do
  72 AC_LANG_CPLUSPLUS
  73 dnl we do not need that currently (and probably all our supported
  74 dnl compiler allow that)
  75 dnl LYX_CXX_PARTIAL
  76 LYX_CXX_EXPLICIT
  77 LYX_CXX_STL_STRING
  78 LYX_CXX_GOOD_STD_STRING
  79 LYX_CXX_CHEADERS
  80 LYX_CXX_GLOBAL_CSTD
  81 LYX_STD_COUNT
  82 dnl we disable rtti for now
  83 dnl LYX_CXX_RTTI
  84 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  85 LYX_CXX_STL_MODERN_STREAMS
  86
  87 ### and now some special lyx flags.
  88 AC_ARG_ENABLE(assertions,
  89   [  --enable-assertions     add runtime sanity checks in the program],,
  90   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  91         enable_assertions=yes;
  92     else
  93         enable_assertions=no;
  94     fi;])
  95 if test "x$enable_assertions" = xyes ; then
  96    lyx_flags="$lyx_flags assertions"
  97    AC_DEFINE(ENABLE_ASSERTIONS,1,
  98     [Define if you want assertions to be enabled in the code])
  99 fi
 100
 101 ### Library Files
 102 dnl by testing these we check if it is ok to have
 103 dnl -lc and -lm as args to the compiler
 104 AC_CHECK_LIB(m, sin)
 105 AC_CHECK_LIB(c, fopen)
 106
 107 ### Add extra directories to check for libraries.
 108 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 109 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 110 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 111
 112 ### Add extra directories to check for include files.
 113 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 114 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 115 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 116
 117 ### Add both includes and libraries
 118 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 119 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 120 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 121   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 122
 123 ### Check for the -liberty library
 124 test "x$GXX" = xyes && lyx_use_liberty=yes
 125 AC_ARG_WITH(liberty,
 126   [  --without-liberty       do not try to link against libiberty.a],
 127   [lyx_use_liberty=$withval])
 128 if test x$lyx_use_liberty = xyes; then
 129   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 130   AC_CHECK_LIB(iberty,main)
 131 fi
 132
 133 AC_ARG_WITH(aiksaurus,
 134   [  --without-aiksaurus     do not use the Aiksaurus library],
 135   [lyx_use_aiksaurus=$withval])
 136 if test x$lyx_use_aiksaurus != xno; then
 137 AC_CHECK_LIB(Aiksaurus, main,
 138         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 139          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 140         ],,"-lbz2")
 141 fi
 142 AC_SUBST(AIKSAURUS_LIBS)
 143
 144 ### Setup libtool
 145 AC_DISABLE_SHARED
 146 AC_LIBTOOL_WIN32_DLL
 147 #AM_PROG_LIBTOOL
 148 LYX_PROG_LIBTOOL
 149
 150 ### Check if we want pspell libraries
 151 CHECK_WITH_PSPELL
 152
 153 ### Check for X libraries
 154 # The real thing.
 155 AC_PATH_XTRA
 156 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 157 # Since solaris X headers use int as implicit return type and modern
 158 # gcc's do not like that, let's use -isystem instead of -I.
 159 # We should test for gcc version and see whether it supports -isystem,
 160 # but since at least gcc 2.6.x supports it and it is still too old for
 161 # us, it seems we are safe.
 162 if test -n "$GXX" ; then
 163   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 164 fi
 165 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 166
 167 ## Check whether X is new enough to handle the input method stuff
 168 AC_CHECK_FUNCS(XOpenIM)
 169
 170 ### check which frontend we want to use
 171 # We have to check for xforms anyway
 172 LYX_PATH_XPM
 173 LYX_PATH_XFORMS
 174
 175 #LYX_USE_FRONTEND
 176 dnl The code below is not in a macro, because this would cause big
 177 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 178 case "$lyx_use_frontend" in
 179   xforms)
 180   # for now don't set it for xforms as this is always entered
 181         FRONTEND="xforms"
 182         FRONTEND_GUILIB="xforms/*.lo"
 183         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 184         FRONTEND_LIBS="@XFORMS_IMAGE_LIB@ @XFORMS_LIB@ @XPM_LIB@"
 185         FRONTEND_INFO=`cat <<EOF
 186     libXpm version:               ${XPM_VERSION}\n\
 187     libforms version:             ${XFORMS_VERSION}\n
 188 `
 189         ;;
 190   gnome)
 191     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 192     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 193     AC_SUBST(GNOME_FRONTEND_LIBS)
 194
 195     FRONTEND="xforms gnome"
 196     FRONTEND_GUILIB="gnome/*.lo"
 197     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 198     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 199     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}";;
 200   qt2)
 201     QT2_DO_IT_ALL
 202     FRONTEND="qt2"
 203     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo qt2/xforms/*.lo"
 204     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 205     FRONTEND_INCLUDES="-I\${srcdir}/qt2 -I\${top_srcdir}/src/frontends/xforms \$(QT2_INCLUDES)"
 206     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ \$(QT2_LIBS)";;
 207   *)
 208     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 209 esac
 210
 211 ### Check for xforms and xpm (only if X has been found).
 212 if test "$have_x" = no ; then
 213 # We surely need these two libraries and want to check carefully the
 214 # version numbers...
 215 #LYX_PATH_XPM
 216 #LYX_PATH_XFORMS
 217 #FRONTEND_INFO=`cat <<EOF
 218 #    libXpm version:               ${XPM_VERSION}\n\
 219 #    libforms version:             ${XFORMS_VERSION}\n
 220 #`
 221 #
 222 #AC_SUBST(LYX_LIBS)
 223 #else
 224 LYX_ERROR(dnl
 225 [Cannot find X window libraries and/or headers. Check your installation.
 226    If you use a Linux system, check that you have installed
 227    the development tools.])
 228 fi
 229
 230 ### Check whether the xforms library has a viable image loader
 231 ### For now, run this test always so config.h is unchanged by a change in
 232 ### frontend
 233 LYX_USE_XFORMS_IMAGE_LOADER
 234
 235 ### Setup GNU gettext
 236 dnl GNU gettext is written in C
 237 AC_LANG_C
 238 # Some tests that may be useful for gettext
 239 AC_C_CONST
 240 AC_C_INLINE
 241 # Do the real setup now
 242 AM_GNU_GETTEXT
 243 # a hack for those who try to change LyX, but do not have gettext installed
 244 case  "${XGETTEXT}" in
 245  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 246 esac
 247
 248 AC_SUBST(LINGUAS)
 249
 250 AC_LANG_CPLUSPLUS
 251
 252 # some standard header files
 253 AC_HEADER_DIRENT
 254 AC_HEADER_MAJOR
 255 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 256
 257 # some annoying header files
 258 #LYX_PATH_HEADER(stl_string_fwd.h)
 259 LYX_STL_STRING_FWD
 260
 261 # some standard structures
 262 AC_HEADER_STAT
 263 AC_HEADER_TIME
 264 AC_STRUCT_ST_BLKSIZE
 265 AC_STRUCT_ST_BLOCKS
 266 AC_STRUCT_ST_RDEV
 267
 268 # some standard types
 269 AC_TYPE_MODE_T
 270 AC_TYPE_OFF_T
 271 AC_TYPE_PID_T
 272 AC_TYPE_SIGNAL
 273 AC_TYPE_SIZE_T
 274 AC_TYPE_UID_T
 275
 276 # some functions we'd like to have
 277 AC_ARG_WITH(broken-headers,
 278     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 279     [lyx_broken_headers=$withval])
 280 if test "x$lyx_broken_headers" = "xyes"; then
 281   lyx_flags="$lyx_flags broken-headers"
 282   AC_DEFINE(BROKEN_HEADERS, 1,
 283     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 284 fi
 285 AC_CHECK_FUNCS(snprintf vsnprintf)
 286 LYX_CHECK_DECL(snprintf, stdio.h)
 287 LYX_CHECK_DECL(vsnprintf, stdio.h)
 288 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 289
 290 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 291 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 292 dnl We aim to remove this eventually, since we should test as much as
 293 dnl possible with the compiler which will use the functions (JMarc)
 294 AC_LANG_C
 295 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo mkstemp mktemp)
 296 # SunOS 4.1.3 does not have strerror and atexit
 297 AC_REPLACE_FUNCS(strerror atexit)
 298 AC_LANG_CPLUSPLUS
 299
 300 dnl Until this is fixed in autoconf we provide our own version
 301 LYX_FUNC_SELECT_ARGTYPES
 302
 303 dnl check whether we have to work around solaris broken putenv()
 304 LYX_FUNC_PUTENV_ARGTYPE
 305
 306
 307 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 308
 309 ### Some information on what just happened
 310 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 311 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 312 VERSION_INFO=`cat <<EOF
 313 Configuration\n\
 314   Host type:                      ${host_alias}\n\
 315   Special build flags:           ${lyx_flags}\n\
 316   C   Compiler:                   ${CC}\n\
 317   C   Compiler flags:             ${CFLAGS}\n\
 318   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 319   C++ Compiler flags:             ${CXXFLAGS}\n\
 320   Linker flags:                   ${LDFLAGS}\n\
 321   Frontend:                       ${lyx_use_frontend}\n\
 322 ${FRONTEND_INFO}\
 323   LyX binary dir:                 ${real_bindir}\n\
 324   LyX files dir:                  ${real_datadir}\n
 325 `
 326
 327 AC_SUBST(VERSION_INFO)
 328
 329 ### Finish the work.
 330 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 331 AC_OUTPUT([Makefile \
 332        boost/Makefile \
 333        boost/libs/Makefile \
 334        boost/libs/regex/Makefile \
 335        boost/libs/regex/src/Makefile \
 336        boost/libs/signals/Makefile \
 337        boost/libs/signals/src/Makefile \
 338        config/Makefile \
 339        development/lyx.spec \
 340        lib/Makefile \
 341        intl/Makefile \
 342        po/Makefile.in \
 343        sourcedoc/Doxyfile \
 344        src/Makefile \
 345        src/version.C \
 346        src/mathed/Makefile \
 347        src/graphics/Makefile \
 348        src/insets/Makefile \
 349        src/support/Makefile \
 350        src/frontends/Makefile \
 351        src/frontends/controllers/Makefile \
 352        src/frontends/xforms/Makefile \
 353        src/frontends/xforms/forms/Makefile \
 354        src/frontends/qt2/Makefile \
 355        src/frontends/qt2/xforms/Makefile \
 356        src/frontends/qt2/moc/Makefile \
 357        src/frontends/qt2/ui/Makefile \
 358        src/frontends/qt2/ui/moc/Makefile \
 359        src/frontends/gnome/Makefile \
 360 ])
 361
 362 # show version information
 363 echo
 364 printf "$VERSION_INFO"
 365 echo
 366
 367 # Display a final warning if there has been a LYX_ERROR
 368 LYX_CHECK_ERRORS