configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/lyx.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 AC_ARG_WITH(lyxname,
  15   [  --with-lyxname          the name under which lyx will be installed],
  16   [lyxname=$withval],[lyxname=lyx])
  17
  18 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  19
  20 # The list of languages known to LyX
  21 # This is needed by GNU gettext
  22 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  23
  24 AC_PREFIX_PROGRAM(lyx)
  25
  26 # fix the value of the prefixes.
  27 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  28 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  29
  30 ### Set the execute permissions of the various scripts correctly
  31 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  32   chmod 755 ${srcdir}/${file}
  33 done
  34
  35 ### Check for programs
  36 AC_PROG_MAKE_SET
  37 AC_PROG_INSTALL
  38 #AC_PROG_RANLIB
  39 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  40 if test "x$KPSEWHICH" = xkpsewhich ; then
  41     AC_DEFINE(HAVE_KPSEWHICH, 1,
  42     [Define this if you have the kpsewhich program working on your system.])
  43 fi
  44
  45 # Work around a problem in automake 1.4: when invoking install-strip,
  46 # INSTALL_PROGRAM is changed to 'install -s', and since
  47 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  48 # which returns an error condition when stripping fails.
  49 INSTALL_SCRIPT='${INSTALL}'
  50
  51 ### we will also need a C compiler to compile GNU gettext
  52 AC_PROG_CC
  53
  54 ### check for special systems
  55 AC_ISC_POSIX
  56 AC_AIX
  57 LYX_HPUX
  58 LYX_SUNOS4
  59 LYX_SCO
  60
  61 ### Check for program extensions (.exe or nothing)
  62 AC_EXEEXT
  63
  64 ### Check for a C++ compiler
  65 AC_LANG_CPLUSPLUS
  66 LYX_PROG_CXX
  67 AC_PROG_CXXCPP
  68 AC_DISABLE_SHARED
  69 AC_LIBTOOL_WIN32_DLL
  70 AM_PROG_LIBTOOL
  71
  72 ### Some checks on what the C++ compiler can(not) do
  73 LYX_CXX_MUTABLE
  74 LYX_CXX_PARTIAL
  75 LYX_CXX_EXPLICIT
  76 dnl we do not use stl stack, or at least not on gcc 2.7, which was the
  77 dnl cause for this test.
  78 dnl LYX_CXX_STL_STACK
  79 LYX_CXX_STL_STRING
  80 LYX_CXX_GOOD_STD_STRING
  81 LYX_CXX_NAMESPACES
  82 LYX_CXX_CHEADERS
  83 LYX_STD_COUNT
  84 dnl we disable rtti for now
  85 dnl LYX_CXX_RTTI
  86 AC_CHECK_HEADERS(ostream istream sstream)
  87 LYX_CXX_STL_MODERN_STREAMS
  88 dnl It seems this is needed by gtk/gnome stuff
  89 AC_LANG_C
  90
  91 ### We need a regex implementation, so we provide our own if none is found.
  92 LYX_REGEX
  93
  94 ### Library Files
  95 dnl by testing these we check if it is ok to have
  96 dnl -lc and -lm as args to the compiler
  97 AC_CHECK_LIB(m, sin)
  98 AC_CHECK_LIB(c, fopen)
  99
 100 ### Add extra directories to check for libraries.
 101 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 102 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 103 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 104
 105 ### Add extra directories to check for include files.
 106 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 107 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 108 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 109
 110 ### Add both includes and libraries
 111 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 112 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 113 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 114   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 115
 116 ### Check for the -liberty library
 117 test "x$GXX" = xyes && lyx_use_liberty=yes
 118 AC_ARG_WITH(liberty,
 119   [  --without-liberty       do not try to link against libiberty.a],
 120   [lyx_use_liberty=$withval])
 121 if test x$lyx_use_liberty = xyes; then
 122   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 123   AC_CHECK_LIB(iberty,main)
 124 fi
 125
 126 ### Check which libsigc++ we're using
 127 LYX_WITH_SIGC
 128
 129 ### Check for X libraries
 130 # Check for the pt library (for SCO, needed for X)
 131 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 132 # The real thing.
 133 AC_PATH_XTRA
 134 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 135 # Since solaris X headers use int as implicit return type and modern
 136 # gcc's do not like that, let's use -isystem instead of -I.
 137 # We should test for gcc version and see whether it supports -isystem,
 138 # but since at least gcc 2.6.x supports it and it is still too old for
 139 # us, it seems we are safe.
 140 if test -n "$GXX" ; then
 141   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 142 fi
 143 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 144
 145 ## Check whether X is new enough to handle the input method stuff
 146 AC_CHECK_FUNCS(XOpenIM)
 147
 148 ### check which frontend we want to use
 149 LYX_USE_FRONTEND
 150 dnl The code below is not in a macro, because this would cause big
 151 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 152 case "$lyx_use_frontend" in
 153   kde)
 154     KDE_DO_IT_ALL
 155     FRONTEND="kde"
 156     FRONTEND_GUILIB="\${top_builddir}/src/frontends/kde/libkde.la"
 157     FRONTEND_LDFLAGS="\$(QT_LDFLAGS) \$(KDE_LDFLAGS)"
 158     FRONTEND_INCLUDES="\$(QT_INCLUDES) \$(KDE_INCLUDES)"
 159     FRONTEND_LIBS="\$(KDE_LIBS)"
 160     AC_DEFINE(KDEGUI);;
 161   xforms)
 162     FRONTEND="xforms"
 163     FRONTEND_GUILIB="\${top_builddir}/src/frontends/xforms/libxforms.la";;
 164   gtk)
 165     GNOME_INIT
 166     GNOME_COMPILE_WARNINGS
 167     GNOME_X_CHECKS
 168
 169     AM_PATH_GTKMM(1.2.1,,
 170         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 171     AM_PATH_GNOMEMM
 172
 173     FRONTEND="gtk"
 174     FRONTEND_GUILIB="\${top_builddir}/src/frontends/gtk/libgtk.la"
 175     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR) \$(GNOME_LIBDIR)"
 176     FRONTEND_INCLUDES="\$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS) \$(GNOME_INCLUDEDIR) \$(GTK_CFLAGS)"
 177     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS) \$(GNOME_LIBS) \$(GTK_LIBS)"
 178     AC_DEFINE(GTKGUI);;
 179   *)
 180     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 181 esac
 182
 183 ### Check for xforms and xpm (only if X has been found).
 184 if test "$have_x" = yes ; then
 185 # We surely need these two libraries and want to check carefully the
 186 # version numbers...
 187 LYX_PATH_XPM
 188 LYX_PATH_XFORMS
 189 AC_SUBST(LYX_LIBS)
 190 else
 191 LYX_ERROR(dnl
 192 [Cannot find X window libraries and/or headers. Check your installation.
 193    If you use a Linux system, check that you have installed
 194    the development tools.])
 195 fi
 196
 197 ### Setup GNU gettext
 198 dnl GNU gettext is written in C
 199 AC_LANG_C
 200 # Some tests that may be useful for gettext
 201 AC_C_CONST
 202 AC_C_INLINE
 203 # Do the real setup now
 204 AM_GNU_GETTEXT
 205 # a hack for those who try to change LyX, but do not have gettext installed
 206 case  "${XGETTEXT}" in
 207  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 208 esac
 209
 210 AC_SUBST(LINGUAS)
 211
 212 AC_LANG_CPLUSPLUS
 213
 214 # some standard header files
 215 AC_HEADER_DIRENT
 216 AC_HEADER_MAJOR
 217 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 218
 219 # some annoying header files
 220 #LYX_PATH_HEADER(stl_string_fwd.h)
 221 LYX_STL_STRING_FWD
 222
 223 # some standard structures
 224 AC_HEADER_STAT
 225 AC_HEADER_TIME
 226 AC_STRUCT_ST_BLKSIZE
 227 AC_STRUCT_ST_BLOCKS
 228 AC_STRUCT_ST_RDEV
 229
 230 # some standard types
 231 AC_TYPE_MODE_T
 232 AC_TYPE_OFF_T
 233 AC_TYPE_PID_T
 234 AC_TYPE_SIGNAL
 235 AC_TYPE_SIZE_T
 236 AC_TYPE_UID_T
 237
 238 # some functions we'd like to have
 239 AC_ARG_WITH(broken-headers,
 240     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 241     [lyx_broken_headers=$withval])
 242 if test "x$lyx_broken_headers" = "xyes"; then
 243   lyx_flags="$lyx_flags broken-headers"
 244   AC_DEFINE(BROKEN_HEADERS, 1,
 245     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 246 fi
 247 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo)
 248
 249 dnl Until this is fixed in autoconf we provide our own version
 250 LYX_FUNC_SELECT_ARGTYPES
 251
 252 dnl check whether we have to work around solaris broken putenv()
 253 LYX_FUNC_PUTENV_ARGTYPE
 254
 255 # SunOS 4.1.3 does not have strerror and atexit
 256 AC_REPLACE_FUNCS(strerror atexit)
 257
 258 ### and now some special lyx flags.
 259 AC_ARG_ENABLE(assertions,
 260   [  --enable-assertions     add runtime sanity checks in the program],,
 261   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
 262         enable_assertions=yes;
 263     else
 264         enable_assertions=no;
 265     fi;])
 266 if test "x$enable_assertions" = xyes ; then
 267    lyx_flags="$lyx_flags assertions"
 268    AC_DEFINE(ENABLE_ASSERTIONS,1,
 269     [Define if you want assertions to be enabled in the code])
 270 fi
 271
 272 ### Finish the work.
 273 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 274 AC_OUTPUT([Makefile \
 275        development/lyx.spec \
 276        lib/Makefile \
 277        intl/Makefile \
 278        po/Makefile.in \
 279        src/Makefile \
 280        src/mathed/Makefile \
 281        src/insets/Makefile \
 282        src/support/Makefile \
 283        src/xtl/Makefile \
 284        src/frontends/Makefile \
 285        src/frontends/xforms/Makefile \
 286        src/frontends/kde/Makefile \
 287        src/frontends/gtk/Makefile \
 288 ],  [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
 289
 290
 291 cat <<EOF
 292
 293 Configuration:
 294   Source code location:       ${srcdir}
 295   C++ Compiler:                   ${CXX}
 296   C++ Compiler flags:             ${CXXFLAGS}
 297   C   Compiler:                   ${CC}
 298   C   Compiler flags:             ${CFLAGS}
 299   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 300   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 301   Special flags:              ${lyx_flags}
 302
 303 EOF
 304
 305 # Display a final warning if there has been a LYX_ERROR
 306 LYX_CHECK_ERRORS