configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,2.3.0dev,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_PRESERVE_HELP_ORDER
   5 # Use ISO format only. The frontend needs to parse this
   6 AC_SUBST(LYX_DATE, ["2016-04-16"])
   7 AC_PREREQ(2.60)
   8 AC_CONFIG_SRCDIR(src/main.cpp)
   9 AC_CONFIG_HEADERS([config.h])
  10
  11 AC_CONFIG_AUX_DIR(config)
  12
  13 # First check the version
  14 LYX_CHECK_VERSION
  15 LYX_VERSION_SUFFIX
  16 LYX_CHECK_QT5
  17 # Check how the files should be packaged
  18 AC_CANONICAL_TARGET
  19 LYX_USE_PACKAGING
  20 # We need to define these variables here and the no-define option of
  21 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  22 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  23
  24 dnl Default maintainer mode to true for development versions
  25 if test "${enable_maintainer_mode+set}" != set; then
  26   enable_maintainer_mode=$lyx_devel_version
  27 fi
  28 AM_MAINTAINER_MODE
  29
  30 save_PACKAGE=$PACKAGE
  31 dnl The test for _AM_PROG_CC_C_O intends to test for automake 1.14 or newer,
  32 dnl which are the versions where subdir-objects can beused.
  33 dnl see: https://www.mail-archive.com/lyx-devel@lists.lyx.org/msg181023.html
  34 m4_define([LYX_OBJECTS_LAYOUT], m4_ifdef([_AM_PROG_CC_C_O],[subdir-objects],))
  35 # Automake is pulling the historical V7 format. This tar format supports
  36 # file names only up to 99 characters. tar-ustar selects the ustar format defined
  37 # by POSIX 1003.1-1988. This format is believed to be old enough to be portable.
  38 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.8 tar-ustar] LYX_OBJECTS_LAYOUT)
  39 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  40 PACKAGE=$save_PACKAGE
  41
  42 # Allow to build some parts of the code as one big chunk
  43 m4_define([ALLPARTS],[boost,client,insets,mathed,core,tex2lyx,frontend_qt])
  44 AC_ARG_ENABLE(monolithic-build,
  45   AC_HELP_STRING([--enable-monolithic-build@<:@=LIST@:>@],
  46                 [Use monolithic build for modules in LIST (default: ALLPARTS)]),
  47   [test "$enable_monolithic_build" = yes && enable_monolithic_build="ALLPARTS"
  48    test "$enable_monolithic_build" = no && enable_monolithic_build=
  49    IFS="${IFS=  }"; ac_save_ifs="$IFS"; IFS=" ,"
  50    for i in $enable_monolithic_build ; do
  51        eval "enable_monolithic_$i=yes"
  52    done
  53    IFS="$ac_save_ifs"],
  54   [enable_monolithic_build=])
  55
  56 AM_CONDITIONAL(MONOLITHIC_BOOST, test "x$enable_monolithic_boost" = "xyes")
  57 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "x$enable_monolithic_client" = "xyes")
  58 AM_CONDITIONAL(MONOLITHIC_INSETS, test "x$enable_monolithic_insets" = "xyes")
  59 AM_CONDITIONAL(MONOLITHIC_MATHED, test "x$enable_monolithic_mathed" = "xyes")
  60 AM_CONDITIONAL(MONOLITHIC_CORE, test "x$enable_monolithic_core" = "xyes")
  61 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "x$enable_monolithic_tex2lyx" = "xyes")
  62 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT, test "x$enable_monolithic_frontend_qt" = "xyes")
  63
  64 ### Set the execute permissions of the various scripts correctly
  65 for file in config/install-sh ; do
  66   chmod 755 ${srcdir}/${file}
  67 done
  68
  69 # Find a suitable python interpreter
  70 LYX_PATH_PYTHON23([2.7.0], [3.3.0])
  71 # do the usual python setup stuff
  72 AM_PATH_PYTHON
  73
  74 # Tools for creating libraries (note that we do not use libtool)
  75 m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) dnl AM_PROG_AR requires automake 1.12
  76 AC_PROG_RANLIB
  77
  78 ### Check for a C++ compiler
  79 dnl We have to do weird tricks so that autoconf does not touch CXXFLAGS even
  80 dnl if it is not set. We do not use autoconf defaults.
  81 lyx_has_CXXFLAGS=${CXXFLAGS+yes}
  82 if ! test "$lyx_has_CXXFLAGS" = yes; then
  83   dnl set to a dummy value so that AC_PROG_CXX does not try to set CXXFLAGS
  84   CXXFLAGS=" "
  85 fi
  86 LYX_PROG_CXX
  87 if ! test "$lyx_has_CXXFLAGS" = yes; then
  88   unset CXXFLAGS
  89 fi
  90 AC_LANG(C++)
  91
  92 ### Objective-C compiler
  93 AC_PROG_OBJC
  94 _AM_DEPENDENCIES([OBJC])
  95
  96 ### Add extra directories to check for libraries.
  97 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  98 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  99 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
 100
 101 ### Add extra directories to check for include files.
 102 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 103 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 104 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 105
 106 ### Add both includes and libraries
 107 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 108 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 109   LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 110   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)
 111 ])
 112
 113 ### These are needed in windows
 114 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 115 AC_SUBST(LIBSHLWAPI)
 116 AC_CHECK_LIB(psapi, main, [LIBPSAPI=-lpsapi])
 117 AC_SUBST(LIBPSAPI)
 118 AC_CHECK_LIB(gdi32, main)
 119 AC_CHECK_LIB(ole32, main)
 120 test x"$WINDRES" = x && WINDRES=windres
 121 AC_SUBST(WINDRES)
 122
 123 LYX_USE_INCLUDED_BOOST
 124 LYX_USE_INCLUDED_MYTHES
 125
 126 ### we need to know the byte order for unicode conversions
 127 AC_C_BIGENDIAN
 128
 129 # Nice to have when an assertion triggers
 130 LYX_CHECK_CALLSTACK_PRINTING
 131
 132 # Needed for our char_type
 133 AC_CHECK_SIZEOF(wchar_t)
 134
 135 # Taken from gettext, needed for libiconv
 136 AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
 137    [AC_TRY_COMPILE([#include <stddef.h>
 138       wchar_t foo = (wchar_t)'\0';], ,
 139       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
 140 if test $gt_cv_c_wchar_t = yes; then
 141   AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
 142   HAVE_WCHAR_T=1
 143 else
 144   HAVE_WCHAR_T=0
 145 fi
 146 AC_SUBST([HAVE_WCHAR_T])
 147
 148 # Needed for Mingw-w64
 149 AC_TYPE_LONG_LONG_INT
 150 if test "$ac_cv_type_long_long_int" = yes; then
 151   AC_CHECK_SIZEOF(long)
 152   AC_CHECK_SIZEOF(long long)
 153 fi
 154
 155 ### We need iconv for unicode support (Qt4 frontend requires it too)
 156 LYX_USE_INCLUDED_ICONV
 157
 158 ### check for compression support
 159 LYX_USE_INCLUDED_ZLIB
 160
 161 ### check for file magic support (currently optional)
 162 AC_CHECK_HEADERS(magic.h,
 163  [AC_CHECK_LIB(magic, magic_open, [LIBS="$LIBS -lmagic"],
 164   LYX_WARNING([cannot find libmagic. Please check that the libmagic library
 165    is correctly installed on your system.
 166    Falling back to builtin file format detection.]))],
 167  [LYX_WARNING([cannot find magic.h. Please check that the libmagic library
 168    is correctly installed on your system.
 169    Falling back to builtin file format detection.])])
 170
 171 ### setup the qt frontend.
 172 dnl The code below is not in a macro, because this would cause big
 173 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 174 QT_DO_IT_ALL([4.5.0])
 175 AC_SUBST([FRONTENDS_SUBDIRS], [qt4])
 176 FRONTEND_INFO="${FRONTEND_INFO}\
 177   Qt Frontend:\n\
 178       Qt version:\t   ${QTLIB_VERSION}\n"
 179
 180 # fix the value of the prefixes.
 181 test "x$prefix" = xNONE && prefix=$default_prefix
 182 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 183 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 184   LYX_WARNING([the installation prefix \"${prefix}\" contains a space, which
 185    causes problems with the Makefiles. The installation will be done in
 186    directory \"`pwd`/installprefix\" instead. Please move its contents to
 187    the right place after installation.])
 188   prefix=`pwd`/installprefix
 189 fi
 190
 191 ### Setup po directory
 192 AM_NLS
 193 if test $USE_NLS = "yes" ; then
 194   AC_DEFINE(ENABLE_NLS, 1,
 195     [Define to 1 if translation of program messages to the user's native language
 196    is requested.])dnl'
 197 fi
 198 AM_PO_SUBDIRS
 199
 200 # some standard header files
 201 AC_HEADER_MAJOR
 202 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h locale.h utime.h sys/utime.h)
 203
 204 # some standard types
 205 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 206 AC_TYPE_OFF_T
 207 AC_TYPE_PID_T
 208 AC_TYPE_SIZE_T
 209 AC_TYPE_UID_T
 210
 211 LYX_CHECK_DEF(PATH_MAX, limits.h, [int n = PATH_MAX;])
 212
 213 AC_CHECK_FUNCS(chmod close _close fork getpid _getpid lockf lstat mkfifo open _open pclose _pclose popen _popen readlink putenv setenv strerror unsetenv)
 214 # Check the form of mkdir()
 215 AC_FUNC_MKDIR
 216 AC_FUNC_SELECT_ARGTYPES
 217
 218 LYX_CHECK_SPELL_ENGINES
 219
 220 lyx_client_subdir=true
 221 dnl AC_LANG_PUSH(C)
 222 dnl LIBS already contains some X extra libs that may interfere.
 223 save_LIBS="$LIBS"
 224 LIBS=
 225 AC_CHECK_FUNCS(fcntl,
 226   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 227    AC_SEARCH_LIBS([socket], [socket network], [],
 228      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 229                 [], [-lnsl])])],
 230   [lyx_client_subdir=false])
 231 AC_SUBST(SOCKET_LIBS,$LIBS)
 232 LIBS="$save_LIBS"
 233 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 234 dnl AC_LANG_POP(C)
 235
 236 lyx_win_res=false;
 237 case ${host} in
 238     *mingw*|*cygwin*) lyx_win_res=true;;
 239 esac
 240 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 241 LYX_SET_VERSION_INFO
 242
 243
 244 ### Some information on what just happened
 245 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 246 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 247 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 248 VERSION_INFO="Configuration\n\
 249   Host type:               ${host}\n\
 250   Special build flags:     ${lyx_flags}\n\
 251   C++ Compiler:            ${CXX} ${CXX_VERSION}\n\
 252   C++ Compiler flags:      ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 253   C++ Compiler user flags: ${CPPFLAGS} ${CXXFLAGS}\n\
 254   Linker flags:            ${AM_LDFLAGS}\n\
 255   Linker user flags:       ${LDFLAGS}\n\
 256 ${FRONTEND_INFO}\
 257   Packaging:               ${lyx_use_packaging}\n\
 258   LyX binary dir:          ${real_bindir}\n\
 259   LyX files dir:           ${real_pkgdatadir}\n"
 260
 261 AC_SUBST(VERSION_INFO)
 262 AC_SUBST(AM_CPPFLAGS)
 263 AC_SUBST(AM_CXXFLAGS)
 264 AC_SUBST(AM_LDFLAGS)
 265 AC_SUBST(real_pkgdatadir)
 266
 267 ## Some config.h stuff
 268
 269 AH_TOP([
 270 /* -*- C++ -*- */
 271 /*
 272  * \file config.h
 273  * This file is part of LyX, the document processor.
 274  * Licence details can be found in the file COPYING.
 275  *
 276  * This is the compilation configuration file for LyX.
 277  * It was generated by autoconfs configure.
 278  * You might want to change some of the defaults if something goes wrong
 279  * during the compilation.
 280  */
 281
 282 #ifndef _CONFIG_H
 283 #define _CONFIG_H
 284 ])
 285
 286 AH_BOTTOM([
 287 /************************************************************
 288  ** You should not need to change anything beyond this point */
 289
 290 #if __cplusplus >= 201103L || defined(__GXX_EXPERIMENTAL_CXX0X__)
 291 #define LYX_USE_CXX11
 292 #endif
 293
 294 #ifndef HAVE_STRERROR
 295 #if defined(__cplusplus)
 296 extern "C"
 297 #endif
 298 char * strerror(int n);
 299 #endif
 300
 301 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 302 #  define USE_BOOST_FORMAT 1
 303 #else
 304 #  define USE_BOOST_FORMAT 0
 305 #endif
 306
 307 #define BOOST_USER_CONFIG <config.h>
 308
 309 #if !defined(ENABLE_ASSERTIONS)
 310 #  define BOOST_DISABLE_ASSERTS 1
 311 #endif
 312 #define BOOST_ENABLE_ASSERT_HANDLER 1
 313
 314 #define BOOST_DISABLE_THREADS 1
 315 #define BOOST_NO_WREGEX 1
 316 #define BOOST_NO_WSTRING 1
 317 #define BOOST_SIGNALS_NO_DEPRECATION_WARNING 1
 318
 319 #ifdef __CYGWIN__
 320 #  define NOMINMAX
 321 #  define BOOST_POSIX 1
 322 #  define BOOST_POSIX_API 1
 323 #  define BOOST_POSIX_PATH 1
 324 #endif
 325
 326 #ifdef __sparc__
 327 #  ifndef __BIG_ENDIAN__
 328 #    define __BIG_ENDIAN__ 1
 329 #  endif
 330 #endif
 331
 332 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4
 333 #  define USE_WCHAR_T
 334 #endif
 335
 336 #ifdef HAVE_LONG_LONG_INT
 337 #if SIZEOF_LONG_LONG > SIZEOF_LONG
 338 #define LYX_USE_LONG_LONG
 339 #endif
 340 #endif
 341
 342 #endif
 343 ])
 344
 345 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 346 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 347 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 348
 349 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 350         "${lyx_abs_top_srcdir}", [Top source directory])
 351 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 352         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 353 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 354         "${lyx_abs_installed_datadir}",[Hard system support directory])
 355 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 356         "${version_suffix}",[Program version suffix])
 357
 358 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 359 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 360 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 361 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 362 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 363 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 364 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 365 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 366
 367 AC_CONFIG_FILES([Makefile \
 368       lyx.1:lyx.1in \
 369       3rdparty/Makefile \
 370       3rdparty/boost/Makefile \
 371       3rdparty/hunspell/Makefile \
 372       3rdparty/libiconv/Makefile \
 373       $ICONV_ICONV_H_IN \
 374       3rdparty/zlib/Makefile \
 375       autotests/Makefile \
 376       config/Makefile \
 377       development/Makefile \
 378       development/MacOSX/Makefile \
 379       development/MacOSX/Info.plist \
 380       development/MacOSX/lyxrc.dist \
 381       development/MacOSX/spotlight/Makefile \
 382       development/cygwin/Makefile \
 383       development/cygwin/lyxrc.dist \
 384       development/lyx.spec \
 385       lib/lyx.desktop-temp:lib/lyx.desktop.in
 386       lib/Makefile \
 387       lib/doc/Makefile \
 388       lib/lyx2lyx/lyx2lyx_version.py \
 389       lib/lyx2lyx/Makefile \
 390       m4/Makefile \
 391       po/Makefile.in \
 392       sourcedoc/Doxyfile \
 393       sourcedoc/Makefile \
 394       src/client/Makefile \
 395       src/client/lyxclient.1:src/client/lyxclient.1in \
 396       src/Makefile \
 397       src/tex2lyx/Makefile \
 398       src/tex2lyx/tex2lyx.1:src/tex2lyx/tex2lyx.1in \
 399       src/support/Makefile \
 400       src/frontends/Makefile \
 401       src/frontends/qt4/Makefile
 402 ])
 403
 404
 405 AC_OUTPUT
 406
 407 # show version information
 408 echo
 409 printf "$VERSION_INFO"
 410 echo
 411
 412 # Display a final warning if there has been a LYX_WARNING
 413 LYX_CHECK_WARNINGS
 414
 415 cat <<EOF
 416 Configuration of LyX was successful.
 417 Type 'make' to compile the program,
 418 and then 'make install' to install it.
 419 EOF