configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.3.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="bg ca cs da de es eu fi fr he hu it nl no pl pt ro ru sk sl sv tr wa"
  24
  25 # fix the value of the prefixes.
  26 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  28
  29 ### Set the execute permissions of the various scripts correctly
  30 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  31   chmod 755 ${srcdir}/${file}
  32 done
  33
  34 ### Check for programs
  35 AC_PROG_MAKE_SET
  36 AC_PROG_INSTALL
  37 #AC_PROG_RANLIB
  38 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  39 if test "x$KPSEWHICH" = xkpsewhich ; then
  40     AC_DEFINE(HAVE_KPSEWHICH, 1,
  41     [Define this if you have the kpsewhich program working on your system.])
  42 fi
  43 AC_CHECK_PROGS(M4, gm4 gnum4 m4, m4)
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### check which frontend we want to use
  65 LYX_USE_FRONTEND
  66
  67 #old gnome stuff removed by Michael Koziarski 25-05-2002
  68
  69 ### Check for a C++ compiler
  70 LYX_PROG_CXX
  71 ### Some checks on what the C++ compiler can(not) do
  72 AC_LANG_CPLUSPLUS
  73 dnl we do not need that currently (and probably all our supported
  74 dnl compiler allow that)
  75 dnl LYX_CXX_PARTIAL
  76 LYX_CXX_EXPLICIT
  77 LYX_CXX_STL_STRING
  78 LYX_CXX_GOOD_STD_STRING
  79 LYX_CXX_CHEADERS
  80 LYX_CXX_GLOBAL_CSTD
  81 LYX_STD_COUNT
  82 dnl we disable rtti for now
  83 dnl LYX_CXX_RTTI
  84 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  85 LYX_CXX_STL_MODERN_STREAMS
  86
  87 ### and now some special lyx flags.
  88 AC_ARG_ENABLE(assertions,
  89   [  --enable-assertions     add runtime sanity checks in the program],,
  90   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  91         enable_assertions=yes;
  92     else
  93         enable_assertions=no;
  94     fi;])
  95 if test "x$enable_assertions" = xyes ; then
  96    lyx_flags="$lyx_flags assertions"
  97    AC_DEFINE(ENABLE_ASSERTIONS,1,
  98     [Define if you want assertions to be enabled in the code])
  99 fi
 100
 101 ### Library Files
 102 dnl by testing these we check if it is ok to have
 103 dnl -lc and -lm as args to the compiler
 104 AC_CHECK_LIB(m, sin)
 105 AC_CHECK_LIB(c, fopen)
 106
 107 ### Add extra directories to check for libraries.
 108 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 109 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 110 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 111
 112 ### Add extra directories to check for include files.
 113 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 114 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 115 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 116
 117 ### Add both includes and libraries
 118 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 119 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 120 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 121   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 122
 123 ### Check for the -liberty library
 124 test "x$GXX" = xyes && lyx_use_liberty=yes
 125 AC_ARG_WITH(liberty,
 126   [  --without-liberty       do not try to link against libiberty.a],
 127   [lyx_use_liberty=$withval])
 128 if test x$lyx_use_liberty = xyes; then
 129   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 130   AC_CHECK_LIB(iberty,main)
 131 fi
 132
 133 AC_ARG_WITH(aiksaurus,
 134   [  --without-aiksaurus     do not use the Aiksaurus library],
 135   [lyx_use_aiksaurus=$withval])
 136 if test x$lyx_use_aiksaurus != xno; then
 137 AC_CHECK_LIB(Aiksaurus, main,
 138         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 139          AIKSAURUS_LIBS="-lAiksaurus -lbz2"
 140         ],,"-lbz2")
 141 fi
 142 AC_SUBST(AIKSAURUS_LIBS)
 143
 144 ### Setup libtool
 145 AC_DISABLE_SHARED
 146 AC_LIBTOOL_WIN32_DLL
 147 #AM_PROG_LIBTOOL
 148 LYX_PROG_LIBTOOL
 149
 150 ### Check if we want pspell libraries
 151 CHECK_WITH_PSPELL
 152
 153 ### Check for X libraries
 154 # The real thing.
 155 AC_PATH_XTRA
 156 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 157 # Since solaris X headers use int as implicit return type and modern
 158 # gcc's do not like that, let's use -isystem instead of -I.
 159 # We should test for gcc version and see whether it supports -isystem,
 160 # but since at least gcc 2.6.x supports it and it is still too old for
 161 # us, it seems we are safe.
 162 if test -n "$GXX" ; then
 163   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 164 fi
 165 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 166
 167 ## Check whether X is new enough to handle the input method stuff
 168 AC_CHECK_FUNCS(XOpenIM)
 169
 170 ### check which frontend we want to use
 171 #LYX_USE_FRONTEND
 172 dnl The code below is not in a macro, because this would cause big
 173 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 174 case "$lyx_use_frontend" in
 175   xforms)
 176   # for now don't set it for xforms as this is always entered
 177         LYX_PATH_XPM
 178         LYX_PATH_XFORMS
 179         FRONTEND="xforms"
 180         FRONTEND_GUILIB="xforms/*.lo"
 181         FRONTEND_INCLUDES="-I\$(srcdir)/xforms"
 182         FRONTEND_LIBS="@XFORMS_IMAGE_LIB@ @XFORMS_LIB@ @XPM_LIB@"
 183         FRONTEND_INFO=`cat <<EOF
 184     libXpm version:               ${XPM_VERSION}\n\
 185     libforms version:             ${XFORMS_VERSION}\n
 186 `
 187         ;;
 188   gnome)
 189     LYX_PATH_XPM
 190     LYX_PATH_XFORMS
 191
 192     PKG_CHECK_MODULES(GNOME_FRONTEND, gtkmm-2.0 libglademm-2.0)
 193     AC_SUBST(GNOME_FRONTEND_CFLAGS)
 194     AC_SUBST(GNOME_FRONTEND_LIBS)
 195
 196     FRONTEND="xforms gnome"
 197     FRONTEND_GUILIB="gnome/*.lo"
 198     FRONTEND_LDFLAGS="${GNOME_FRONTEND_LIBS}"
 199     FRONTEND_INCLUDES="-I\${srcdir}/gnome -I\${srcdir}/xforms ${GNOME_FRONTEND_CFLAGS} "
 200     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ ${GNOME_FRONTEND_LIBS}";;
 201   qt2)
 202         LYX_PATH_XPM
 203         LYX_PATH_XFORMS
 204     QT2_DO_IT_ALL
 205     FRONTEND="qt2"
 206     FRONTEND_GUILIB="qt2/*.lo qt2/ui/*.lo qt2/moc/*.lo qt2/ui/moc/*.lo qt2/xforms/*.lo"
 207     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 208     FRONTEND_INCLUDES="-I\${srcdir}/qt2 -I\${top_srcdir}/src/frontends/xforms \$(QT2_INCLUDES)"
 209     FRONTEND_LIBS="@XPM_LIB@ @XFORMS_LIB@ \$(QT2_LIBS)";;
 210   *)
 211     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 212 esac
 213
 214 ### Check for xforms and xpm (only if X has been found).
 215 if test "$have_x" = no ; then
 216 # We surely need these two libraries and want to check carefully the
 217 # version numbers...
 218 #LYX_PATH_XPM
 219 #LYX_PATH_XFORMS
 220 #FRONTEND_INFO=`cat <<EOF
 221 #    libXpm version:               ${XPM_VERSION}\n\
 222 #    libforms version:             ${XFORMS_VERSION}\n
 223 #`
 224 #
 225 #AC_SUBST(LYX_LIBS)
 226 #else
 227 LYX_ERROR(dnl
 228 [Cannot find X window libraries and/or headers. Check your installation.
 229    If you use a Linux system, check that you have installed
 230    the development tools.])
 231 fi
 232
 233 ### Check whether the xforms library has a viable image loader
 234 ### For now, run this test always so config.h is unchanged by a change in
 235 ### frontend
 236 LYX_USE_XFORMS_IMAGE_LOADER
 237 LYX_XFORMS_IMAGE_LOADER_NEEDS_JPEG
 238
 239 ### Setup GNU gettext
 240 dnl GNU gettext is written in C
 241 AC_LANG_C
 242 # Some tests that may be useful for gettext
 243 AC_C_CONST
 244 AC_C_INLINE
 245 # Do the real setup now
 246 AM_GNU_GETTEXT
 247 # a hack for those who try to change LyX, but do not have gettext installed
 248 case  "${XGETTEXT}" in
 249  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 250 esac
 251
 252 AC_SUBST(LINGUAS)
 253
 254 AC_LANG_CPLUSPLUS
 255
 256 # some standard header files
 257 AC_HEADER_DIRENT
 258 AC_HEADER_MAJOR
 259 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h)
 260
 261 # some annoying header files
 262 #LYX_PATH_HEADER(stl_string_fwd.h)
 263 LYX_STL_STRING_FWD
 264
 265 # some standard structures
 266 AC_HEADER_STAT
 267 AC_HEADER_TIME
 268 AC_STRUCT_ST_BLKSIZE
 269 AC_STRUCT_ST_BLOCKS
 270 AC_STRUCT_ST_RDEV
 271
 272 # some standard types
 273 AC_TYPE_MODE_T
 274 AC_TYPE_OFF_T
 275 AC_TYPE_PID_T
 276 AC_TYPE_SIGNAL
 277 AC_TYPE_SIZE_T
 278 AC_TYPE_UID_T
 279
 280 # some functions we'd like to have
 281 AC_ARG_WITH(broken-headers,
 282     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 283     [lyx_broken_headers=$withval])
 284 if test "x$lyx_broken_headers" = "xyes"; then
 285   lyx_flags="$lyx_flags broken-headers"
 286   AC_DEFINE(BROKEN_HEADERS, 1,
 287     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 288 fi
 289 AC_CHECK_FUNCS(snprintf vsnprintf)
 290 LYX_CHECK_DECL(snprintf, stdio.h)
 291 LYX_CHECK_DECL(vsnprintf, stdio.h)
 292 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 293
 294 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 295 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 296 dnl We aim to remove this eventually, since we should test as much as
 297 dnl possible with the compiler which will use the functions (JMarc)
 298 AC_LANG_C
 299 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo mkstemp mktemp)
 300 # SunOS 4.1.3 does not have strerror and atexit
 301 AC_REPLACE_FUNCS(strerror atexit)
 302 AC_LANG_CPLUSPLUS
 303
 304 dnl Until this is fixed in autoconf we provide our own version
 305 LYX_FUNC_SELECT_ARGTYPES
 306
 307 dnl check whether we have to work around solaris broken putenv()
 308 LYX_FUNC_PUTENV_ARGTYPE
 309
 310
 311 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 312
 313 ### Some information on what just happened
 314 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 315 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 316 VERSION_INFO=`cat <<EOF
 317 Configuration\n\
 318   Host type:                      ${host_alias}\n\
 319   Special build flags:           ${lyx_flags}\n\
 320   C   Compiler:                   ${CC}\n\
 321   C   Compiler flags:             ${CFLAGS}\n\
 322   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 323   C++ Compiler flags:             ${CXXFLAGS}\n\
 324   Linker flags:                   ${LDFLAGS}\n\
 325   Frontend:                       ${lyx_use_frontend}\n\
 326 ${FRONTEND_INFO}\
 327   LyX binary dir:                 ${real_bindir}\n\
 328   LyX files dir:                  ${real_datadir}\n
 329 `
 330
 331 AC_SUBST(VERSION_INFO)
 332
 333 ### Finish the work.
 334 AC_CONFIG_SUBDIRS(lib lib/reLyX)
 335 AC_OUTPUT([Makefile \
 336        boost/Makefile \
 337        boost/libs/Makefile \
 338        boost/libs/regex/Makefile \
 339        boost/libs/regex/src/Makefile \
 340        boost/libs/signals/Makefile \
 341        boost/libs/signals/src/Makefile \
 342        config/Makefile \
 343        development/lyx.spec \
 344        lib/Makefile \
 345        intl/Makefile \
 346        po/Makefile.in \
 347        sourcedoc/Doxyfile \
 348        src/Makefile \
 349        src/version.C \
 350        src/mathed/Makefile \
 351        src/graphics/Makefile \
 352        src/insets/Makefile \
 353        src/support/Makefile \
 354        src/frontends/Makefile \
 355        src/frontends/controllers/Makefile \
 356        src/frontends/xforms/Makefile \
 357        src/frontends/xforms/forms/Makefile \
 358        src/frontends/qt2/Makefile \
 359        src/frontends/qt2/xforms/Makefile \
 360        src/frontends/qt2/moc/Makefile \
 361        src/frontends/qt2/ui/Makefile \
 362        src/frontends/qt2/ui/moc/Makefile \
 363        src/frontends/gnome/Makefile \
 364 ])
 365
 366 # show version information
 367 echo
 368 printf "$VERSION_INFO"
 369 echo
 370
 371 # Display a final warning if there has been a LYX_ERROR
 372 LYX_CHECK_ERRORS