configure.in

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(src/main.C)
   4 AC_PREREQ(2.13) dnl We want to use autoconf 2.13
   5 AM_CONFIG_HEADER(src/config.h)
   6 dnl This is a trick to make autoheader do the right thing
   7 dnl AM_CONFIG_HEADER(src/config.h)
   8 AC_CONFIG_AUX_DIR(config)
   9 LYX_GET_VERSION(${srcdir}/src/version.h)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_VALIDATE_CACHE_SYSTEM_TYPE
  13
  14 LYX_VERSION_SUFFIX
  15
  16 AM_INIT_AUTOMAKE($lyxname, $VERSION)
  17
  18 # The list of languages known to LyX
  19 # This is needed by GNU gettext
  20 ALL_LINGUAS="ca cs da de es eu fi fr he hu it nl no pl pt ro ru sl sv tr wa"
  21
  22 AC_PREFIX_PROGRAM(lyx)
  23
  24 # fix the value of the prefixes.
  25 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  26 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  27
  28 ### Set the execute permissions of the various scripts correctly
  29 for file in config/install-sh config/mkinstalldirs lib/configure ; do
  30   chmod 755 ${srcdir}/${file}
  31 done
  32
  33 ### Check for programs
  34 AC_PROG_MAKE_SET
  35 AC_PROG_INSTALL
  36 #AC_PROG_RANLIB
  37 AC_CHECK_PROG(KPSEWHICH, kpsewhich, kpsewhich, :)
  38 if test "x$KPSEWHICH" = xkpsewhich ; then
  39     AC_DEFINE(HAVE_KPSEWHICH, 1,
  40     [Define this if you have the kpsewhich program working on your system.])
  41 fi
  42
  43 # Work around a problem in automake 1.4: when invoking install-strip,
  44 # INSTALL_PROGRAM is changed to 'install -s', and since
  45 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  46 # which returns an error condition when stripping fails.
  47 INSTALL_SCRIPT='${INSTALL}'
  48
  49 ### we will also need a C compiler to compile GNU gettext
  50 AC_PROG_CC
  51
  52 ### check for special systems
  53 AC_ISC_POSIX
  54 AC_AIX
  55 LYX_HPUX
  56 LYX_SUNOS4
  57 LYX_SCO
  58
  59 ### Check for program extensions (.exe or nothing)
  60 AC_EXEEXT
  61
  62 ### check which frontend we want to use
  63 LYX_USE_FRONTEND
  64 dnl The code below is not in a macro, because this would cause big
  65 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
  66 case "$lyx_use_frontend" in
  67   gnome)
  68     GNOME_INIT
  69     GNOME_COMPILE_WARNINGS
  70     GNOME_X_CHECKS
  71 esac
  72
  73 ### Check for a C++ compiler
  74 AC_LANG_CPLUSPLUS
  75 LYX_PROG_CXX
  76 AC_PROG_CXXCPP
  77 ### Some checks on what the C++ compiler can(not) do
  78 dnl we do not need that currently (and probably all our supported
  79 dnl compiler allow that)
  80 dnl LYX_CXX_PARTIAL
  81 LYX_CXX_EXPLICIT
  82 LYX_CXX_STL_STRING
  83 LYX_CXX_GOOD_STD_STRING
  84 LYX_CXX_CHEADERS
  85 LYX_CXX_GLOBAL_CSTD
  86 LYX_STD_COUNT
  87 dnl we disable rtti for now
  88 dnl LYX_CXX_RTTI
  89 AC_CHECK_HEADERS(ostream istream sstream locale limits)
  90 LYX_CXX_STL_MODERN_STREAMS
  91
  92 ### and now some special lyx flags.
  93 AC_ARG_ENABLE(assertions,
  94   [  --enable-assertions     add runtime sanity checks in the program],,
  95   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  96         enable_assertions=yes;
  97     else
  98         enable_assertions=no;
  99     fi;])
 100 if test "x$enable_assertions" = xyes ; then
 101    lyx_flags="$lyx_flags assertions"
 102    AC_DEFINE(ENABLE_ASSERTIONS,1,
 103     [Define if you want assertions to be enabled in the code])
 104 fi
 105
 106 ### We need a regex implementation, so we provide our own if none is found.
 107 LYX_REGEX
 108
 109 ### Library Files
 110 dnl by testing these we check if it is ok to have
 111 dnl -lc and -lm as args to the compiler
 112 AC_CHECK_LIB(m, sin)
 113 AC_CHECK_LIB(c, fopen)
 114 AC_ARG_WITH(aiksaurus,
 115   [  --without-aiksaurus     do not use the AikSaurus library],
 116   [lyx_use_aiksaurus=$withval])
 117 if test x$lyx_use_aiksaurus != xno; then
 118 AC_CHECK_LIB(AikSaurus, main,
 119         [AC_DEFINE(HAVE_LIBAIKSAURUS,,[Define this if you have the AikSaurus library])
 120          AIKSAURUS_LIBS="-lAikSaurus -lbz2"
 121         ],,"-lbz2")
 122 fi
 123 AC_SUBST(AIKSAURUS_LIBS)
 124
 125 ### Add extra directories to check for libraries.
 126 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
 127 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
 128 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 129
 130 ### Add extra directories to check for include files.
 131 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 132 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 133 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 134
 135 ### Add both includes and libraries
 136 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 137 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 138 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 139   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 140
 141 ### Check for the -liberty library
 142 test "x$GXX" = xyes && lyx_use_liberty=yes
 143 AC_ARG_WITH(liberty,
 144   [  --without-liberty       do not try to link against libiberty.a],
 145   [lyx_use_liberty=$withval])
 146 if test x$lyx_use_liberty = xyes; then
 147   # AC_CHECK_LIB(iberty,main,LIBS="-liberty $LIBS")
 148   AC_CHECK_LIB(iberty,main)
 149 fi
 150
 151 ### Setup libtool
 152 AC_DISABLE_SHARED
 153 AC_LIBTOOL_WIN32_DLL
 154 #AM_PROG_LIBTOOL
 155 LYX_PROG_LIBTOOL
 156
 157 ### Check which libsigc++ we're using
 158 LYX_WITH_SIGC
 159
 160 ### Check if we want pspell libraries
 161 CHECK_WITH_PSPELL
 162
 163 ### Check for X libraries
 164 # Check for the pt library (for SCO, needed for X)
 165 AC_CHECK_LIB(pt,ptsname,X_EXTRA_LIBS="-lpt $X_EXTRA_LIBS")
 166 # The real thing.
 167 AC_PATH_XTRA
 168 LIBS="$X_PRE_LIBS $LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
 169 # Since solaris X headers use int as implicit return type and modern
 170 # gcc's do not like that, let's use -isystem instead of -I.
 171 # We should test for gcc version and see whether it supports -isystem,
 172 # but since at least gcc 2.6.x supports it and it is still too old for
 173 # us, it seems we are safe.
 174 if test -n "$GXX" ; then
 175   X_CFLAGS=`echo ${X_CFLAGS} | sed -e 's/-I/-isystem /'`
 176 fi
 177 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 178
 179 ## Check whether X is new enough to handle the input method stuff
 180 AC_CHECK_FUNCS(XOpenIM)
 181
 182 ### check which frontend we want to use
 183 #LYX_USE_FRONTEND
 184 dnl The code below is not in a macro, because this would cause big
 185 dnl problems with the AC_REQUIRE contained in KDE_DO_IT_ALL.
 186 case "$lyx_use_frontend" in
 187   xforms)
 188   # for now don't set it for xforms as this is always entered
 189     FRONTEND=""
 190     FRONTEND_GUILIB="xforms/libxforms.la";;
 191   gnome)
 192     AM_PATH_GTKMM(1.2.1,,
 193         AC_MSG_ERROR(Cannot find GTK--: Please install Version 1.2.1+))
 194     AM_PATH_GNOMEMM
 195
 196 dnl ******************************
 197 dnl LibGlade checking
 198 dnl ******************************
 199 dnl Ensure gnome-config is available...
 200         AC_PATH_PROG(GNOME_CONFIG, gnome-config, no)
 201         AC_MSG_CHECKING(for Glade libraries)
 202         if $GNOME_CONFIG --libs libglade > /dev/null 2>&1; then
 203         AC_MSG_RESULT(found)
 204         else
 205             AC_MSG_ERROR(Did not find libGlade installed)
 206         fi
 207
 208     FRONTEND="gnome"
 209     FRONTEND_GUILIB="gnome/libgnome.la"
 210     FRONTEND_LDFLAGS="\$(GNOMEMM_LIBDIR)"
 211     FRONTEND_INCLUDES="-I\${srcdir}/gnome \$(GNOMEMM_INCLUDEDIR) \$(GTKMM_CFLAGS)"
 212     FRONTEND_LIBS="\$(GNOMEMM_LIBS) \$(GTKMM_LIBS) `gnome-config --libs libglade`";;
 213   qt2)
 214     QT2_DO_IT_ALL
 215     FRONTEND="qt2"
 216     FRONTEND_GUILIB="qt2/libqt2.la"
 217     FRONTEND_LDFLAGS="\$(QT2_LDFLAGS)"
 218     FRONTEND_INCLUDES="-I\${srcdir}/qt2 \$(QT2_INCLUDES)"
 219     FRONTEND_LIBS="\$(QT2_LIBS)";;
 220   *)
 221     LYX_ERROR(Unknown frontend $lyx_use_frontend);;
 222 esac
 223
 224 ### Check for xforms and xpm (only if X has been found).
 225 if test "$have_x" = yes ; then
 226 # We surely need these two libraries and want to check carefully the
 227 # version numbers...
 228 LYX_PATH_XPM
 229 LYX_PATH_XFORMS
 230 AC_SUBST(LYX_LIBS)
 231 else
 232 LYX_ERROR(dnl
 233 [Cannot find X window libraries and/or headers. Check your installation.
 234    If you use a Linux system, check that you have installed
 235    the development tools.])
 236 fi
 237
 238 ### Setup GNU gettext
 239 dnl GNU gettext is written in C
 240 AC_LANG_C
 241 # Some tests that may be useful for gettext
 242 AC_C_CONST
 243 AC_C_INLINE
 244 # Do the real setup now
 245 AM_GNU_GETTEXT
 246 # a hack for those who try to change LyX, but do not have gettext installed
 247 case  "${XGETTEXT}" in
 248  *:) XGETTEXT='cp ${srcdir}/lyx.pot ./${PACKAGE}.po ; :'
 249 esac
 250
 251 AC_SUBST(LINGUAS)
 252
 253 AC_LANG_CPLUSPLUS
 254
 255 # some standard header files
 256 AC_HEADER_DIRENT
 257 AC_HEADER_MAJOR
 258 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h)
 259
 260 # some annoying header files
 261 #LYX_PATH_HEADER(stl_string_fwd.h)
 262 LYX_STL_STRING_FWD
 263
 264 # some standard structures
 265 AC_HEADER_STAT
 266 AC_HEADER_TIME
 267 AC_STRUCT_ST_BLKSIZE
 268 AC_STRUCT_ST_BLOCKS
 269 AC_STRUCT_ST_RDEV
 270
 271 # some standard types
 272 AC_TYPE_MODE_T
 273 AC_TYPE_OFF_T
 274 AC_TYPE_PID_T
 275 AC_TYPE_SIGNAL
 276 AC_TYPE_SIZE_T
 277 AC_TYPE_UID_T
 278
 279 # some functions we'd like to have
 280 AC_ARG_WITH(broken-headers,
 281     [  --with-broken-headers   define some functions on SunOS4 and SCO],
 282     [lyx_broken_headers=$withval])
 283 if test "x$lyx_broken_headers" = "xyes"; then
 284   lyx_flags="$lyx_flags broken-headers"
 285   AC_DEFINE(BROKEN_HEADERS, 1,
 286     [Define on SunOS 4 and SCO, were some functions are missing from the headers])
 287 fi
 288 AC_CHECK_FUNCS(snprintf vsnprintf)
 289 LYX_CHECK_DECL(snprintf, stdio.h)
 290 LYX_CHECK_DECL(vsnprintf, stdio.h)
 291 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 292
 293 AC_CHECK_FUNCS(memmove memset strchr putenv setenv mkfifo \
 294   mkstemp mktemp)
 295
 296 dnl Until this is fixed in autoconf we provide our own version
 297 LYX_FUNC_SELECT_ARGTYPES
 298
 299 dnl check whether we have to work around solaris broken putenv()
 300 LYX_FUNC_PUTENV_ARGTYPE
 301
 302 # SunOS 4.1.3 does not have strerror and atexit
 303 AC_REPLACE_FUNCS(strerror atexit)
 304
 305 LYX_CHECK_DECL_HDRS(mkstemp,[unistd.h stdlib.h])
 306
 307 ### Finish the work.
 308 AC_CONFIG_SUBDIRS(sigc++ lib lib/reLyX)
 309 AC_OUTPUT([Makefile \
 310        boost/Makefile \
 311        development/lyx.spec \
 312        lib/Makefile \
 313        intl/Makefile \
 314        po/Makefile.in \
 315        sourcedoc/Doxyfile \
 316        src/Makefile \
 317        src/mathed/Makefile \
 318        src/graphics/Makefile \
 319        src/insets/Makefile \
 320        src/support/Makefile \
 321        src/frontends/Makefile \
 322        src/frontends/support/Makefile \
 323        src/frontends/controllers/Makefile \
 324        src/frontends/xforms/Makefile \
 325        src/frontends/qt2/Makefile \
 326        src/frontends/gnome/Makefile \
 327 ])
 328
 329
 330 cat <<EOF
 331
 332 Configuration:
 333   Source code location:       ${srcdir}
 334   C++ Compiler:                   ${CXX}
 335   C++ Compiler flags:             ${CXXFLAGS}
 336   C   Compiler:                   ${CC}
 337   C   Compiler flags:             ${CFLAGS}
 338   LyX binary dir:             `eval "echo \`eval \"echo ${bindir}\"\`"`
 339   LyX files dir:              `eval "echo \`eval \"echo ${datadir}/${PACKAGE}\"\`"`
 340   Special flags:              ${lyx_flags}
 341
 342 EOF
 343
 344 # Display a final warning if there has been a LYX_ERROR
 345 LYX_CHECK_ERRORS