configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9
  10 PACKAGE=lyx${program_suffix}
  11 VERSION="1.2.0cvs"
  12 LYX_CHECK_VERSION
  13
  14 AC_CANONICAL_SYSTEM
  15 AC_VALIDATE_CACHE_SYSTEM_TYPE
  16
  17 LYX_VERSION_SUFFIX
  18
  19 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  20
  21 # The list of languages known to LyX
  22 # This is needed by GNU gettext
  23 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  24
  25 AC_PREFIX_PROGRAM(lyx)
  26
  27 # fix the value of the prefixes.
  28 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  29 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  30
  31 ### Set the execute permissions of the various scripts correctly
  32 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  33   chmod 755 ${srcdir}/${file}
  34 done
  35
  36 ### Check for programs
  37 AC_PROG_MAKE_SET
  38 AC_PROG_INSTALL
  39 #AC_PROG_RANLIB
  40 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  41 if test "x$KPSEWHICH" = xkpsewhich ; then
  42     AC_DEFINE(HAVE_KPSEWHICH, 1,
  43     [Define this if you have the kpsewhich program working on your system.])
  44 fi
  45
  46 # Work around a problem in automake 1.4: when invoking install-strip,
  47 # INSTALL_PROGRAM is changed to 'install -s', and since
  48 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  49 # which returns an error condition when stripping fails.
  50 INSTALL_SCRIPT='${INSTALL}'
  51
  52 ### we will also need a C compiler to compile GNU gettext
  53 AC_PROG_CC
  54
  55 ### check for special systems
  56 AC_ISC_POSIX
  57 AC_AIX
  58 LYX_HPUX
  59 LYX_SUNOS4
  60 LYX_SCO
  61
  62 ### Check for program extensions (.exe or nothing)
  63 AC_EXEEXT
  64
  65 ### check which frontend we want to use
  66 LYX_USE_FRONTEND
  67 dnl The code below is not in a macro, because this would cause big
  68 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  69 case "$lyx_use_frontend" in
  70   gnome)
  71     GNOME_INIT
  72     GNOME_COMPILE_WARNINGS
  73     GNOME_X_CHECKS
  74 esac
  75
  76 ### Check for a C++ compiler
  77 AC_LANG_CPLUSPLUS
  78 LYX_PROG_CXX
  79 AC_PROG_CXXCPP
  80 ### Some checks on what the C++ compiler can(not) do
  81 dnl we do not need that currently (and probably all our supported
  82 dnl compiler allow that)
  83 dnl LYX_CXX_PARTIAL
  84 LYX_CXX_EXPLICIT
  85 LYX_CXX_STL_STRING
  86 LYX_CXX_GOOD_STD_STRING
  87 LYX_CXX_CHEADERS
  88 LYX_CXX_GLOBAL_CSTD
  89 LYX_STD_COUNT
  90 dnl we disable rtti for now
  91 dnl LYX_CXX_RTTI
  92 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  93 LYX_CXX_STL_MODERN_STREAMS
  94
  95 ### and now some special lyx flags.
  96 AC_ARG_ENABLE(assertions,
  97   [  --enable-assertions     add runtime sanity checks in the program],,
  98   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  99         enable_assertions=yes;
 100     else
 101         enable_assertions=no;
 102     fi;])
 103 if test "x$enable_assertions" = xyes ; then
 104    lyx_flags="$lyx_flags assertions"
 105    AC_DEFINE(ENABLE_ASSERTIONS,1,
 106     [Define if you want assertions to be enabled in the code])
 107 fi
 108
 109 ### We need a regex implementation, so we provide our own if none is found.
 110 LYX_REGEX
 111
 112 ### Library Files
 113 dnl by testing these we check if it is ok to have
 114 dnl -lc and -lm as args to the compiler
 115 AC_CHECK_LIB(m, sin)
 116 AC_CHECK_LIB(c, fopen)
 117 AC_ARG_WITH(aiksaurus,
 118   [  --without-aiksaurus     do not use the AikSaurus library],
 119   [lyx_use_aiksaurus=$withval])
 120 if test x$lyx_use_aiksaurus != xno; then
 121 AC_CHECK_LIB(AikSaurus, main,
 122         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 123          AIKSAURUS_LIBS="-lAikSaurus -lbz2"
 124         ],,"-lbz2")
 125 fi
 126 AC_SUBST(AIKSAURUS_LIBS)
 127
 128 ### Add extra directories to check for libraries.
 129 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 130 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 131 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 132
 133 ### Add extra directories to check for include files.
 134 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 135 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 136 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 137
 138 ### Add both includes and libraries
 139 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 140 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 141 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 142   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 143
 144 ### Check for the -liberty library
 145 test "x$GXX" = xyes && lyx_use_liberty=yes
 146 AC_ARG_WITH(liberty,
 147   [  --without-liberty       do not try to link against libiberty.a],
 148   [lyx_use_liberty=$withval])
 149 if test x$lyx_use_liberty = xyes; then
 150   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 151   AC_CHECK_LIB(iberty,main)
 152 fi
 153
 154 ### Setup libtool
 155 AC_DISABLE_SHARED
 156 AC_LIBTOOL_WIN32_DLL
 157 #AM_PROG_LIBTOOL
 158 LYX_PROG_LIBTOOL
 159
 160 ### Check which libsigc++ we're using
 161 LYX_WITH_SIGC
 162
 163 ### Check if we want pspell libraries
 164 CHECK_WITH_PSPELL
 165
 166 ### Check for X libraries
 167 # Check for the pt library (for SCO, needed for X)
 168 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 169 # The real thing.
 170 AC_PATH_XTRA
 171 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 172 # Since solaris X headers use int as implicit return type and modern
 173 # gcc's do not like that, let's use -isystem instead of -I.
 174 # We should test for gcc version and see whether it supports -isystem,
 175 # but since at least gcc 2.6.x supports it and it is still too old for
 176 # us, it seems we are safe.
 177 if test -n "$GXX" ; then
 178   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 179 fi
 180 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 181
 182 ## Check whether X is new enough to handle the input method stuff
 183 AC_CHECK_FUNCS(XOpenIM)
 184
 185 ### check which frontend we want to use
 186 #LYX_USE_FRONTEND
 187 dnl The code below is not in a macro, because this would cause big
 188 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 189 case "$lyx_use_frontend" in
 190   xforms)
 191   # for now don't set it for xforms as this is always entered
 192     FRONTEND=""
 193     FRONTEND_GUILIB="xforms/libxforms.la";;
 194   gnome)
 195     AM_PATH_GTKMM(1.2.1,,
 196         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 197     AM_PATH_GNOMEMM
 198
 199 dnl ******************************
 200 dnl LibGlade checking
 201 dnl ******************************
 202 dnl Ensure gnome-config is available...
 203         AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 204         AC_MSG_CHECKING(for Glade libraries)
 205         if $GNOME_CONFIG --libs libglade > /dev/null 2>&1; then
 206         AC_MSG_RESULT(found)
 207         else
 208             AC_MSG_ERROR(Did not find libGlade installed)
 209         fi
 210
 211     FRONTEND="gnome"
 212     FRONTEND_GUILIB="gnome/libgnome.la"
 213     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 214     FRONTEND_INCLUDES="-I\${srcdir}/gnome \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 215     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS) `gnome-config --libs libglade`";;
 216   qt2)
 217     QT2_DO_IT_ALL
 218     FRONTEND="qt2"
 219     FRONTEND_GUILIB="qt2/libqt2.la"
 220     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 221     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT2_INCLUDES)"
 222     FRONTEND_LIBS="\$(QT2_LIBS)";;
 223   *)
 224     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 225 esac
 226
 227 ### Check for xforms and xpm (only if X has been found).
 228 if test "$have_x" = yes ; then
 229 # We surely need these two libraries and want to check carefully the
 230 # version numbers...
 231 LYX_PATH_XPM
 232 LYX_PATH_XFORMS
 233 FRONTEND_INFO=`cat <<EOF
 234     libXpm version:               ${XPM_VERSION}\n\
 235     libforms version:             ${XFORMS_VERSION}\n
 236 `
 237
 238 AC_SUBST(LYX_LIBS)
 239 else
 240 LYX_ERROR(dnl
 241 [Cannot find X window libraries and/or headers. Check your installation.
 242    If you use a Linux system, check that you have installed
 243    the development tools.])
 244 fi
 245
 246 ### Setup GNU gettext
 247 dnl GNU gettext is written in C
 248 AC_LANG_C
 249 # Some tests that may be useful for gettext
 250 AC_C_CONST
 251 AC_C_INLINE
 252 # Do the real setup now
 253 AM_GNU_GETTEXT
 254 # a hack for those who try to change LyX, but do not have gettext installed
 255 case  "${XGETTEXT}" in
 256  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 257 esac
 258
 259 AC_SUBST(LINGUAS)
 260
 261 AC_LANG_CPLUSPLUS
 262
 263 # some standard header files
 264 AC_HEADER_DIRENT
 265 AC_HEADER_MAJOR
 266 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 267
 268 # some annoying header files
 269 #LYX_PATH_HEADER(stl_string_fwd.h)
 270 LYX_STL_STRING_FWD
 271
 272 # some standard structures
 273 AC_HEADER_STAT
 274 AC_HEADER_TIME
 275 AC_STRUCT_ST_BLKSIZE
 276 AC_STRUCT_ST_BLOCKS
 277 AC_STRUCT_ST_RDEV
 278
 279 # some standard types
 280 AC_TYPE_MODE_T
 281 AC_TYPE_OFF_T
 282 AC_TYPE_PID_T
 283 AC_TYPE_SIGNAL
 284 AC_TYPE_SIZE_T
 285 AC_TYPE_UID_T
 286
 287 # some functions we'd like to have
 288 AC_ARG_WITH(broken-headers,
 289     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 290     [lyx_broken_headers=$withval])
 291 if test "x$lyx_broken_headers" = "xyes"; then
 292   lyx_flags="$lyx_flags broken-headers"
 293   AC_DEFINE(BROKEN_HEADERS, 1,
 294     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 295 fi
 296 AC_CHECK_FUNCS(snprintf vsnprintf)
 297 LYX_CHECK_DECL(snprintf, stdio.h)
 298 LYX_CHECK_DECL(vsnprintf, stdio.h)
 299 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 300
 301 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo \
 302   mkstemp mktemp)
 303
 304 dnl Until this is fixed in autoconf we provide our own version
 305 LYX_FUNC_SELECT_ARGTYPES
 306
 307 dnl check whether we have to work around solaris broken putenv()
 308 LYX_FUNC_PUTENV_ARGTYPE
 309
 310 # SunOS 4.1.3 does not have strerror and atexit
 311 AC_REPLACE_FUNCS(strerror atexit)
 312
 313 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 314
 315 ### Some information on what just happened
 316 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 317 real_datadir=`eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 318 VERSION_INFO=`cat <<EOF
 319 Configuration\n\
 320   Host type:                      ${host_alias}\n\
 321   Special build flags:           ${lyx_flags}\n\
 322   C   Compiler:                   ${CC}\n\
 323   C   Compiler flags:             ${CFLAGS}\n\
 324   C++ Compiler:                   ${CXX} ${CXX_VERSION}\n\
 325   C++ Compiler flags:             ${CXXFLAGS}\n\
 326   Linker flags:                   ${LDFLAGS}\n\
 327   Frontend:                       ${lyx_use_frontend}\n\
 328 ${FRONTEND_INFO}\
 329   LyX binary dir:                 ${real_bindir}\n\
 330   LyX files dir:                  ${real_datadir}\n
 331 `
 332
 333 AC_SUBST(VERSION_INFO)
 334
 335 ### Finish the work.
 336 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 337 AC_OUTPUT([Makefile \
 338        boost/Makefile \
 339        development/lyx.spec \
 340        lib/Makefile \
 341        intl/Makefile \
 342        po/Makefile.in \
 343        sourcedoc/Doxyfile \
 344        src/Makefile \
 345        src/version.C \
 346        src/mathed/Makefile \
 347        src/graphics/Makefile \
 348        src/insets/Makefile \
 349        src/support/Makefile \
 350        src/frontends/Makefile \
 351        src/frontends/support/Makefile \
 352        src/frontends/controllers/Makefile \
 353        src/frontends/xforms/Makefile \
 354        src/frontends/qt2/Makefile \
 355        src/frontends/qt2/moc/Makefile \
 356        src/frontends/qt2/ui/Makefile \
 357        src/frontends/qt2/ui/moc/Makefile \
 358        src/frontends/gnome/Makefile \
 359 ])
 360
 361 # show version information
 362 echo
 363 printf "$VERSION_INFO"
 364 echo
 365
 366 # Display a final warning if there has been a LYX_ERROR
 367 LYX_CHECK_ERRORS